Cómo crear encabezados y pies

En esta sección:

Existen varios tipos de encabezados o pies:



x
Limitaciones de los encabezados y pies

Las siguientes limitaciones se aplican a los encabezados y pies de informes, encabezados y pies de páginas, y encabezados y pies de clasificación:


Principio de página

x
Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe

Cómo:

En una sola línea de código de encabezado o pie, entre comillas dobles, puede haber un máximo de 32K de caracteres. Ahora bien, en algunos editores, la longitud máxima de una línea de código en un procedimiento es de 80 caracteres. En casos como ese, puede utilizar el marcador de posición <0X para continuar su encabezado en el próximo archivo. El contenido y los espacios del encabezado o pie aparecen exactamente como si hubieran sido escritos en una sola línea.

aunque no necesite ampliar su código más allá del límite de 80 caracteres por línea, esta técnica le ofrece conveniencia, toda vez que las líneas más cortas suelen ser más fáciles de leer en la pantalla o de imprimir en las impresoras.



x
Procedimiento: Cómo Ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe

Para ampliar la longitud de un encabezado o pie de una sola línea sobre el límite de los 80 caracteres:

  1. Empiece el encabezado con comillas dobles (").
  2. Divida el contenido del encabezado o el pie en múltiples líneas de hasta 76 caracteres cada una mediante el marcador de posición <0X en cualquier punto de la línea para continuar su encabezado en la siguiente línea. (Se necesitan los cuatro espacios restantes para el marcador de posición, con un espacio en blanco antes de éste.)
  3. La línea de encabezado o pie puede contener un máximo de 410 caracteres y cada línea debe terminar con un marcador de posición <0X.
  4. Coloque las comillas dobles de cierre al final de la última línea del código del encabezado o el pie.

Puede utilizar esta técnica para crear un encabezado o pie de informe, un encabezado o pie de página o un encabezado o pie de clasificación de hasta 410 caracteres. Para ver una explicación de esto, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.



Ejemplo: Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe

Esta solicitud crea un encabezado de clasificación codificado en dos líneas. El marcado de indicador <0X coloca el primer carácter en la línea que sigue inmediatamente a la derecha del último carácter de la línea anterior. (No se insertan espacios entre el marcador de posición y el inicio de una línea de continuación.)

SET ONLINE-FMT = HTML
SET PAGE-NUM = OFF
JOIN STORE_CODE IN CENTCOMP TO STORE_CODE IN CENTORD
TABLE FILE CENTCOMP
HEADING
"Century Corporation Orders Report"
PRINT PROD_NUM QUANTITY LINEPRICE
BY STORE_CODE NOPRINT
BY ORDER_NUM
ON STORE_CODE SUBHEAD
"Century Corporation orders for store <STORENAME <0X
    (store # <STORE_CODE|) in <STATE|."
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
TYPE=HEADING, FONT='ARIAL', STYLE=BOLD, $
TYPE=SUBHEAD, OBJECT=FIELD, ITEM=2, STYLE=ITALIC, $
TYPE=SUBHEAD, OBJECT=FIELD, ITEM=3, STYLE=BOLD, $
ENDSTYLE
END

El resultado parcial es:

Sugerencia: Puede utilizar esta técnica para crear un encabezado de hasta 410 caracteres. Aunque se ha usado aquí para un encabezado de clasificación, puede utilizar esta técnica para cualquier línea de encabezado o pie.


Principio de página

x
Cómo crear un informe personalizado o un título de hoja de cálculo

Cómo:

Puede crear un título de informe que:

Los nombres de las pestañas de la hoja de cálculo, en un informe de tabla de contenidos de Excel, son los valores de campos BY correspondientes a los datos de la hoja actual. Se ignorará si el usuario especifica la palabra clave TITLETEXT en la hoja de estilos.



x
Sintaxis: Cómo Crear un título de informe personalizado

Añada la siguiente declaración a su hoja de estilos de WebFOCUS.

TYPE=REPORT, TITLETEXT='title', $

donde:

title

Es el texto de su título.

El máximo número de caracteres para:

  • El nombre de la pestaña de la hoja de cálculo en un informe EXL2K es de 31. Cualquier texto que supere los 31 caracteres será truncado.
  • El título de navegador de un informe HTML o un gráfico es 95. Este es el límite impuesto por el navegador.

    El texto especificado en el título se coloca en el archivo tal como está y no se codifica. Los caracteres especiales, como <, > y &, no deben usarse, puesto que tienen un significado especial en HTML y pueden producir resultados inesperados. Nota: Las palabras "Microsoft Internet Explorer" se adjuntan siempre a cualquier título de informe HTML.



Ejemplo: Cómo crear un título de informe personalizado en un informe HTML

A continuación se muestra cómo reemplazar el título de informe predeterminado en un informe HTML mediante el atributo TITLETEXT en su hoja de estilos.

TABLE FILE SHORT
SUM PROJECTED REGION
BY REGION
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, TITLETEXT='1999 Sales Report', $ 
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:



Ejemplo: Cómo crear un título de informe personalizado en un informe EXL2K

A continuación se muestra cómo reemplazar el título de hoja de cálculo predeterminado en un informe EXL2K mediante el atributo TITLETEXT en su hoja de estilos.

TABLE FILE SHORT
SUM PROJECTED_RETURN
BY REGION
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE * 
TYPE=REPORT, TITLETEXT='1999 Sales Report', $ 
ENDSTYLE
END

La salida es:


Principio de página

x
Cómo crear un encabezado o pie de informe

Cómo:

Antes de la primera página de un informe aparece un encabezado de informe, que es uno de los componentes más importantes del informe. Ofrece un nombre único para un informe e identifica su propósito o contenido. Puede usar un encabezado corto, de una línea, que satisfaga las necesidades del usuario, o uno que incluya varias líneas con la información correspondiente.

Después de la última página de un informe aparece un pie de informe. Puede añadir un pie de informe para indicar el final de los datos, de manera que el usuario sepa que ha terminado el informe. Un pie de informe también proporciona información adicional, como por ejemplo quién es el autor del informe.

Un encabezado o pie puede contener texto, campos, variables de Dialogue Manager, imágenes y marcadores de posición.



x
Sintaxis: Cómo Crear un encabezado de informe

Incluya la sintaxis siguiente en la solicitud. Cada línea de encabezado o pie debe empezar y terminar con comillas dobles.

ON TABLE [PAGE-BREAK AND] SUBHEAD
 "content ... "
["content ... "]
.
.
.
["content ... "]

donde:

PAGE-BREAK
Es un comando opcional que crea el encabezado de informe en la primera página por sí solo, seguido de la página o páginas de datos. Si no utiliza PAGE-BREAK, el encabezado de informe aparece en la primera página del informe, seguido de un encabezado de página, si tuviera alguno, y títulos de columna. Para obtener información relacionada, consulte Cómo colocar el encabezado o pie de página de un informe en su propia página.
SUBHEAD
Es el comando necesario para designar un encabezado de informe.
content
El contenido de un encabezado o pie puede incluir los siguientes elementos, entre comillas dobles. (Si se omiten las comillas del final, las líneas posteriores se consideran como parte del encabezado del informe).
text
Es el texto que aparece en la primera página del informe. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, después del comando SUBHEAD.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable
Puede ser cualquiera de los siguientes o una combinación de estos:

Fields (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o un campo de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Images. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker
Le permite colocar elementos, identificarlos para formatearlos y ampliar el código más allá del límite de línea de 80 caracteres de algunos editores de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un encabezado, pie, título o texto libre de FML.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n para colocar el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

Blank lines
Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)


Ejemplo: Cómo crear un encabezado de informe de una sola línea

Esta solicitud crea un encabezado de informe de una sola línea que identifica el contenido del informe.

TABLE FILE GGSALES
PRINT BUDDOLLARS DOLLARS
BY STCD
WHERE STCD EQ 'R1019' 
ON TABLE SUBHEAD
"Sales Report for Store Code R1019" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET WEBVIEWER ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF,$
ENDSTYLE
END

La salida muestra la colocación de un encabezado de informe en un informe HTML de múltiples páginas. El encabezado de informe se encuentra en la parte superior de la primera página.

Las páginas posteriores no tienen encabezado.

Sugerencia: Si no ve las flechas de navegación, pulse sobre el botón para ampliar la pantalla.



x
Sintaxis: Cómo Crear un pie de informe

Incluya la sintaxis siguiente en la solicitud. Cada línea de encabezado o pie debe empezar y terminar con comillas dobles.

ON TABLE [PAGE-BREAK AND] SUBFOOT
 "content ... "
["content ... "]
.
.
.
["content ... "]

donde:

PAGE-BREAK
Es un comando opcional que, por sí solo, crea el pie del informe después de la última página. Si no incluye PAGE-BREAK, el pie de informe aparece como la última línea del informe. Para obtener información relacionada, consulte Cómo colocar el encabezado o pie de página de un informe en su propia página.
SUBFOOT
Es el comando necesario para utilizar un pie de informe.
content
El contenido de un encabezado o pie puede incluir los siguientes elementos, entre comillas dobles. (Si se omite la comilla final, todas las líneas posteriores de la solicitud se consideran parte del pie de informe, a menos que utilice el marcador de posición <0X.)
text
Es el texto que aparece en la última página del informe. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, después del comando SUBFOOT.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable
Puede ser cualquiera de los siguientes o una combinación de estos:

Fields (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o un campo de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Images. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker
Le permite colocar elementos, identificar elementos para dar formato y ampliar el código más allá del límite de 80 caracteres por línea del editor de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un encabezado, pie, título o texto libre de FML.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n para colocar el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

Blank lines
Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)


Ejemplo: Cómo crear un pie de informe de una sola línea

Esta solicitud crea un pie de informe de una sola línea que identifica al autor del informe.

TABLE FILE GGSALES
PRINT UNITS
WHERE UNITS GE 1400
BY STCD BY REGION
WHERE REGION EQ 'Northeast' 
ON TABLE SUBFOOT
"AUTHOR: MARY SMITH" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET WEBVIEWER ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF,$
ENDSTYLE
END

La salida muestra la ubicación de un pie de informe en un informe HTML de múltiples páginas. El pie de informe viene después de los datos en la última página.

Sugerencia: Si no ve las flechas de navegación, pulse sobre el botón para ampliar la pantalla.


Principio de página

x
Cómo crear un encabezado o pie de página

Cómo:

Referencia:

En la parte superior de cada página de un informe aparece un encabezado de página, en tanto que en el fondo de cada página aparece un pie de página.

Añada un encabezado de página para identificar y reforzar el contenido de un informe y su propósito de página en página o incluya una variable que personalice el encabezado de cada página. Por ejemplo, piense en un informe con información bancaria de empleados organizado por departamento. La información de cada departamento aparece en una página por separado. El encabezado de página de este informe identifica el departamento citado en cada página (por ejemplo, ACCOUNT REPORT FOR PRODUCTION DEPARTMENT).

Añada un pie de página para proveer información que deba repetirse en cada página, como la fecha del informe o un recordatorio de que es confidencial. También puede usar un pie de página para proveer información descriptiva acerca de un informe, del tipo PRELIMINARY o DRAFT COPY.

Los encabezados y pies de página pueden incluir texto, campos variables de Dialogue Manager y marcadores de posición.

Además, puede utilizar la sintaxis del encabezado o el pie de página para crear un informe de formato libre (es decir, que no sea tabular), en que coloque los datos en una página mediante un diseño de su propia invención. Para obtener información detallada, consulte Cómo crear un informe de formato libre.

Las solicitudes TABLE pueden tener más de un encabezado o pie de página. Para cada encabezado o pie, las cláusulas WHEN emitidas frente a los datos que se están recuperando pueden determinar si el encabezado o pie aparece en la salida del informe.

En un encabezado, los datos de la cláusula WHEN y los valores de campos de datos mostrados en el encabezado están basados en la primera línea de la página. En un pie, los datos de la cláusula WHEN y los valores de campos de datos mostrados en el pie están basados en la última línea de la página.

El atributo de hoja de estilos CONDITION le permite identificar una cláusula WHEN específica para dar estilo a cada encabezado o pie, de forma independiente. Para más información, consulte Cómo identificar un encabezado o pie .



x
Sintaxis: Cómo Crear un encabezado de página

Incluya la sintaxis siguiente en la solicitud. Cada línea de encabezado o pie debe empezar y terminar con comillas dobles.

[HEADING [CENTER]]
 "content ... "
["content ... "]
.
.
.
["content ... "]

donde:

HEADING
Es un comando opcional si coloca el texto antes del primer comando de visualización (por ejemplo, PRINT o SUM); de lo contrario, es obligatorio identificar el texto como encabezado de página.
CENTER
Es un comando opcional que centra el encabezado de página sobre los datos del informe. Para obtener información detallada, consulte Cómo Centrar un encabezado o pie de página utilizando el formato Legacy.
content
El contenido de un encabezado o pie puede incluir los siguientes elementos, entre comillas dobles. (Si se omite la comilla final, todas las líneas posteriores de la solicitud se consideran parte del encabezado de informe.)
text
Es el texto de un encabezado de página. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, después del comando HEADING.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable
Puede ser cualquiera de los siguientes o una combinación de estos:

Fields (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o un campo de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Images. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker
Le permite colocar elementos, identificar elementos para dar formato y ampliar el código más allá del límite de 80 caracteres por línea del editor de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un encabezado, pie, título o texto libre de FML.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n para colocar el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

Blank lines
Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)


Ejemplo: Cómo crear un encabezado de página de una sola línea

Esta solicitud omite el comando HEADING, pues el encabezado de página precede al comando de visualización PRINT. El encabezado de página incluye texto y un campo insertado.

TABLE FILE EMPLOYEE 
"ACCOUNT REPORT FOR DEPARTMENT <DEPARTMENT" 
PRINT CURR_SAL BY DEPARTMENT BY HIGHEST BANK_ACCT
BY EMP_ID
ON DEPARTMENT PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$
ENDSTYLE
END

La salida muestra la colocación de un encabezado de página en un informe HTML de múltiples páginas. El encabezado de página aparece en ambas páginas del informe e identifica el departamento al que se aplican los datos. Para obtener información acerca de valores de campo insertados, consulte Cómo incluir un valor de campo en un encabezado o un pie. La primera página de datos se aplica al departamento MIS.

La segunda página de datos se aplica al departamento PRODUCTION.



x
Sintaxis: Cómo Crear un pie de página

Incluya la sintaxis siguiente en la solicitud. Cada línea de encabezado o pie debe empezar y terminar con comillas dobles.

FOOTING [CENTER] [BOTTOM]
  "content ... "
["content ... "]
.
.
.
["content ... "]

donde:

FOOTING
Es el comando necesario para identificar el contenido como un pie de página.
CENTER
Es un comando opcional que centra el pie de página sobre los datos del informe. Para obtener información detallada acerca de CENTER, consulte Cómo Centrar un encabezado o pie de página utilizando el formato Legacy.
BOTTOM
Es un comando opcional que coloca el pie de página al final de la página. Si omite BOTTOM, el pie de página aparece dos líneas por debajo de los datos del informe. Para obtener información detallada acerca de BOTTOM, consulte Cómo Colocar un pie de página al final de la página.
content
El contenido de un encabezado o pie puede incluir los siguientes elementos, entre comillas dobles. (Si se omite la comilla final, todas las líneas posteriores de la solicitud se consideran parte del pie de página, a menos que use el marcador de posición <0X.)
text
Es texto para el pie de página. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, luego del comando FOOTING.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable
Puede ser cualquiera de los siguientes o una combinación de estos:

Fields (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o un campo de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Images. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker
Le permite colocar elementos, identificar elementos para dar formato y ampliar el código más allá del límite de 80 caracteres por línea del editor de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un encabezado, pie, título o texto libre de FML.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n coloca el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

Blank lines
Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)


Ejemplo: Cómo crear un pie de página de una sola línea

Esta solicitud crea un pie de página de dos líneas que identifica los datos como preliminares e indica cuándo estará disponible el informe final.

TABLE FILE GGSALES
PRINT UNITS DOLLARS
BY CATEGORY BY STCD
WHERE TOTAL DOLLARS GE 25000 
FOOTING
"PRELIMINARY SALES FIGURES"
"FINAL TO COME END OF MONTH" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET WEBVIEWER ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF,$
ENDSTYLE
END

La salida parcial muestra la colocación de pies de página en un informe HTML de múltiples páginas. El pie de página aparece en ambas páginas del informe.

Sugerencia: Si no ve las flechas de navegación, pulse sobre el botón para ampliar la pantalla.



x
Sintaxis: Cómo Especificar un encabezado o pie con una cláusula WHEN
{HEADING [CENTER]|FOOTING}
"text_and_data1"
   .
   .
   .
"text_and_datan"
WHEN expression						

donde:

text_and_data1, text_and_datan
Es el texto y los datos de cada línea de encabezado o pie.
expression
Es una expresión que se resuelve en TRUE o FALSE (1 o 0). Si su valor se resuelve en TRUE, el encabezado o pie aparece. Si la expresión se resuelve en FALSE, el encabezado o pie no aparece.


x
Referencia: Notas de uso para encabezados múltiples

Principio de página

x
Cómo congelar encabezados, pies y títulos de columna HTML

Cómo:

Referencia:

Puede que desee desplazarse por los datos de un informe al tiempo que congela los encabezados, títulos de columna y pies, para ver el contexto de salida del informe.

Los atributos de hoja de estilos le permiten establecer un área de desplazamiento para la salida de informes HTML.

La característica HTML HFREEZE de los informes es compatible con las versiones de los navegadores listados en la Matriz de compatibilidad con navegadores de WebFOCUS Edición 8.0.x. La característica HFREEZE aparece listada en la Matriz de soporte de navegadores 8.0.x, en la fila Componentes de JavaScript de la sección Características de informes HTML.



x
Sintaxis: Cómo Crear un área de desplazamiento en un informe HTML
TYPE=REPORT, HFREEZE={ON|TOP|BOTTOM|OFF}, [ SCROLLHEIGHT={4|nn[.n]}], $

donde:

HFREEZE=ON
Congela el encabezado, los títulos de columna, los totales generales y el pie.
HFREEZE=TOP
Congela el encabezado y los títulos de columna.
HFREEZE=BOTTOM
Congela los totales generales y el pie.
nn[.n]
Es la altura, en pulgadas, del área de desplazamiento. La altura predeterminada es de 4 pulgadas.


x
Referencia: HFREEZE con títulos de columnas en blanco

La característica FREEZE de los informes es compatible con los títulos de columnas en blanco. La barra de desplazamiento vertical HFREEZE queda alineada con la primera fila de datos del informe.



x
Referencia: Notas de uso para la congelación de áreas de salida de informes HTML

Principio de página

x
Cómo crear un encabezado o pie de clasificación

Cómo:

Referencia:

Un encabezado de clasificación es un texto que precede a un cambio en un valor de campo de clasificación e identifica el principio de un grupo de datos relacionados. Un pie de clasificación es un texto que sigue a un cambio en un valor de campo de clasificación e identifica el final de un grupo de datos relacionados.

Los encabezados o pies de clasificación, que aparecen en el cuerpo de un informe, le ayudan a identificar las distintas áreas de detalle de un informe. Los encabezados o pies de clasificación pueden incluir texto, campos, variables de Dialogue Manager, imágenes y marcadores de posición.

La inclusión de una frase WHEN en una solicitud puede generar un mensaje, implementado como encabezado o pie de clasificación, para datos que satisfagan los criterios que haya definido. Para obtener información detallada acerca del formato condicional, consulte Cómo controlar el formato del informe. Para ilustrar esta técnica; consulte Cómo crear un pie de clasificación condicional con múltiples opciones de clasificación.

Si utiliza un comando RECAP para crear valores de subtotal en un cálculo, puede reemplazar la etiqueta RECAP predeterminada por un pie de clasificación más relevante introduciendo un comando SUBFOOT para un campo inmediatamente después del comando RECAP para dicho campo. Para obtener información detallada acerca del comando RECAP, consulte Cómo incluir totales y subtotales.

Si hay uno o más campos insertados en el pie de clasificación, puede omitir un comando de salida del informe, toda vez que, de forma predeterminada, se suman los campos de datos en las cabeceras y los pies. Ahora bien, si una solicitud no contiene un comando SUM explícita y además se especifica un campo de visualización en el pie de clasificación, se suma el campo en el pie de clasificación. Para una explicación de este procedimiento, consulte Cómo omitir un comando de visualización en un pie de clasificación. También puede omitir el comando de visualización en otros tipos de encabezados y pies. Fíjese que los datos de los encabezados se toman del primer grupo de clasificación, mientras que los datos de los pies se toman del último grupo de clasificación. Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

WebFOCUS genera una línea en blanco antes de un subencabezado o subpie, por defecto. Puede eliminar estas líneas en blanco automáticas emitiendo el comando SET DROPBLNKLINE=ON.



x
Referencia: Alineación de subencabezados y subpies

Por defecto, con SQUEEZE=ON, el borde del margen derecho usado para los bordes y color de fondo de los subencabezados y subpies está basado en el ancho máximo de todas las líneas de encabezado, pie, subencabezado y subpie. La longitud de las líneas de subencabezado y subpie está ligada a la longitud del encabezado y pie de página; no el tamaño de las columnas de datos en el cuerpo del informe. El atributo ALIGN-BORDERS=BODY en una hoja de estilos le permite alinear los subencabezados y subpies con el cuerpo de un informe o de los dato, en formato PDF, en lugar de los otros elementos del encabezado.



x
Sintaxis: Cómo Crear un encabezado de clasificación

Cada línea de encabezado o pie de página debe ponerse entre comillas dobles, a menos que utilice el marcador de posición de continuación de línea (<0X).

BY fieldname SUBHEAD [NEWPAGE]
 "content ... "
["content ... "]
.
.
.
["content ... "]
[WHEN expression;]
BY fieldname 
ON fieldname SUBHEAD [NEWPAGE]
 "content ... "
["content ... "]
.
.
.
["content ... "]
[WHEN expression;]

OR

BY fieldname 
ON fieldname SUBHEAD [NEWPAGE]
 "content ... "
["content ... "]
.
.
.
["content ... "]
[WHEN expression;]

donde:

fieldname
Es el campo de clasificación al cual precede el texto del encabezado.
content
El contenido de un encabezado o pie puede incluir los siguientes elementos, entre comillas dobles. (Si se omiten las comillas finales, todos las líneas posteriores de la solicitud se consideran parte del encabezado.)
text
Es el texto del encabezado de clasificación. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, después del comando SUBHEAD.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable
Puede ser cualquiera de los siguientes o una combinación de estos:

Fields (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o un campo de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Images. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker
Le permite colocar elementos, identificar elementos para dar formato y ampliar el código más allá del límite de 80 caracteres por línea del editor de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un encabezado, pie, título o texto libre de FML.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n para colocar el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

WHEN expression
Especifica una condición bajo la cual se muestra un encabezado de clasificación, tal como lo determine una expresión lógica. Debe colocar la frase WHEN en una línea después del texto.

Para obtener información detallada acerca del formato condicional, consulte Cómo controlar el formato del informe. Para obtener información relacionada, consulte Cómo utilizar expresiones.

Blank lines
Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)

NEWPAGE
Inserta una nueva página después del encabezado de clasificación. Aparecen títulos de columna en cada página.

Se puede usar NEWPAGE con informes PDF. En informes HTML, se añade un espacio en blanco en vez de una página nueva.



Ejemplo: Cómo crear un encabezado de clasificación cuando cambia la descripción de un producto

Esta solicitud muestra un encabezado de clasificación cada vez que la descripción del producto cambia. El encabezado de clasificación incluye texto y un campo insertado.

TABLE FILE GGPRODS
PRINT PACKAGE_TYPE AND UNIT_PRICE
WHERE UNIT_PRICE GT 50
BY PRODUCT_DESCRIPTION NOPRINT BY PRODUCT_ID 
ON PRODUCT_DESCRIPTION SUBHEAD
"Summary for <PRODUCT_DESCRIPTION" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

El encabezado de clasificación identifica el producto al que se aplica la próxima línea de datos.

Para obtener información acerca de valores de campo insertados, consulte Cómo incluir un valor de campo en un encabezado o un pie.



Ejemplo: Cómo crear un encabezado de clasificación condicional

Esta solicitud muestra un encabezado de clasificación para una categoría sólo si las ventas caen por debajo de los $17,000,000.

TABLE FILE GGSALES
SUM DOLLARS 
BY CATEGORY SUBHEAD
"<CATEGORY ALERT: SALES FALL BELOW $17,000,000"
WHEN DOLLARS LT 17000000; 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Las ventas correspondientes a la categoría Gifts (regalos) han caído por debajo del monto especificado, tal como lo advierte el encabezado de clasificación. No hay otra categoría que venga precedida de un encabezado de clasificación.

Para obtener información acerca de valores de campo insertados, consulte Cómo incluir un valor de campo en un encabezado o un pie.



x
Sintaxis: Cómo Crear un pie de clasificación

Cada línea de encabezado o pie debe empezar y terminar con comillas dobles.

Para un campo de clasificación individual, use la siguiente sintaxis

BY fieldname SUBFOOT [WITHIN] [MULTILINES] [NEWPAGE]
 "content ... "
["content ... "]
.
.
.
["content ... "]
[WHEN expression;]
BY fieldname 
ON fieldname SUBFOOT [WITHIN] [MULTILINES] [NEWPAGE]
 "content ... "
["content ... "]
.
.
.
["content ... "]
[WHEN expression;]

Para campos de clasificación múltiples, use la siguiente sintaxis

BY fieldname 
ON fieldname SUBFOOT [MULTILINES] [NEWPAGE]
 "content ... "
["content ... "]
.
.
.
["content ... "]
[WHEN expression;]

donde:

fieldname
Es el campo de clasificación que precede al texto del pie.
WITHIN
Hace que los campos del SUBFOOT se calculen en cada valor del fieldname. Sin esta opción, se toma un campo del SUBFOOT de la última línea de la salida del informe, situada sobre el subpie.
MULTILINES
Suprime el pie de clasificación cuando hay sólo una línea de datos para un valor de campo de clasificación. (MULTI-LINES es sinónimo de MULTILINES.)
content
El contenido de un encabezado o pie puede incluir los siguientes elementos, entre comillas dobles. (Si se omite la comilla final, todas las líneas posteriores de la solicitud se consideran parte del pie de clasificación.)
text
Es el texto que aparece en la primera página del informe. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, después del comando SUBFOOT.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable
Puede ser cualquiera de los siguientes o una combinación de estos:

Fields (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o un campo de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Images. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker
Le permite colocar elementos, identificar elementos para dar formato y ampliar el código más allá del límite de 80 caracteres por línea del editor de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un encabezado, pie, título o texto libre de FML.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n para colocar el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

WHEN expression
Especifica una condición bajo la cual se muestra un encabezado de clasificación, tal como lo determine una expresión lógica. Debe colocar la frase WHEN en una línea después del texto.

Para obtener información detallada acerca del formato condicional, consulte Cómo controlar el formato del informe. Para obtener información relacionada, consulte Cómo utilizar expresiones.

Blank lines
Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)
NEWPAGE
Inserta una nueva página antes del pie de clasificación.


Ejemplo: Cómo crear un pie de clasificación cuando cambia la descripción de un producto

Esta solicitud muestra un encabezado de clasificación cada vez que cambie la descripción del producto.

TABLE FILE GGPRODS
PRINT PACKAGE_TYPE AND UNIT_PRICE
WHERE UNIT_PRICE GT 50
BY PRODUCT_DESCRIPTION NOPRINT BY PRODUCT_ID 
ON PRODUCT_DESCRIPTION SUBFOOT
"Summary for <PRODUCT_DESCRIPTION" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Para obtener información acerca de valores de campo insertados, consulte Cómo incluir un valor de campo en un encabezado o un pie.



Ejemplo: Cómo crear un pie de clasificación condicional con múltiples opciones de clasificación

Este informe lista pedidos, fechas de pedidos y totales de pedidos de la Century Corporation. Utiliza un pie de clasificación condicional para distinguir entre los pedidos cuyo total sea superior a $200,000 y aquellas cuyo total sea inferior a $200,000.

Fíjese que una frase de clasificación (ON ORDER_NUM) especifica varias opciones relativas a clasificación (dos frases SUBFOOT diferentes) y que cada opción tiene su propia frase WHEN.

TABLE FILE CENTORD
HEADING
"Order Revenue"
" "
SUM ORDER_DATE LINEPRICE AS 'Order,Total:'
BY HIGHEST 5 ORDER_NUM 
ON ORDER_NUM 
   SUBFOOT
      "--- Order total is less than $200,000 ---"
      " "
      WHEN LINEPRICE LT 200000;    
   SUBFOOT
      "+++ Order total is greater than or equal to $200,000 +++"
      " "
      WHEN LINEPRICE GE 200000; 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Aparece el siguiente informe.



Ejemplo: Cómo suprimir una opción de clasificación

Esta solicitud suprime el pie de clasificación de cualquier producto que tenga sólo una línea de datos (es decir, un producto que haya sido ordenado sólo una vez en fecha 01/01/96).

TABLE FILE GGORDER
PRINT QUANTITY
BY PRODUCT_CODE NOPRINT BY PRODUCT_DESCRIPTION
WHERE ORDER_DATE EQ '01/01/96'
WHERE STORE_CODE EQ 'R1019'
WHERE PRODUCT_DESCRIPTION EQ 'Hazelnut' OR 'Biscotti' OR 'Croissant' 
ON PRODUCT_CODE SUBFOOT MULTILINES
"<PRODUCT_DESCRIPTION has multiple orders." 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

En la salida se suprime el pie de clasificación de Biscotti.



Ejemplo: Cómo reemplazar la etiqueta predeterminada RECAP por un pie de clasificación

En esta solicitud, un comando SUBFOOT para el campo DEPARTMENT sigue a un comando RECAP para dicho campo. El comando RECAP crea valores de subtotal para el cálculo.

TABLE FILE SHORT
SUM BALANCE AS 'Dollars' ENGLAND_POUND AS 'Sterling'
BY REGION
WHERE REGION EQ 'FAR EAST' OR 'CENTRAL AMERICA' OR 'WESTERN EUROPE';
BY COUNTRY NOPRINT
RECAP EURO/D16=BALANCE * 1.03;
SUBFOOT
" "
"Balance of investments for <COUNTRY> in Euros is <EURO>."
" "
END

El texto del pie de clasificación (por ejemplo, "Balance of investments for FRANCE in Euros is 87,336,971.") reemplaza a la etiqueta predeterminada para el valor RECAP (** EURO 87,336,971).



Ejemplo: Cómo omitir un comando de visualización en un pie de clasificación

Esta solicitud crea un informe completo como un pie de clasificación. No requiere un comando de visualización porque el contenido del pie de clasificación incluye los campos de datos DEPARTMENT y SALARY. De forma predeterminada, el campo SALARY se suma en el pie de clasificación.

TABLE FILE EMPLOYEE 
BY DEPARTMENT NOPRINT SUBFOOT
"<DEPARTMENT DEPARTMENT TOTAL SALARY IS <SALARY" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:



x
Referencia: Notas de uso de subpies

WebFOCUS