x

fieldname [AND] ROW-TOTAL[/justification][/format] [AS 'label'] 
fieldname [AND] COLUMN-TOTAL[/justification] [AS 'label']

oder

fieldname [AND] COLUMN-TOTAL[/justification] [AS 'label']

Hierbei gilt:

fieldname

Ist ein Feld, das in einem Anzeigebefehl genannt wird.

justification

Ist die Ausrichtung des Labels. Gültige Werte sind:

L platziert das Label links.

R platziert das Label rechts.

C zentriert das Label.

Zugehörige Informationen finden Sie unter Ein Label für eine Zeilen- oder Spaltensumme ausrichten..

Format

Ist das Format der Zeile oder Spaltensumme. Wenn Felder mit demselben Format summiert werden, ist das Format der Summe identisch mit dem Format der Felder. Wenn Felder mit unterschiedlichen Formaten summiert werden, wird der Default D12.2 für die Zeilen- oder Spaltensumme verwendet.

Label

Ist die angepasste Zeile oder Spaltensummenlabel. Das Default-Label ist TOTAL.

Sie können eine Zeilen- oder Spaltensumme auch mit einer ON TABLE-Phrase angeben. Bei dieser Syntax können Sie keine Feldnamen mit ROW-TOTAL aufnehmen. Feldnamen sind mit COLUMN-TOTAL optional.

ON TABLE ROW-TOTAL[/justification][/format] [AS 'label']
ON TABLE COLUMN-TOTAL[/justification] [AS 'label']
 [fieldname fieldname fieldname]

Wenn eine Anfrage ein Feld mit COMPUTE abfragt, wird der Wert dieses Feldes in eine Zeilen- oder Spaltensumme aufgenommen. Beachten Sie dies, wenn Sie ein Label anpassen, das die Summe identifiziert.

Nach oben

Beispiel: Ein Label für eine Zeile und Spaltensumme erstellen

Diese Anfrage erstellt das Label Gesamtbevölkerung nach Staat für die Zeilensumme, und das Label Gesamtbevölkerung nach Geschlecht für die Spaltensumme. Das Format D12 für ROW-TOTAL zeigt diese Daten mit Kommas an.

TABLE FILE GGDEMOG
PRINT MALEPOP98 FEMPOP98 
ROW-TOTAL/D12 AS 'Total Population by State' 
BY ST
WHERE (ST EQ 'WY' OR 'MT') 
ON TABLE COLUMN-TOTAL AS 'Total Population by Gender' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Ausgabe ist:

Nach oben

Beispiel: Ein Zeilensumme-Label mit ACROSS erstellen

Diese Anfrage fügt die Bevölkerungen von zwei Staaten hinzu, sortiert die Informationen mit der ACROSS-Phrase und beschriftet die Zeilensummen mit Gesamt pro Geschlecht. Es gibt zwei Zeilensummen innerhalb der Spalte Gesamt pro Geschlecht, und zwar Männliche Bevölkerung und Weibliche Bevölkerung.

TABLE FILE GGDEMOG
SUM MALEPOP98/D12 FEMPOP98/D12 
ROW-TOTAL AS 'Total by Gender'  
ACROSS ST
WHERE ST EQ 'WY' OR 'MT';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Ausgabe ist:

x

{BY|ON} fieldname {SUB-TOTAL|SUBTOTAL|COLUMN-TOTAL} [MULTILINES]
        [field1 [AND] field2...] [AS 'label'] [WHEN expression;]

Hierbei gilt:

fieldname

Ist ein Sortierfeld, das in einer BY- oder ON-Phrase genannt wird.

MULTILINES

Unterdrückt eine Zwischensumme, wenn es an einem Sortierumbruch nur einen Wert gibt. Nachdem es angegeben wurde unterdrückt MULTILINES die Zwischensumme für jeden Sortierumbruch mit nur einer Detailzeile. MULTI-LINES ist ein Synonym für MULTILINES.

field1 field2

Sind bestimmte Felder, für die eine Zwischensumme erstellt wird. Ein angegebenes Feld überschreibt den Default, der alle numerischen Anzeigefelder beinhaltet.

AS 'label'

