TABLE FILE EMPLOYEE
SUM DED_AMT AND GROSS
BY DEPARTMENT BY PAY_DATE
ON DEPARTMENT RECAP DEPT_NET/D8.2M = GROSS-DED_AMT;
WHEN PAY_DATE GT 820101
ON DEPARTMENT SUBTOTAL
END

x

TYPE=type, [BY=sortfield] [coltype=column]

donde:

type

Identifica un subtotal o total. Seleccione entre:

GRANDTOTAL que es el total (generado mediante COLUMN-TOTAL, SUBTOTAL, SUB-TOTAL, RECOMPUTE o SUMMARIZE). Consulte Cómo identificar un total general para ver un ejemplo.

SUBTOTAL que es un subtotal (generado mediante SUBTOTAL, SUB-TOTAL, RECOMPUTE o SUMMARIZE). Consulte Cómo identificar subtotales para ver un ejemplo.

RECAP que es un cálculo de subtotal (generado mediante ON sortfield RECAP u ON sortfield COMPUTE). Consulte Cómo identificar un cálculo de subtotal (RECAP/COMPUTE) para ver un ejemplo.

BY

Si tiene una solicitud con varios campos BY y dos o más de estos incluyen comandos de subtotal asociados, puede identificar cada campo mediante el identificador BY. Esto es útil cuando desea formatear cada subtotal de forma diferente o cuando desea formatear solamente un subtotal.

Sólo necesita incluir el identificador BY si tiene múltiples campos BY en su solicitud.

sortfield

Especifica el campo BY asociado a varios comandos de subtotal de un informe. Utilice el nombre de campo para el valor (BY=fieldname).

coltype

Identifica una columna específica a la cual aplicar el formato. Cuando incluya el identificador COLUMN o ACROSSCOLUMN en su declaración, solamente los valores de subtotal recibirán formato, no el texto de etiqueta. Los valores pueden ser:

COLUMN que es una columna de visualización (generada por PRINT, LIST, SUM o COUNT) o una columna calculada (generada por COMPUTE).

ACROSSCOLUMN en el que cada caso de columna de visualización o calculada se repite a través de una fila de clasificación horizontal (ACROSS).

Si existen varias columnas que se totalizan o subtotalizan mediante un comando y no especifica una columna en la hoja de estilo, el formato se aplicará a los totales y subtotales para todas las columnas. También se aplicará al texto de etiqueta para los valores de total y subtotal.

column

Especifica la columna cuyos totales o subtotales desea formatear. Para obtener una lista de valores, vaya a Cómo Identificar una columna completa.

Principio de página

Ejemplo: Cómo identificar un total general

A continuación se muestra cómo identificar un total general en una solicitud de informe. En este ejemplo sólo deseamos formatear el valor del total general para el campo LINE_COGS, de manera que el atributo COLUMN quede incluido en la declaración de hoja de estilo. El total general en esta solicitud se genera mediante COLUMN-TOTAL. La declaración de hoja de estilos correspondiente queda resaltada en la solicitud.

Nota:

• Para estilizar una línea completa de total general, elimine el atributo de columna de la declaración de hoja de estilo.
• Para producir los mismos resultados utilice, como alternativa, los valores N5, P5 o C3 para el atributo COLUMN en la declaración de hoja de estilo.

TABLE FILE CENTORD
SUM QUANTITY LINEPRICE LINE_COGS AND COLUMN-TOTAL
BY ORDER_NUM BY PRODNAME
WHERE ORDER_NUM EQ '48053' OR '48798'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=GRANDTOTAL, COLUMN=LINE_COGS, STYLE=BOLD, SIZE=11,$ 
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo identificar subtotales

A continuación se muestra cómo identificar subtotales en una solicitud de informe. En este ejemplo, solamente se han formateado los valores de subtotal en los campos QUANTITY y LINE_COGS, de manera que el atributo COLUMN está incluido en las declaraciones de hoja de estilo.

Además, dado que existen dos comandos SUBTOTAL asociados a dos de los tres campos BY (PLANT y ORDER_NO), el atributo BY también queda incluido en cada declaración para garantizar que el formato se aplique al valor correcto. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

Nota:

• Para estilizar toda una fila de subtotal, elimine los atributos COLUMN y BY de la declaración de hoja de estilo.
• Para producir los mismos resultados utilice, como alternativa, los valores COLUMN=N6, COLUMN=P6 o COLUMN=C3 para el atributo COLUMN=LINE_COGS.
• Para producir los mismos resultados utilice, como alternativa, los valores COLUMN=N4, COLUMN=P4 o COLUMN=C1 para el atributo COLUMN=QUANTITY.

TABLE FILE CENTORD
SUM QUANTITY LINEPRICE LINE_COGS AS 'Line Cost of, Goods Sold'
BY PLANT
BY ORDER_NUM
BY PRODNAME
ON PLANT SUBTOTAL
ON ORDER_NUM SUBTOTAL
WHERE ORDER_NUM EQ '35774' OR '48041'
WHERE PLANT EQ 'BOS'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=SUBTOTAL, BY=PLANT, COLUMN=LINE_COGS, STYLE=BOLD+ITALIC,
    COLOR=BLUE,$
TYPE=SUBTOTAL, BY=ORDER_NUM, COLUMN=QUANTITY, STYLE=BOLD, SIZE=11,$ 
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo identificar un cálculo de subtotal (RECAP/COMPUTE)

A continuación se muestra cómo identificar un cálculo de subtotal creado con una frase RECAP o COMPUTE. En este ejemplo, el cálculo de subtotal se genera con ON PLANT RECAP QTY/F6=QUANTITY. La declaración de hoja de estilos correspondiente queda resaltada en la solicitud.

Nota: Si existe más de un campo RECAP o COMPUTE en su solicitud, puede distinguirlos añadiendo BY=fieldname a la declaración de hoja de estilo.

TABLE FILE CENTORD
SUM QUANTITY LINEPRICE LINE_COGS AS 'Line Cost of, Goods Sold'
BY PLANT BY ORDER_NUM
ON PLANT RECAP QTY/F6=QUANTITY;
WHERE PLANT EQ 'BOS'
WHERE ORDER_NUM LT '56098'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=RECAP, STYLE=BOLD+ITALIC, $ 
ENDSTYLE
END

						
La salida es: