Vorgehensweise:
Referenz: |
Sie können eine Kopf- oder Fußzeile in einem StyleSheet linksbündig, rechtsbündig oder zentriert ausrichten. Kopf- und Fußzeilen sind per Default linksbündig ausgerichtet. Zusätzlich dazu können Sie eine individuelle Zeile oder mehrere Zeilen in einer Kopf- oder Fußzeile mit mehreren Zeilen ausrichten.
Um eine Seitenkopf- oder Seitenfußzeile über den Reportdaten zu zentrieren, können Sie eine Legacy-Format-Methode verwenden, für die keine StyleSheet benötigt wird; beziehen Sie einfach den Befehl CENTER in einem HEADING- oder FOOTING-Befehl mit ein.
Ausrichtung in HTML und PDF. Für HTML-Reports wird die Ausrichtung in Hinblick auf die Reportbreite implementiert. Das bedeutet, dass eine zentrierte Kopfzeile über dem Reportinhalt zentriert wird. Im Gegensatz hierzu ist der defaultmäßige Ausrichtungsbereich bei PDF-Reports die Seitenbreite und nicht die Reportbreite, was dazu führt, dass die Kopf- und Fußzeilen im Report nicht zentriert sind. In den meisten Fällen können Sie die auf dem Report basierende Ausrichtung in einem PDF-Report erreichen, indem Sie Ihrer Anfrage den Befehl SET SQUEEZE=ON hinzufügen. Dieser Befehl verbessert das Erscheinungsbild des Reports, indem unnötiger Platz zwischen Spalten entfernt wird und Ausrichtung über dem Reportinhalt implementiert wird. Falls die Kopfzeile jedoch breiter als der Report ist, wird diese im Verhältnis zur Seite zentriert, selbst wenn SQUEEZE=ON.
Tipp: Sie können die Syntax für das Ausrichten auch zusammen mit anderer StyleSheet-Syntax verwenden, um Kopf- und Fußzeilen sowie andere Elemente in ihnen mit anderen Reportelementen auszurichten, wobei dies entweder auf Messgrößen oder auf der Beziehung zu anderen Reportelementen basieren kann. Eine Zusammenfassung dieser Optionen finden Sie in Eine Ausrichtungsmethode für Kopf- und Fußzeilenelemente auswählen.
TYPE = headfoot, [LINE = line_#,] JUSTIFY = option, $
Hierbei gilt:
- headfoot
- Ist der Kopf- bzw. Fußzeilentyp. TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD und SUBFOOT sind gültige Werte.
- line_#
- Identifiziert optional eine Zeile über ihre Position in der Kopf- oder Fußzeile, so dass sie individuell ausgerichtet werden kann. Falls eine Kopf- oder Fußzeile mehrere Zeilen enthält und Sie diese Option weglassen, gilt der Wert von JUSTIFY für alle Zeilen.
- option
- Ist der Anordnungstyp. Gültige Werte sind:
LEFT richtet die Kopf- oder Fußzeile linksbündig aus. LEFT ist der Defaultwert.
RIGHT richtet die Kopf- oder Fußzeile rechtsbündig aus.
CENTER zentriert die Kopf- oder Fußzeile.
Ein alternative Methode für das Zentrieren einer Seitenkopf- oder -fußzeile ohne StyleSheets finden Sie unter Eine Seitenkopfzeile oder -fußzeile mit Legacy-Formatierung zentrieren.
Hinweis: JUSTIFY wird mit WRAP nicht unterstützt.
Diese Anfrage zentriert die Reportkopfzeile PRODUCT REPORT mit dem Attribut JUSTIFY = CENTER.
TABLE FILE GGPRODS
SUM UNITS BY PRODUCT_DESCRIPTION BY PRODUCT_ID BY VENDOR_NAME
ON TABLE SUBHEAD
"PRODUCT REPORT"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID=OFF, $
TYPE = REPORT, COLUMN = VENDOR_NAME, JUSTIFY = CENTER, $
TYPE = TABHEADING, JUSTIFY = CENTER, $
ENDSTYLE
END Die Ausgabe ist:
Tipp: Falls Sie diesen Report im PDF-Format ausführen möchten, fügen Sie den Code ON TABLE SET SQUEEZE ON hinzu, um überschüssige weiße Leerstellen zwischen den Spalten zu entfernen und den Inhalt über dem Report geeignet auszurichten.
Weitere Informationen über das Ausrichten eines Spaltentitels finden Sie unter Einen Spaltentitel ausrichten.
In dieser Anfrage ist die Kopfzeile 1 (SALES REPORT) zentriert, die Kopfzeile 2 (**CONFIDENTIAL**) ist auch zentriert und die Kopfzeile 3 (Dezember 2001) ist rechtsbündig ausgerichtet.
TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"SALES REPORT"
"**(CONFIDENTIAL)**"
"December 2001"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID=OFF, $
TYPE = TABHEADING, LINE = 1, JUSTIFY = CENTER, $
TYPE = TABHEADING, LINE = 2, JUSTIFY = CENTER, $
TYPE = TABHEADING, LINE = 3, JUSTIFY = RIGHT, $
ENDSTYLE
END Die Ausgabe ist:
Tipp: Fügen Sie, falls Sie diesen Report im PDF-Format ausführen möchten, den Code ON TABLE SET SQUEEZE ON hinzu, um unnötigen Platz zwischen Spalten zu entfernen und den Inhalt über dem Report zu zentrieren.
Diese Anfrage zentriert alle Zeilen in einer mehrzeiligen Reportkopfzeile mit einem einzigen StylsSheet-Attribut für die gesamte Kopfzeile.
TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"SALES REPORT"
"**(CONFIDENTIAL)**"
"December 2001"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID=OFF, $
TYPE = TABHEADING, JUSTIFY = CENTER, $
ENDSTYLE
END Die Ausgabe ist:
Tipp: Fügen Sie, falls Sie diesen Report im PDF-Format ausführen möchten, den Code ON TABLE SET SQUEEZE ON hinzu, um unnötigen Platz zwischen Spalten zu entfernen und den Inhalt über dem Report zu zentrieren.
Der Bereich, in dem Text ausgerichtet wird, hängt von der Beziehung der Größen bestimmter Elemente im Report ab:
- Wenn SQUEEZE=ON (der Default) eingestellt wurde, wird die maximale Breite aller Kopfzeilentypen im Report berechnet. Dieser Wert wird MaxHeadWidth genannt.
Wenn MaxHeadWidth kleiner als oder gleich der gesamten Breite aller Spalten des Reports ist, werden Kopfzeilen im Bereich über den Reportspalten ausgerichtet.
Wenn MaxHeadWidth über die gesamte Breite aller Spalten des Report hinausgeht, werden Kopfzeilen zentriert und rechtsbündig in Bezug zur gesamten Breite der Seite ausgerichtet.
- Wenn SQUEEZE=OFF, ist die Maximalbreite aller Kopfzeilen nicht vorberechnet. Kopfzeilen sind zentriert in der Gesamtmitte der Seite.
In einem Report mit Styling und mehreren Panels (bei denen die Breite eine Seite überschreitet) können Kopfzeilen nur im ersten Panel angezeigt werden. Daher beziehen sich die vorhergehenden Berechnungen auf die Gesamtbreite der Spalten im ersten Panel und nicht auf die Gesamtbreite aller Spalten im Report.
{HEADING|FOOTING} CENTER
"content ... "
["content ... "]
.
.
.
["content ... "] Hierbei gilt:
- HEADING
- Ist eine Seitenkopfzeile.
- FOOTING
- Ist eine Seitenfußzeile.
- CENTER
- Zentriert die Seitenkopfzeile oder -fußzeile über oder unter den Reportdaten.
- Inhalte
- Kopf- oder Fußzeilen können die folgenden Elemente zwischen doppelten Anführungszeichen enthalten. Wenn das schließende Anführungszeichen weggelassen wird, werden alle folgenden Zeilen der Anfrage als Teil der Kopf- oder Fußzeile behandelt.
-
- Text
- Ist Text für die Kopf- oder Fußzeile. Sie können mehrere Textzeilen aufnehmen.
Der Text muss in seiner eigenen Zeile beginnen und dem HEADING- oder FOOTING-Befehl folgen.
Text kann mit Variablen und Platzmarkierungen kombiniert werden.
Zugehörige Informationen finden Sie in Beschränkungen für Kopf- und Fußzeilen.
- variable
- Kann eine oder mehrere der folgenden Möglichkeiten sein:
Felder (reale Datenquellen-Felder, die mit dem DEFINE-Befehl in einer Masterdatei oder Reportanfrage erstellt wurden; berechnete Werte, die mit dem COMPUTE-Befehl in einer Anfrage erstellt wurden; ein Systemfeld wie z. B. TABPAGENO). Sie können Datenquellenfelder mit bestimmten Präfixoperatoren qualifizieren.
Dialogue Manager variables.
Bilddateien. Sie können Bilder in eine Kopf- oder Fußzeile aufnehmen.
Genaueres finden Sie unter Ein Element in eine Kopf- oder Fußzeile aufnehmen.
- Platzmarkierung
- Ermöglicht es Ihnen, Elemente zu positionieren, Elemente zu identifizieren, die formatiert werden sollen, und Code über die Begrenzung von 80 Zeichen hinaus zu verlängern, die im Texteditor besteht.
<+0> unterteilt eine Kopf- oder Fußzeile in Elemente für Formatierung. Genaueres finden Sie unter Eine Kopfzeile, eine Fußzeile, einen Titel oder FML-Freitext identifizieren.
</n gibt übersprungene Zeilen an. Details finden Sie in Die vertikale Position einer Kopf- oder Fußzeile steuern.
<-n, um das nächste Zeichen in der Zeile zu positionieren. Details finden Sie in Platzmarkierungen verwenden, um die Positionierung zu verfeinern.
<0X führt eine Kopf- oder Fußzeilen-Spezifikation in der nächsten Zeile der Anfrage fort. Details finden Sie in Kopf- und Fußzeilencode auf mehrere Zeilen in einer Reportanfrage erweitern.
Hinweis: Wenn auf eine schließende Platzmarkierung direkt eine öffnende folgt (><), wird zwischen den Platzmarkierungen eine Leerstelle platziert (> <). Dies muss beachtet werden, wenn Formatierung angewendet wird.
- Leerzeilen
- Wenn Sie jeglichen Text, jegliche Variablen und Platzmarkierungen weglassen, dann haben Sie eine leere Kopf- oder Fußzeile (z. B. '' ''), die Sie verwenden können, um eine Zeile im Kopf oder Fuß zu überspringen. (Sie können eine Zeile auch überspringen, indem Sie eine vertikale Platzmarkierung wie z. B. </1 verwenden.)
Tipp: Verwenden Sie nicht den Befehl CENTER mit dem StyleSheet-Attribut JUSTIFY = CENTER. Eine einzige Methode erzeugt das gewünschte Ergebnis.
Diese Anfrage verwendet den Befehl CENTER in der Seitenkopfzeilensyntax.
TABLE FILE EMPLOYEE
HEADING CENTER
"ACCOUNT REPORT FOR DEPARTMENT <DEPARTMENT"
PRINT CURR_SAL BY DEPARTMENT BY HIGHEST BANK_ACCT
BY EMP_ID
ON DEPARTMENT PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET WEBVIEWER ON
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, SIZE=10, GRID=OFF,$
ENDSTYLE
END Die Seitenkopfzeile ist zentriert über den Reportdaten, wie es auf der ersten Seite der Ausgabe zu sehen ist.
Tipp: Wenn Sie die Navigationspfeile nicht verwenden, klicken Sie auf den Button Maximieren.