Ist das angepasste Label für die Zwischensumme. Sie können das Default-Label für ein Sortierfeld einer höheren Ebene nicht ändern, wenn Sie SUB-TOTAL verwenden.

WHEN-Formel

Gibt eine bedingte Zwischensumme an, wie es durch eine logische Formel festgelegt wird. Details finden Sie in Formeln verwenden.

Nach oben

Beispiel: Eine Label für eine Zwischen- und eine Gesamtsumme erstellen

Diese Anfrage erstellt ein angepasstes Label für die Zwischensumme, welche der gesamte Dollarbetrag ist, der pro Abteilung vom Gehalt der Angestellten für Gemeindesteuern abgezogen wird; und für die Gesamtsumme, welche der gesamte Dollarbetrag für beide Abteilungen ist.

TABLE FILE EMPLOYEE
SUM DED_AMT BY DED_CODE BY DEPARTMENT
BY BANK_ACCT
WHERE DED_CODE EQ 'CITY'
WHERE BANK_ACCT NE 0 
ON DEPARTMENT SUBTOTAL AS 'Total City Deduction for'
ON TABLE COLUMN-TOTAL AS '**GRAND TOTAL**' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

In der Ausgabe werden die Abteilungswerte MIS und PRODUCTION per Default in das angepasste Zwischensummen-Label aufgenommen.

Nach oben

Beispiel: Ein Label für die Zwischensumme eines spezifischen Feldes erstellen

Diese Anfrage erstellt ein angepasstes Label (Gesamtbestellung) für die Zwischensumme für LINEPRICE. Sie verwendet das Default-Label TOTAL für die Gesamtsumme.

TABLE FILE CENTORD
PRINT PNUM QUANTITY LINEPRICE 
BY ORDER_NUM SUBTOTAL LINEPRICE AS 'Order Total' 
WHERE ORDER_NUM EQ '28003' OR '28004';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Ausgabe ist:

x

{BY|ON} fieldname {SUMMARIZE|RECOMPUTE} [MULTILINES]
        [field1 [AND] field2...] [AS 'label'] [WHEN expression;]
ON TABLE {SUMMARIZE|RECOMPUTE}

Hierbei gilt:

fieldname

Ist ein Sortierfeld, das in einer BY- oder ON-Phrase genannt wird.

MULTILINES

Unterdrückt eine Zwischensumme, wenn es an einem Sortierumbruch nur einen Wert gibt. Nachdem es angegeben wurde unterdrückt MULTILINES die Zwischensumme für jeden Sortierumbruch mit nur einer Detailzeile. MULTI-LINES ist ein Synonym für MULTILINES.

field1 field2

Sind bestimmte Felder, für die eine Zwischensumme erstellt wird. Angegebene Felder überschreiben den Default, der alle numerischen Anzeigefelder beinhaltet.

AS 'label'

Ist das angepasste Label für die Zwischensumme. Sie können das Default-Label für ein Sortierfeld einer höheren Ebene nicht ändern, wenn Sie SUMMARIZE verwenden.

WHEN-Formel

Gibt eine bedingte Zwischensumme an, wie es durch eine logische Formel festgelegt wird. Details finden Sie in Formeln verwenden.

Sie können eine Zwischensumme auch mit der Phrase ON TABLE erzeugen:

ON TABLE {SUMMARIZE|RECOMPUTE}

Nach oben

Beispiel: Ein Label für die Zwischensumme eines berechneten Werts erstellen

Diese Anfrage erstellt ein angepasstes Label für die Zwischensumme, einschließlich der Berechnung für das Feld DG_RATIO, erstellt mit COMPUTE.

TABLE FILE EMPLOYEE
SUM GROSS DED_AMT AND COMPUTE
DG_RATIO/F4.2 = DED_AMT / GROSS;
BY DEPARTMENT BY BANK_ACCT
WHERE BANK_ACCT NE 0 
ON DEPARTMENT SUMMARIZE AS 'SUBTOTAL FOR ' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

In der Ausgabe werden die Abteilungswerte MIS und PRODUCTION per Default in das angepasste Zwischensummen-Label aufgenommen. Das defaultmäßige Label für die Gesamtsumme ist TOTAL.