Microsoft hat das Format und die Struktur der Excel-Arbeitsmappe in Excel 2007 geändert. Die neue .xlsx-Datei ist eine binäre Kompilierung einer Gruppe von xml-Dateien. Um dieses neue Dateiformat mit WebFOCUS zu erzeugen, sind zwei Schritte nötig, die daraus bestehen, dass die xml-Dateien erzeugt werden, die die Reportausgabe enthalten, und die xml-Dokumente in das binäre .xlsx-Format komprimieren. Der Reporting Server führt die Erzeugung von xml durch. Die Komprimierung kann entweder der Client (WebFOCUS Servlet) oder der Server (JSCOM3) durchführen:

• WebFOCUS Servlet. Der WebFOCUS Client im Anwendungsserver führt die Komprimierung durch. Dies kann im lokalen Client oder über einen Client durchgeführt werden, auf den fernzugegriffen wird. Die Servlet-Methode ist die defaultmäßige Herangehensweise, die für jeden WebFOCUS Client definiert ist, wobei der Client per Default auf sich selbst verweist.
• JSCOM3. Der Java-Layer des Reporting Servers führt die Komprimierung durch. Diese Option kann verwendet werden in gesicherten Umgebungen, da sie keinen URL-Zugriff auf einen Remote-Client erfordert.

Sie weisen die Methode und Stelle zu, wo die Komprimierung stattfindet, indem Sie EXCELSERVURL auf eine URL (für das WebFOCUS Servlet) oder auf ein Leerzeichen (für JSCOM3) einstellen. Sie können diesen Wert für eine spezifische Prozedur einstellen oder für die gesamte Umgebung:

• Für eine Prozedur. Geben Sie den Befehl SET EXCELSERVURL innerhalb der Prozedur aus.
• Für die gesamte Umgebung. Bearbeiten Sie die Variable IBIF_excelservurl in der WebFOCUS-Administrationskonsole, indem Sie Folgendes auswählen:

  Configuration/Client Settings/General/IBIF_excelservurl

  Weitere Informationen dazu, wie Sie auf die WebFOCUS-Administrationskonsole zugreifen und die Variable IBIF_excelservurl einstellen, finden Sie im Handbuch WebFOCUS-Sicherheit und -Administration.

Der Wert, den Sie EXCELSERVURL zuweisen, bestimmt, ob das WebFOCUS Servlet oder JSCOM3 die Komprimierung durchführt:

• Das Servlet angeben. Um anzugeben, dass das WebFOCUS-Servlet verwendet werden soll, stellen Sie den Parameter EXCELSERVURL oder die IBIF_variable auf die URL einer WebFOCUS 7.7.02 Client-Konfiguration oder höher ein. Beispiel,

  In einer Prozedur:

  SET EXCELSERVURL = http://servername:8080/ibi_apps									

  In der WebFOCUS-Administrationskonsole:

  IBIF_excelservurl = http://servername:8080/ibi_apps									

• JSCOM3 angeben. Um anzugeben, dass JSCOM3 innerhalb des aktuallen Reporting Servers verwendet werden sollte, stellen Sie EXCELSERVURL auf leer oder eine leere Zeichenfolge ein.

  In einer Prozedur:

  SET EXCELSERVURL = ''

  In der WebFOCUS-Administrationskonsole:

  IBIF_excelservurl = ''

Per Default enthält jeder WebFOCUS Client die folgende URL-Definition, die auf sich selbst verweist:

&URL_PROTOCOL://&SERVER_NAME:&SERVER_PORT&IBIF_webapp

Sie können angeben, dass ein Report als Excel 2007/2010-Arbeitsmappe gespeichert werden soll, im Browser angezeigt werden soll oder in der Excel 2007/2010-Anwendung.

ON TABLE {PCHOLD|HOLD} AS name FORMAT EXL07

Hierbei gilt:

PCHOLD

Zeigt die erzeugte Arbeitsmappe entweder im Browser oder der Excel 2007/2010-Anwendung an, basierend auf Ihren Desktop-Einstellungen. Informationen finden Sie unter Excel-Arbeitsmappen im Browser oder in der Excel-Anwendung anzeigen.

HOLD

Speichert eine Arbeitsmappe mit einer .xlsx-Erweiterung an der festgelegten Stelle.

name

Gibt einen Dateinamen für die erzeugte Arbeitsmappe an.

Hinweis: Der AS-Name wird für PCHOLD nur verwendet, wenn die Option Report speichern auf YES eingestellt ist für die .xlsx-Dateierweiterung in den Umleitungseinstellungen des WebFOCUS Client. Wenn der Report im Browser geöffnet wird, werden Benutzer aufgefordert, die Reportausgabe mit dem designierten Dateinamen zu speichern. Für Reports, die in der Excel 2007/2010-Anwendung geöffnet werden, behält die erzeugte Arbeitsmappe den designierten AS-Namen bei. Weitere Informationen entnehmen Sie bitte dem Handbuch WebFOCUS-Sicherheit und -Administration.

