Utilice la sintaxis siguiente para especificar la posición inicial de todo el encabezado o pie, en relación al margen izquierdo del informe.

TYPE = headfoot, POSITION = position, $

donde:

headfoot

Es el tipo de encabezado o pie. Los valores válidos son TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD y SUBFOOT.

position

Es la distancia deseada desde la izquierda, expresada mediante el atributo UNITS (las pulgadas son la unidad predeterminada).

Nota: En un informe HTML, esta sintaxis debe utilizarse junto con una hoja de estilos interna en cascada. Para ver una muestra, consulte Cómo ajustar la posición inicial de un encabezado de informe en HTML.

Esta solicitud posiciona El encabezado de informe a 1.25 pulgadas del margen izquierdo.

SET ONLINE-FMT=PDF
TABLE FILE GGSALES
PRINT BUDDOLLARS DOLLARS
BY STCD
WHERE BUDDOLLARS GE 25000
WHERE STCD EQ 'R1019'
ON TABLE SUBHEAD
"Sales Report"
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET * 
TYPE = TABHEADING, POSITION = 1.25, $ 
ENDSTYLE
END

La salida es:

La solicitud genera una hoja de estilos interna en cascada como parte de su código HTML, lo que permite el uso del atributo POSITION para especificar la posición inicial del encabezado Sales Report, a una distancia de 1,5 pulgadas del margen izquierdo.

SET ONLINE-FMT = HTML
TABLE FILE GGSALES
PRINT BUDDOLLARS DOLLARS
BY STCD
WHERE BUDDOLLARS GE 25000
WHERE STCD EQ 'R1019'
ON TABLE SUBHEAD
"Sales Report"
" "
ON TABLE SET PAGE-NUM OFF 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $ 
TYPE = TABHEADING, POSITION = 1.5, $ 
ENDSTYLE
END

La salida es:

En un informe PDF o PS utilice la sintaxis que sigue para especificar la posición inicial de un elemento de encabezado o pie con relación al elemento precedente.

TYPE = headfoot, [subtype,] POSITION = {+|-}option, $

donde:

headfoot

Es el tipo de encabezado o pie. Los valores válidos son TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD y SUBFOOT.

subtype

Son atributos adicionales que identifican el componente de informe. Estas opciones se pueden usar de forma individual o combinada, dependiendo del grado de especificidad que necesite para identificar cabalmente un elemento. Los valores válidos son:

LINE que identifica una línea por su posición en el encabezado o pie. La identificación de líneas individuales le permite dar formato a cada línea de manera diferente.

Si un encabezado o pie consta de múltiples líneas y aplica una declaración de hoja de estilos que no especifica LINE, la declaración pasa a aplicarse en todas las líneas. Los líneas en blanco se cuentan al interpretar el valor de LINE.

ITEM que identifica un elemento por su posición dentro de la línea. Para dividir un encabezado o pie en diferentes elementos, puede utilizar el marcador de posición <+0>. Consulte Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

Para determinar un número de ITEM para un OBJECT, siga estas instrucciones:

• Si lo utiliza con OBJECT=TEXT, cuente sólo las cadenas de texto desde la izquierda hasta la derecha.
• Si lo utiliza con OBJECT=FIELD, cuente sólo los valores desde la izquierda hasta la derecha.
• Si lo utiliza con OBJECT, cuente las cadenas de texto y los valores de campo desde la izquierda hasta la derecha.

Si aplica una declaración de hoja de estilos que especifique ITEM, se cuentan los números desde el principio de cada línea en el encabezado o pie de página, no solamente desde el principio de la primera línea.

OBJECT que identifica un elemento en un encabezado o pie como una cadena de texto o valor de campo. Los valores válidos son TEXT o FIELD. TEXT puede representar texto libre o una variable ampersand "&" de Dialogue Manager.

No es necesario especificar OBJECT=TEXT a menos que esté dando estilo tanto a las cadenas de texto como a los campos insertados en el mismo encabezado o pie.

option

Es el método de alineación. Los valores válidos son:

position que es la distancia deseada, indicada por el atributo UNITS (el valor predeterminado es pulgadas) para la posición general.

