Cómo identificar un encabezado, pie, título o texto libre de FML

En esta sección:

Los datos de un informe se enmarcan mediante encabezados, pies y títulos. Estos proporcionan un contexto a los datos. Puede identificar y dar formato a muchas categorías de cabeceras, pies y títulos en un informe, incluyendo a:

Principio de página
x
Cómo identificar un título de columna o fila

Cómo:

Para dar formato a los títulos de columna y valores de clasificación horizontal (ACROSS), identifíquelos en la hoja de estilos. El ejemplo que sigue muestra dónde se encuentran los títulos de columna y valores de clasificación horizontal de un informe y qué valores TYPE se utilizan para identificarlos. 

TABLE FILE EMPLOYEE
SUM GROSS AND DED_AMT
ACROSS DEPARTMENT BY PAY_DATE
END

Nota: Dado que esta solicitud simplemente muestra cómo identificar títulos de columna y valores de clasificación horizontal en un informe, omite una hoja de estilo.

x
Sintaxis: Cómo Identificar un título de columna
TYPE=TITLE, [COLUMN=column]

donde:

COLUMN

Se utiliza para especificar uno o varios títulos de columna. Si omite el atributo y el valor, el formato queda aplicado a todos los títulos de las columnas del informe.

column

Especifica la columna cuyo título desea formatear. Para valores de columna, vaya a Cómo Identificar una columna completa.
x
Sintaxis: Cómo Identificar un título o valor de clasificación horizontal
TYPE={ACROSSTITLE|ACROSSVALUE}, [ACROSS=column]

donde:

ACROSSTITLE

Especifica un título de clasificación horizontal (ACROSS).

ACROSSVALUE

Especifica un valor de clasificación horizontal (ACROSS).

Aunque los valores de clasificación horizontal no son títulos en el sentido técnico, suelen funcionar como títulos que categorizan los títulos de columna que aparecen debajo de estos.

ACROSS

Se utiliza para especificar títulos o valores de un campo de clasificación horizontal específico. Si omite el atributo y el valor, el formato queda aplicado a los títulos o valores de los campos de clasificación horizontales de todos los informes.

column

Especifica el campo de clasificación horizontal (ACROSS) cuyos título y valores desea formatear. Para obtener información acerca de los valores que puede asignar a este atributo, vaya a Cómo Identificar una fila de datos clasificación horizontal (ACROSS).
Ejemplo: Cómo identificar títulos de columna y valores de clasificación horizontal (ACROSS)

Este ejemplo muestra cómo identificar títulos de clasificación vertical, títulos de clasificación horizontal y valores de clasificación horizontal. Los títulos de clasificación vertical (TYPE=TITLE) son Manufacturing Plant, Quantity Sold y Product Cost; el título de clasificación horizontal (TYPE=ACROSSTITLE) es Year; finalmente, los valores de clasificación horizontal (TYPE=ACROSSVALUE) son 2001, 2002 y TOTAL.

También se demuestra cómo asignar valores drill-down a los valores ACROSS individuales de 2001 y 2002, y no el valor ROW-TOTAL de TOTAL. Las declaraciones de la hoja de estilo en esta solicitud están en negrita. 

TABLE FILE CENTORD
SUM QUANTITY AS 'Quantity,Sold' LINE_COGS/I9 AS 'Product,Cost'
BY PLANT
ACROSS YEAR
WHERE YEAR EQ '2001' OR '2002'
HEADING
"Plant Production Cost Analysis"
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=TITLE, STYLE=BOLD, $
TYPE=ACROSSTITLE, STYLE=BOLD, $
TYPE=ACROSSVALUE, STYLE=BOLD+ITALIC, COLOR=BLUE, FOCEXEC=DETAILS, $
TYPE=ACROSSVALUE, COLUMN=N4, STYLE=BOLD, COLOR=RED, $
TYPE=ACROSSVALUE, COLUMN=ROWTOTAL(1), COLOR='BLACK',FOCEXEC=NONE, $ 
ENDSTYLE
END

La imagen que aparece a continuación muestra la salida del informe.
x
Sintaxis: Cómo Identificar texto libre en un informe FML
TYPE=FREETEXT, LABEL={Rn|label}

donde:

n

Es una etiqueta de fila implícita. Para determinar el valor de n, cuente el número de filas hasta la fila deseada (incluida).

label

Es una etiqueta de fila implícita.

Ejemplo: Cómo identificar texto libre en un informe FML

Vea a continuación cómo identificar texto libre en un informe FML. En este ejemplo, las líneas "CASH ACCOUNTS" y "OTHER CURRENT ASSETS" constituyen el texto libre. Las declaraciones relevantes de hoja de estilo aparecen en negrita. 

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
" --- CASH ACCOUNTS ---" LABEL CA            OVER
1010 AS 'CASH ON HAND'                       OVER
1020 AS 'DEMAND DEPOSITS'                    OVER
1030 AS 'TIME DEPOSITS'                      OVER
" "                                          OVER
" --- OTHER CURRENT ASSETS ---" LABEL OCA    OVER
1100 AS 'ACCOUNTS RECEIVABLE'                OVER
1200 AS 'INVENTORY'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=FREETEXT, LABEL=CA, STYLE=BOLD, SIZE=12, $
TYPE=FREETEXT, LABEL=OCA, STYLE=BOLD, SIZE=12, $ 
ENDSTYLE
END

La salida es:
Principio de página
x
Cómo identificar un encabezado o pie

Cómo:

Para dar formato a encabezados, pies, líneas individuales, cadenas de texto y sus correspondientes campos, identifíquelos en la hoja de estilos.

Las solicitudes TABLE pueden tener más de un encabezado o pie de página. Para cada encabezado o pie, las cláusulas WHEN emitidas frente a los datos que se están recuperando pueden determinar si el encabezado o pie aparece en la salida del informe. El atributo de hoja de estilos CONDITION le permite identificar una cláusula WHEN específica para dar estilo a cada encabezado o pie, de forma independiente.

En los siguientes ejemplos de código y salida se muestra dónde se encuentran en un informe el encabezado de informe (TABHEADING), un encabezado de página (HEADING), un encabezado de clasificación (SUBHEAD), un pie de clasificación (SUBFOOT) y un pie de informe (TABFOOTING) y Qué valores TYPE se utilizan para identificarlos.

TABLE FILE EMPLOYEE
PRINT CURR_SAL HIRE_DATE
BY LAST_NAME
BY FIRST_NAME
ON TABLE SUBHEAD
"CONFIDENTIAL INFORMATION"
"SWIFTY INFORMATION GROUP - EMPLOYEE LIST BY DEPARTMENT"
HEADING CENTER
"</1>EMPLOYEE LIST FOR DEPARTMENT: <DEPARTMENT"
ON LAST_NAME SUBHEAD
"ID: <EMP_ID"
ON LAST_NAME SUBFOOT
"** REVIEW SALARY FOR <FIRST_NAME <LAST_NAME"
FOOTING
"CONFIDENTIAL INFORMATION"
ON TABLE SUBFOOT
"</1>***END OF REPORT***"
ON TABLE SET ONLINE-FMT STANDARD
END

La siguiente salida va con el anterior ejemplo de código:

Nota: Dado que esta solicitud simplemente muestra cómo identificar diferentes tipos de encabezados y pies, omite una hoja de estilo.

x
Sintaxis: Cómo Identificar un encabezado o pie
TYPE=headfoot, [BY=sortcolumn]

donde:

headfoot

Identifica un encabezado o pie. Seleccione entre:

TABHEADING que es el componente de informe. Aparece una vez al principio del informe y se genera mediante ON TABLE SUBHEAD.

TABFOOTING que es el pie de informe. Aparece una vez al final del informe y se genera mediante ON TABLE SUBFOOT.

HEADING que es el encabezado de página. Aparece en la parte superior de cada página del informe y se genera mediante HEADING.

FOOTING que es el pie de la página. Aparece en la parte inferior de cada página del informe y se genera mediante FOOTING.

SUBHEAD que es el encabezado de clasificación. Aparece al principio de un grupo de clasificación vertical (BY) (se genera mediante ON sortfield SUBHEAD).

SUBFOOT es un pie de clasificación. Aparece al final de un grupo de clasificación vertical (BY) (se genera mediante ON sortfield SUBFOOT).

BY

Cuando existen varios encabezados o pies de clasificación, cada uno relacionado con una columna de clasificación vertical (BY) diferente, puede identificar cuál encabezado o pie de clasificación desea formatear.

Si existen varios encabezados o pies de clasificación relacionados con diferentes columnas de clasificación vertical (BY) y omite este atributo y valor, se aplicará el formato a todos los encabezados y pies de clasificación.

sortcolumn

Especifica la columna de clasificación vertical (BY) asociada a uno de los encabezados o pies de clasificación del informe.

Ejemplo: Cómo identificar un encabezado de página en un pie de informe

Vea a continuación cómo identificar un encabezado de página que aparece en la parte superior de cada página de informe y un pie de informe, que aparece solamente en la última página del informe. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud. 

TABLE FILE CENTORD
HEADING
"Sales Quantity and Amount by Plant"
SUM QUANTITY LINEPRICE  
BY PLANT 
ON TABLE SUBFOOT
" "
"***End of Report***"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=HEADING, FONT=TIMES, SIZE=12, STYLE=BOLD,$
TYPE=TABFOOTING, JUSTIFY=CENTER, STYLE=BOLD, SIZE=11,$ 
ENDSTYLE
END

La salida es:
x
Sintaxis: Cómo Identificar una línea individual en un encabezado o pie
TYPE=type, LINE=line_#

donde:

type

Identifica un tipo de encabezado o pie. Seleccione de HEADING, FOOTING, TABHEADING, TABFOOTING, SUBHEAD o SUBFOOT. Para ver información detallada, vaya a Cómo Identificar un encabezado o pie.

line_#

Identifica una línea por su posición en el encabezado o pie.

Ejemplo: Cómo identificar una línea individual en un encabezado

El siguiente ejemplo muestra cómo formatear líneas individuales en un encabezado. La línea 1 del encabezado (Sales Quantity Analysis) está en negrita y tiene un tamaño de 11. La línea 1 del encabezado (**Confidential**) es roja y está en negrita. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud. 

TABLE FILE CENTORD
HEADING
"Sales Quantity Analysis"
"**Confidential**"
" "
SUM QUANTITY
ACROSS YEAR
BY PLANT
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=HEADING, LINE=1, SIZE=11, STYLE=BOLD,$
TYPE=HEADING, LINE=2, COLOR=RED, STYLE=BOLD,$ 
TYPE=HEADING, JUSTIFY=CENTER,$
ENDSTYLE
END