Excel 2000 und Excel 2003 können mit dem Microsoft Office Compatibility Pack aktualisiert werden, so dass sie Excel 2007- oder 2010-Arbeitsmappen lesen können. Dies ist auf der Microsoft-Site für Downloads verfügbar (http://www.microsoft.com/downloads/en/default.aspx). Wenn die Dateierweiterung der Datei, die geöffnet wird, .xlsx (Excel 2007/2010-Arbeitsmappe) ist, führt das Microsoft Office Compatibility Pack die nötige Umwandlung durch, um zu ermöglichen, dass Excel 2000/2003 sie lesen und öffnen kann.

Es ist wichtig, dass Sie zusätzlich zum Microsoft Office Compatibility Pack die Option Speichern als in den WebFOCUS Client-Umleitungseinstellungen aktivieren, so dass Excel 2000/2003 die Excel 2007/2010-Reportausgabe öffnen kann, ohne dass sie zuerst auf dem Rechner mit der Dateierweiterung .xlxs gespeichert werden muss. Die Option Speichern als in den WebFOCUS Client-Umleitungseinstellungen konfiguriert, wie der WebFOCUS Client die jeweiligen Reportausgabedateitypen an den Rechner des Benutzers sendet. Diese Option kann wie folgt eingestellt werden:

• Option Speichern als deaktiviert (NO). Die Umleitungseinstellung des WebFOCUS Client Speichern als ist per Default deaktiviert. Wenn die Option Speichern als deaktiviert ist, sendet der WebFOCUS Client die Reportausgabe an den Rechner des Benutzers im Speicher, wobei die Anwendungszuordnung für das Reportformat in der Konfigurationsdatei (mime.wfs) der WF Client-Umleitungseinstellungen angegeben ist.

  Die Anwendungszuordnung für Excel 2007/2010 lautet:

  application/vnd.openxmlformats-officedocument.spreadsheetml.sheet

  Der Rechner eines Benutzers, auf dem Excel 2007/2010 nicht installiert ist, erkennt die Anwendungszuordnung für Excel 2007/2010 nicht und zeigt die folgende Meldung an:

  

  Der Benutzer von Excel 2000/2003 kann Speichern auswählen und einen Dateinamen bereitstellen mit der Erweiterung .xlsx, um die Reportausgabe auf seinem Rechner zu speichern. Der Benutzer kann dann die .xlsx-Datei direkt mit Excel 2000/2003 öffnen.

• Option Speichern als aktiviert (YES). Wenn die WebFOCUS-Umleitungsoption Speichern als aktiviert ist, sendet der WebFOCUS Client die Reportausgabe an den Benutzer als eine Datei mit der Erweiterung, die in der Konfigurationsdatei (mime.wfs) der WebFOCUS Client-Umleitungseinstellungen angegeben ist.

  Wenn Windows die Datei erhält, wird die Datei herunterladen-Eingabeaufforderung angezeigt, die den Benutzer dazu auffordert, die Datei mit dem gekennzeichneten Anwendungstyp zu Öffnen oder zu Speichern. Wie es in der folgenden Abbildung zu sehen ist, zeigt die Datei herunterladen-Eingabeaufforderung den Namen mit der Dateierweiterung xlsx für die Reportausgabe an, was als der Dateityp Excel 2007/2010 erkannt wird.

  

  Hinweis: Die Download-Eingabeaufforderung wird für alle Benutzer angezeigt, einschließlich der Benutzer, auf deren Rechnern Excel 2007/2010 installiert ist.

  Wenn ein Benutzer von Excel 2000/2003 diese Datei öffnet, erkennt das Microsoft Office Compatibility Pack die Dateierweiterung .xlsx und führt die nötige Umwandlung durch, damit Excel 2000/2003 die Excel 2007/2010-Arbeitsmappe lesen kann.

  Wenn ein Excel 2007/2010-Benutzer die Datei öffnet, erkennt Excel 2007/2010 die Dateierweiterung .xlsx und liest die Excel 2007/2010-Arbeitsmappe.

Zusätzliche Informationen über Umleitungseinstellungen des WebFOCUS Client finden Sie im Handbuch WebFOCUS-Sicherheit und -Administration.

Jedes numerische WebFOCUS-Format wird übertragen in ein angepasstes numerisches Excel-Format. Der numerische Wert wird angezeigt im Excel-Formel-Balken für die ausgewählte Zelle. In der tatsächlichen Zelle wird der Wert mit der angewendeten Formatierungsmaske angezeigt.

Die WebFOCUS-Formate für die folgenden numerischen Datentypen werden in Excel 2007/2010-Formatierungsmasken übertragen, wodurch vollständige Bearbeitung in der sich ergebenden Arbeitsmappe unterstützt wird:

• Datentypen: E, F, D , I, P.
• Kommabearbeitungsoption (C).
• Unterdrückung von Null (S).
• Vorangestellte Null (L).
• Gleitendes Währungszeichen (M).

  Hinweis: Excel unterstützt nicht automatisch die Platzierung von Währungszeichen oder anderer Formatierung allein in die erste Datenzeile. Obwohl unterschiedliche Formate für die einzelnen Zellen definiert werden können, wird, wenn der Benutzer die Daten sortiert, das erste Format mit der ersten Zeile basierend auf dem Sortierwert verschoben. Es werden daher in jeder Datenzeile fixierte Währungszeichen bereitgestellt, ähnlich wie bewegliche Zeichen:

• Kommaunterdrückung (c).
• Minuszeichen auf der rechten Seite (-).
• Kredit negativ (CR).
• Klammer negativ (B).
• Fixiertes erweitertes Währungszeichen (!d, !e, !l, !y).
• Bewegliches erweitertes Währungszeichen (!D, !E, !L, !Y).
• Prozent (%).

Im folgenden Beispiel werden dem Feld DOLLARS unterschiedliche numerische Formate zugewiesen, um unterschiedliche verfügbare Optionen aufzuzeigen. Die Spaltentitel wurden bearbeitet und zeigen jetzt die WebFOCUS-Formatoptionen an, die angewendet wurden:

TABLE FILE GGSALES
SUM DOLLARS/D12.2 AS 'D12.2'
    DOLLARS/D12C  AS 'D12C'
    DOLLARS/D12CM AS 'D12CM'
BY REGION
BY CATEGORY
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET BYDISPLAY ON
END

Beachten Sie, dass im sich ergebenden Arbeitsblatt die Zelle C2, die den DOLLAR-Wert enthält für Kaffee Mittlerer Westen, den Wert mit dem WebFOCUS-Format D12.2 darstellt, welches das Komma und die zwei Dezimalstellen anzeigt. In der Bearbeitungsleiste wird der Ist-Wert ohne jegliche Formatierung dargestellt. Untersuchen Sie jeden der DOLLAR-Werte in jeder Zeile, um sicherzustellen, dass der Wert, der in der Bearbeitungsleiste angezeigt wird, gleich bleibt, und sich nur die Anzeigewerte ändern, die in den einzelnen Zellen angezeigt werden.

Beachten Sie auch, dass mit SET BYDISPLAY ON die BY-Feldwerte für jede Zeile im Arbeitsblatt wiederholt werden. Dies führt zu vollqualifizierten Datenzeilen, die mit unterschiedlicher Datensortierung, Filterung und Tabellen-Features in Excel verwendet werden können, ohne nützlich Informationen zu verlieren. Diese Einstellung wird als beste Vorgehensweise für alle Arbeitsblätter empfohlen:

Im folgenden Beispiel wird das Format Fixierter Dollar (N) verwendet, und auch mehrere kombinierte Formatoptionen. Jede WebFOCUS-Formatoption wird in die entsprechende Excel 2007/2010-Formatierungsmaske übertragen und auf den Zellenwert angewendet:

TABLE FILE GGSALES
SUM BUDDOLLARS/D12N
    DOLLARS/D12M
COMPUTE OVERBUDGET/D12BMc=BUDDOLLARS-DOLLARS; AS 'Over Budget'
BY REGION
BY CATEGORY
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET BYDISPLAY ON
END

Beachten Sie, dass das festgelegte numerische Format, das für die Spalte BUDDOLLARS (Spalte C) definiert ist, das örtliche Währungszeichen an einer festen Position in jeder Zelle darstellt, unabhängig von der Größe des Datenwerts. In der Bearbeitungsleiste wird der Wert im berechneten Feld Über dem Budget als negativer Wert weitergereicht, wenn dies angebracht ist. In den tatsächlichen Zellen werden die negativen Werte in Klammern gesetzt, was Teil der angepassten Excel 2007/2010-Formatmaske ist:

Hinweis: Excel unterstützt nicht automatisch die Platzierung von Währungszeichen oder anderer Formatierung allein in die erste Datenzeile. Obwohl unterschiedliche Formate für die einzelnen Zellen definiert werden können, wird, wenn der Benutzer die Daten sortiert, das erste Format mit der ersten Zeile basierend auf dem Sortierwert verschoben. Es werden daher in jeder Datenzeile fixierte Währungszeichen bereitgestellt, ähnlich wie bewegliche Zeichen.

Per Default werden Kopf- und Fußzeilen an Excel als einzelne Zeichenfolge weitergereicht. Platzmarkierungen werden nicht unterstützt für die Positionierung innerhalb jeder Zeile. Numerische Felder und Daten, die in Kopf- und Fußzeilen weitergereicht werden, werden als Textfolgen in den Gesamtinhalten der Kopf- oder Fußzeile weitergereicht.

Um numerische Felder und Daten in Kopf- und Fußzeilen als numerische Werte oder Datumswerte anzuzeigen, verwenden Sie HEADALIGN=BODY im StyleSheet, um jedes der Elemente in der Kopfzeile als eine individuelle Zelle zu definieren. Jede Zelle, die numerische Werte oder Datumswerte enthält, wird dann als der entsprechende Wert mit der zugehörigen Formatierungsmaske weitergereicht. Informationen über das Attribut HEADALIGN finden Sie unter Ein Kopf- oder Fußzeilenelement in einem HTML-, EXL07-, EXL2K- oder PDF-Report ausrichten.

Hinweis: Die Einstellungen für die Kontinentale Dezimalschreibweise (CDN) im Hauptteil des Reports werden aktiviert durch die Ländereinstellungen auf dem Desktop des Kunden. In Kopf- und Fußzeilen, in denen HEADALIGN nicht angegeben wurde, werden die numerischen Werte mit CDN-Einstellungen in Textkopfzeilen umgewandelt, wie es die Prozedur angibt, da die Anwendung nicht auf die eingebetteten Textwerte zugreifen kann. In HEADALIGN-Szenarien, in denen die Elemente in der Kopfzeile in individuelle Zellen platziert werden, ähnlich der Datentabelle, werden die CDN-Einstellungen nicht vom Reporting Server angewendet, sondern werden zurückgestellt auf die Ländereinstellungen des Desktops.

Für Datenspalten werden alle Währungsformate mit Excel 2007/2010-Formatierungsmasken übertragen, die die Zeichensetzungsregeln verwenden, die die Ländereinstellungen des Desktops definieren.

In Sprachen, die die kontinentale Dezimalschreibweise verwenden, bestimmen die Währungsdefinitionen, dass ein Komma als Dezimaltrennzeichen verwendet wird, und ein Punkt als Tausendertrennzeichen, so dass D12.2CM den Wert als $ 9.999,99 darstellt, und nicht wie auf Englisch (USA) als $ 9,999.99. In Kopf- und Fußzeilen können Sie bestimmen, dass die Zeichensetzung in kontinentale Dezimalschreibweise umgewandelt werden soll, indem Sie den Befehl SET CDN=ON ausgeben. Wenn dies eingestellt ist, werden die Daten, die in die Textfolgen von Kopfzeilen und Fußzeilen eingebettet sind, mit der umgewandelten Zeichensetzung formatiert. Geben Sie HEADALIGN=BODY an, um Elemente als individuelle Zellen zu skizzieren und um die numerische Formatierung innerhalb des Feldes beizubehalten, welches dieselben Regeln befolgt, wie die Reportdaten in den Datenspalten.

Die meisten übertragenen Daten und Smart-Daten können an Excel 2007/2010 als standardmäßige Datumswerte mit Formatierungsmasken gesendet werden, was es Excel ermöglicht, sie in Funktionen, Formeln und Sortiersequenzen zu verwenden.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 1, 2010 und wandelt es in vier Datumsformate mit übertragenem Text um:

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
WRMtrDY/WRMtrDY = NEWDATE;
wDMTY/wDMTY= NEWDATE;
wrDMTRY/wrDMTRY= NEWDATE;
wrYMtrD/wrYMtrD= NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE WRMtrDY wDMTY wrDMTRY wrYMtrD
ON TABLE PCHOLD FORMAT EXL07
END

In der folgenden Tabelle sehen Sie, wie die Daten angezeigt werden sollten:

Datumsformate, die den Tageswert nicht explizit angeben, werden definiert als der Datumswert des ersten Tages des Monats. Es kann daher vorkommen, dass der Wert, der in die Zelle platziert wird, sich vom Tageskomponente-Wert im Quelldaten-Feld unterscheidet und er kann unerwartete Resultate hervorbringen, wenn er für Sortierung oder Datumsberechnungen in einer Excel-Formel verwendet wird.

In der folgenden Tabelle ist zu sehen, wie WebFOCUS-Datumsformate in EXL07 dargestellt werden. Die Tabelle zeigt, wie der Wert in der Zelle beibehalten wird und wie die Anzeige erzeugt wird, unter Verwendung der Formatierungsmaske, die dem WebFOCUS-Datumsformat entspricht.

DATEFLD/MDYY = '01/02/2010'

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum 2. Januar 2010 und reicht es an Excel 2007/2010 mit den Formaten MDYY, DMYY, MY und MTDY weiter:

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/02/2010';
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE AS 'MDYY' NEWDATE/DMYY AS 'DMYY' NEWDATE/MY AS 'MY' 
        NEWDATE/MTY AS 'MTY' NEWDATE/MTDY AS 'MTDY'
ON TABLE PCHOLD FORMAT EXL07 
END

Die Spalten D und E haben tatsächliche Datumswerte mit Formatierungsmasken, die von Excel 2007/2010 in Groß- und Kleinschreibung angezeigt werden. Da das MTY-Format keine Tageskomponente hat, ist der Datumswert, der gespeichert wird, der erste Januar 1 (2010/2010/1), und nicht der zweite Januar 2 (1/2/2010):

Daten, die als individuelle Komponenten (z. B. D, Y, M, W) formatiert sind, werden an Excel als numerische Werte weitergereicht, die als Parameter für Excel-Datumsfunktionen verwendet werden können. Die Werte werden als allgemeines Format weitergereicht, die von Excel als Zahlen erkannt werden.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 2010, 2007, extrahiert numerische Datumskomponentenund reicht sie an Excel 2007/2010 weiter:

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
D/D= NEWDATE;
Y/Y = NEWDATE;
W/W=NEWDATE;
w/w=NEWDATE;
M/M = NEWDATE;
YY/YY = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE D Y W w M YY
ON TABLE PCHOLD FORMAT EXL07 
END

Die Ausgabe ist:

Datumsformate, die eine Quartalskomponente enthalten, werden an Excel immer als Textfolgen weitergereicht, da Excel Quartalsformate nicht unterstützt.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 1, 2010 und wandelt es in Datumsformate um, die eine Quartalskomponente enthalten:

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
Q/Q= NEWDATE;
QY/QY = NEWDATE;
YBQ/YBQ=NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE Q QY YBQ
ON TABLE PCHOLD FORMAT EXL07 
END

In Excel 2007 oder 2010 haben die Zellen, die Daten mit Quartalskomponenten enthalten, das Format Allgemein. Sie können dies sehen, indem Sie die Zellen formatieren-Dialogbox öffnen.

Die Ausgabe ist:

Datumsformate, die keine ausreichenden Informationen enthalten, um ein gültiges Datumsergebnis in Excel anzuzeigen, werden nicht in einen Wert übertragen, einschließlich der Formate, die keine Jahres- und/oder Monatsinformationen enthalten. Diese Daten werden an Excel als Text gesendet. Wenn keine vollständigen Informationen vorhanden sind, ist der Default für das Jahr das aktuelle Jahr, so dass der gesendete Wert nicht richtig wäre, wenn dieser Formattyp als ein Datumswert weitergereicht würde. Die folgenden Formate werden nicht als Werte gesendet:

• MT, MTR, Mt, Mtr
• W, w, WR, wr

Wenn Datumsformate an Excel 2007/2010 mit Formatierungsmasken weitergereicht werden, bestehen alle Monats- und Tagesnamen aus Groß-/Kleinschreibung, unabhängig davon, was im WebFOCUS-Format angegeben wurde. Da jedoch die Werte in diesem Beispiel immer als Text gesendet werden, wird in der sich ergebenden Zelle die Groß-/Kleinschreibung angewendet, die im WebFOCUS-Format definiert wurde.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 1, 2010 und wandelt es in Datumsformate um, die entweder als Monatsname oder Tagesname definiert sind:

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
MT/MT= NEWDATE;
MTR/MTR= NEWDATE;
Mtr/Mtr = NEWDATE;
WR/WR = NEWDATE;
wr/wr = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE MT MTR Mtr WR wr
ON TABLE PCHOLD FORMAT EXL07 
END

In Excel 2007 oder 2010 haben die Zellen, die die Tage enthalten, das Format Allgemein. Sie können dies sehen, indem Sie die Zellen formatieren-Dialogbox öffnen.

Die Ausgabe ist:

[TYPE=REPORT,] XLSXPAGESETS={ON|OFF} [,PAGESIZE={pagesize|LETTER}]
 [,ORIENTATION={PORTRAIT|LANDSCAPE}] [,TOPMARGIN=n] [,BOTTOMMARGIN=m],$

Hierbei gilt:

XLSPAGESETS={ON|OFF}

ON führt dazu, dass die Seiteneinstellungen, die in der WebFOCUS-Anfrage definiert sind, auf die Seiteneinstellungen des Excel-Arbeitsblatts angewendet werden. OFF behält die Default-Seiteneinstellungen bei, die in der standardmäßigen Excel-Arbeitsmappe definiert sind. OFF ist der Defaultwert.

n

Definiert den oberen Rand für das Arbeitsblatt in den Einheiten, die durch den Parameter UNITS angegeben werden (per Default Zoll). Der Defaultwert ist 0,25.

m

Definiert den unteren Rand für das Arbeitsblatt in den Einheiten, die durch den Parameter UNITS angegeben werden (per Default Zoll). Der Defaultwert ist 0,25.

pagesize

Ist einer der PAGESIZE-Werte, die in einem WebFOCUS StyleSheet unterstützt werden, wie es beschrieben wird in Die Seitengröße, Ausrichtung und Farbe auswählen. LETTER ist die Default-Seitengröße.

PORTRAIT|LANDSCAPE

PORTRAIT richtet den Report auf einer vertikalen Seite so aus, dass er sich über die schmalere Seite erstreckt. Die Länge der Seite ist somit größer als die Breite. PORTRAIT ist der Defaultwert.

LANDSCAPE richtet den Report auf einer horizontalen Seite so aus, dass er sich über die längere Seite erstreckt. Die Breite der Seite ist somit größer als die Länge.

TYPE={PAGEHEADER|PAGEFOOTER},OBJECT=IMAGE,
 IMAGE=imagename, JUSTIFY={LEFT|CENTER|RIGHT} 
 [,DISPLAYON={FIRST|NOT-FIRST}] [,SIZE=(w								h)],$

Hierbei gilt:

PAGEHEADER

Platziert das Bild in die Kopfzeile des Arbeitsblatts.

PAGEFOOTER

Platziert das Bild in die Fußzeile des Arbeitsblatts.

imagename

Ist der Name einer gültigen Bilddatei, die in die Kopf- oder Fußzeile platziert werden soll. Das Bild muss sich auf dem definierten Anwendungspfad befinden. Die unterstützten Bildtypen sind GIF und JPEG.

JUSTIFY={LEFT|CENTER|RIGHT}

Identifiziert den Bereich in der Kopf- oder Fußzeile, der das Bild enthalten soll, und die Ausrichtung oder Platzierung innerhalb dieses definierten Bereichs.

DISPLAYON

Definiert, ob das Bild nur auf die erste Seite platziert werden soll oder auf alle Seiten außer der ersten Seite. Lassen Sie das Attribut weg, um das Bild auf alle Seiten zu platzieren.

Gültige Werte sind:

FIRST platziert das Bild nur auf die erste Seite.

NOT-FIRST platziert das Bild auf alle Seiten außer der ersten Seite.

SIZE=(w h)

Ist die Größe des Bildes. Per Default wird ein Bild in seiner ursprünglichen Größe hinzugefügt.

s ist die Breite des Bildes in der Maßeinheit, die im Parameter UNITS angegeben ist.

h ist die Höhe des Bildes in der Maßeinheit, die im Parameter UNITS angegeben ist.

Die folgende Anfrage mit der GGSALES-Datenquelle platziert das Bild ibi_logo.gif in den linken Kopfzeilenbereich der ersten Seite und in den rechten Kopfzeilenbereich aller anderen Seiten des sich ergebenden Arbeitsblatts. Sie platziert auf allen Seiten das Bild webfocus1.gif in den mittleren Bereich der Fußzeile:

TABLE FILE GGSALES
SUM DOLLARS UNITS BUDDOLLARS BUDUNITS 
BY REGION
BY ST
BY CATEGORY
BY PRODUCT
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL07 
ON TABLE SET STYLE *
FONT=ARIAL,SIZE=12,
XLSXPAGESETS=ON,TOPMARGIN=1,BOTTOMMARGIN=1,ORIENTATION=LANDSCAPE,
PAGESIZE=LETTER,$
TYPE=TITLE, COLOR=WHITE, BACKCOLOR=GREY,$
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=LEFT, IMAGE=IBI_LOGO.GIF, DISPLAYON=FIRST,$
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=RIGHT, IMAGE=IBI_LOGO.GIF,  DISPLAYON=NOT-FIRST,$
TYPE=PAGEFOOTER, OBJECT=IMAGE, JUSTIFY=CENTER, IMAGE=webfocus1.gif, $
END

Auf der ersten Ausgabeseite befindet sich das Bild ibilogo.gif im linken Bereich der Kopfzeile und das Bild webfocus1.gif im mittleren Bereich der Fußzeile.

Auf der zweiten Ausgabeseite befindet sich das Bild ibilogo.gif im rechten Bereich der Kopfzeile und das Bild webfocus1.gif im mittleren Bereich der Fußzeile.

• Die Größe der Kopf- und Fußzeilen in Excel wird nicht automatisch basierend auf den Inhalten der Bereiche angepasst. Definieren Sie Seitenränder innerhalb der Seiteneinstellungen so, dass für die Bilder auf jeder Reportseite ausreichend Platz vorhanden ist.
• Die Anpassung der Bildgröße auf die angegebene Höhe und Breite ist nicht proportional. Die Anpassung der Größe kann dazu führen, dass das Bild verzerrt wird.
• BLOB-Bildfelder werden in diesem Release nicht unterstützt.

Wasserzeichen können in die Excel-Kopfzeilen platziert werden und auf jeder gedruckten Seite des erzeugten Arbeitsblatts angezeigt werden.

Excel platziert Bilder auf die Seite, indem mit der Kopfzeile begonnen wird von links nach rechts und dann mit der Fußzeile von links nach rechts fortgefahren wird. Große Bilder, die in die Kopfzeile platziert werden, können Bilder, die sich vor ihnen befinden, überlappen, und überlagern die vorherigen Bilder. Für Seiten-Layouts mit einem Logo im linken Bereich und einem Wasserzeichen in der Mitte der Seite, sollte der Hintergrund des Wasserzeichens transparent sein, so dass das Logo nicht überlagert wird.

In Excel werden Bilder zuerst auf der Seite platziert. Alle anderen Inhalte des Arbeitsblatts werden dann auf die Bilder platziert. Text in Zellen und Styling wie z. B. Hintergrundfarbe und Zeichnungsobjekte werden auf die Bilder platziert. Excel unterstützt Transparenz beim Abbilden von Objekten und Bildern, aber nicht bei der Hintergrundfarbe von Zellen. BACKCOLOR verdeckt Bilder, die auf die Seite platziert werden.

Die folgende Anfrage mit der Datenquelle GGSALES verwendet das Bild internaluseonly.gif als Wasserzeichen, das im Hintergrund jeder Seite des Arbeitsblatts angezeigt wird. Obwohl das Bild in den mittleren Bereich der Kopfzeile platziert wird, ist es groß genug, um sich über die gesamte Arbeitsblattseite zu erstrecken. Es hat einen durchsichtigen Hintergrund, so dass es die Logos nicht verdeckt, die links in der Kopfzeile platziert sind, und in der Mitte der Fußzeile:

TABLE FILE GGSALES
SUM DOLLARS UNITS BUDDOLLARS BUDUNITS 
BY REGION
BY ST
BY CATEGORY
BY PRODUCT
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL07 
ON TABLE SET STYLE *
XLSXPAGESETS=ON,
TOPMARGIN=1,BOTTOMMARGIN=1,LEFTMARGIN=1, RIGHTMARGIN=1, ORIENTATION=LANDSCAPE,PAGESIZE=LETTER,$
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=LEFT, IMAGE=IBI_LOGO.GIF, DISPLAYON=FIRST, $
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=CENTER, IMAGE=INTERNALUSEONLY.GIF, $
TYPE=PAGEFOOTER, OBJECT=IMAGE, JUSTIFY=RIGHT, IMAGE=WEBFOCUS1.GIF, $
END

Die erste Seite des erzeugten Arbeitsblatts zeigt das Wasserzeichen unter den Daten an. Dieses Bild wird auf jeder Seite des Arbeitsblatts angezeigt.

Umleitung ist per Default deaktiviert für die Dateierweiterung .xlsx, da dies ermöglicht, dass Drilldowns erfolgreich ausgeführt werden, unabhängig davon, ob der Rechner des Benutzers so konfiguriert ist, dass Excel im Browser gestartet wird, oder als eine Anwendung außerhalb des Browsers.

Informationen zu WebFOCUS Client-Umleitung und Excel-Drilldown-Reports finden Sie unter Umleitung und Excel-Drilldown-Reports.

Um die erweiterten Template-Dateitypen zu unterstützen, wurde das Attribut Template-Dateiname verbessert, und es kann jetzt die Dateierweiterung aufgenommen werden. Wenn im Template-Namen keine Erweiterung angegeben ist, ist die Dateierweiterung per Default .XLTX.

ON TABLE PCHOLD FORMAT EXL07 TEMPLATE template_name SHEETNUMBER n							

Hierbei gilt:

template_name

Ist der Name der Excel-Template-Datei (Arbeitsmappe) einschließlich des Dateinamens und der Erweiterung, die sich auf dem Suchpfad des WebFOCUS Reporting Server-Anwendungsverzeichnisses befindet. Beispielsweise IPOLICY.XLTX, PRINTSHEETS.XLTM oder DASHBOARD.XLSM. Wenn die Erweiterung nicht bereitgestellt wird, ist sie per Default .XLTX.

n

Ist die Anzahl der Excel-Arbeitsblätter, die in der Template-Datei (Arbeitsmappe) ersetzt werden sollen.

Das Arbeitsmappe-Template, das von der WebFOCUS-Prozedur verwendet wird, muss gültige Arbeitsblätter enthalten.

• Das Arbeitsblatt, das aktualisiert wird, muss in der Arbeitsmappe vorhanden sein, da WebFOCUS das Arbeitsblatt nicht einfügt, sondern ersetzt. Wenn das vorgesehene Arbeitsblatt nicht vorhanden ist, gibt die Prozedur einen Fehler zurück.
• In einer Template-Datei muss wenigstens eines der Arbeitsblätter in der Arbeitsmappe eine Zelle mit einem gültigen Wert enthalten (leer oder ein anderer Wert). Um ein Arbeitsblatt in einem Template zu ersetzen, das nur leere Arbeitsblätter enthält, ersetzen Sie eine der Zellen in einem beliebigen Arbeitsblatt mit einem Leerzeichen und speichern Sie. Dies instanziiert die Arbeitsblätter, so dass WebFOCUS auf sie für Aktualisierungszwecke zugreifen kann.

Ihrem WebFOCUS StyleSheet das Attribut ROWOVERFLOW hinzufügen

TYPE=REPORT, ROWOVERFLOW={ON|OFF|PBON}, [ROWLIMIT={n|MAX}...

Hierbei gilt:

ON

Aktiviert Überlauf-Arbeitsblätter.

OFF

Deaktiviert Überlauf-Arbeitsblätter. OFF ist der Defaultwert.

PBON

Fügt WebFOCUS-Seitenumbrüche ein, die die Seitenkopfzeile, Seitenfußzeile und Spaltentitel an den entsprechenden Stellen in den Arbeitsblattzeilen anzeigen. Diese Option führt nicht dazu, dass ein neues Arbeitsblatt begonnen wird, wenn ein WebFOCUS-Seitenumbruch vorkommt.

ROWLIMIT=n

Stellt einen Zielwert auf n Zeilen ein für die Anzahl der Zeilen, die in ein Arbeitsblatt aufgenommen werden sollen. Der Defaultwert ist der LINES-Wert (per Default 57).

ROWLIMIT=MAX

Stellt einen Zielwert von 1.048.000 Zeilen für EXL07-Ausgabe für die Anzahl der Zeilen ein, die in ein Arbeitsblatt aufgenommen werden sollen.

Dieses Attribut funktioniert mit allen Excel-Ausgabeformaten. Für alle anderen Ausgabetypen wird das ROWOVERFLOW StyleSheet-Attribut ignoriert und der Datenfluss ist nicht betroffen.

• Die Reportkopfzeile wird einmal an den Anfang des ersten Arbeitsblatts platziert. Die Reportfußzeile wird einmal an das Ende des letzten Überlauf-Arbeitsblatts platziert.
• Wenn nicht die Einstellung PBON verwendet wird, werden Arbeitsblattkopfzeilen und Spaltentitel oben auf dem ursprünglichen Arbeitsblatt und auf jedem nachfolgenden Überlauf-Arbeitsblatt wiederholt. Arbeitsblattfußzeilen werden an das Ende des ursprünglichen Arbeitsblatts und auf jedes nachfolgende Überlauf-Arbeitsblatt platziert. Die Datenwerte werden in der obersten Datenzeile jedes Überlauf-Arbeitsblatts angezeigt, wie dies auch der Fall wäre für eine standardmäßige neue Seite.
• Die Gesamtzeilenanzahl im Report wird im unteren Bereich des letzten Überlauf-Arbeitsblatts direkt über den letzten Seiten- und Tabellenfußzeilen angezeigt.
• Zwischenkopfzeilen, Zwischenfußzeilen und Zwischensummenzeilen werden im Datenfluss normal angezeigt. Es wird nicht versucht, Gruppierungen in einem gegebenen Arbeitsblatt beizubehalten.
• Wenn ROWOVERFLOW=PBON, werden die Seitenkopfzeilen und -fußzeilen und Spaltentitel im Arbeitsblatt angezeigt, wenn ein WebFOCUS-Befehl einen Seitenumbruch verursacht.
• Wenn für EXL07K-Ausgabe das ROWOVERFLOW-Attribut im StyleSheet angegeben ist, und ROWLIMIT größer als 1MB ist, wird die folgende Meldung angezeigt und keine Ausgabedatei erzeugt:

  (FOC3338) The row limit for EXCEL XLSX worksheets is 1048576.

• Ausgabetypen, die Formelbezüge enthalten (EXL2K PIVOT und EXL2K FORMULA), werden nicht unterstützt, da Formelbezüge nicht automatisch aktualisiert werden, um die Platzierung auf neuen Überlauf-Arbeitsblättern widerzuspiegeln.
• Das Überlauf-Arbeitsblatt-Feature trifft nur auf Zeilen und nicht auf Spalten zu. Es wird nicht automatisch ein neues Arbeitsblatt erstellt, wenn ein Report mehr als das Limit von 16.384 Spalten in Excel 2007/2010 erzeugt.
• ROWOVERFLOW wird unterstützt für BYTOC-Reports für EXL07.
• Da benannte Bereiche in Excel sich nicht über mehrere Arbeitsblätter erstrecken können, wird die IN-RANGES-Phrase, die benannte Bereiche in der resultierenden Arbeitsmappe definiert, mit dem ROWOVERFLOW-Feature nicht unterstützt. Wenn sie beide in derselben Anfrage vorhanden sind, hat ROWOVERFLOW Vorrang und die IN-RANGES-Phrase wird ignoriert.

Die folgende Anfrage erstellt EXL07-Reportausgabe mit Überlauf-Arbeitsblättern. Das Attribut ROWOVERFLOW=ON im StyleSheet aktiviert das Überlauf-Feature. Ohne dieses Attribut wäre nur ein Arbeitsblatt anstelle von drei erzeugt worden.

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
-* ****Worksheet Heading****
HEADING
"SALES REPORT WORKSHEET <TABPAGENO"
" "
-* ****Worksheet Footing****
FOOTING
" "
"END OF WORKSHEET <TABPAGENO"
PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION
BY CATEGORY
BY PRODUCT
BY DATE

-* ****Subfoot****
ON REGION SUBFOOT
" "
" End of Region <REGION"
" "
-* ****Subhead****
ON REGION SUBFOOT
" "
" End of Region <REGION"
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT=EXLOVER, ROWOVERFLOW=ON, ROWLIMIT=2000,$
ENDSTYLE
END

Die Reportkopfzeile wird nur auf dem ersten Arbeitsblatt angezeigt, die Seitenkopfzeile und Spaltentitel auf jedem Arbeitsblatt und die Zwischenkopfzeile und Zwischenfußzeile immer dann, wenn sich der Wert des assoziierten Sortierfeldes ändert. In der folgenden Abbildung sehen Sie den Anfang des ersten Arbeitsblatts, wo die Reportkopfzeile, die Seitenkopfzeile, die Spaltentitel und die erste Zwischenkopfzeile angezeigt wird.

Beachten Sie, dass das TITLETEXT-Attribut im StyleSheet den Namen EXLOVER angibt, so dass die drei Arbeitsblätter mit den Namen EXLOVER1, EXLOVER2 und EXLOVER3 erzeugt wurden. Wenn es kein TITLETEXT-Attribut gegeben hätte, wären die Arbeitsblätter als SHEET1, SHEET2 und SHEET3 benannt worden.

Die Arbeitsblattfußzeile wird am Ende jedes Arbeitsblatts und die Reportfußzeile am Ende des letzten Arbeitsblatts angezeigt. In der folgenden Abbildung sehen Sie das Ende des letzten Arbeitsblatts, wo die letzte Zwischenfußzeile, die Seitenfußzeile und die Reportfußzeile angezeigt werden.

Die folgende Anfrage erstellt EXL07-Reportausgabe mit Überlauf-Arbeitsblättern. Das Attribut ROWOVERFLOW=PBON im StyleSheet aktiviert das Überlauf-Feature, und ROWLIMIT=250 stellt die maximale Anzahl der Zeilen in jedem Arbeitsblatt auf etwa 250 ein. Ohne das Attribut wäre ein Arbeitsblatt erzeugt worden. Die Sortierphrase PRODUCT gibt einen Seitenumbruch an.

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION 
BY HIGHEST CATEGORY 
BY PRODUCT PAGE-BREAK
BY DATE
WHERE DATE GE '19971001'
-* ****Page Heading****
HEADING
" Product: <PRODUCT in Category: <CATEGORY for Region: <REGION"
-* ****Page Footing****
FOOTING
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET STYLE *
INCLUDE=endeflt,TITLETEXT=EXLOVER, ROWOVERFLOW=PBON, ROWLIMIT=250,
$
ENDSTYLE
END

Die Reportkopfzeile wird nur auf dem ersten Arbeitsblatt angezeigt, die Seitenkopfzeile, Seitenfußzeile und Spaltentitel auf jedem Arbeitsblatt und an jedem WebFOCUS-Seitenumbruch (jedes Mal, wenn sich das Produkt ändert), und die Zwischenkopfzeile und Zwischenfußzeile werden angezeigt, wenn sich der Wert des assoziierten Sortierfeldes ändert. In der folgenden Abbildung sehen Sie den oberen Bereich des ersten Arbeitsblatts.

Die Syntax ist identisch mit der von HTML TOC-Reports, mit der Ausnahme, dass nur ein einziges BY-Feld in EXL07 erlaubt ist, wohingegen in HTML mehrere BY-Felder erlaubt sind.

ON TABLE {HOLD|PCHOLD} FORMAT EXL07 BYTOC

Da nur eine Inhaltsverzeichnis-Ebene in EXL07-Reports erlaubt ist, kann die optionale Zahl, die dem BYTOC-Schlüsselwort folgt, nur 1 sein.

Wie bei HTML, kann die SET COMPOUND-Syntax, die dem TABLE-Befehl vorausgeht, auch verwendet werden, um anzugeben, dass ein TOC erstellt werden soll:

SET COMPOUND=BYTOC

Da ein Inhaltsverzeichnis-Report je nach dem Wert des ersten BY-Feldes im Report separate Arbeitsblätter erzeugt, muss der Report wenigstens ein BY-Feld enthalten. Das Burst-Feld darf ein NOPRINT-Feld sein.

Das Feature BYTOC wird nicht unterstützt mit dem Format EXL07 TEMPLATE.

• Die Tab-Namen des Arbeitsblattes sind die BY-Feldwerte, die den Daten des aktuellen Arbeitsblattes entsprechen. Wenn der Benutzer das TITLETEXT-Schlüsselwort im StyleSheet angibt, wird es ignoriert.
• Excel beschränkt die Länge von Arbeitsblatttiteln auf 31 Zeichen. Die folgenden Sonderzeichen können nicht verwendet werden: ':', '?', '*' und '/'.
• Wenn Sie ein Datumsfeld als das BY-Feld verwenden möchten, können Sie das Zeichen - anstelle des Zeichens / aufnehmen. Das Zeichen "-" ist in einem Excel-Tab-Titel gültig. Wenn Sie jedoch das "/"-Zeichen verwenden, wird WebFOCUS es mit dem "-"-Zeichen ersetzen.

Die folgende Anfrage mit der Datenquelle GGSALES erstellt separate Tabs basierend auf dem Sortierfeld REGION:

TABLE FILE GGSALES
SUM UNITS/D12C DOLLARS/D12CM
BY REGION NOPRINT
BY CATEGORY
BY PRODUCT
HEADING
"<REGION Region Sales"
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET BYDISPLAY ON
ON TABLE SET COMPOUND BYTOC
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL,SIZE=9,$
TYPE=HEADING, SIZE=12,$
TYPE=TITLE, BACKCOLOR=GREY,COLOR=WHITE, $
ENDSTYLE
END

Die Ausgabe ist:

Um Nullwerte in EXL2K-Reports identifizieren, verwenden Sie

ON TABLE SET NODATA character_string							

ON TABLE SET EMPTYCELLS [ON|OFF]

Hierbei gilt:

character_string

Ist die Zeichenfolge, die für die Felder im Report, für die aus der Datenbank Nullwerte aufgerufen werden, angezeigt wird. Es sind maximal 11 Zeichen zulässig. Wenn die Anzahl der Zeichen in der Zeichenfolge größer ist als das Ausgabefeld, werden die zusätzlichen Zeichen nicht angezeigt. Falls Sonderzeichen verwendet werden, muss die Zeichenfolge in einfache Anführungszeichen gesetzt werden. SET EMPTYCELLS OFF muss auch angegeben werden, um den SET NODATA-Befehl zu aktivieren.

ON

Gibt an, dass für alle Felder im Report, für die Nullwerte aus der Datenbank abgerufen werden, Leerstellen im Report angezeigt werden. ON ist der Default.

OFF

Gibt an, dass Nullen oder die mit dem SET NODATA-Befehl angegebene Zeichenfolge für alle Felder im Report angezeigt wird, für die aus der Datenbank Nullwerte abgerufen werden. OFF muss angegeben werden, wenn SET NODATA verwendet wird.

Die folgende Syntax verwendet das Default-Verhalten von ON TABLE SET EMPTYCELLS ON, der im Hintergrund eingestellt wird:

TABLE FILE CAR
   SUM SALES BY COUNTRY ACROSS SEATS
   ON TABLE PCHOLD FORMAT EXL2K
END

Die folgende Ausgabe zeigt Leerstellen für alle Felder im Report an, für die Nullwerte aus der Datenbank abgerufen wurden:

Die folgende Syntax setzt den SET NODATA-Befehl ein:

TABLE FILE CAR
   SUM SALES BY COUNTRY ACROSS SEATS
   ON TABLE SET NODATA 'n/a'
   ON TABLE SET EMPTYCELLS OFF
   ON TABLE PCHOLD FORMAT EXL2K
END

Hinweis: Wenn Sie SET EMPTYCELLS OFF nicht hinzufügen, wird der SET NODATA-Befehl ignoriert.

Die folgende Ausgabe zeigt 'n/a' für alle Felder im Report an, für die Nullwerte aus der Datenbank abgerufen wurden:

Die folgende Syntax stellt das Default-Verhalten SET EMPTYCELLS ab und verwendet SET NODATA nicht, wodurch es unmöglich ist, Nullwerte von Anzahl Null zu unterscheiden:

TABLE FILE CAR
   SUM SALES BY COUNTRY ACROSS SEATS
   ON TABLE SET EMPTYCELLS OFF
   ON TABLE PCHOLD FORMAT EXL2K
END

Die folgende Ausgabe zeigt Nullen für alle Felder im Report an, für die aus der Datenbank entweder Nullwerte abgerufen werden, oder deren Anzahl null ist:

Die folgenden Formate werden in EXL2K nicht unterstützt. Sie werden in das allgemeine Excel-Format übertragen und können eventuell unvorhergesehene Ergebnisse liefern:

• Feststehende Dollarformate (N).
• Mehrfache Formatierungsoptionen. Es werden bei der Verwendung von FORMAT EXL2K nur einfache Formatierungsoptionen unterstützt. Die Formate I9C und I9B werden beispielsweise unterstützt, I9BC aber nicht.

Folgendes gilt für Kopf- und Fußzeilen mit eingebetteten numerischen Feldern:

• Wenn Sie ein numerisches Feld in eine Kopfzeile, Zwischenkopfzeile, Fußzeile oder Zwischenfußzeile eines Reports in einem EXL2K-Report einbetten, wird das numerische Feld im allgemeinen Format für Excel (Text) angezeigt. Sie müssen, um ein numerisches Feld im numerischen Format von Excel anzuzeigen, HEADALIGN=BODY im StyleSheet einstellen.

  Hinweis: Die Einstellungen für die Kontinentale Dezimalschreibweise (CDN) im Hauptteil des Reports werden aktiviert durch die Ländereinstellungen auf dem Desktop des Kunden. In Kopf- und Fußzeilen, in denen HEADALIGN nicht angegeben wurde, werden die numerischen Werte mit CDN-Einstellungen in Textkopfzeilen umgewandelt, wie es die Prozedur angibt, da die Anwendung nicht auf die eingebetteten Textwerte zugreifen kann. In HEADALIGN-Szenarien, in denen die Elemente in der Kopfzeile in individuelle Zellen platziert werden, ähnlich der Datentabelle, werden die CDN-Einstellungen nicht vom Reporting Server angewendet, sondern werden zurückgestellt auf die Ländereinstellungen des Desktops.

Die folgenden Formate werden in EXL2K nicht unterstützt. Sie werden in das allgemeine Excel-Format übertragen und können eventuell unvorhergesehene Ergebnisse liefern:

• YY, Y, M, D, JUL und I2MT.
• Alle Datumsformate mit einem Q (Quartal).
• Alle gepackten Dezimaldatumsformate (P).
• Alle alphanumerischen Datumsformate (A).

Um einen Bindestrich "-" als Trennzeichen zwischen Monat, Tag und Jahr in Excel 2000/2003 zu verwenden, müssen Sie das Default-Datumstrennzeichen für Windows ändern. Diese Einstellung befindet sich in den Regionsoptionen im Control Panel.

Manche übertragenen Daten können an Excel 2000/2003 als standardmäßige Datumswerte mit Formatierungsmasken gesendet werden, was es Excel ermöglicht, sie in Funktionen, Formeln und Sortiersequenzen zu verwenden. Der SET EXL2KTXTDATE-Befehl ermöglicht es Ihnen, anzugeben, dass übertragene Daten nicht als Textwerte sondern als Datumswerte mit Formatierungsmasken gesendet werden sollen.

SET EXL2KTXTDATE = {TEXT|VALUE}

SET EXL2KTXTDATE=TEXT
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
WRMtrDY/WRMtrDY = NEWDATE;
wDMTY/wDMTY= NEWDATE;
wrDMTRY/wrDMTRY= NEWDATE;
wrYMtrD/wrYMtrD= NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE WRMtrDY wDMTY wrDMTRY wrYMtrD
ON TABLE PCHOLD FORMAT EXL2K
END

Datumsformate, die den Tageswert nicht explizit angeben, werden definiert als der Datumswert des ersten Tages des Monats. Es kann daher vorkommen, dass der Wert, der in die Zelle platziert wird, sich vom Tageskomponente-Wert im Quelldaten-Feld unterscheidet und er kann unerwartete Resultate hervorbringen, wenn er für Sortierung oder Datumsberechnungen in einer Excel-Formel verwendet wird.

In der folgenden Tabelle ist zu sehen, wie WebFOCUS-Datumsformate in EXL2K-Reportausgabe dargestellt werden. Die Tabelle zeigt, wie der Wert in der Zelle beibehalten wird und wie die Anzeige erzeugt wird, unter Verwendung der Formatierungsmaske, die dem WebFOCUS-Datumsformat entspricht.

DATEFLD/MDYY = '01/02/2010'

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum 2. Januar 2010 und reicht es an Excel 2000/2003 mit den Formaten MDYY, DMYY, MY und MTDY weiter:

SET EXL2KTXTDATE=TEXT
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/02/2010';
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE AS 'MDYY' NEWDATE/DMYY AS 'DMYY' NEWDATE/MY
        AS 'MY' NEWDATE/MTY AS 'MTY' NEWDATE/MTDY AS 'MTDY'
ON TABLE PCHOLD FORMAT EXL2K 
END

Mit EXL2KTXTDATE=TEXT haben die Spalten D und E nicht Datumswerte sondern Textwerte. Die Werte werden großgeschrieben angezeigt, wie es durch die WebFOCUS-Formate (MTY und MTDY) angegeben ist:

Mit EXL2KTXTDATE=VALUE haben die Spalten D und E tatsächliche Datumswerte mit Formatierungsmasken, die von Excel 2000 in Groß- und Kleinschreibung angezeigt werden. Da das MTY-Format keine Tageskomponente hat, ist der Datumswert, der gespeichert wird, der erste Januar 1 (2010/2010/1), und nicht der zweite Januar 2 (1/2/2010):

Daten, die als individuelle Komponenten (z. B. D, Y, M, W) formatiert sind, werden an Excel 2000/2003 als numerische Werte weitergereicht, die als Parameter für Excel-Datumsfunktionen verwendet werden können. Die Werte werden als allgemeines Textformat weitergereicht, die von Excel 2000/2003 als Zahlen erkannt werden. Diese Werte werden an Excel im selben Format weitergereicht, unabhängig von der Einstellung für EXL2KTXTDATE.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 2010, 2000, extrahiert numerische Datumskomponentenund reicht sie an Excel 2000/2003 weiter:

SET EXL2KTXTDATE=VALUE
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
D/D= NEWDATE;
Y/Y = NEWDATE;
W/W=NEWDATE;
w/w=NEWDATE;
M/M = NEWDATE;
YY/YY = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE D Y W w M YY
ON TABLE PCHOLD FORMAT EXL2K 
END

Mit SET EXL2KTXTDATE=VALUE ist die Ausgabe wie folgt:

Datumsformate, die eine Quartalskomponente enthalten, werden an Excel immer als Textfolgen weitergereicht, da Excel Quartalsformate nicht unterstützt.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 1, 2010 und wandelt es in Datumsformate um, die eine Quartalskomponente enthalten:

SET EXL2KTXTDATE=VALUE
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
Q/Q= NEWDATE;
QY/QY = NEWDATE;
YBQ/YBQ=NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE Q QY YBQ
ON TABLE PCHOLD FORMAT EXL2K 
END

Selbst mit SET EXL2KTXTDATE=VALUE haben in EXL2K-Reportausgabe die Zellen, die Daten mit Quartalskomponenten enthalten, das Format Allgemein. Sie können dies sehen, indem Sie die Zellen formatieren-Dialogbox öffnen.

Die Ausgabe ist:

Datumsformate, die keine ausreichenden Informationen enthalten, um das gültige Datumsergebnis in Excel anzuzeigen, werden nicht in einen Wert übertragen, einschließlich der Formate, die keine Jahres- und/oder Monatsinformationen enthalten. Diese Daten werden an Excel 2000/2003 weiter als Text gesendet, unabhängig von der Einstellung SET EXL2KTXTDATE. Wenn keine vollständigen Informationen vorhanden sind, ist der Default für das Jahr das aktuelle Jahr, so dass der gesendete Wert nicht richtig wäre, wenn dieser Formattyp als ein Datumswert weitergereicht würde. Die folgenden Formate werden nicht als Werte gesendet:

• MT, MTR, Mt, Mtr
• W, w, WR, wr

Beachten Sie, dass, da diese Werte immer als Text gesendet werden, die Groß-/Kleinschreibung, die im WebFOCUS-Format definiert ist, auf die resultierende Zelle angewendet wird.

Die folgende Anfrage an die GGSALES-Datenquelle erstellt das Datum Januar 1, 2010 und wandelt es in Datumsformate um, die entweder als Monatsname oder Tagesname definiert sind:

SET EXL2KTXTDATE=VALUE
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
MT/MT= NEWDATE;
MTR/MTR= NEWDATE;
Mtr/Mtr = NEWDATE;
WR/WR = NEWDATE;
wr/wr = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE MT MTR Mtr WR wr
ON TABLE PCHOLD FORMAT EXL2K 
END

In Excel 2000/2003 haben die Zellen, die die Tage enthalten, das Format Allgemein. Sie können dies sehen, indem Sie die Zellen formatieren-Dialogbox öffnen.

Die Ausgabe ist:

TYPE=REPORT, [COLUMN=column,] WRAP=value, $

Hierbei gilt:

column

Gibt eine bestimmte Spalte an, auf die das Umbruchverhalten angewendet werden soll. Wenn COLUMN in der Deklaration nicht enthalten ist, wird das Umbruchverhalten auf den gesamten Report angewendet.

Wert

Ist eines des Folgenden:

ON

Aktiviert den Datenumbruch. ON ist der Defaultwert. Bei dieser Einstellung wird die Spaltenbreite vom Client (Excel) bestimmt. Daten werden umgebrochen, wenn die Spaltenbreite nicht ausreicht, und die Höhe wird entsprechend der neuen Höhe der Daten angepasst.

OFF

Deaktiviert den Datenumbruch. Es werden in keiner Zelle der Spalte Daten umgebrochen.

n

Gibt einen speziellen numerischen Wert an, auf den die Spaltenbreite eingestellt werden kann. Der Wert stellt die Maßeinheit dar, die im UNITS-Parameter angegeben ist (der Default ist Zoll).

Diese Einstellung setzt ON voraus. Die Spaltenbreite ist jedoch auf die angegebene Breite eingestellt, es sei denn, die Daten sind breiter als die Spaltenbreite. Erst dann werden die Daten wie mit ON umgebrochen.

TYPE=REPORT, [COLUMN=column,] SQUEEZE={ON|OFF|n}, $

Hierbei gilt:

column

Identifiziert eine bestimmte Spalte. Wenn COLUMN in der Deklaration nicht enthalten ist, wird das Default-SQUEEZE-Verhalten auf den gesamten Report angewendet.

n

Gibt einen speziellen numerischen Wert an, auf den die Spaltenbreite eingestellt werden kann. Der Wert stellt die Maßeinheit dar, die im UNITS-Parameter angegeben ist (der Default ist Zoll).

Dies ist die in EXL2K-Reports am häufigsten verwendete SQUEEZE-Einstellung.

Hinweis:

• ON/OFF-Einstellungen für SQUEEZE haben in EXL2K keine Bedeutung und führen beide zum Default-Verhalten.
• SQUEEZE = n deaktiviert den Datenumbruch. Wenn ein Datenwert breiter als die angegebene Spaltenbreite ist, wird er nicht vollständig angezeigt. Sie können die Spaltenbreite in Excel anpassen, nachdem das Arbeitsblatt erzeugt wurde.
• SQUEEZE wird für Spalten, die mit der OVER-Phrase oder mit TABLEF erstellt wurden, nicht unterstützt.

Das folgende Beispiel verdeutlicht, wie Sie Datenumbrüche für eine Spalte aktivieren bzw. deaktivieren und wie Sie die Breite für eine bestimmte Spalte einstellen. UNITS ist in diesem Beispiel auf Zoll eingestellt (Default).

  DEFINE FILE CAR
  MYDATE/MDY='10/22/60';
  RCD/D14.3=RETAIL_COST;
  VERYLONG/A80='Subtract dealer cost from retail cost to calculate
  profit.';
  END

   TABLE FILE CAR
   PRINT MYDATE RCD 
   VERYLONG AS 'Default' VERYLONG AS 'WRAP=OFF'
   VERYLONG AS 'WRAP=4.1' VERYLONG AS 'WRAP=2'
   VERYLONG AS 'SQUEEZE=2' SALES   BY COUNTRY
   ON TABLE PCHOLD FORMAT EXL2K
   ON TABLE SET STYLE *
   TYPE=DATA, COLUMN=MYDATE, JUSTIFY=CENTER, $ 
1. TYPE=REPORT, COLUMN=VERYLONG(2), WRAP=OFF, $
2. TYPE=REPORT, COLUMN=VERYLONG(3), WRAP=4.1, $
3. TYPE=REPORT, COLUMN=VERYLONG(4), WRAP=2, $
4. TYPE=REPORT, COLUMN=VERYLONG(5), SQUEEZE=2, $ 
   END

Hierbei gilt:

1. Identifiziert die Spalte mit dem Titel "WRAP=OFF" und deaktiviert den Datenumbruch für diese Spalte.
2. Identifiziert die Spalte mit dem Titel "WRAP=4.1" und stellt die Spaltenbreite auf 4.1 Zoll ein, wobei der Datenumbruch aktiviert ist.
3. Identifiziert die Spalte mit dem Titel "WRAP=2" und stellt die Spaltenbreite auf 2 Zoll ein, wobei der Datenumbruch aktiviert ist.
4. Identifiziert die Spalte mit dem Titel "SQEEZE=2" und stellt die Spaltenbreite auf 2 Zoll, wobei der Datenumbruch deaktiviert ist.

Hinweis: Die Spalte mit dem Titel "Default" stellt die Default-Spaltenbreite und das Umbruchverhalten dar.

Da die Ausgabe breiter als diese Seite ist, wird sie in zwei Abschnitten angezeigt. Die folgende Ausgabe zeigt die Spalten "Default", "WRAP=OFF" und "WRAP=4.1" an:

Die folgende Ausgabe zeigt die Spalten "WRAP=2" und "SQUEEZE=2" an:

Verwenden Sie die folgenden Attribute, um die Sperrung zu aktivieren:

TYPE=REPORT, PROTECTED={ON|OFF}, [LOCKED={ON|OFF}],$

Hierbei gilt:

TYPE=REPORT, PROTECTED=ON

Ist nötig, um Arbeitsblattsperrung zu aktivieren. PROTECTED=OFF ist der Default. Es wird das gesamte Arbeitsblatt gesperrt, wenn Sie das Attribut LOCKED=OFF weglassen.

LOCKED=ON

Sperrt das gesamte Arbeitsblatt. ON ist der Defaultwert.

LOCKED=OFF

Entsperrt das ganze Arbeitsblatt, ermöglicht aber, dass Sie einzelne Zellen oder Zellengruppen sperren oder entsperren.

Wenn Sie die folgende Deklaration in Ihr StyleSheet aufnehmen, können Sie das LOCKED-Attribut für bestimmte Zellen oder Zellengruppen angeben:

TYPE=REPORT, PROTECTED=ON, LOCKED=OFF,$

Fügen Sie, um bestimmte Teile des Arbeitsblatts zu sperren, der StyleSheet-Deklaration für die zu sperrenden Zellen das Attribut LOCKED=ON hinzu.

TYPE=type, [ COLUMN=columnspec ] ,LOCKED={ON|OFF},$

Hierbei gilt:

type

Ist der Elementtyp, der die Zellen beschreibt, die Sie sperren möchten.

columnspec

Ist eine gültige Spaltenspezifikation.

Die folgende Anfrage sperrt die gesamte Arbeitsmappe, da die StyleSheet-Deklarationen die folgende Deklaration enthalten:

TYPE=REPORT, PROTECTED=ON, $

Die Anfrage ist:

TABLE FILE CAR
HEADING
"Profit By Car "
" "
SUM RETAIL_COST AND DEALER_COST AND
COMPUTE PROFIT/D12.2 = RETAIL_COST - DEALER_COST;
BY CAR
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD AS EXLFORM1 FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=REPORT, PROTECTED=ON,            $
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
ENDSTYLE                                          
END

Sie können Werte im Arbeitsblatt nicht bearbeiten. Beim Versuch dies zu tun, wird eine Meldung angezeigt, die besagt, dass die Tabellenkalkulation gesperrt·ist:

Die folgende Anfrage sperrt die zweite Spalte (RETAIL_COST), da die StyleSheet-Deklarationen die folgenden Deklarationen enthalten:

TYPE=REPORT, PROTECTED=ON, LOCKED=OFF, $
TYPE=DATA, COLUMN=2, LOCKED=ON,$

Die Anfrage ist:

TABLE FILE CAR
HEADING
"Profit By Car "
" "
SUM RETAIL_COST AND DEALER_COST AND
COMPUTE PROFIT/D12.2 = RETAIL_COST - DEALER_COST;
BY CAR
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD AS EXLFORM2 FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=REPORT, PROTECTED=ON, LOCKED=OFF,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
TYPE=DATA, COLUMN=2, LOCKED=ON,$
ENDSTYLE
END

Sie können die Werte in der zweiten Spalte nicht bearbeiten, obwohl Sie Werte in anderen Spalten bearbeiten können. Wenn Sie versuchen, einen Wert in der Spalte 2 zu bearbeiten, wird eine Meldung angezeigt, die besagt, dass die Zellen gesperrt·sind:

Fügen Sie Ihrer Anfrage die folgende Syntax hinzu, um die Excel-Formeln in Ihrer Arbeitsmappe verwenden zu können:

ON TABLE {PCHOLD|HOLD}  FORMAT EXL2K FORMULA

Hierbei gilt:

PCHOLD

Zeigt die Ausgabe in einer EXL2K-Arbeitsmappe an.

HOLD

Speichert die Ausgabe zur Wiederverwendung in einem Excel 2000/2003-Arbeitsblatt. Genaueres finden Sie unter Ihre Reportausgabe speichern und wiederverwenden.

Das folgende Beispiel verdeutlicht, wie eine Spaltensumme in einer Reportanfrage in eine Excel-Formel übertragen wird, wenn Sie das Format EXL2K FORMULA verwenden. Beachten Sie, dass die Formatierung der Spaltensumme (TYPE=GRANDTOTAL) in der Excel 2000/2003-Arbeitsmappe beibehalten wird.

Wenn Sie die Summe im Report auswählen, wird die Gleichung =SUM(B4:B10) in der Bearbeitungsleiste angezeigt und spiegelt die Spaltensumme als Summe der Zellenbereiche wider.

TABLE FILE SHORT
HEADING
"Projected Return By Region"
" "
SUM PROJECTED_RETURN AS 'RETURN'
BY REGION AS 'REGION'
ON TABLE COLUMN-TOTAL
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD+UNDERLINE, SIZE=10,$
TYPE=GRANDTOTAL, STYLE=BOLD, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

Die Ausgabe ist:

Sie können alle Summen (Zwischensummen, Zeilensummen oder Spaltensummen) in eine Excel-Formel übertragen. Zugehörige Informationen finden Sie unter Übertragungsunterstützung für FORMAT EXL2K FORMULA

Diese Anfrage berechnet die Summen für Einnahmen und Bilanzen auf mehreren Kontinenten. Die Zeilensummen werden als Summen von Zellenbereichen dargestellt.

TABLE FILE SHORT
HEADING
"Projected Return Across Continent"
" "
SUM PROJECTED_RETURN AS 'RETURN' AND BALANCE AS 'BALANCE'
ACROSS CONTINENT AS 'CONTINENT'
BY REGION AS 'REGION'
ON CONTINENT ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
TYPE=SUBTOTAL,STYLE=BOLD, $
TYPE=GRANDTOTAL,STYLE=BOLD,SIZE=11,$
TYPE=ACROSSTITLE,STYLE=BOLD,SIZE=11,JUSTIFY=LEFT,$
TYPE=ACROSSVALUE,STYLE=BOLD,SIZE=10,JUSTIFY=CENTER,$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K FORMULA 
END

Die folgende Ausgabe markiert die Formel, welche die Zeilensumme in der Zelle I12=C12+E12+G12 berechnet:

Diese Anfrage summiert die Spalten für Verbraucherpreis und Händlerpreis und berechnet den Wert eines Feldes namens PROFIT, indem der Händlerpreis vom Verbraucherpreis abgezogen wird.

Die Formel für die berechneten Werte wird erzeugt, indem die interne Form der WebFOCUS-Formel (COMPUTE PROFIT/D12.2 = RC - DC;) in eine Excel-Formel übertragen wird. In diesem Beispiel werden die Formeln in den Zellen B14, C14 und D14 angezeigt.

Alle Felder, auf die in der Berechnung verwiesen wird, sollten im Report angezeigt werden, damit eine gültige Formel erstellt werden kann, die Zellenverweise verwendet. Andernfalls kann es sein, dass sie mit Werten erstellt wird, die sich nicht im Report befinden. Wenn die Felder, die in der Berechnung verwendet werden, im Report nicht vorhanden sind, und es nachfolgend zu einer Neuberechnung kommt, ist die Formel, die für die Neuberechnung erstellt wird, nicht richtig.

TABLE FILE CAR
ON TABLE SET PAGE-NUM OFF
SUM RC AND DC AND
COMPUTE PROFIT/D12.2 = RC - DC;
BY CAR
HEADING
"Profit By Car"
" "
ON TABLE COLUMN-TOTAL
ON TABLE PCHOLD FORMAT EXL2K FORMULA
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
TYPE=GRANDTOTAL, STYLE=BOLD, SIZE=11,$
ENDSTYLE
END

Die folgende Ausgabe markiert die Formel, die die Spaltensumme von PROFIT: D14=SUM(D4:D13) berechnet.

Im Anschluss wird gezeigt, wie Funktionen in Excel 2000/2003-Reports übertragen werden. Die Funktion IMOD dividiert ACCTNUMBER durch 1000 und gibt den Rest an LAST3_ACCT zurück. Die Excel-Formel entspricht =TRUNC((MOD($C3,(1000)))). TRUNC wird verwendet, wenn die Antwort, die eine Gleichung zurückgibt, in ein Ganzzahlfeld platziert wird, um sicherzustellen, dass es keine Dezimalstellen gibt:

TABLE FILE EMPLOYEE
PRINT ACCTNUMBER AS 'Account Number' AND COMPUTE
LAST3_ACCT/I3L = IMOD(ACCTNUMBER, 1000, LAST3_ACCT);
BY LAST_NAME AS 'Last Name' 
BY FIRST_NAME AS 'First Name'
WHERE (ACCTNUMBER NE 000000000) AND (DEPARTMENT EQ 'MIS');
ON TABLE PCHOLD FORMAT EXL2K FORMULA
ON TABLE SET STYLE *
TYPE=TITLE, SIZE=12, STYLE=BOLD, $
END

Die Ausgabe ist:

Wenn Ihr Report einen berechneten Wert enthält (durch den COMPUTE- oder RECOMPUTE-Befehl erzeugt), müssen alle Felder, auf die der berechnete Wert verweist, im Report angezeigt werden, damit Zellenverweise in die Formel aufgenommen werden. Wenn eine verwiesene Spalte in der Arbeitsmappe nicht angezeigt ist, wird der Datenwert in die Formel platziert, und nicht ein Zellenverweis. Im Fall einer Neuberechnung kann es sein, dass der verwendete Wert ein unzulässiger Wert aus dem letzten Detaildatensatz des Sortierumbruchs ist.

Die folgende Anfrage berechnet die Differenz (DIFF), indem budgetierte Dollar vom Dollarabsatz abgezogen werden. Das Feld "Budgetierte Dollar", das in der Formel verwendet wird, ist im Befehl SUM nicht enthalten. Der Wert von DIFF wird auf der Ebene Region neuberechnet:

TABLE FILE GGSALES
HEADING
"Profit By Region"
" "
SUM DOLLARS 
COMPUTE DIFF/I9=DOLLARS - BUDDOLLARS;
BY REGION
BY CATEGORY
ON REGION RECOMPUTE
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

Die Ausgabe zeigt, dass die Formel einen Datenwert subtrahiert, der auf dem Arbeitsblatt nicht angezeigt wird. Es ist in der Tat der Wert BUDDOLLARS aus der vorherigen Zeile:

Wenn Sie den SUM-Befehl folgendermaßen ändern, kann die Formel richtig neuberechnet werden:

SUM DOLLARS BUDDOLLARS

Die Formel, die mit dem neuen SUM-Befehl erzeugt wird, enthält Zellenverweise für beide Felder, die in der Berechnung verwendet werden:

Dieses Thema beschreibt Übersetzungsunterstützung für FORMAT EXL2K FORMULA. Die Verwendung von nicht unterstützten WebFOCUS-Features kann zu unzuverlässigen Ergebnissen führen.

• Alle Standardoperatoren werden unterstützt. Dazu gehören arithmetische Operatoren, relationale Operatoren, Zeichenfolgen-Operatoren, IF/THEN/ELSE-Operatoren und logische Operatoren. Es wird jedoch Spaltenschreibweise nicht unterstützt.

  Die Operatoren IS-PRESENT, IS-MISSING, IS-FROM, FROM, NOT-FROM, IS-MORE-THAN, IS---LESS-THAN, CONTAINS und OMITS werden nicht unterstützt.

  Die logischen Operatoren AND und OR werden nicht unterstützt in bedingten (IF-THEN-ELSE) oder logischen Formeln.

• Die folgenden Funktionen werden unterstützt:

  ABS, ARGLEN, ATODBL, BYTVAL, CHARGET, CTRAN, DMOD, DOWK, DOWK, DOWKL, EXP, FMOD, HEXBYT, HHMMSS, IMOD, LCWORD, LOCASE, LOG, MAX, MIN, OVRLAY, POSIT, RDUNIF, SQRT, SUBSTR, TODAY, UPCASE. Die Funktion EDIT wird unterstützt für die Umwandlung von Formaten (eine Argumentvariante). Sie wird nicht unterstützt für die Bearbeitung von Zeichenfolgen.

  Die Funktionen CTRFLD, LJUST und RJUST werden nicht empfohlen für die Ausrichtung von Daten in Excel-Spalten. Für die Verwendung mit proportionalen Excel-Schriftarten ist das StyleSheet-Attribut JUSTIFY besser geeignet.

  Sie müssen vorsichtig sein, wenn Sie Funktionen verwenden, die Dezimalwerte als Argument verwenden (BYTVAL, CTRAN, HEXBYT). Je nachdem, ob die Betriebsumgebung EBCDIC oder ASCII ist, können sich die Ergebnisse unterscheiden.

• EXL2K FORMULA wird für die folgenden WebFOCUS-Befehle und -Phrasen nicht unterstützt:
  • DEFINE.
  • OVER.
  • FOR.
  • NOPRINT.
  • Mehrfachanzeige-Befehle (PRINT, LIST, SUM und COUNT).
  • StyleSheet-Attribut SEQUENCE.
  • RECAP.
  • SET HIDENULLACRS.
  • SET SUBTOTALS = ABOVE.
  • LAST.
• Wenn Ihr Report einen berechneten Wert enthält (durch den COMPUTE- oder RECOMPUTE-Befehl erzeugt), müssen alle Felder, auf die der berechnete Wert verweist, im Report angezeigt werden, damit ein Zellenverweis in die Formel aufgenommen wird. Wenn die verwiesene Spalte in der Arbeitsmappe nicht angezeigt ist, wird der Datenwert in die Formel platziert, und nicht ein Zellenverweis.
• Es wird die BYDISPLAY ON-Einstellung empfohlen, da ansonsten der Sortierfeldwert nicht in allen Zeilen für Neuberechnungen verfügbar ist.
• Wenn eine Formel mehr als 1024 Zeichen erfordert, platziert WebFOCUS den Wert in die Zelle, und nicht die Formel.
• Bedingtes Styling basiert auf den Werten im ursprünglichen Report. Wenn die Werte im Arbeitsblatt geändert und die Formeln neuberechnet werden, spiegelt das Styling die aktualisierten Informationen nicht wider.

EXL2K FORMULA-Ausgabe unterstützt Präfixoperatoren, die in Summenzeilen verwendet werden, erzeugt von WebFOCUS-Befehlen, wie z. B. SUBTOTAL und RECOMPUTE. Wenn eine entsprechende Formel in Excel vorhanden ist, werden diese Präfixoperatoren in die entsprechende Excel-Summenformel übertragen. Wenn Präfixoperatoren direkt mit abgerufenen Daten verwendet werden, werden die Ergebnisse an Excel als Werte weitergereicht, und nicht als Formeln.

In der folgenden Tabelle werden die Präfixoperatoren identifiziert, die von EXL2K FORMULA unterstützt werden, wenn sie auf Summenzeilen verwendet werden, und die entsprechende Excel-Formel, platziert in das erzeugte Arbeitsblatt.

In der folgenden Anfrage mit der Datenquelle GGSALES berechnet der RECOMPUTE-Befehl für das Sortierfeld REGION das Maximum des aggregierten DOLLARS-Feldes und das Minimum des aggregierten BUDDOLLARS-Feldes:

TABLE FILE GGSALES
SUM UNITS DOLLARS BUDDOLLARS
AND COMPUTE DIFF/I10= DOLLARS-BUDDOLLARS;
BY REGION
BY CATEGORY
WHERE CATEGORY EQ 'Food' OR 'Coffee'
WHERE REGION EQ 'West' OR 'Midwest'
ON REGION RECOMPUTE MAX. DOLLARS MIN. BUDDOLLARS DIFF
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

In der Ausgabe wurde die Zelle, die für das neu berechnete DOLLARS für die Region Mittlerer Westen steht als die folgende Formel erzeugt:

=MIN(E2:E3)

In der folgenden Anfrage mit der Datenquelle GGSALES werden die Präfixoperatoren CNT., AVE. und PCT. im Anzeigebefehl SUM verwendet:

TABLE FILE GGSALES
SUM UNITS
CNT.UNITS
AVE.UNITS
PCT.UNITS
BY REGION 
BY ST 
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

In der Ausgabe ist zu sehen, dass die Präfixoperatoren an Excel nicht als Formeln weitergereicht wurden. Sie wurden als Datenwerte weitergereicht.

Die PivotTable-Toolbar wird nicht automatisch angezeigt, wenn ein PivotTable erstellt wird. Verwenden Sie, um die PivotTable-Toolbar anzuzeigen, die folgende Prozedur:

1. Klicken Sie in der Excel-Toolbar auf Ansicht.
2. Markieren Sie Toolbars.
3. Klicken Sie auf PivotTable.

   Excel 2000/2003 zeigt die PivotTable-Toolbar an und listet alle Felder auf, die in den Hauptteil des PivotTable-Reports gezogen werden können. Es muss im PivotTable eine Zelle ausgewählt sein, damit die PivotTable-Toolbar alle Felder anzeigen kann.

Der PivotTable wird mit dem PRINT-Befehl in Kombination mit den Phrasen BY, ACROSS, PAGEFIELDS und CACHEFIELDS erzeugt. Er enthält alle Optionen, die verwendet werden, um den Report und auch Felder, die in der PIVOT-Anfrage angegeben sind, zu entwerfen und zu formatieren. Felder können von der Toolbar in den Report gezogen werden. Die folgende Grafik zeigt die PivotTable-Ausgabe mit den Hauptelementen.

Die folgende Übersichtstabelle zeigt PivotTable-Elemente und die entsprechende FOCUS-Syntax.

Die folgende Tabelle fasst TABLE-Syntaxelemente zusammen, die in EXL2K PIVOT unterstützt werden. Die Auswirkung jedes Befehls auf Ihre PivotTable-Anfrage wird zusammen mit der erforderlichen Verwendung aufgelistet.

Das Folgende sind Syntaxvariationen, die Sie verwenden können, um FORMAT EXL2K PIVOT zu aktivieren.

• So können Sie die Ausgabe umgehend in Excel 2000/2003 betrachten:

  ON TABLE PCHOLD FORMAT EXL2K PIVOT

• So speichern Sie die Ausgabe zur späteren Ansicht auf der Festplatte:

  ON TABLE HOLD FORMAT EXL2K PIVOT AS mypivot									

  Hierbei gilt:

  mypivot

  Ist ein Name, den Sie der HOLD-Datei zuweisen.

  Es werden mit dieser Syntax zwei Dateien erzeugt:

  • MYPIVOT.XHT ist die Hauptdatei, die im Browser- oder Excel-Fenster angezeigt wird.
  • MYPIVO$.XML ist die Pivot-Cachedatei.

Sie sollten Folgendes berücksichtigen, wenn Sie Anfragen zur Ausgabe in einem PivotTable schreiben:

• Anfragen müssen den Anzeigebefehl PRINT verwenden. Dies ist notwendig, um alle Daten (jeden individuellen Datensatz) in die Pivot-Cachedatei zu extrahieren. Das Feld, das dem PRINT-Befehlt folgt, ist das designierte PivotTable-Datenfeld und muss ein numerisches Feld sein.

  Beachten Sie, dass die Befehle SUM und COUNT für EXL2K PIVOT nicht unterstützt werden. Sie können dennoch dieses systemeigene PivotTable-Verhalten in Excel verwenden, nachdem die Daten an einen Excel-PivotTable ausgegeben wurden.

• Ein Feld, das in einem PivotTable verwendet wird, kann nur einmal in der Reportanfrage gelistet werden. In einer FORMAT EXL2K PIVOT-Anfrage kann jedes Feld nur in jeweils einer Rolle eingesetzt werden. Ein Seitenfeld kann beispielsweise nicht gleichzeitig als Spalten- und Zeilenfeld angezeigt werden.
• Das Design ist vom anfänglichen Status Ihres Reports abhängig und wird nur beschränkt beibehalten, wenn Sie einen Pivot für die Ausgabe anwenden.
• NODATA-Felder werden als leere Zellen innerhalb des PivotTables angezeigt.
• Textfelder und Zeitstempelfelder können in Excel-PivotTables nicht verwendet werden. Stellen Sie außerdem sicher, dass für kein Feld Daten fehlen.
• Sie können Spalten-, Zeilen-, Gesamt- und Zwischensummen in einen PivotTable aufnehmen. Falls in einer Anfrage keine Summen angegeben sind, werden in Excel 2000/2003 keine Summen angezeigt.
• Ränder werden für Excel-Pivot-Tabellen nicht unterstützt.

Das folgende Beispiel zeigt, wie Sie einen PivotTable erzeugen:

TABLE FILE CAR
HEADING
"CAR File PivotTable"
"Sum of Sales by Car Across Model"
PRINT SALES
BY CAR
ACROSS MODEL
ON TABLE COLUMN-TOTAL
ON TABLE SET STYLE *
TYPE=HEADING, LINE=1, FONT='ARIAL', COLOR=PURPLE, SIZE=16, STYLE=BOLD,$
TYPE=HEADING, LINE=2, FONT='ARIAL', COLOR=PURPLE, SIZE=12, STYLE=BOLD,$
TYPE=DATA, FONT='ARIAL', COLOR=PURPLE,$
TYPE=GRANDTOTAL, FONT='ARIAL', COLOR=PURPLE, SIZE=16, STYLE=BOLD,$
ENDSTYLE 
ON TABLE PCHOLD AS CARPIVOT FORMAT EXL2K PIVOT
PAGEFIELDS COUNTRY
CACHEFIELDS RETAIL_COST TYPE  
END

Der Befehl ON TABLE PCHOLD FORMAT EXL2000K PIVOT zeigt den PivotTable in Excel 2000/2003 an. Alle Felder (einschließlich der Felder PRINT, BY und ACROSS sowie PAGEFIELDS und CACHEFIELDS) werden in der Toolbar angezeigt.

Felder, die als CACHEFIELDS bestimmt werden, müssen direkt nach dem PIVOT-Schlüsselwort in der ON TABLE PCHOLD FORMAT EXL2K PIVOT-Syntax oder nach einer PAGEFIELDS-Phrase platziert werden. Als CACHEFIELD angegebene Felder können nirgendwo sonst in der Anfrage designiert werden. Eine Liste der CACHEFIELDS wird durch dieselben Schlüsselwörter beendet, die eine normale Reportanfrage beenden, wie z. B. END oder eine weitere ON-Phrase.

Das folgende Beispiel verdeutlicht, wie Sie CACHEFIELDS angeben, um die PivotTable-Toolbar aufzufüllen.

TABLE FILE CAR
HEADING
"My PivotTable"
PRINT SALES 
BY COUNTRY BY CAR
ON COUNTRY SUB-TOTAL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=COUNTRY, COLOR=RED, $
type=heading,color=blue,style=bold, size=14, $
ENDSTYLE 
ON TABLE PCHOLD FORMAT EXL2K PIVOT
CACHEFIELDS MODEL TYPE  
END

Die Ausgabe ist:

Nur die Formate EXL2K und EXL2K FORMULA werden unterstützt und Excel-Templates können nur mit Excel 2002 oder einer neueren Version verwendet werden.

EXL2K PIVOT, EXL2K BYTOC-Reports, EXL97, EXCEL und zusammengesetzte Excel-Reports werden von Excel-Templates nicht unterstützt.

Mit dem EXL2K TEMPLATE-Format ist WEBARCHIVE automatisch aktiviert.

Der PCHOLD-Befehl gibt eine .xmh-Datei zurück, die Mid-Tier in .mht umwandelt. HOLD erstellt eine .xht-Datei.

Um einen Report mit einem Excel-Template zu erstellen, geben Sie Folgendes an:

ON TABLE PCHOLD FORMAT EXL2K TEMPLATE template_name SHEETNUMBER #

Hierbei gilt:

template_name

Der Name der Excel-Template-Datei (Arbeitsmappe), die sich auf dem WebFOCUS Reporting Server befindet.

#

Die Anzahl der Excel-Arbeitsblätter, die in der Template-Datei (Arbeitsmappe) ersetzt werden sollen.

Verwenden Sie zur Erstellung von benannten Bereichen in Excel

TYPE=type, IN-RANGES=rangename, $

Hierbei gilt:

type

Kennzeichnet die WebFOCUS-Report-Komponenten, die in den Bereich aufgenommen werden soll. Normalerweise werden die Folgenden gemeinsam verwendet:

DATA fügt dem benannten Bereich das DATA-Element des Reports hinzu (ausschließlich Kopfzeile, Fußzeile und Spaltentitel).

TITLE fügt dem benannten Bereich das TITLE-Element des Reports hinzu (einschließlich aller Spaltentitel).

Hinweis: Es können demselben benannten Bereich mehrere Elemente hinzugefügt werden.

rangename

Ist der Name, der der Ausgabe in der Excel-Arbeitsmappe zugewiesen wird, die von Ihrer Anwendung erstellt wird, und ist auch der Name auf den andere WebFOCUS-Anwendungen verweisen werden.

In diesem Beispiel wird ein Report in einem Arbeitsblatt einer Excel-Arbeitsmappe erstellt. Der für benannte Bereiche in Excel spezifische Code wird in der folgenden Syntax in Fettdruck angezeigt.

TABLE FILE GGSALES
PRINT
     PRODUCT
     DATE
     UNITS
BY REGION
BY DOLLARS
ON TABLE SET PAGE-NUM OFF
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
     UNITS=IN, SQUEEZE=ON, ORIENTATION=PORTRAIT, $
TYPE=REPORT, FONT='ARIAL', SIZE=9, COLOR='BLACK', BACKCOLOR='NONE',
STYLE=NORMAL, $ 
TYPE=DATA, IN-RANGES='RegionalSales', $
TYPE=TITLE, STYLE=BOLD, IN-RANGES='RegionalSales', $  
ENDSTYLE
END

Die Ausgabe in Excel ist:

Der dem benannten Bereich in Excel zugewiesene Name ist RegionalSales. Wenn zusätzliche Datenreihen hinzugefügt werden oder Datenspalten eingefügt werden, schließt der benannte Bereich sowohl die neuen als auch die alten Daten mit ein.

• Der Excel-Datenbereich, der mit einem benannten Bereich verbunden ist, muss zusammenhängend sein und darf keine Lücken enthalten. SUBHEAD und SUBFOOT gehören z. B. zu den Reportkomponenten, die Lücken in den Daten enthalten, und können nicht Teil eines benannten Bereichs sein.
• Es wird empfohlen ON TABLE SET BYDISPLAY ON zu verwenden. Dabei wird die Option, sich wiederholende Sortierwerte anzuzeigen, aktiviert, wodurch eine zusammenhängende Ausgabe ohne Datenlücken erzeugt wird.
• Es können zwei unterschiedliche Arbeitsblätter in der gleichen Arbeitsmappe nicht den gleichen Bereichsnamen haben.
• Wenn Sie zusammengesetzte Excel-Reports erstellen (d.h. mehrere TABLE-Ausgaben werden an dieselbe Excel-Arbeitsmappe ausgegeben), muss jeder Report einen eindeutigen Bereichsnamen haben, der auf der Ebene der Arbeitsmappe gespeichert wird.

Benannte Bereiche in Excel werden für die folgenden Excel-Formate unterstützt:

EXL2K, EXL2K FORMULA, EXL2K TEMPLATE

Benannte Bereiche in Excel werden für die folgenden Excel-Formate nicht unterstützt:

EXL2K BYTOC, EXCEL PIVOT

Benannte Bereiche in Excel werden dann nicht unterstützt, wenn die Reportsyntax Daten mit Lücken erzeugt, oder wenn Spaltenverweise sich über mehrere Spalten hinziehen, wie z. B.:

ACROSSCOLUMN, RECAP, RECOMPUTE, SUBHEAD, SUBFOOT, SUBTOTAL, SUB-TOTAL

Die Syntax ist identisch mit der von HTML TOC-Reports, mit der Ausnahme, dass nur ein einziges BY-Feld in EXL2K erlaubt ist, wohingegen in HTML mehrere BY-Felder erlaubt sind.

ON TABLE {HOLD|PCHOLD} FORMAT EXL2K BYTOC

Da nur eine Inhaltsverzeichnis-Ebene in EXL2K-Reports erlaubt ist, kann die optionale Zahl, die dem BYTOC-Schlüsselwort folgt, nur 1 sein.

Wie bei HTML, kann die SET COMPOUND-Syntax, die dem TABLE-Befehl vorausgeht, auch verwendet werden, um anzugeben, dass ein TOC erstellt werden soll:

SET COMPOUND=BYTOC

Da ein Inhaltsverzeichnis-Report je nach dem Wert des ersten BY-Feldes im Report in Arbeitsblätter aufgeteilt wird, muss der Report wenigstens ein BY-Feld enthalten. Das Burst-Feld darf ein NOPRINT-Feld sein.

• Ein Inhaltsverzeichnis-Report kann nicht in einen zusammengesetzten Report eingebettet werden.
• Ein Inhaltsverzeichnis-Report darf kein PivotTable-Report sein.
• Ein TOC-Report kann nicht mit einer Mehrfachverbanfrage erzeugt werden.

Hinweis: FORMULA wird mit Bursting nicht unterstützt.

Die folgende Anfrage mit der Datenquelle GGSALES erstellt separate Tabs basierend auf dem Sortierfeld REGION:

TABLE FILE GGSALES
SUM UNITS/D12C DOLLARS/D12CM
BY REGION NOPRINT
BY CATEGORY
BY PRODUCT
HEADING
"<REGION Region Sales"
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET BYDISPLAY ON
ON TABLE SET COMPOUND BYTOC
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL,SIZE=9,$
TYPE=HEADING, SIZE=12,$
TYPE=TITLE, BACKCOLOR=GREY,COLOR=WHITE, $
ENDSTYLE
END

Die Ausgabe ist:

• Die Tab-Namen des Arbeitsblattes sind die BY-Feldwerte, die den Daten des aktuellen Arbeitsblattes entsprechen. Wenn der Benutzer das TITLETEXT-Schlüsselwort im StyleSheet angibt, wird es ignoriert.
• Excel beschränkt die Länge von Arbeitsblatttiteln auf 31 Zeichen. Die folgenden Sonderzeichen können nicht verwendet werden: ':', '?', '*' und '/'.
• Wenn Sie Datumsfelder als BY-Burstfelder verwenden möchten, können Sie das Zeichen "-" anstatt dem Zeichen "/" aufnehmen. Das Zeichen "-" ist in einem Excel-Tab-Titel gültig. Wenn Sie jedoch das "/"-Zeichen verwenden, wird WebFOCUS es mit dem "-"-Zeichen ersetzen.

Die Option BYTOC des Formats WebFOCUSEXL2K erzeugt eine Arbeitsmappe, die ein individuelles Arbeitsblatt für jedes primäre Sortierfeld (BY) im Report enthält. Jedes Arbeitsblatt wird benannt mit dem Wert des primären Sortierfeldes, um die Daten zu identifizieren, die darin enthalten sind.

Es muss in Excel jeder Arbeitsblattname eindeutig sein. Excel ist nicht von Groß-/Kleinschreibung abhängig, was bedeutet, dass es Werte als identisch wertet, wenn sie dieselben Zeichen enthalten, aber die Groß-/Kleinschreibung sich unterscheidet. Beispielsweise wertet Excel die Werte COFFEE und Coffee als identische Werte, weshalb sie nicht als Arbeitsblattnamen für zwei unterschiedliche Arbeitsblätter verwendet werden können.

Per Default ist die WebFOCUS-Sortierverarbeitung von Groß-/Kleinschreibung abhängig, so dass derselbe Feldwert mit unterschiedlicher Groß-/Kleinschreibung als zwei unterschiedliche Werte betrachtet wird, wenn er als Sortierfeld (BY) verwendet werden. In einem Excel-BYTOC-Report erzeugt WebFOCUS Arbeitsblätter mit Arbeitsblattnamen für jeden Wert des primären Sortierschlüssels (BY), basierend auf Unterscheidung nach Groß-/Kleinschreibung. Für Sortierwerte, die sich nur durch die Groß-/Kleinschreibung unterscheiden, erhält das erste Arbeitsblatt den Sortierwert, und Excel hat Schwierigkeiten mit allen nachfolgenden Arbeitsblättern, die mit demselben Namen erzeugt werden. Der zweite Arbeitsblattname wird angezeigt als Recovered_Sheet1 anstelle des Wertes, den Excel als ein Duplikat wertet.

Im folgenden Beispiel erzeugt WebFOCUS separate Arbeitsblätter für die Werte Coffee und COFFEE. Das erste Arbeitsblatt wird COFFEE benannt, aber das nachfolgende Arbeitsblatt, das den Wert Coffee darstellt, kann Excel den Wert nicht als Arbeitsblattnamen verwenden, und zeigt den wiederhergestellten Wert an.

DEFINE FILE GGSALES
SHOWCAT/A15=IF PRODUCT EQ 'Espresso' THEN 'COFFEE' ELSE CATEGORY;
END
TABLE FILE GGSALES
BY SHOWCAT 
BY PRODUCT
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET COMPOUND 'BYTOC 1'
END

In der Ausgabe hat der zweite Tab den Namen Recovered_Sheet1, anstelle des von Groß-/Kleinschreibung abhängigen Wertes Coffee:

DEFINE FILE GGSALES
SHOWCAT/A15=IF PRODUCT EQ 'Espresso' THEN 'COFFEE' ELSE CATEGORY;
END
TABLE FILE GGSALES
PRINT SHOWCAT NOPRINT
COMPUTE CNTR/I2 = IF SHOWCAT EQ LAST SHOWCAT THEN LAST CNTR ELSE CNTR + 1; NOPRINT
BY TOTAL COMPUTE SHOWCAT2/A20 = EDIT(CNTR) | '-' | SHOWCAT; NOPRINT
BY SHOWCAT 
BY PRODUCT
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET COMPOUND BYTOC
ON TABLE SET STYLE *
GRID=OFF, $
ENDSTYLE
END

Ihrem WebFOCUS StyleSheet das Attribut ROWOVERFLOW hinzufügen

TYPE=REPORT, ROWOVERFLOW={ON|OFF|PBON}, [ROWLIMIT={n|MAX}...

Hierbei gilt:

ON

Aktiviert Überlauf-Arbeitsblätter.

OFF

Deaktiviert Überlauf-Arbeitsblätter. OFF ist der Defaultwert.

PBON

Fügt WebFOCUS-Seitenumbrüche ein, die die Seitenkopfzeile, Seitenfußzeile und Spaltentitel an den entsprechenden Stellen in den Arbeitsblattzeilen anzeigen. Diese Option führt nicht dazu, dass ein neues Arbeitsblatt begonnen wird, wenn ein WebFOCUS-Seitenumbruch vorkommt.

ROWLIMIT=n

Stellt einen Zielwert auf n Zeilen ein für die Anzahl der Zeilen, die in ein Arbeitsblatt aufgenommen werden sollen. Der Defaultwert ist der LINES-Wert (per Default 57).

ROWLIMIT=MAX

Stellt einen Zielwert von 65.000 Zeilen für EXL2K-Ausgabe für die Anzahl der Zeilen ein, die in ein Arbeitsblatt aufgenommen werden sollen.

Dieses Attribut funktioniert nur mit EXL2K- oder EXL07-Ausgabe. Für alle anderen Ausgabetypen wird das ROWOVERFLOW StyleSheet-Attribut ignoriert und der Datenfluss ist nicht betroffen.

• Die Reportkopfzeile wird einmal an den Anfang des ersten Arbeitsblatts platziert. Die Reportfußzeile wird einmal an das Ende des letzten Überlauf-Arbeitsblatts platziert.
• Wenn nicht die Einstellung PBON verwendet wird, werden Arbeitsblattkopfzeilen und Spaltentitel oben auf dem ursprünglichen Arbeitsblatt und auf jedem nachfolgenden Überlauf-Arbeitsblatt wiederholt. Arbeitsblattfußzeilen werden an das Ende des ursprünglichen Arbeitsblatts und auf jedes nachfolgende Überlauf-Arbeitsblatt platziert. Die Datenwerte werden in der obersten Datenzeile jedes Überlauf-Arbeitsblatts angezeigt, wie dies auch der Fall wäre für eine standardmäßige neue Seite.
• Die Gesamtzeilenanzahl im Report wird im unteren Bereich des letzten Überlauf-Arbeitsblatts direkt über den letzten Seiten- und Tabellenfußzeilen angezeigt.
• Zwischenkopfzeilen, Zwischenfußzeilen und Zwischensummenzeilen werden im Datenfluss normal angezeigt. Es wird nicht versucht, Gruppierungen in einem gegebenen Arbeitsblatt beizubehalten.
• Wenn ROWOVERFLOW=PBON, werden die Seitenkopfzeilen und -fußzeilen und Spaltentitel im Arbeitsblatt angezeigt, wenn ein WebFOCUS-Befehl einen Seitenumbruch verursacht.
• Wenn für EXL2K-Ausgabe das ROWOVERFLOW-Attribut im StyleSheet angegeben ist, und SET LINES größer als 65K ist, wird die folgende Meldung angezeigt und keine Ausgabedatei erzeugt:

  (FOC3313) The line number limit per EXCEL 2003 worksheet is 65536.

• Ausgabetypen, die Formelbezüge enthalten (EXL2K PIVOT und EXL2K FORMULA) werden nicht unterstützt. Formelbezüge werden nicht automatisch aktualisiert, um die Platzierung auf neuen Überlauf-Arbeitsblättern widerzuspiegeln.
• Das Überlauf-Arbeitsblatt-Feature trifft nur auf Zeilen und nicht auf Spalten zu. Es wird nicht automatisch ein neues Arbeitsblatt erstellt, wenn ein Report mehr als das Limit von 256 Spalten in Excel 2003 erzeugt.
• ROWOVERFLOW wird für zusammengesetztes Layout und BYTOC-Reports unterstützt.
• Da benannte Bereiche in Excel sich nicht über mehrere Arbeitsblätter erstrecken können, wird die IN-RANGES-Phrase, die benannte Bereiche in der resultierenden Arbeitsmappe definiert, mit dem ROWOVERFLOW-Feature nicht unterstützt. Wenn sie beide in derselben Anfrage vorhanden sind, hat ROWOVERFLOW Vorrang und die IN-RANGES-Phrase wird ignoriert.

Die folgende Anfrage erstellt EXL2K-Reportausgabe mit Überlauf-Arbeitsblättern. Der SET LINES-Befehl stellt die maximale Zeilenanzahl in jedem Arbeitsblatt auf etwa 2000 ein, und das ROWOVERFLOW=ON-Attribut im StyleSheet aktiviert das Überlauf-Feature. Ohne dieses Attribut wäre nur ein Arbeitsblatt anstelle von drei erzeugt worden:

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
-* ****Worksheet Heading****
HEADING
"SALES REPORT WORKSHEET <TABPAGENO"
" "
-* ****Worksheet Footing****
FOOTING
" "
"END OF WORKSHEET <TABPAGENO"

PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION
BY CATEGORY
BY PRODUCT
BY DATE
-* ****Subfoot****
ON REGION SUBFOOT
" "
" End of Region <REGION"
" "
-* ****Subhead****
ON CATEGORY SUBHEAD
" "
" Category <CATEGORY for Region <REGION"
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE SET LINES 2000
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT=EXLOVER, ROWOVERFLOW=ON,$
ENDSTYLE
END

Die Reportkopfzeile wird nur auf dem ersten Arbeitsblatt angezeigt, die Seitenkopfzeile und Spaltentitel auf jedem Arbeitsblatt und die Zwischenkopfzeile und Zwischenfußzeile immer dann, wenn sich der Wert des assoziierten Sortierfeldes ändert. In der folgenden Abbildung sehen Sie den Anfang des ersten Arbeitsblatts, wo die Reportkopfzeile, die Seitenkopfzeile, die Spaltentitel und die erste Zwischenkopfzeile angezeigt wird:

Beachten Sie, dass das TITLETEXT-Attribut im StyleSheet den Namen EXLOVER angibt, so dass die drei Arbeitsblätter mit den Namen EXLOVER1, EXLOVER2 und EXLOVER3 erzeugt wurden. Wenn es kein TITLETEXT-Attribut gegeben hätte, wären die Arbeitsblätter als SHEET1, SHEET2 und SHEET3 benannt worden.

Die Arbeitsblattfußzeile wird am Ende jedes Arbeitsblatts und die Reportfußzeile am Ende des letzten Arbeitsblatts angezeigt. In der folgenden Abbildung sehen Sie das Ende des letzten Arbeitsblatts, wo die letzte Zwischenfußzeile, die Seitenfußzeile und die Reportfußzeile angezeigt werden:

Die folgende Anfrage erstellt EXL2K-Reportausgabe mit Überlauf-Arbeitsblättern. Das Attribut ROWOVERFLOW=PBON im StyleSheet aktiviert das Überlauf-Feature, und ROWLIMIT=250 stellt die maximale Anzahl der Zeilen in jedem Arbeitsblatt auf etwa 250 ein. Ohne das Attribut wäre ein Arbeitsblatt erzeugt worden. Die Sortierphrase PRODUCT gibt einen Seitenumbruch an.

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION 
BY HIGHEST CATEGORY 
BY PRODUCT PAGE-BREAK
BY DATE
WHERE DATE GE '19971001'
-* ****Page Heading****
HEADING
" Product: <PRODUCT in Category: <CATEGORY for Region: <REGION"
-* ****Page Footing****
FOOTING
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
INCLUDE=endeflt,TITLETEXT=EXLOVER, ROWOVERFLOW=PBON, ROWLIMIT=250,
$
ENDSTYLE
END

Die Reportkopfzeile wird nur auf dem ersten Arbeitsblatt angezeigt, die Seitenkopfzeile, Seitenfußzeile und Spaltentitel auf jedem Arbeitsblatt und an jedem WebFOCUS-Seitenumbruch (jedes Mal, wenn sich das Produkt ändert), und die Zwischenkopfzeile und Zwischenfußzeile werden angezeigt, wenn sich der Wert des assoziierten Sortierfeldes ändert. In der folgenden Abbildung sehen Sie den oberen Bereich des ersten Arbeitsblatts.

Für einen Drilldown-Hyperlink auf eine FOCEXEC:

TYPE=type, [subtype], FOCEXEC=fex[(parameters ...)], [TARGET=frame,]
 [ALT='tooltip_text',] $

Für einen Drilldown-Hyperlink auf eine URL:

TYPE=type, [subtype], URL=url[(parameters ...)], [TARGET=frame,] [ALT='tooltip_text',] $

Hierbei gilt:

type

Bezeichnet die Reportkomponente, die Sie im Webbrowser ausgewählt haben, um den Link auszuführen. Das TYPE-Attribut und sein Wert müssen am Anfang der Deklaration stehen.

subtype

Sind alle weiteren Attribute, wie z. B. COLUMN, LINE, oder ITEM, die benötigt werden, um die Reportkomponente zu identifizieren, die Sie formatieren.

fex

Identifiziert den Dateinamen der verknüpften Prozedur, die ausgeführt werden soll, wenn Sie die Reportkomponente auswählen.

url

Identifiziert eine beliebige gültige URL einschließlich einer URL, die ein WebFOCUS Servlet-Programm angibt, oder den Namen einer Reportspalte in Klammern, deren Wert eine gültige URL ist, mit der der Link ein Verbindung herstellen wird.

parameters

Werte, die an den Report oder die URL weitergereicht werden.

frame

Identifiziert den Zielrahmen in der Webseite, in der die Ausgabe des Drilldown-Links angezeigt wird.

tooltip_text

Ist der informative Text, der angezeigt werden soll, wenn mit der Maus über den Hyperlink gefahren wird.

Die JAVASCRIPT- und IMAGE-Drilldown-Optionen werden mit dem EXL2K-Format nicht unterstützt.

In der folgenden Reportanfrage ist der Produktabsatz zusammengefasst und die Daten nach Region, Staat und Ladencode sortiert. Der Ladencode wird auch in den Zwischenfußzeilen angezeigt, wo Links zu detaillierten Reports über den Absatz des Ladens (nach Produkt oder Datum) angezeigt werden). Jede Zeile in der Zwischenfußzeile enthält zwei Textobjekte und ein eingebettetes Feld.

TABLE FILE GGSALES
HEADING
"Sales Report"
SUM DOLLARS/I08M
BY REGION BY ST BY STCD
ON STCD SUBFOOT
"View Store <STCD Sales By Product"
" "
"View Store <STCD Sales By Date"
ON TABLE PCHOLD FORMAT EXL2K
ON REGION PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=HEADING, SIZE=12, STYLE=BOLD, $
TYPE=SUBFOOT, LINE=1, OBJECT=TEXT, ITEM=2, 
FOCEXEC=PRDSALES(STOREID=STCD), ALT='Product Sales',$
TYPE=SUBFOOT, LINE=3, OBJECT=TEXT, ITEM=2, 
FOCEXEC=HSTSALES(STOREID=STCD),ALT='Sales History', $
ENDSTYLE
END

Unter Verwendung von StyleSheet-Deklarationen wird die Zischenfußphrase Absatz nach Produkt mit einer zweiten Prozedur verknüpft, die PRDSALES heißt, und übergibt ihr den Wert von STCD, der in der Zwischenfußzeile angezeigt ist. Die Zischenfußphrase Umsatz nach Datum verknüpft mit einer zweiten Prozedur, die HSTSALES heißt, und übergibt ihr den Wert von STCD, der in der Zwischenfußzeile angezeigt ist. Die ALT-Attribute in den StyleSheet-Deklarationen für die Hyperlinks bieten informative Meldungen.

Der verknüpfte PRDSALES-Report folgt:

TABLE FILE GGSALES
SUM UNITS
BY STCD
BY PRODUCT
WHERE STCD = '&STOREID'
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Der verknüpfte HSTSALES-Report folgt:

TABLE FILE GGSALES
SUM UNITS
BY STCD
BY DATE
WHERE STCD = '&STOREID'
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Es folgt die erste Reportseite für den Hauptreport. Wenn Sie mit der Maus über den Umsatz nach Datum-Link fahren, wird der informative Text Umsatzhistorie angezeigt:

Zusätzlich zu der Methode, die im Beispiel Einen WebFOCUS-Report in eine Excel 2000/2003-Arbeitsmappe einbetten beschrieben wird, können Sie andere Methoden einsetzen, um Web Query in Ihrem Arbeitsblatt zu nutzen. Wenn Sie beispielsweise ein vorhandenes Arbeitsblatt mit vielen vordefinierten Elementen haben, kann es sein, dass Sie die Abfrage in einem separaten Arbeitsblatt ausführen müssen, um herauszufinden wie viel Platz benötigt wird, bevor Sie sie der dem "Hauptarbeitsbereich" des Arbeitsblatts hinzufügen. Es ist eine gute Idee, ein bestimmtes Arbeitsblatt für Ihre Query vorzusehen und alles sonstige, das sich auf die Daten bezieht, über ein anderes Arbeitsblatt mit Formeln abzuwickeln.

Sie können aber auch alles in dasselbe Arbeitsblatt aufnehmen. Andere umliegende Elemente im Arbeitsblatt sollen automatisch neu positioniert werden, wenn die Daten zurückgegeben werden. Sie sollten ggf. trotzdem ein wenig Spielraum um die Abfrage freihalten, um sicher zu stellen, dass genügend Platz für die Reportausgabe vorhanden ist.

Eine IQY-Datei wird folgendermaßen konstruiert:

Type_of_query     [CR ]Version_of_query  [CR]URL               [CR]
{POST|GET} parameters   [CR]

Hierbei gilt:

Type_of_query

Ist Web. Da Web der Default-Wert ist, ist diese Eingabe optional.

Version_of_query

Ist die aktuelle Version der Web Query-Software. 1 ist der Defaultwert. Diese Eingabe ist optional.

URL

Ist eine notwendige Eingabe, die auf den WebFOCUS Server verweist. Die URL muss als ein Aufruf an das WebFOCUS-Servlet konstruiert werden und alle entsprechenden Parameter enthalten, die überreicht werden müssen.

POST parameters

Ist die bevorzugte Methode für das Abrufen großer Datenmengen und das Zurücksenden von Daten als separate Textzeile. Beispiel:

http://WFserver/ibi_apps/WFServlet[CR]
PARAM1=value & PARAM2=value

GET parameters

Ist die bevorzugte Methode für das Abrufen kleinerer Datenmengen und das Hinzufügen der Daten zur URL. Beispiel:

http://server/ibi_apps/WFServlet?PARAM1=value&PARAM2=value

[CR]

Bestimmt die benötigten Zeilenumschaltungen.

Schritt 1: Erstellen Sie den WebFOCUS-Report

Erstellen und speichern Sie den folgenden WebFOCUS-Report als webq97 mit vollständigem Styling. Sie betten diesen Report in eine Excel 97-Tabellenkalkulation ein. (Stellen Sie sicher, dass Cascading StyleSheets nicht aktiviert sind, damit die Anfrage in Excel 97 richtig ausgeführt wird und das passende Styling besitzt. SET HTMLCSS=OFF ist der Default-Wert.)

Die Zahlen links neben jeder Codezeile entsprechen den Anmerkungen, die der Anfrage folgen.

1.  TABLE FILE CENTORD 
2.  SUM LINEPRICE AS 'Sales' 
3.  BY YEAR AS 'Year' 
4.  BY PRODCAT AS 'Category' 
5.  BY PRODNAME AS 'Product' 
6.  WHERE YEAR EQ '&YEAR'; 
7.  ON TABLE SET BYDISPLAY ON 
8.  ON TABLE PCHOLD FORMAT HTML 
9.  ON TABLE SET PAGE-NUM TOP 
10. ON TABLE SET STYLE * 
11. TYPE=REPORT, FONT=ARIAL, SIZE=10, GRID=OFF, BACKCOLOR=YELLOW, $ 
12. TYPE=TITLE, SIZE=11, STYLE=BOLD, $ 
13. TYPE=DATA, COLOR=RED, WHEN=LINEPRICE LT 15000000, $ 
14. TYPE=DATA, COLUMN=PRODCAT, FOCEXEC=webq2(PRODCAT=N1), $ 
15. ENDSTYLE 
16. END

Die Zeile 1 identifiziert die Musterdatenquelle CENTORD, die Verkaufsdaten der Century Corporation enthält.

Die Zeilen 2-5 definieren Anzeige- und Sortiervoraussetzungen für den Report.

Die Zeile 6 gibt Auswahlkriterien mit der Variablen &YEAR an.

Die Zeile 7 stellt BYDISPLAY auf ON. Diese Einstellung stellt sicher, dass wiederholte Sortierwerte im Report mit Daten aufgefüllt werden.

Per Default werden wiederholte Sortierwerte in vertikalen Spalten (oder BY-Feldern) eines WebFOCUS-Reports unterdrückt und führen so zu leeren Feldern im Report. Dieses Verhalten ist für Excel-Reports nicht wünschenswert, da sie mit Daten arbeiten, die in jeder Spalte, auf die sie zutreffen, wiederholt werden. Eine leere Spalte oder Zeile kann zu irreführenden Ergebnissen führen, wenn Daten sortiert werden.

Die Zeile 8 definiert das Ausgabeformat als HTML.

Wichtig: Der Report muss im HTML-Format sein (und nicht in EXL97). Dies ist so, da Microsoft Query vollständig formatierte HTML-Seiten oder individuelle HTML-Tabellen in eine Tabellenkalkulation importiert. Wenn eine EXL97-Anfrage aus einer Abfrage ausgeführt wird, werden keine Daten in die Tabellenkalkulation transferiert.

Die Zeile 9 deaktiviert die Seitennummerierung und entfernt alle zusätzlichen Zeilen, die über dem Spaltentitel erzeugt wurden.

Die Zeilen 10-15 geben Styling-Attribute für den Report an: Hintergrundfarbe, bedingtes Styling, ein Drilldown auf eine andere Prozedur und andere Styling-Elemente wurden festgelegt. Styling, einschließlich Drilldowns, wird in Excel übernommen.

Schritt 2: Eine Web Query-Datei (IQY) erstellen

Öffnen Sie einen Texteditor und erstellen Sie die folgende Web Query-Datei

1.  WEB 
2.  1 
3.  http://WFserver/ibi_apps/WFServlet?IBIF_ex=webq97
       &YEAR=["YEAR","Select Year"]

Hierbei gilt:

Die Zeile 1 identifiziert dies als eine Webanfrage.

Die Zeile 2 identifiziert die aktuelle Version von Microsoft Query.

Die Zeile 3 ist eine typische WebFOCUS-Anfrage und verwendet die GET-Methode. Der Name der Prozedur ist webq97. Die URL-Zeile übergibt einen YEAR-Parameter in die Prozedur. Der Benutzer wird aufgefordert, einen Wert für YEAR anzugeben. Das Übergeben von Parametern ist natürlich optional. Im obigen Beispiel ist der Parameter dynamisch, die Parameter können aber auch statisch sein. Dies bedeutet, dass sie in der IQY-Datei hardcodiert werden.

Beachten Sie, dass in dieser Datei Zeilenumschaltungen zwischen Zeilen notwendig sind.

Speichern Sie, nachdem Sie die Abfrage konstruiert haben, das Dokument mit einer .iqy-Erweiterung im Verzeichnis Abfragen unter Microsoft Office. Beispiel,

<drive>:\Program Files\Microsoft Office\Queries\webq97.iqy

Nun, da die IQY-Datei fertiggestellt ist, können Sie die Tabellenkalkulation erstellen und die Abfrage einbetten.

Schritt 3: Die Abfrage in eine Excel 97-Tabellenkalkulation einbetten

Dieses Beispiel beginnt mit einer leeren Tabellenkalkulation, bettet die Abfrage ein und fügt dann die Besonderheiten hinzu.

1. Öffnen Sie eine leere Tabellenkalkulation. Wählen Sie im Datenmenü Externe Daten abrufen und dann Webanfrage ausführen aus. Die Dialogbox Abfrage ausführen wird geöffnet.
2. Lokalisieren Sie die IQY-Datei webq97.icy und klicken Sie auf den Button Daten abrufen. Die Dialogbox Abfrage ausführen wird geöffnet.

   

3. Geben Sie an, wo die Daten in Ihrer Tabellenkalkulation platziert werden sollen. Sie können einen Bereich in der aktuellen Tabellenkalkulation auswählen oder Sie können die Daten in ein neues Arbeitsblatt einfügen. Geben Sie in diesem Fall den Bereich an, wie es gezeigt wird:

   

   In einem leeren Arbeitsblatt ist es nicht notwendig, einen Bereich auszuwählen. Sie können jedoch die Daten auch in ein neues Arbeitsblatt ausgeben und Formelverweise verwenden, um mit den Daten zu arbeiten.

4. Klicken Sie auf den Button Eigenschaften in der Dialogbox Externe Daten zurückgeben. Die Externe Datenbereich-Eigenschaften-Dialogbox wird geöffnet. Benennen Sie die Abfrage und stellen Sie ihr Verhalten ein. Sie können die Abfrage beispielsweise so einstellen, dass sie jedes Mal, wenn das Arbeitsblatt geöffnet wird, automatisch aktualisiert wird. (Beachten Sie, dass Sie diese Eigenschaften auch nach der ersten Ausführung einstellen können.)

   

   Klicken Sie auf OK.

5. Klicken Sie auf den Button Parameter in der Dialogbox Externe Daten zurückgeben, um das Verhalten für alle Parameter, die in Ihrer Abfrage vorkommen, einzustellen. Sie können den Benutzer zur Eingabe auffordern, einen statischen Wert einstellen oder einen Wert aus einer Zelle im Arbeitsblatt verwenden. In diesem Beispiel fordern Sie den Benutzer auf, einen Wert für YEAR einzugeben.

   Geben Sie den Wert 1999 ein.

   

6. Klicken Sie, nachdem Sie den Bereich ausgewählt und alle Abfrageeigenschaften eingestellt haben, auf den Button OK.

   Die Abfrage wird ausgeführt und die Daten importiert. Die folgende Meldung wird in der Tabellenkalkulation angezeigt:

   webq97: Getting Data...

   Die Daten werden in der Tabellenkalkulation angezeigt:

   

7. Nun, da die Daten in die Tabellenkalkulation transferiert wurden, können Sie Features wie z. B. Formeln, Bilder, Diagramme, Macros usw. hinzufügen.

   

Sie können die Tabellenkalkulation nun entweder lokal auf Ihrem PC oder auf einem freigegebenen Netzlaufwerk, auf das mehrere Benutzer Zugriff haben, speichern oder sie in Ihrer Webanwendung bereitstellen. Siehe Ein Arbeitsblatt mit WebFOCUS Web Query deployen.