+ que inicia el elemento de encabezado o pie de página a la distancia especificada a la derecha del elemento que lo precede. Para el primer elemento en un encabezado o pie, el elemento precedente es el margen izquierdo del informe.

- que inicia el elemento de encabezado o pie de página a a la distancia especificada a la izquierda del elemento que lo precede. Esto resulta útil si desea solapar imágenes en un encabezado.

column_title que alinea el elemento de encabezado o pie de página con el primer carácter de la columna designada.

Esta solicitud utiliza el marcador de posición <+0> para dividir el encabezado de informe en tres cadenas de texto. Inicia la tercera cadena de texto, 1st Qtr 2001, a tres pulgadas del margen izquierdo del informe. Esta técnica se puede utilizar tanto en informes PDF como en informes PS.

SET ONLINE-FMT = PDF
TABLE FILE GGSALES
SUM UNITS DOLLARS BY CATEGORY BY PRODUCT
ON TABLE SUBHEAD 
"Sales Report - <+0>All Products<+0> 1st Qtr 2001" 
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET * 
TYPE = TABHEADING, OBJECT = TEXT, ITEM=1, SIZE = 12, STYLE = BOLD, $
TYPE = TABHEADING, OBJECT = TEXT, ITEM=2, STYLE = BOLD, $
TYPE = TABHEADING, OBJECT = TEXT, ITEM=3, POSITION = 3, $ 
ENDSTYLE
END

La salida es:

Esta solicitud utiliza el marcador de posición <+0> para dividir el encabezado de informe en tres cadenas de texto. Inicia la tercera cadena de texto, 1st Qtr 2001, a una pulgada a la derecha del elemento anterior de la línea de encabezado. La pulgada es la unidad de medida predeterminada. Esta técnica se puede utilizar tanto en informes PDF como en informes PS.

SET ONLINE-FMT = PDF
TABLE FILE GGSALES
SUM UNITS DOLLARS BY CATEGORY BY PRODUCT
ON TABLE SUBHEAD 
"Sales Report - <+0>All Products<+0> 1st Qtr 2001" 
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET * 
TYPE = TABHEADING, OBJECT = TEXT, ITEM=1, SIZE = 12, STYLE = BOLD, $
TYPE = TABHEADING, OBJECT = TEXT, ITEM=2, STYLE = BOLD, $
TYPE = TABHEADING, OBJECT = TEXT, ITEM=3, POSITION = +1, $ 
ENDSTYLE
END

La salida es:

Esta solicitud utiliza el marcador de posición <+0> para dividir el encabezado de informe en tres cadenas de texto. Inicia la segunda cadena de texto en la posición horizontal donde se encuentra la columna UNITS (Unit Sales). Esta técnica se puede utilizar tanto en informes PDF como en informes PS.

SET ONLINE-FMT = PDF
TABLE FILE GGSALES
SUM UNITS DOLLARS BY CATEGORY BY PRODUCT
ON TABLE SUBHEAD 
"Sales Report - <+0>All Products<+0> 1st Qtr 2001" 
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET * 
TYPE = TABHEADING, LINE=1, ITEM=2, POSITION=UNITS, $ 
ENDSTYLE
END

La salida es:

Sugerencia: En esta solicitud la columna (UNITS) se identifica por su nombre. No obstante, hay otras maneras de identificar una columna a la que desee dar formato. Consulte Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

PRINTPLUS cuenta con mejoras de las alternativas de visualización que ofrece WebFOCUS. Por ejemplo, puede colocar un FOOTING en su informe después de un SUBFOOT. PRINTPLUS le ofrece la flexibilidad necesaria para producir el informe preciso que desee.

El parámetro PRINTPLUS debe estar en ON para aprovechar las siguientes posibilidades de TABLE:

