Vorgehensweise: |
Sie können einen Feldnamen in Kopfzeilentext oder Fußzeilentext aufnehmen. Wenn die Anfrage ausgeführt wird, enthält die Ausgabe den Feldwert. Das Ergebnis ist eine angepasste Kopf- oder Fußzeile mit spezifischer Datenidentifikation für den Benutzer.
Sie können diese Methode zwar in jedem Report verwenden, aber sie ist essenziell, wenn Sie einen Freiform-Report erstellen. Details finden Sie unter Einen Freiform-Report erstellen.
Bei Anfragen mit mehreren Gruppen von Anzeige- und Sortierfeldern, werden Felder in einer fields in einer Reportkopfzeile oder Reportfußzeile oder Seitenkopfzeile oder Seitenfußzeile ausgewertet, als ob sie Objekte des ersten Anzeigebefehls wären. Felder in einer Sortierkopfzeile oder einer Sortierfußzeile werden als Teil des ersten Anzeigebefehls bewertet, in dem auf sie verwiesen wird. Wenn auf ein Feld nicht verwiesen wird, wird es als Teil des letzten Anzeigebefehls ausgewertet.
Sie können einen Präfixoperator verwenden, um einen Feldwert in einer Kopf- oder Fußzeile abzuleiten. Eine Liste der Berechnungen, die Sie mit Präfixoperatoren durchführen können, finden Sie unter Reportdaten anzeigen.
Zwei Operatoren wurden speziell für die Verwendung mit einer Sortierfußzeile konzipiert:
- ST. erzeugt einen Zwischensummenwert eines numerischen Feldes an einem Sortierumbruch in einem Report. Ein Beispiel finden Sie unter Einen Feldwert über mehrere Spalten hinweg ausrichten.
- CT. erzeugt eine kumulative Summe eines numerischen Feldes.
<[prefix_operator]fieldname<fieldname[>]
oder
<fieldname[>] Hierbei gilt:
- <fieldname
- Platziert den Feldwert in die Kopf- oder Fußzeile und unterdrückt nachgestellte Leerzeichen in einem alphanumerischen Feld für alle Werte, falls SET STYLEMODE.
- <fieldname>
- Platziert den Feldwert in die Kopf- oder Fußzeile und behält nachgestellte Leerzeichen in einem alphanumerischen Feld bei, falls SET STYLEMODE = FIXED. Unterdrückt nachgestellte Leerzeichen für alle anderen Werte von SET STYLEMODE. PDF-Ausgabe behält nachgestellte Leerzeichen bei, unabhängig von der Einstellung STYLEMODE.
- prefix_operator
- Führt eine Berechnung direkt mit dem Wert eines Feldes durch. Ein Präfixoperator wird auf ein einzelnes Feld angewendet, und wirkt sich nur auf dieses Feld aus.
Diese Anfrage enthält den Feldnamen DEPARTMENT sowohl im Seitenkopfzeilentext als auch im Seitenfußzeilentext. Der Befehl HEADING wird in der Anfrage nicht benötigt, da der Text der Seitekopfzeile vor dem PRINT-Befehl angezeigt wird.
TABLE FILE EMPLOYEE "<DEPARTMENT : BANK, EMPLOYEES AND SALARIES" PRINT CURR_SAL BY DEPARTMENT NOPRINT BY BANK_ACCT BY LAST_NAME BY FIRST_NAME ON DEPARTMENT PAGE-BREAK FOOTING "<DEPARTMENT EMPLOYEES WITH ELECTRONIC TRANSFER ACCOUNTS" ON TABLE SET ONLINE-FMT HTML ON TABLE SET WEBVIEWER ON ON TABLE SET PAGE-NUM OFF ON TABLE SET STYLESHEET * TYPE=REPORT, GRID=OFF, $ ENDSTYLE END
Die Ausgabe zeigt die Ausgabe für einen mehrseitigen HTML-Report an. Auf der ersten Ausgabeseite ist der Wert von DEPARTMENT in der Seitenkopfzeile und Seitenfußzeile MIS.
Auf der zweiten Ausgabeseite ist der Wert von DEPARTMENT PRODUCTION.
Hinweis: Wenn Sie die Navigationspfeile nicht sehen, klicken Sie bitte auf den Button Maximieren.
Nachgestellte Leerzeichen werden in standardmäßiger HTML-Ausgabe nicht beibehalten. Wenn der Ausgabetyp HTML ist, ist STYLEMODE per Default auf FULL eingestellt. Um nachgestellte Leerzeichen im alphanumerischen Feld DEPARTMENT beizubehalten, wurde die Einstellung STYLEMODE in dieser Anfrage in FIXED geändert und die Trennzeichen < und > wurden im Sortierfußzeilentext um den Feldnamen herum aufgenommen.
SET STYLEMODE = FIXED
TABLE FILE EMPLOYEE
SUM SALARY
BY DEPARTMENT SUBFOOT
"<DEPARTMENT> DEPARTMENT TOTAL SALARY IS <SALARY"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END Werte für DEPARTMENT werden in der Sortierfußzeile als MIS und PRODUCTION angezeigt.
Hinweis: SET STYLEMODE=FIXED deaktiviert die HTML-Formatierung Ihres Browsers für diesen Report. Der sich ergebende Report wird in einer festgelegten Schriftart und ohne Farben oder anderen Web-Fähigkeiten angezeigt.
Diese Anfrage verwendet den Präfixoperator TOT, um Gesamtsummen für drei Felder zu erzeugen.
DEFINE FILE SALES
ACTUAL_SALES/D8.2 = UNIT_SOLD - RETURNS;
SALES/F5.1 = 100 * ACTUAL_SALES / UNIT_SOLD;
END
TABLE FILE SALES
"SUMMARY OF ACTUAL SALES"
"UNITS SOLD <TOT.UNIT_SOLD"
"RETURNS <TOT.RETURNS"
"TOTAL SOLD <TOT.ACTUAL_SALES"
" "
"BREAKDOWN BY PRODUCT"
PRINT UNIT_SOLD AND RETURNS AND ACTUAL_SALES
BY PROD_CODE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END Die Summen werden in der Seitenkopfzeile angezeigt.
Diese Anfrage verwendet die Präfixoperatoren MAX, MIN, AVE und TOT. Sie erfordert keinen Anzeigebefehl, da der Seitenkopfzeilentext Datenfelder enthält.
TABLE FILE SALES
"MOST UNITS SOLD WERE <MAX.UNIT_SOLD"
"LEAST UNITS SOLD WERE <MIN.UNIT_SOLD"
"AVERAGE UNITS SOLD WERE <AVE.UNIT_SOLD"
"TOTAL UNITS SOLD WERE <TOT.UNIT_SOLD"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END Die Präfixoperatoren erzeugen Summendaten in der Seitenkopfzeile.
Diese Anfrage verwendet die Präfixoperatoren CNT und AVE in einer Sortierfußzeile. Die Ausgabe enthält keine Datenspalten. Es sind alle Daten in der Sortierfußzeile selbst enthalten.
TABLE FILE EMPLOYEE
BY DEPARTMENT NOPRINT SUBFOOT
"NUMBER OF EMPLOYEES IN DEPARTMENT <DEPARTMENT = <CNT.LAST_NAME"
"WITH AVERAGE SALARY OF <AVE.CURR_SAL"
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END Die Sortierfußzeile ist ein zusammenfassender Report über die Anzahl der Angestellten in einer Abteilung und deren durchschnittliches Gehalt.
Die Präfixoperatoren erzeugen Summendaten in der Seitenkopfzeile.
NUMBER OF EMPLOYEES IN DEPARTMENT MIS = 6 WITH AVERAGE SALARY OF $18,000.33 NUMBER OF EMPLOYEES IN DEPARTMENT PRODUCTION = 6 WITH AVERAGE SALARY OF $19,047.00