La salida es:
x
Sintaxis: Cómo Identificar una cadena de texto en un encabezado o pie
TYPE=type, [LINE=line_#], [OBJECT=TEXT], ITEM=item_#

donde:

type

Identifica un tipo de encabezado o pie. Seleccione de HEADING, FOOTING, TABHEADING, TABFOOTING, SUBHEAD o SUBFOOT. Para ver información detallada, vaya a Cómo identificar un encabezado o pie .

line_#

Identifica una línea por su posición en el encabezado o pie. Si tiene un encabezado o pie de múltiples líneas, sólo necesita incluir el atributo LINE.

TEXT

Formatea solamente cadenas de texto y variables de Dialogue Manager (también conocidas como &variables). No es necesario utilizar OBJECT=TEXT en su declaración a menos que estilice tanto las cadenas de texto como los campos insertados en el mismo encabezado y pie.

item_#

Identifica un elemento por su posición en una línea.

Si necesita aplicar formato a varias partes de una cadena de texto continuo que muestre en una línea, puede dividir el encabezado o pie en múltiples partes con marcadores de posición. Coloque el marcador de posición después de la cadena de texto que desee especificar. El marcador de posición <+0> no añadirá espacios adicionales a su encabezado o pie. Cuando utiliza marcadores de posición, el texto se divide así:

Para ver un ejemplo, vaya a Cómo identificar una cadena de texto en un encabezado mediante marcadores de posición.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

El valor de posición también depende de si está usando el atributo OBJECT o no. Si está usando:

  • OBJECT=TEXT, cuente solamente las cadenas de texto de izquierda a derecha.
  • Ningún OBJECT, cuente las cadenas de texto y los valores de campo insertados de izquierda a derecha.
Ejemplo: Cómo identificar una cadena de texto en un encabezado mediante marcadores de posición

A continuación se muestra cómo aplicar diferentes formatos a cadenas de texto en un encabezado mediante marcadores de posición. Los marcadores de posición utilizado en este ejemplo son <+0>, pues no añaden espacio alguno. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud. 

TABLE FILE CENTORD
HEADING
"Third Quarter,<+0>2002:<+0> Sales Quantity Analysis"
SUM QUANTITY  BY PLANT
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=HEADING, OBJECT=TEXT, ITEM=1, STYLE=BOLD+UNDERLINE, SIZE=12, $
TYPE=HEADING, OBJECT=TEXT, ITEM=2, COLOR=BLUE, SIZE=12,
     STYLE=BOLD+UNDERLINE, $
TYPE=HEADING, OBJECT=TEXT, ITEM=3, STYLE=ITALIC,$ 
ENDSTYLE
END

La salida es:
x
Sintaxis: Cómo Identificar un campo insertado en un encabezado o pie
TYPE=type, [LINE=line_#], OBJECT=FIELD, [ITEM=item #]

donde:

type

Identifica un tipo de encabezado o pie. Seleccione de HEADING, FOOTING, TABHEADING, TABFOOTING, SUBHEAD o SUBFOOT. Para ver información detallada, vaya a Cómo identificar un encabezado o pie .

line_#

Identifica una línea por su posición en el encabezado o pie. Si tiene un encabezado o pie de múltiples líneas, sólo necesita incluir el atributo LINE.

item_#

Identifica un elemento por su posición en una línea.

Si tiene más de un campo insertado en un encabezado o pie, debe especificar el campo que desea formatear, lo que se logra dando el número del elemento. Cuente los elementos de izquierda a derecha. No incluya campos de texto en la cuenta. No necesita especificar el número del elemento si sólo hay un campo insertado en el encabezado o pie.

Nota: Las opciones de BORDER no están admitidas en determinados ITEMS de un HEADING, FOOTING, SUBHEAD o SUBFOOT.

Ejemplo: Cómo identificar campos insertados en un encabezado

A continuación se muestra cómo formatear un campo insertado en un encabezado. Note que el número del elemento no se especifica en la declaración de hoja de estilo, porque sólo hay un campo insertado en el encabezado. La declaración de hoja de estilos correspondiente queda resaltada en la solicitud. 

TABLE FILE CENTORD
HEADING
"Sales For <YEAR By Plant"
SUM QUANTITY  BY PLANT
WHERE YEAR EQ 2000  
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=HEADING, OBJECT=TEXT, COLOR=BLUE,$ 
TYPE=HEADING, OBJECT=FIELD, COLOR=RED, STYLE=BOLD,$ 
ENDSTYLE
END

La salida es:
x
Sintaxis: Cómo Identificar un encabezado o pie específico basado en una cláusula WHEN
TYPE = {HEADING|FOOTING}, CONDITION = n, ... ,$

donde:

n

Es el número de la condición WHEN en el encabezado o pie, de arriba abajo. Si no se ha especificado, el formato queda aplicado a todos los encabezados y pies.
Ejemplo: Cómo dar estilo a varios encabezados con WHEN

La siguiente solicitud muestra una página para cada empleado, con información salarial y el código de puesto. Se aplica la primera condición WHEN cuando el empleado es mujer. Se aplica la segunda condición WHEN cuando el empleado es varón. Se aplica la tercera condición cuando el departamento es MIS. Se aplica la cuarta condición cuando el departamento es PRODUCTION. Las declaraciones de hoja de estilos incluyen los elementos de estilo de la segunda y tercera condición:

DEFINE FILE EMPLOYEE                                             
GENDER/A1 = DECODE FIRST_NAME(ALFRED 'M' RICHARD 'M' JOHN 'M'    
  ANTHONY 'M' ROGER 'M' MARY 'F' DIANE 'F' JOAN 'F' ROSEMARIE 'F'
  BARBARA 'F');                                                  
MIXEDNAME/A15 = LCWORD(15, LAST_NAME, MIXEDNAME);                
NAME/A16 = MIXEDNAME||',';                                       
END                                                              
                                                                 
TABLE FILE EMPLOYEE                                              
PRINT LAST_NAME NOPRINT GENDER NOPRINT NAME NOPRINT         
HEADING                                                          
"Dear Ms. <NAME"                                                 
   WHEN GENDER EQ 'F';                                           
HEADING                                                          
"Dear Mr. <NAME>"                                                
      WHEN GENDER EQ 'M';                                        
HEADING                                                           
" "                                                 
HEADING                                             
"This is to inform you that your current salary is "
"<CURR_SAL and <CURR_JOBCODE>is your job code."
" "                                                 
"Sincerely,"                                       
HEADING                                             
"Barbara Cross "                                   
  WHEN DEPARTMENT EQ 'MIS';                         
HEADING                                             
"John Banning   "                                  
  WHEN DEPARTMENT EQ 'PRODUCTION' ;                 
WHERE LAST_NAME NE 'BANNING' OR 'CROSS'             
BY EMP_ID NOPRINT PAGE-BREAK                        
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF     
ON TABLE SET STYLE *                     
TYPE=HEADING, CONDITION=2, STYLE=ITALIC,$
TYPE=HEADING, CONDITION=3, STYLE=BOLD,$  
ENDSTYLE                                 
END

En la hoja de estilos de la solicitud, las líneas de encabezado mostradas debido a la primera condición están en cursiva; las líneas de encabezado mostradas debido a la tercera condición están en negrita.

La primera página de la salida es para un empleado por lo que la línea de saludo aparece en cursiva:

La segunda página de la salida es para un empleado del departamento MIS, por lo que la línea de firma aparece en negrita:

WebFOCUS