• PAGE-BREAK se maneja internamente para ofrecer el espaciado correcto de las páginas. Por ejemplo, si se inicia una nueva página de informe y se encuentra un comando para saltar una línea en la parte superior de la nueva página, WebFOCUS sabe cómo suprimir el espacio en blanco y empezar en la parte superior de la página.
• NOSPLIT se maneja internamente. (Utilice NOSPLIT para forzar un salto en un punto específico).
• Puede realizar RECAP en casos en que se satisfagan condiciones previamente especificadas.
• Ahora, el SUBFOOT de informe se imprime sobre el pie en vez de debajo de éste.
• Los datos se muestran correctamente en los subpies cuando se usan IF/WHERE TOTAL o BY HIGHEST.
• Las acciones del campo BY están enlazadas con las opciones de campo BY, por lo que aparecen en la misma página. El pie ya no aparece dividido en dos páginas.
• Los pies y subpies siempre aparecen en una página con al menos un elemento de datos y nunca aparecerán divididos entre dos páginas.
• Ya no se imprime más allá de la longitud de la página.
• Ya no se dividen en páginas separadas los campos enlazados mediante OVER.
• No hay espacio reservado para salida condicional. La página de salida se utiliza completamente.
• Ya no es relevante el orden de los campos de clasificación.

Nota: Las hojas de estilos no admiten PRINTPLUS. En este caso se genera una advertencia.

SET PRINTPLUS = {ON|OFF}

SET PRINTPLUS = ON
 TABLE FILE CAR
  PRINT CAR MODEL
  BY SEATS BY COUNTRY
  IF COUNTRY EQ ENGLAND OR FRANCE OR ITALY
  ON TABLE SUBFOOT
  " "
  " SUMMARY OF CARS IN COUNTRY BY SEATING CAPACITY"
  FOOTING
  " RELPMEK CAR SURVEY "
ON TABLE SET STYLE *
TYPE=REPORT,GRID=OFF,$
 END

SEATS

COUNTRY

CAR

MODEL

-----

-------

—

-----

    2

ENGLAND

TRIUMPH

TR7

ITALY

ALFA ROMEO

2000 GT VELOCE

ALFA ROMEO

2000 SPIDER VELOCE

MASERATI

DORA 2 DOOR

    4

ENGLAND

JAGUAR

V12XKE AUTO

JENSEN

INTERCEPTOR III

ITALY

ALFA ROMEO

2000 4 DOOR BERLINA

    5

ENGLAND

JAGUAR

XJ12L AUTO

FRANCE

PEUGEOT

504 4 DOOR

 SUMMARY OF CARS IN COUNTRY BY SEATING CAPACITY

 RELPMEK CAR SURVEY

Puede emplear varios tipos de marcadores de posición para afinar el posicionamiento de los encabezados y pies así como de los elementos que formen parte de estos, tanto en informes HTML como en informes PDF que utilicen fuentes proporcionales. Para un control estricto, combine marcadores de posición con otras técnicas de alineación. Consulte Cómo elegir un método de ajuste de la alineación para elementos de un encabezado o pie de página.

Los siguientes marcadores de posición le permiten posicionar e identificar elementos a los que se va a dar formato:

• <+0> divide un encabezado o pie en elementos a los que dar formato.

  Para dividir un encabezado o pie en elementos que se puedan formatear por separado, coloque el marcador de posición <+0> después de la cadena o campo de texto que desee especificar. No añadirá ningún espacio adicional a su encabezado o pie. Para obtener información detallada, consulte Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

• </n especifica saltos de línea.

  Para especificar saltos de línea en un encabezado o pie, coloque el marcador de posición </n> en la misma línea que el texto de la solicitud. Si lo coloca en una línea independiente, WebFOCUS cuenta la línea en que se encuentra el marcador de posición más el número de líneas que saltar que especifique. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

• <-n controla la ubicación de un carácter inmediatamente después de un campo. Para ver ejemplos de cómo funciona esta técnica, vaya a Cómo posicionar un carácter inmediatamente después de un campo en un informe HTML y a Cómo posicionar un carácter inmediatamente después de un campo en un informe PDF o PS.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

También puede utilizar marcadores de posición para colocar elementos de encabezados y pies en posiciones de columna fijas y relativas. Varios marcadores de posición controlan la ubicación a partir del ancho predefinido de un carácter en una fuente monoespacio. Esta es una técnica de formato legacy que no admiten las fuentes proporcionales.

Esta solicitud genera un informe HTML en que el paréntesis final y el punto en el encabezado de clasificación van inmediatamente después de los campos STORE_CODE y STATE, respectivamente. Este comportamiento es controlado por los marcadores de posición <-1, que indican una posición inicial relativa con respecto al objeto precedente. Si no se colocan estos marcadores de posición para indicar que los caracteres de puntuación deben ir después de los objetos precedentes, aparece un espacio adicional en cada una de estas posiciones en la visualización.

SET ONLINE-FMT = HTML
SET PAGE-NUM = OFF
JOIN STORE_CODE IN CENTCOMP TO STORE_CODE IN CENTORD

TABLE FILE CENTCOMP
HEADING
"Century Corporation Orders Report </1"
PRINT PROD_NUM QUANTITY LINEPRICE
BY STORE_CODE NOPRINT
BY ORDER_NUM
ON STORE_CODE SUBHEAD 
"Century Corporation orders for store <STORENAME <0X
(store # <STORE_CODE<-1 ) in <STATE|.</1" 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

El resultado parcial es:

En informes PDF, los campos insertados en un encabezado pie deben venir seguidos de un espacio en la solicitud para que se reconozcan durante el procesamiento. Sin embargo, este espacio podría no ser deseable en la salida. Este ejemplo demuestra dos técnica para posicionar caracteres de puntuación inmediatamente después de un campo en un informe PDF.

La primera técnica utiliza el atributo de POSITION en una hoja de estilos para colocar el paréntesis final inmediatamente después del valor STORE_CODE. La segunda técnica utiliza el marcador de posición <-1 para colocar el punto inmediatamente después del valor de STATE. La medida de POSITION se basa en los POINTS de designación de UNITS. La experiencia demuestra que -7 puntos mueve los paréntesis finales a la ubicación apropiada después del campo mediante la fuente y el tamaño proporcionales predeterminados.

SET ONLINE-FMT = PDF
SET PAGE-NUM = OFF
JOIN STORE_CODE IN CENTCOMP TO STORE_CODE IN CENTORD
 
TABLE FILE CENTCOMP
HEADING
"Century Corporation Orders Report"
PRINT PROD_NUM QUANTITY LINEPRICE
BY STORE_CODE NOPRINT
BY ORDER_NUM
ON STORE_CODE SUBHEAD
"Century Corporation orders for store <STORENAME (store # <STORE_CODE ) 
in <0X <STATE <-1 . </1"
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, UNITS=POINTS, $ 
TYPE=SUBHEAD, OBJECT=TEXT, ITEM=3, POSITION= -7, $
ENDSTYLE
END

La salida es:

Sin el marcador de posición y la medida de ubicación, la salida hubiera tenido el aspecto que a seguidas se muestra:

Esta solicitud utiliza una fuente Helvetica de 12 puntos. La experiencia demuestra que el valor de ubicación de -2 puntos mueve el texto con esta fuente y tamaño a la ubicación requerida.

SET ONLINE-FMT = PDF
SET PAGE-NUM = OFF
JOIN STORE_CODE IN CENTCOMP TO STORE_CODE IN CENTORD
 
TABLE FILE CENTCOMP
HEADING
"CENTURY CORPORATION ORDERS REPORT"
PRINT PROD_NUM QUANTITY LINEPRICE
BY STORE_CODE NOPRINT WHERE STORE_CODE EQ '1003NY' OR '1003CT' OR
    '1003NJ'
BY ORDER_NUM
ON STORE_CODE SUBHEAD
"CENTURY CORPORATION ORDERS FOR STORE <STORENAME (store # <STORE_CODE)<0X
 IN <STATE <-1 . </1"
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, UNITS=POINTS, FONT='Helvetica', SIZE=12, $ 
TYPE=SUBHEAD, OBJECT=TEXT, ITEM=3, POSITION= -2, $ 
ENDSTYLE
END

Sugerencia: No puede utilizar el atributo POSITION para posicionar un elemento de encabezado en un informe HTML. Sí puede, sin embargo, lograr el mismo resultado usando el marcador de posición horizontal <-1 justo después de los campos STORE_CODE y STATE. No añada un espacio entre el campo y el carácter que lo siga.

La salida es: