La sección de informe compuesto, o declaración SECTION, es un agrupamiento de los informes de componente, dentro de un informe compuesto. Aunque la funcionalidad actual sólo admite informes con una sola sección, esta estructura se emplea para dar soporte a informes más complejos. La declaración SECTION es obligatoria para crear un informe de diseño compuesto.

La sintaxis de SECTION aparece como:

SECTION=section-name, LAYOUT=ON, [MERGE=ON|OFF,]
 [UNITS=IN|CM|PTS,] [PAGESIZE=Style Sheet selections,] [ORIENTATION=PORTRAIT|LANDSCAPE,]
 [LEFTMARGIN=m,] [RIGHTMARGIN=m,]
 [TOPMARGIN=m,] [BOTTOMMARGIN=m,] $

donde:

section-name

Es el identificador único de la sección, con hasta 16 caracteres.

LAYOUT=ON

Indica que la sección emplea un diseño complejo.

Nota: LAYOUT=ON es la única opción aplicable en este momento.

MERGE={ON|OFF}

Indica si la sección está coordinada (fusionada) en base al valor del campo BY inicial.

Nota: El valor predeterminado es OFF.

m

Indica los márgenes (LEFT, RIGHT, TOP, BOTTOM) en pulgadas, centímetros o puntos.

Si los elementos opcionales, UNITS, PAGESIZE, ORIENTATION o MARGIN, están presentes en la declaración SECTION, anulan cualquier configuración de estos parámetros dentro de los informes de componentes, comandos SET globales, comandos ON TABLE SET y palabras claves de hoja de estilos.

SECTION consiste de una o varias declaraciones PAGELAYOUT. Cada una de éstas agrupa un número de declaraciones COMPONENT que aparecen en esa página específica de la sección.

La palabra clave PAGELAYOUT pone entre corchetes el siguiente grupo de declaraciones COMPONENT hasta la próxima palabra clave PAGELAYOUT o el fin de la sección.

La sintaxis de PAGELAYOUT aparece como:

PAGELAYOUT={n|ALL},
 [TOPMARGIN=m,] [BOTTOMMARGIN=m,]$

donde:

{n|ALL}

Indica en qué pagina del diseño multipágina aparecen los componentes. El valor (n) se trata de un número de página en la sección actual o ALL, indicando que el componente aparece en todas las páginas de la sección.

• Los valores de PAGELAYOUT están numerados a partir del 1. Por ejemplo, si se imprime un informe compuesto por la dos caras de una página, los informes de componente de la parte frontal se especifican como PAGELAYOUT 1 y los de la trasera, PAGELAYOUT 2.

  Nota: La sintaxis es obligatoria incluso cuando el informe sólo tiene una página.

  PAGELAYOUT=1, $

• La sintaxis PAGELAYOUT=ALL especifica un componente que aparece en todas las páginas. Esto es útil en componentes que generan encabezados o pies de páginas.

  PAGELAYOUT=ALL, $

m

Define los límites (TOP, BOTTOM) de los informes de flujo, en unidades actuales. Para una descripción de los informes de flujo, consulte Declaración COMPONENT.

Los componentes incluidos en una declaración de PAGELAYOUT=ALL aparecen en todas las páginas de salida del informe. Resultan útiles a la hora de crear un tema para el diseño de la salida de informe compuesto:

• Las páginas modelo deben tener un componente de informe predeterminado (ya que COMPONENT es un elemento de sintaxis obligatorio), aunque éste no debe mostrar ningún dato, excepto en el encabezado. Si el componente muestra datos o gráficos en el encabezado, deje espacio para el encabezado en cada página y tenga cuidado de no colocar componentes en otras áreas de la página que puedan solaparse con el encabezado.

  Por ejemplo, el informe siguiente no muestra ningún dato:

  SET COMPONENT='DfltCmpt1'
  TABLE FILE SYSCOLUM
  SUM TBNAME NOPRINT
  IF READLIMIT EQ 1
  ON TABLE SET PREVIEW ON
  ON TABLE SET PAGE-NUM NOLEAD
  END

• Las páginas modelo para informes compuestos coordinados deben tener el mismo campo BY primario que el resto de componentes del informe de diseño compuesto. La mejor manera de crear el componente predeterminado para la página modelo en un informe compuesto coordinado es utilizando uno de los orígenes de datos para uno de los informes de diseño compuestos. Por ejemplo, si se emite un informe de componente para PAGELAYOUT1 frente al origen de datos GGSALES y el campo primario es PCD, el componente predeterminado de la página modelo sería:

  SET COMPONENT='DfltCmpt1'
  TABLE FILE GGSALES
  SUM UNITS NOPRINT
  BY PCD NOPRINT
  IF READLIMIT EQ 1
  ON TABLE SET PREVIEW ON
  ON TABLE SET PAGE-NUM NOLEAD
  END

  Tenga en cuenta que el modo recomendado de crear un tema de diseño con textos e imágenes repetidos en una página modelo es colocando los objetos de dibujo en la página modelo. Para más información, consulte Cómo Dibujar objetos con la sintaxis del Compositor de documentos..

• En cuanto al estilo de la página modelo, el tamaño y orientación sólo son aplicables al nivel de documento predeterminado. El tamaño y posición de los elementos de la página modelo no se ajustan automáticamente en algunas orientaciones de página del documento. En documentos que requieren orientaciones de página mixtas, puede definir el diseño de cada página con su propia orientación. En este caso, los elementos de estilo deben aplicarse en cada diseño de página individual para que el estilo se adapte correctamente a cada cambio efectuado en la orientación de las páginas.

El orden de las declaraciones COMPONENT, en el bloque COMPOUND LAYOUT, debe coincidir con el orden de ejecución de los informes de componente y debe haber una declaración COMPONENT para cada informe de componente.

Existen dos tipos de componentes: fijos y de flujo. Los componentes fijos llenan el contenedor definido por los parámetros dimensionales en la página y, si hay datos adicionales, se desbordan sobre la página siguiente con el mismo tamaño fijo y en el mismo sitio. Se puede personalizar el tamaño y ubicación del componente de desbordamiento fijo en la página de desbordamiento (usando los parámetros OVERFLOW-POSITION y OVERFLOW-DIMENSION). En los componentes de flujo, los datos fluyen desde la parte superior del componente definido hacia el margen inferior de la página y, después, comienzan a fluir nuevamente sobre el margen superior de la página de desbordamiento, hasta que no haya más datos. La posición inicial de cada tipo de componente está definida por el parámetro POSITION. El aspecto fijo o de flujo del componente está determinado por el parámetro DIMENSION. El parámetro DIMENSION especifica el tamaño de las dimensiones del cuadro de límite de los componentes fijos. Sin embargo, en los componentes de flujo, el parámetro DIMENSION especifica asteriscos (* *) para las dimensiones.

La sintaxis de COMPONENT aparece como:

COMPONENT=component-name, TYPE=component-type,
    POSITION=(x y), DIMENSION=(xsize ysize),
    [OVERFLOW-POSITION=(x y),] [OVERFLOW-DIMENSION=(xsize ysize),] [DRILLMAP=((L1 targetreport)),]    $

donde:

component-name

El nombre del componente debe ser un identificador único de hasta 16 caracteres. Designa un informe de componente que aparece más adelante en la solicitud (en el mismo procedimiento (FOCEXEC) o en un procedimiento llamado) y está identificado por la sintaxis SET COMPONENT=component-name, utilizando el mismo nombre.

Nota: La sintaxis SET sólo etiqueta los informes con estilo que pueden participar en un informe compuesto, para poder colocarse antes de los informes sin estilo que preceden al informe que se va a nombrar. Por ejemplo, informes que generan archivos de extracción.

component-type

Especifica el tipo de componente que se está declarando. El único tipo de componente admitido en estos momentos es REPORT.

POSITION=(x y)

Especifica la coordenada (x y) sobre la página en que se va a colocar la esquina superior izquierda del componente. Todas las coordenadas están en UNIT (pulgadas, por defecto) actuales; (0 0) es la esquina superior izquierda de la página física.

Nota: Por defecto, las coordenadas son ubicaciones absolutas en la página física. Si x o y está precedida por un signo más (+) o un signo menos (-), por ejemplo, (+.25 +0), la coordenada es relativa al margen izquierdo o superior de la página.

DIMENSION=(xsize ysize)

Especifica el tamaño del cuadro de límite del componente (en UNITs actuales).

En los componentes fijos, xsize y ysize deben tratarse de tamaños de dimensión numéricos.

En los componentes de flujo, xsize y ysize deben ser asteriscos DIMENSION = (* *).

OVERFLOW-POSITION=(x y) y OVERFLOW-DIMENSION=(xsize ysize)

Estos elementos opcionales especifican la posición y dimensión de un componente fijo en páginas posteriores, si desborda su cuadro de límite inicial.

DRILLMAP=((L1 targetreport))

Indica el identificador de vínculo y el informe de destino para un hipervínculo drill through desde su informe. En estos momentos, L1 constituye un identificador de vínculo válido. Para más información sobre los informes de drill through, consulte Cómo crear un informe compuesto PDF con vínculos drill through.

Nota: El doble paréntesis es obligatorio.

En este simple ejemplo que emplea el archivo máster GGSALES, la palabra clave MERGE especifica que se va a generar un informe de diseño compuesto coordinado. Puesto que el primer camp BY de cada componente es REGION, se genera una página para cada valor de REGION, con el primer informe (Ventas) colocado en (1 1) y el segundo (Unidades), en (6.25 1).

Introduzca la sintaxis siguiente en la pestaña Editor de texto del Compositor de documentos.

SET PAGE-NUM=OFF
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=1, $
COMPONENT=Sales, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
COMPONENT=Units, TYPE=REPORT, POSITION=(6.25 1), DIMENSION=(4 4), $
END
SET COMPONENT=Sales
TABLE FILE GGSALES
"Sales report for <REGION"
" "
SUM DOLLARS/F8M
BY REGION NOPRINT
BY ST
BY CITY
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=RED, SQUEEZE=ON, $
END
SET COMPONENT=Units
TABLE FILE GGSALES
"Number of unit sales per product for <REGION"
" "
SUM CNT.UNITS AS 'Number of units sold'
BY REGION NOPRINT
BY PRODUCT
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=BLUE, SQUEEZE=ON, $
END
COMPOUND END

La sintaxis siguiente es un ejemplo del aspecto que puede presentar el mismo informe, si los informes de componente estuviesen en procedimientos preexistentes (FOCEXEC), como indican R1 y R2.

SET PAGE-NUM=OFF
SET SQUEEZE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=1, $
COMPONENT=R1, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
COMPONENT=R2, TYPE=REPORT, POSITION=(6 1), DIMENSION=(4 4), $
END
SET COMPONENT=R1
EX REPORT1
SET COMPONENT=R2
EX REPORT2
COMPOUND END

La primera página de salida es:

Este ejemplo, que utiliza el archivo máster GGSALES, genera un informe de diseño compuesto coordinado, que contiene un gráfico y un informe (sustituyendo el primer informe del ejemplo anterior por un gráfico). Tenga en cuenta que las solicitudes de gráfico con dos campos BY generan un gráfico para cada valor del primer campo BY (REGION) y que estos archivos se nombran añadiendo números de secuencia al nombre del archivo HOLD. Por ejemplo, HOLD0.SVG, HOLD1.SVG, etc.

Para colocar estos gráficos en un informe como componente de un informe de diseño compuesto coordinado, es necesario el uso de bastantes comandos COMPUTE para construir el nombre de cada archivo de gráfico (HOLD0.SVG, HOLD1.SVG, etc.). Además, un comando COMPUTE añade los archivos de imagen al HEADING de cada solicitud TABLE para que queden asociados al mismo valor de REGION, donde fueron originados.

Introduzca la sintaxis siguiente en la pestaña Editor de texto del Compositor de documentos.

SET PAGE-NUM=OFF
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=1, $
COMPONENT=Sales, TYPE=REPORT, POSITION=(0.25 1), DIMENSION=(4 4), $
COMPONENT=Fuel, TYPE=REPORT, POSITION=(7.25 1), DIMENSION=(4 4), $
END

SET COMPONENT=Sales
GRAPH FILE GGSALES
SUM PCT.DOLLARS
BY REGION NOPRINT
BY PRODUCT
ON GRAPH SET LOOKGRAPH HBAR
ON GRAPH HOLD AS HOLD FORMAT SVG
ON GRAPH SET GRAPHSTYLE *
setPlace(true);
setColorMode(1);
setDepthRadius(0);
setDepthAngle(0);
setDisplay(getO1MajorGrid(),false);
setTransparentBorderColor(getFrame(),true);
setDisplay(getDataText(),true);
setTextFormatPreset(getDataText(),28);
setFontSizeAbsolute(getDataText(),true);
setFontSizeInPoints(getDataText(),9);
setPlaceResize(getDataText(),0);
setFontStyle(getDataText(),0);
setTransparentBorderColor(getSeries(0),true);
setDisplay(getO1AxisLine(),false);
setFontSizeAbsolute(getO1Label(),true);
setFontSizeInPoints(getO1Label(),9);
setPlaceResize(getO1Label(),0);
setFontSizeAbsolute(getY1Label(),true);
setFontSizeInPoints(getY1Label(),9);
setPlaceResize(getY1Label(),0);
setTextFormatPreset(getY1Label(),28);
setGridStyle(getY1MajorGrid(),3);
setDisplay(getY1AxisLine(),false);
setDisplay(getY1MajorGrid(),false);
setDisplay(getY1Label(),false);
setDataTextPosition(3);
setTextString(getO1Title(),"");
setTextString(getY1Title(),"");
setFontStyle(getTitle(),0);
END

TABLE FILE GGSALES
"Percent of Sales by Product in <REGION"
" "
SUM
COMPUTE CNTR/I4 = CNTR + 1; NOPRINT
COMPUTE CNTR2/A4 = IF &FOCGRAPHCNT EQ 1 THEN ' ' ELSE FTOA(CNTR-1,'(F4)','A4'); NOPRINT
COMPUTE IMG/A16 = 'HOLD'||LJUST(4,CNTR2,'A4')|| '.svg'; NOPRINT
BY REGION NOPRINT
ON REGION PAGE-BREAK
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
type=HEADING, IMAGE=(IMG), position=(0 0), $
TYPE=REPORT,PAGE-LOCATION=OFF,$
TYPE=REPORT, FONT=HELVETICA, COLOR=BLACK, SQUEEZE=ON, $
END

SET COMPONENT=Fuel
TABLE FILE GGSALES
"Sales report for <REGION"
" "
SUM DOLLARS/F8M
BY REGION NOPRINT
BY ST
BY CITY
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=RED, SQUEEZE=ON, $
END
COMPOUND END

La primera página de salida es:

En este ejemplo, que emplea el archivo máster GGSALES, los diseños multipágina permiten colocar los componentes en lugares fijos en páginas diferentes. Para este ejemplo, el informe de diseño compuesto coordinado, puede contener informes de componente R1 y R2 para cada valor del primer campo de clasificación, en las páginas impares (parte frontal), y R3, en las páginas pares (parte inversa). Además, puede colocar el mismo encabezado, junto con un logo y un texto, con el valor insertado del primer campo de clasificación, en la parte superior de cada lado.

Cree un procedimiento (HEADER.FEX) e introduzca la sintaxis siguiente para un informe de encabezado:

TABLE FILE GGSALES
" "
"Report package for <REGION"
BY REGION NOPRINT
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, SIZE=20, $
TYPE=REPORT, IMAGE=poweredbyibi.gif, POSITION=(+.25 +.25), $
TYPE=HEADING, LINE=2, ITEM=1, POSITION=4, $
END

Utilizaremos los componentes R1 y R2 del ejemplo anterior. Si no la hecho todavía, guárdelos como REPORT1.FEX y REPORT2.FEX. Introduzca la sintaxis siguiente como componente R3, mediante la creación de un procedimiento llamado REPORT3.FEX.

TABLE FILE GGSALES
"Report R3 for <REGION"
BY REGION NOPRINT
SUM DOLLARS BY ST
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=GREEN, $
END

Desde la pestaña Editor de texto del Compositor de documentos, introduzca la sintaxis siguiente, indicando que los componentes de informe R1 y R2 aparezcan en la página 1. El componente R3 aparece en la página 2, mientras que el encabezado del informe aparece en todas las páginas del documento.

SET PAGE-NUM=OFF
SET SQUEEZE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=ALL, $
COMPONENT=HEADER, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
PAGELAYOUT=1, $
COMPONENT=R1, TYPE=REPORT, POSITION=(1 3), DIMENSION=(4 4), $
COMPONENT=R2, TYPE=REPORT, POSITION=(6 3), DIMENSION=(4 4), $
PAGELAYOUT=2, $
COMPONENT=R3, TYPE=REPORT, POSITION=(4 3), DIMENSION=(4 4), $
END

SET COMPONENT=HEADER
EX HEADER
SET COMPONENT=R1
EX REPORT1
SET COMPONENT=R2
EX REPORT2
SET COMPONENT=R3
EX REPORT3
COMPOUND END

Página 1 de la salida:

Página 2 de la salida:

Un tipo de informe común contiene un diseño fijo en la parte superior de la página, seguido de un informe con registros detallados de longitud variable. Por ejemplo, un resumen de cartera de valores puede contener el nombre y dirección de un cliente, un gráfico de asignación de valores y una comparativa de la cartera con índices bursátiles en la parte superior, seguida de una lista de los títulos mantenidos en la cuenta. En el caso de que la lista de títulos se desborde en la primera página, nos gustaría que la lista continuase en la segunda, debajo del encabezado común que aparece en todas las páginas (logo, número de cuenta, número de página). La sintaxis de OVERFLOW-POSITION y OVERFLOW-DIMENSION nos permite especificar dónde continúa el informe en la páginas de desbordamiento y cuál debe ser su longitud en cada una. (Tenga en cuenta que el ancho no debe variar de una página a otra.)

El ejemplo siguiente, que emplea el archivo máster GGSALES, demuestra cómo se puede usar OVERFLOW-POSITION y OVERFLOW-DIMENSION para volver a colocar el segundo componente de informe (R2), para que empiece debajo del primer componente de la página inicial y dos pulgadas por debajo de la parte superior de las páginas posteriores. Observe que esto deja espacio suficiente para el componente de encabezado (HEADER) del informe, al principio de cada página.

Además, PAGELAYOUT=ALL obliga al componente HEADER a aparecer en la parte superior de cada página de desbordamiento.

Introduzca la sintaxis siguiente en la pestaña Editor de texto del Compositor de documentos.

SET PAGE-NUM=OFF
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=Example, LAYOUT=ON, MERGE=OFF, $
 PAGELAYOUT=1, $
    COMPONENT=R1, TYPE=REPORT, POSITION=(1.5 2), DIMENSION=(8 3), $
    COMPONENT=R2, TYPE=REPORT, POSITION=(.5 5), DIMENSION=(8 5),
        OVERFLOW-POSITION=(.5 2), OVERFLOW-DIMENSION=(8 8.5), $
  PAGELAYOUT=ALL, $    
    COMPONENT=HEADER, TYPE=REPORT, POSITION=(1.25 1), DIMENSION=(6 1), $
END

SET COMPONENT=R1
TABLE FILE GGSALES
HEADING CENTER
"Report 1"
"Sales Summary by Category"
" "
SUM UNITS BUDUNITS DOLLARS BUDDOLLARS BY CATEGORY
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, SQUEEZE=ON, $
END

SET COMPONENT=R2
TABLE FILE GGSALES
HEADING CENTER
"Report 2"
"Sales Detail Report"
" "
SUM UNITS BUDUNITS DOLLARS BUDDOLLARS
BY CATEGORY BY PRODUCT BY REGION
ON CATEGORY UNDER-LINE
ON PRODUCT SUB-TOTAL
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, SQUEEZE=ON, $
END

SET COMPONENT=HEADER 
TABLE FILE GGSALES
HEADING
"Gotham Grinds sales to Information Builders, October 1997"
BY CATEGORY NOPRINT
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, IMAGE=gotham.gif, POSITION=(3.25 .25), DIMENSION=(2 .75), $
END

La primera página de salida es:

La segunda página de salida es:

Puede dibujar una variedad de objetos sobre la página para mejorar un informe. Entre los objetos admitidos actualmente se encuentran las líneas, cuadros, cadenas de texto estáticas e imágenes.

La sintaxis empleada para dibujar estos objetos puede aparecer en la hoja de estilos de un informe, aunque también puede estar incluida dentro de en un agrupamiento PAGELAYOUT, en las declaraciones COMPOUND LAYOUT. La sintaxis de cada objeto de dibujo está descrita más abajo.

• Líneas. Para trazar una línea de un punto (x1 y1) a otro punto (x2 y2), introduzca la sintaxis siguiente:

  OBJECT=LINE, POSITION=(x1 y1), ENDPOINT=(x2 y2),
          [BORDER=b,] [BORDER-COLOR=c,] [BORDER-STYLE=s,]$

  Opcionalmente, los atributos de borde BORDER, BORDER-COLOR y BORDER-STYLE siguen la sintaxis de BORDER existente, como se indica a continuación:

  OBJECT=LINE, POSITION=(1 1), ENDPOINT=(8 1),
          BORDER=HEAVY, BORDER-COLOR=RED, BORDER-STYLE=DASHED, $

• Cuadros. Para trazar un cuadro, con la esquina superior izquierda situada en (x y) y cuyas dimensiones son xdim por ydim, introduzca la siguiente sintaxis:

  OBJECT=BOX, POSITION=(x y), DIMENSION=(xdim ydim),
          BACKCOLOR=c,
          [BORDER=b,] [BORDER-COLOR=bc,] [BORDER-STYLE=bs,] $

  Sugerencia: El color de fondo, c, especifica el color con que se ha rellenado el cuadro, que puede ser cualquier color válido. Por ejemplo, amarillo o RGB(200 200 200).

  Al igual que en la sintaxis de BORDER, los lados individuales del cuadro pueden tener un estilo diferente. Por ejemplo:

  OBJECT=BOX, POSITION=(1 1), DIMENSION=(2 3),
          BACKCOLOR=YELLOW,
          BORDER=HEAVY, BORDER-TOP-COLOR=RED, BORDER-BOTTOM-COLOR=BLUE, $

  Tenga en cuenta que, al igual que en la sintaxis de BORDER, los atributos de líneas o cuadros que no se han especificado explícitamente presentan estos valores predeterminados:

  • Color: negro
  • Estilo: liso
  • Atributo de ancho del borde: medio
• Cadenas de texto estáticas. Las cadenas de texto estáticas muestran textos que puede introducir como parte de la descripción del objeto.

  Puede aplicar un formato al texto mostrado en un objeto de texto, mediante etiquetas de marcado dentro de la porción de texto del objeto de texto. Los informes con etiquetas de marcado en objetos de texto se denominan informes de marcado. Puede generar un informe de marcado como un archivo de salida PDF, DHTML o PPT. WebFOCUS da soporte a un subconjunto de etiquetas HTML y a sus propias etiquetas de numeración de páginas. Para activar estas etiquetas de marcado (para tratarlas como elementos de formato, en lugar de mostrarlas como texto), añada el atributo MARKUP=ON al objeto de cadena. Para más información, consulte Etiquetas de marcado de formatos de texto para un objeto de texto.

  Para trazar una cadena de texto estática en la posición (x y ), introduzca esta sintaxis:

  OBJECT=STRING, POSITION=(X Y), TEXT='any text you like', [MARKUP={ON|OFF},] [FONT=f,] [SIZE=sz,] [STYLE=st,] [COLOR=c,]
          [WRAP=ON, DIMENSION=(xdim ydim),] [LINESPACING=linesoption ,] 
   $

  donde:

  POSITION=(xy)

  Especifica la coordenada (x y) sobre la página en que se va a colocar la esquina superior izquierda del componente. Todas las coordenadas están en UNIT (pulgadas, por defecto) actuales; (0 0) es la esquina superior izquierda de la página física.

  Nota: Por defecto, las coordenadas son ubicaciones absolutas en la página física. Si x o y está precedida por un signo más (+) o un signo menos (-), por ejemplo, (+.25 +0), la coordenada es relativa al margen izquierdo o superior de la página.

  TEXT='any text you like'

  El texto que se va a colocar en el objeto de texto.

  Nota: Si su texto contiene cualquier carácter de intercalación abierto (<), debe añadir un espacio después de cada signo de intercalación abierto del texto. De lo contrario, todo lo que venga después del signo de intercalación abierto se interpretará como el inicio de una etiqueta de marcado y no aparecerá como texto.

  MARKUP={ON|OFF}

  ON hace que las etiquetas de marcado se interpreten como opciones de formato. OFF muestra las etiquetas como texto. OFF es el valor predeterminado.

  FONT=f

  Es la fuente predefinida usada en el texto.

  SIZE=sz

  Es el tamaño de fuente predefinido usado en el texto.

  STYLE=st

  Es el estilo de fuente predefinido usado en el texto.

  COLOR=c

  Es el color de fuente predefinido usado en el texto.

  WRAP=ON

  Especifica que el texto debe ajustarse cuando alcance el final del cuadro de límite del objeto de texto.

  DIMENSION=(xdimydim)

  Especifica el tamaño del cuadro de límite del objeto de texto (en UNITs actuales).

  LINESPACING=linesoption

  Define la cantidad de espacio vertical situado entre las líneas de texto de un párrafo. Se admiten dos tipos de atributos LINESPACING:

  LINESPACING={SINGLE|1.5LINES|DOUBLE}

  o

  LINESPACING=type(value)

  donde:

  SINGLE

  Acomoda la fuente más grande en esa línea, además de un pequeño espacio extra. La cantidad de espacio extra varía en función de la fuente utilizada. SINGLE es la opción predeterminada.

  1.5LINES

  Es un espacio y medio mayor que el interlineado individual.

  DOUBLE

  El doble que el interlineado individual.

  type(value)

  Puede ser uno de los siguientes, donde valor es un número positivo.

  Tipo	Valor	Ejemplo
  MULTIPLE	El porcentaje en el que se va a aumentar o reducir el interlineado.	LINESPACING=MULTIPLE(1.2) aumenta el interlineado en un 20 por ciento.
  MIN	El interlineado mínimo (en la unidad especificada por el parámetro UNITS), necesario para acomodar la fuente más grande en la línea.	LINESPACING=MIN(0.5) proporciona un interlineado mínimo de media pulgada, cuando UNITS=IN.
  EXACT	El interlineado fijo (en la unidad especificada por el parámetro UNITS) no ajustado por WebFOCUS.	LINESPACING=EXACT(.3)proporciona un interlineado mínimo de 0.3 pulgadas, cuando UNITS=IN.

  Opcionalmente, puede especificar los atributos FONT, SIZE, STYLE y COLOR como en cualquier otro objeto de texto de un informe. Por ejemplo:

  OBJECT=STRING, POSITION=(1 1), TEXT='Hello world!',
          FONT=TIMES, SIZE=12, STYLE=BOLD, COLOR=RED, $

  Nota: La posición de una cadena se mide a partir de la parte inferior izquierda para permitir la alineación de distintas cadenas con una línea de base común. Sin embargo, si WRAP=ON está presente, indica que la cadena debe ajustarse a un cuadro de límite con la esquina superior izquierda situada en (x y) y cuyas dimensiones son (xdim ydim). En este caso, la esquina superior izquierda de la cadena de texto queda colocada en el punto (x y).

• Images. Puede trazar una imagen como un objeto de dibujo introduciendo la sintaxis siguiente:

  OBJECT=IMAGE, IMAGE=file, POSITION=(x y), DIMENSION=(xdim ydim), $

  Nota: El nombre del archivo =file de imagen puede tratarse de cualquier archivo de imagen válido en un informe PDF. POSITION se utiliza como en cualquier imagen convencional, mientras que DIMENSION se usa en lugar del atributo SIZE de una imagen convencional.

El ejemplo siguiente muestra cómo colocar los objetos de dibujo dentro la sintaxis COMPOUND LAYOUT, mediante el archivo máster GGSALES. Observe que un objeto de dibujo, como un COMPONENT, aparece en la página, a continuación de la declaración PAGELAYOUT.

SET PAGE-NUM=OFF
SET SQUEEZE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=1, $
COMPONENT=Sales, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
COMPONENT=Budget, TYPE=REPORT, POSITION=(6.25 1), DIMENSION=(4 4), $ 
OBJECT=IMAGE, IMAGE=gglogo.gif, POSITION=(1 4.5), DIMENSION=(1 1), $ 
OBJECT=BOX, POSITION=(1 1), DIMENSION=(5 3), BACKCOLOR=GOLDENROD, $
END
SET COMPONENT=Sales
TABLE FILE GGSALES
"Sales report for <REGION"
" "
SUM DOLLARS
BY REGION NOPRINT
BY CATEGORY 
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, STYLE=BOLD, $
END
SET COMPONENT=Budget
TABLE FILE GGSALES
"Budget report for <REGION"
" "
SUM BUDDOLLARS
BY REGION NOPRINT
BY CATEGORY
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=BLUE, $
END
COMPOUND END

La primera página de salida es:

Nota: No se trazará un objeto de dibujo a menos que haya un COMPONENT como mínimo en su PAGELAYOUT.

Puede usar el comando SET LAYOUTGRID como ayuda para desarrollar diseños de informes manualmente. La visualización de cuadrículas superpone una ligera cuadrícula de 1x1 pulgadas sobre la página para verificar la posición de los distintos componentes de informe. Actualmente, la cuadrícula sólo funciona en pulgadas.

Para mostrar cuadrículas, introduzca la siguiente sintaxis:

SET LAYOUTGRID=ON

Nota: Si su texto contiene cualquier carácter de intercalación abierto (<), debe añadir un espacio después de cada signo de intercalación abierto del texto. De lo contrario, todo lo que venga después del signo de intercalación abierto se interpretará como el inicio de una etiqueta de marcado y no aparecerá como texto.

Propiedades de fuente

La etiqueta de marcado admite tres atributos: nombre, tamaño y color (el color debe especificarse como un código numérico hexadecimal):

<font face="font" size=[+|-]n color=color_code>text</font>

Por ejemplo:

<font face="New Century Schoolbook">Test1</font>
<font face="Times" size=12>test2</font>
<font face="Times New Roman" color=#0000FF size=+4>Test3</font> 
<font size=-2 face="Times New Roman" color=#0000FF >Test4</font>

Estilos de texto

Los estilos de texto admitidos son negrita, cursiva, subrayado y superíndice.

Negrita: <b>text</b>

Cursiva: <i>text</i>

Subrayado: <u>text</u>

Superíndice: ^text

Saltos de línea

La etiqueta de salto de línea posterior a una porción de texto comienza la próxima porción de texto en una línea nueva. Tenga en cuenta que los saltos de línea no disponen de etiqueta de cierre:

<br>

Alineación de texto

Las opciones de alineación afectan tanto al texto ajustado como a los saltos de línea especificados. Tanto la justificación horizontal como la alineación vertical son compatibles.

• Justificación horizontal

  Justificación izquierda:

  <left>text</left>

  Justificación derecha:

  <right>text</right>

  Justificación centrada:

   <center>text</center>

  Justificación completa:

   <full>text</full>

• Alineación vertical

  Alineación superior:

  <top>text</top>

  Alineación central:

  <mid>text</mid>

  Alineación inferior:

  <bottom>text</bottom>

Lista desordenada (puntos)

La etiqueta de lista desordenada (ul) encierra una lista de puntos (puntos). Cada elemento se encuentra encerrado en una etiqueta de elemento de lista (li). Las etiquetas de inicio y cierre de la lista deben estar en su propia línea. Cada elemento de lista debe comenzar en una línea nueva:

<ul>
<li>list item1</li>
<li>list item2</li>
  .
  .
  .
</ul>

El tipo de punto predefinido es el disco. También puede especificar un círculo o un cuadrado:

<ul type=disc>

<ul type=circle>

<ul type=square>

Lista ordenada (número o letra)

La etiqueta de lista ordenada (ol) encierra una lista en la que cada elemento tiene un número o letra consecutivo. Cada elemento se encuentra encerrado en una etiqueta de elemento de lista (li). Las etiquetas de inicio y cierre de la lista deben estar en su propia línea. Cada elemento de lista debe comenzar en una línea nueva:

<ol>
<li>list item1</li>
<li>list item2</li>
  .
  .
  .
</ol>

Se utilizan números arábigos (tipo=1) por defecto para ordenar la lista. Puede especificar los siguientes tipos de orden:

Números arábigos (por defecto): <ol type=1>

Letras minúsculas: <ol type=a>

Letras mayúsculas: <ol type=A>

Números romanos en minúscula: <ol type=I>

Números romanos en mayúscula: <ol type=I>

Hipervínculos

Puede incluir hipervínculos en el formato de texto de documentos PDF.

La sintaxis de la etiqueta de formato del delimitador es un subconjunto de la sintaxis de delimitadores HTML:

<a href="hyperlink">Text to display</a>

donde:

hyperlink

Es el hipervínculo al que nos dirigimos al pulsar el texto.

Text to display

El texto mostrado para el hipervínculo.

Por ejemplo:

<a href="http://www.example.com/help.htm">Click here for help</a>

La etiqueta de formato del delimitador no es compatible con ningún otro atributo.

Numeración de páginas y fechas

Existen dos etiquetas pseudo-HTML para insertar números de páginas en el texto de una página principal de un informe de diseño compuesto coordinado:

Número de página actual: <ibi-page-number/>

Número total de páginas: <ibi-total-pages/>

Observe que, cuando MARKUP=ON, el espacio se asigna al mayor número de páginas posibles, así que puede existir un espacio considerable entre el número de página y el texto posterior. Para eliminar el espacio adicional del objeto de texto con las etiquetas de numeración de páginas:

• Si no es obligatorio un estilo específico para el objeto de texto, no inserte etiquetas de formato y desactive MARKUP.

  MARKUP=OFF, TEXT='Page <ibi-page-number/> of <ibi-total-pages/> of Sales Report', $

  Aparece lo siguiente

  Page 1 of 100 of Sales Report 

• Si el objeto de texto debe tener un estilo específico, active MARKUP. Con MARKUP=ON, desactive WRAP y no coloque ninguna etiqueta de estilo entre las variables de número de página de la cadena. Las etiquetas pueden emplearse alrededor de la cadena Página n de m completa. El siguiente código produce una cadena de número de página sin los espacios adicionales:

  MARKUP=ON, WRAP=OFF, TEXT='<font face="ARIAL" size=10><i>Page <ibi-page-number/> of <ibi-total-pages/> of Sales Report </i>', $ 

  Aparece lo siguiente

  

Para mostrar una fecha en la salida del informe, inserte una variable de fecha WebFOCUS en un objeto de texto situado en una página principal (por ejemplo, &DATEtrMDYY).

La siguiente solicitud muestra un objeto de texto con etiquetas de marcado, en un archivo de salida PDF.

Nota: La sintaxis de formato de texto no puede contener caracteres de retorno de carro o avance de línea. A fin de presentar el ejemplo en este documento, se han añadido caracteres de avance de línea para que el código de ejemplo se ajuste y encaje en la página mostrada. Para ejecutar este ejemplo en su entorno, copie el código en un editor de texto y borre cualquier carácter de avance de línea que aparezca en el objeto de formato de texto, yendo al final de cada línea y pulsando Borrar. En algunos casos puede que tenga que añadir un espacio para mantener la estructura de la cadena. Para más información sobre cómo mostrar retornos de carro en el objeto de texto, consulte Etiquetas de marcado de formatos de texto para un objeto de texto.

SET PAGE-NUM=OFF
SET LAYOUTGRID=ON
TABLE FILE GGSALES
BY REGION NOPRINT
ON TABLE PCHOLD AS LINESP1 FORMAT PDF
ON TABLE SET STYLE *
type=report, size=8, $
object=string, position=(1 1), dimension=(7 3), wrap=on, markup=on,
 linespacing=multiple(3), 
 text='<b><font face="Arial" size=12>This paragraph is triple-spaced
 (LINESPACING=MULTIPLE(3)):</font></b>
 <full>Our <i>primary</I> goal for fiscal 2006 was to accelerate our
 transformation to customer centricity. In this letter, I’d like to
 give you an update on this work, which contributed to the 22-percent
 increase in earnings from continuing operations we garnered for fiscal
 2006. Since the past is often prologue to the future, I’d like to
 describe how customer centricity is influencing not only our goals for
 fiscal 2007, but also our long-term plans. At Gotham Grinds, customer
 centricity means treating each customer as a unique individual, meeting
 their needs with end-to-end solutions, and engaging and energizing our
 employees to serve them.</full>', $
ENDSTYLE
END

En esta solicitud:

• No se muestra ningún campo del origen de datos. Sólo aparece el objeto de texto en la salida.
• El comando SET LAYOUTGRID muestra una cuadrícula que indica las coordenadas y dimensiones del objeto de texto.
• La declaración OBJECT=STRING especifica un espacio triple: LINESPACING=MULTIPLE(3).
• El siguiente texto aparece en negrita, con una fuente Arial 12 (el tamaño predeterminado es 8, de la declaración TYPE=REPORT):

  ‘Este párrafo presenta un espaciado triple (LINESPACING=MULTIPLE(3)):’

  El marcado de este formato es:

  <b><font face="Arial" size=12>This paragraph is triple-spaced (LINESPACING=MULTIPLE(3)):</font></b>

  Sin embargo, observe que se ha ajustado el tamaño de la imagen para caber en la página, así que puede que la fuente parezca más pequeña:

• El resto del texto aparece con una justificación completa (ambos lados están alineados):

  <full>Our ... </full>

• El marcado siguiente muestra el texto ‘primario’ en cursiva:

  <i>primary</I>

La salida es:

La siguiente solicitud coloca una línea en la página modelo, entre el informe de encabezado y los informes de componentes; además, coloca otra línea y una cadena de texto en la parte inferior de cada página:

SET PAGE-NUM=OFF
SET SQUEEZE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
SECTION=S1, LAYOUT=ON, MERGE=ON, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=ALL, $
COMPONENT=HEADER, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
OBJECT=STRING, POSITION=(1 6.6), MARKUP=ON,
TEXT='<font face="Arial" color=#0000FF size=12> Page <ibi-page-number/>
        </font> ', WRAP=ON, DIMENSION=(4 4),$
OBJECT=LINE, POSITION=(1 2.5), ENDPOINT=(9.5 2.5),
        BORDER-COLOR=BLUE,$
OBJECT=LINE, POSITION=(1 6.5), ENDPOINT=(9.5 6.5),
        BORDER-COLOR=BLUE,$
PAGELAYOUT=1, $
COMPONENT=R1, TYPE=REPORT, POSITION=(1 3), DIMENSION=(4 4), $
COMPONENT=R2, TYPE=REPORT, POSITION=(6 3), DIMENSION=(4 4), $
PAGELAYOUT=2, $
COMPONENT=R3, TYPE=REPORT, POSITION=(4 3), DIMENSION=(4 4), $
END

SET COMPONENT=HEADER
TABLE FILE GGSALES
" "
"Report package for <REGION"
BY REGION NOPRINT
ON TABLE HOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, SIZE=20, $
TYPE=REPORT, IMAGE=gglogo.gif, POSITION=(+.25 +.25), $
TYPE=HEADING, LINE=2, ITEM=1, POSITION=1.5, $
END
SET COMPONENT=R1
TABLE FILE GGSALES
"Sales report for <REGION"
" "
SUM DOLLARS/F8M
BY REGION NOPRINT
BY ST
BY CITY
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=RED, SQUEEZE=ON, $
END
SET COMPONENT=R2
TABLE FILE GGSALES
"Number of unit sales per product for <REGION"
" "
SUM CNT.UNITS AS 'Number of units sold'
BY REGION NOPRINT
BY PRODUCT
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=BLUE, SQUEEZE=ON, $
END
SET COMPONENT=R3
TABLE FILE GGSALES
"Report R3 for <REGION"
BY REGION NOPRINT
SUM DOLLARS BY ST
ON TABLE SET STYLE *
TYPE=REPORT, FONT=HELVETICA, COLOR=GREEN, $
END
COMPOUND END

La primera página de salida es:

La segunda página de la salida presenta los mismos objetos de dibujo:

La siguiente solicitud crea tres cuadros y coloca un objeto de cadena de texto dentro de cada uno:

• En el cuadro izquierdo, el texto se alinea verticalmente en la parte superior.
• En el cuadro del medio, el texto se alinea verticalmente en el medio.
• En el cuadro derecha, el texto se alinea verticalmente en la parte inferior.

Nota: La sintaxis de formato de texto no puede contener caracteres de retorno de carro o avance de línea. A fin de presentar el ejemplo en este documento, se han añadido caracteres de avance de línea para que el código de ejemplo se ajuste y encaje en la página mostrada. Para ejecutar este ejemplo en su entorno, copie el código en un editor de texto y borre cualquier carácter de avance de línea que aparezca en el objeto de formato de texto, yendo al final de cada línea y pulsando Borrar. En algunos casos puede que tenga que añadir un espacio para mantener la estructura de la cadena. Para más información sobre cómo mostrar retornos de carro en el objeto de texto, consulte Etiquetas de marcado de formatos de texto para un objeto de texto.

SET PAGE-NUM=OFF
TABLE FILE GGSALES
BY REGION NOPRINT
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
type=report, font=arial, size=10, $
object=box, position=(1 1), dimension=(6 1), $
object=line, position=(3 1), endpoint=(3 2), $
object=line, position=(5 1), endpoint=(5 2), $ 
object=string, text='<top>Vertically aligned text within a text object using top alignment.</top>', position=(1.05 1), dimension=(2 1), linespacing=exact(.15), markup=on, wrap=on, $
object=string, text='<mid>Vertically aligned text within a text object using middle alignment.</mid>', position=(3.05 1), dimension=(2 1), linespacing=exact(.15), markup=on, wrap=on, $
object=string, text='<bottom>Vertically aligned text within a text object using bottom alignment.</bottom>', position=(5.05 .9), dimension=(2 1),linespacing=exact(.15), markup=on, wrap=on, $ 

END

La salida es:

El informe de diseño compuesto coordinado, consiste de informes o gráficos de componentes individuales con un primer campo de clasificación común. El procedimiento compuesto genera un documento de salida con una página (o conjunto de páginas) independiente para cada valor individual del campo de clasificación, con los componentes insertados, segmentados para mostrar los datos correspondientes al valor del campo de clasificación.

Se genera una página de informe de diseño compuesto coordinado, en el diseño de página asignado, para cada valor de campo de clasificación situado en al menos uno de los informes de componente, mostrando los datos correspondientes a esos componentes, siempre que existan datos para ese valor. Si no existen datos, aparece un informe de componente vacío.

La representación del componente vacío en el informe depende de cómo esté definida la posición del componente en el informe de diseño compuesto coordinado. Los componentes pueden estar definidos con una posición absoluta o relativa respecto a otros componentes del diseño. Si el componente vacío y los componentes posteriores de la página están definidos con una posición absoluta, el informe de componente vacío aparece como un espacio en blanco en la ubicación asignada. Si se ha definido una posición relativa entre el componente vacío y los componentes posteriores, éstos flotarán sobre la página y no aparecerá ningún espacio en blanco en el área definida para el componente vacío.

En los informes compuestos con un posicionamiento relativo definido entre informes, cuando aparezca un informe en blanco, el informe posterior quedará posicionado de forma vertical, en relación a la parte inferior del último informe que no esté vacío, y en horizontal con respecto al margen de la página. Es decir, cuando un informe no contiene datos, el informe posterior flotará (en vertical) y empezará de forma relativa al informe anterior, pero no podrá desplazarse horizontalmente sobre la página, con respecto a ninguno de los informes anteriores.

Cuando se utiliza POSITION = (X,Y), las coordenadas izquierda (X = horizontal) y superior (Y = vertical) determinan la colocación de un informe. Cada coordenada puede definirse de forma independiente, en relación al informe anterior o en una posición fija sobre la página.

Si desea definir el posicionamiento para que el informe flote sobre la página, reemplazando al informe vacío, pero se mantenga anclado en la parte izquierda de la página, puede establecer la coordinada Y (superior) como relativa y anclar la X (izquierda). Para anclar una de las coordenadas de posición, cambie la referencia de una posición relativa (+/-) a una absoluta. Por ejemplo:

Las dos coordenadas relativas: POSITION(+0.003 +0.621)

Anclar horizontal / flotar vertical: POSITION( 0.520 +0.621)

No es necesario cambiar ni añadir sintaxis de WebFOCUS a su solicitud para poder aprovechar esta característica. Sin embargo, preste atención a la selección y relación de los datos de sus componentes coordinados para generar la salida deseada.

En este ejemplo, vamos a crear un conjunto de declaraciones informando sobre los pedidos pendientes de inventario de un grupo determinado de establecimientos. Cada tienda puede tener pedidos incompletos en cualquiera de estas tres categorías de inventario: Alimentos, Café o Regalos.

Para demostrar cómo funciona, primero vamos a construir un conjunto de archivos de datos: un archivo de encabezado, con la información de contacto para el conjunto de establecimientos seleccionado, y archivos de transacción, para cada categoría de inventario. Hemos seleccionado datos específicos para mostrar cómo funciona esto cuando algunos de los informes de componente están vacíos.

Tras crear los archivos de datos, procedemos a construir cuatro informes de componente, uno para mostrar la información del encabezado, y el resto, para cada categoría de inventario.

Finalmente, los integramos en un informe de diseño compuesto coordinado, que muestra toda esta información en un extracto de una sola página para cada tienda

Los cuatro archivos de datos siguientes van a crearse a partir de un join entre los orígenes de datos GGORDER y GGSALES.

APP HOLD baseapp
JOIN
 GGORDER.ORDER01.STORE_CODE IN GGORDER TO
   UNIQUE GGSTORES.STORES01.STORE_CODE
   IN GGSTORES AS J1
END
DEFINE FILE GGORDER
PRODUCT_CATEGORY/A15=IF (PRODUCT_DESCRIPTION IN
                     ('Biscotti','Croissant','Scone')) THEN 'Food'
                     ELSE IF (PRODUCT_DESCRIPTION IN
                     ('French Roast','Hazelnut','Kona')) THEN 'Coffee' ELSE 'Gifts';
END

TABLE FILE GGORDER
SUM
     FST.STORE_NAME
     FST.ADDRESS1
     FST.ADDRESS2
     FST.CITY
     FST.STATE
     FST.ZIP
BY STORE_CODE
WHERE STORE_CODE IN ('R1019','R1020','R1040','R1041');
ON TABLE NOTOTAL
ON TABLE HOLD AS GGHDR FORMAT FOCUS INDEX 'STORE_CODE'
END

TABLE FILE GGORDER
PRINT
     QUANTITY
     UNIT_PRICE
     PACKAGE_TYPE
     SIZE
     VENDOR_NAME
     PRODUCT_CATEGORY
BY STORE_CODE
BY ORDER_DATE
BY PRODUCT_DESCRIPTION
WHERE ( PRODUCT_CATEGORY EQ 'Coffee' ) AND ( ORDER_DATE GE '09/01/97' );
WHERE STORE_CODE IN ('R1019','R1040','R1088');
ON TABLE HOLD AS GG1 FORMAT FOCUS INDEX 'STORE_CODE'
END

TABLE FILE GGORDER
PRINT
     QUANTITY
     UNIT_PRICE
     PACKAGE_TYPE
     SIZE
     VENDOR_NAME
     PRODUCT_CATEGORY
BY STORE_CODE
BY ORDER_DATE
BY PRODUCT_DESCRIPTION
WHERE ( PRODUCT_CATEGORY EQ 'Food' ) AND ( ORDER_DATE GE '09/01/97' );
WHERE STORE_CODE IN ('R1019','R1020','R1041','R1088');
ON TABLE HOLD AS GG2 FORMAT FOCUS INDEX 'STORE_CODE'
END

TABLE FILE GGORDER
PRINT
     QUANTITY
     UNIT_PRICE
     PACKAGE_TYPE
     SIZE
     VENDOR_NAME
     PRODUCT_CATEGORY
BY STORE_CODE
BY ORDER_DATE
BY PRODUCT_DESCRIPTION
WHERE ( PRODUCT_CATEGORY EQ 'Gifts' ) AND ( ORDER_DATE GE '09/01/97' );
WHERE STORE_CODE IN ('R1019','R1020','R1040','R1088');
ON TABLE HOLD AS GG3 FORMAT FOCUS INDEX 'STORE_CODE'
END

El procedimiento siguiente, GGHDR.FEX, genera el primer componente de informe para el informe de diseño compuesto coordinado, a partir del origen de datos GGHDR. Éste actuará como el encabezado de cada página del informe de diseño compuesto. El campo de clasificación compartido por todos los componentes de informe es STORE_CODE. Este procedimiento lista el nombre y dirección de una tienda en cada página del archivo de salida PDF:

TABLE FILE GGHDR
BY STORE_CODE NOPRINT
HEADING
"<STORE_NAME "
"<ADDRESS1 "
"<ADDRESS2 "
"<CITY , <STATE   <ZIP "
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,$
TYPE=HEADING,
     SIZE=10,
     STYLE=BOLD,
     COLOR=BLUE,$
ENDSTYLE
END

El siguiente procedimiento, GGRPT1.FEX, genera el segundo componente de informe para el informe de diseño compuesto coordinado. Muestra datos del origen de datos GG1 con información sobre la categoría de producto Café para el mismo valor de código de tienda del informe de encabezado:

TABLE FILE GG1
SUM
     QUANTITY
     UNIT_PRICE
     FST.PACKAGE_TYPE AS ',Package'
     FST.SIZE AS ',Size'
     VENDOR_NAME
BY STORE_CODE AS 'Store'
BY PRODUCT_DESCRIPTION
HEADING
"<PRODUCT_CATEGORY"
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,$
TYPE=DATA,
     SIZE=10,$
TYPE=TITLE,
     STYLE=BOLD,
     SIZE=10,$
TYPE=HEADING,
     SIZE=10,
     STYLE=BOLD,
    COLOR=RED,$
ENDSTYLE
END

El siguiente procedimiento, GGRPT2.FEX, genera el tercer componente de informe para el informe de diseño compuesto coordinado. Muestra datos del origen de datos GG2 con información sobre la categoría de producto Alimentos para el mismo valor de código de tienda del informe de encabezado:

TABLE FILE GG2
SUM
     QUANTITY
     UNIT_PRICE
     FST.PACKAGE_TYPE AS ',Package'
     FST.SIZE AS ',Size'
     VENDOR_NAME
BY STORE_CODE
BY PRODUCT_DESCRIPTION
HEADING
"<PRODUCT_CATEGORY"
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,$
TYPE=DATA,
    SIZE=10,$
TYPE=TITLE,
     STYLE=BOLD,
     SIZE=10,$
TYPE=HEADING,
     SIZE=10,
     STYLE=BOLD,
     COLOR=RED,$
ENDSTYLE
END

El siguiente procedimiento, GGRPT3.FEX, genera el último componente de informe para el informe de diseño compuesto coordinado. Muestra datos del origen de datos GG3 con información sobre la categoría de producto Regalos para el mismo valor de código de tienda del informe de encabezado:

TABLE FILE GG3
SUM
     QUANTITY
     UNIT_PRICE
     FST.PACKAGE_TYPE AS ',Package'
     FST.SIZE AS ',Size'
     VENDOR_NAME
BY STORE_CODE
BY PRODUCT_DESCRIPTION
HEADING
"<PRODUCT_CATEGORY"
" "
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,$
TYPE=DATA,
     SIZE=10,$
TYPE=TITLE,
     STYLE=BOLD,
     SIZE=10,$
TYPE=HEADING,
     SIZE=10,
     STYLE=BOLD,
     COLOR=RED,$
ENDSTYLE
END

El siguiente procedimiento, GGCMPD.FEX, combina los cuatro componentes en un informe de diseño compuesto coordinado. Los informes y el posicionamiento relativo de cada página aparecen en el diagrama siguiente:

La sintaxis del diseño compuesto coordinado es:

SET HTMLARCHIVE=ON
COMPOUND LAYOUT PCHOLD FORMAT PDF
UNITS=IN, $
SECTION=section1, LAYOUT=ON, MERGE=ON, ORIENTATION=PORTRAIT,
   PAGESIZE=Letter,  $
PAGELAYOUT=1, NAME='Page layout 1', text='Page layout 1',
   TOC-LEVEL=1, BOTTOMMARGIN=0.5, TOPMARGIN=0.5,  $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2,
   POSITION=(0.667 1.083), DIMENSION=(3.417 1.412),  $
COMPONENT='report2', TEXT='report2', TOC-LEVEL=2,
   POSITION=(0.837 2.584), DIMENSION=(* *),  $
COMPONENT='report3', TEXT='report3', TOC-LEVEL=2,
   POSITION=(-0.006 +0.084), DIMENSION=(* *),
   RELATIVE-TO='report2', RELATIVE-POINT=BOTTOM-LEFT,
   POSITION-POINT=TOP-LEFT, $
COMPONENT='report4', TEXT='report4', TOC-LEVEL=2,
   POSITION=(+0.010 +0.080), DIMENSION=(* *),
   RELATIVE-TO='report3', RELATIVE-POINT=BOTTOM-LEFT,
   POSITION-POINT=TOP-LEFT, $
END
SET COMPONENT='report1'
-INCLUDE GGHDR.FEX
SET COMPONENT='report2'
-INCLUDE GGRPT1.FEX
SET COMPONENT='report3'
-INCLUDE GGRPT2.FEX
SET COMPONENT='report4'
-INCLUDE GGRPT3.FEX
COMPOUND END

En la primera página del archivo de salida PDF, todos los componentes tienen datos y aparecen en la salida del informe:

En la segunda página, el informe GGRPT2.FEX no ha recuperado datos de ninguna tienda del encabezado. Por consiguiente, el componente Café no está disponible. Tenga en cuenta que, debido a que los componentes 3 y 4 están posicionados de forma relativa a los componentes definidos encima suya, en la sintaxis del diseño compuesto, los componentes Alimentos y Regalos se han desplazado hacia arriba, en vez de dejar un espacio en blanco en el lugar destinado al componente Café:

En la página 5, el informe de encabezado no ha recuperado datos para un valor de código de tienda presente en los otros tres componentes. Se genera una página para este código de tienda, de todas formas. Puesto que el segundo componente (informe Café) ha quedado colocado de forma absoluta en la sintaxis del diseño compuesto, y no de manera relativa al primer componente (informe de encabezado), el espacio destinado al informe de encabezado se deja en blanco:

La página Tabla de contenido (TOC) muestra un resumen del contenido del documento, con los números de página, y puede imprimirse con el mismo. Las entradas de la tabla de contenido permiten navegar fácilmente a una sección determinada mientras se consulta el documento. Las entradas pueden estar vinculadas a cualquier componente de la salida compuesta (página, informe o gráfico), objeto perteneciente al informe compuesto o valor de campo de clasificación vertical (valores de campo BY) de cada informe de componente.

El contenido real de la tabla de contenido aparece representado como un elemento de texto en la sintaxis de diseño compuesto. Durante el uso de una página de tabla de contenido, puede:

• Personalizar el título de la tabla de contenido, además de aplicar un formato al texto completo.
• Especificar un nivel de tabla de contenido para cada componente incluido en la tabla de contenido.
• Activar la numeración de páginas de tabla de contenido para que cada elemento de la tabla de contenido tenga un número. También puede añadir caracteres de relleno (puntos) entre la entrada y el número de página para facilitar la selección de contenido.
• Controlar los informes y gráficos que aparecen en la tabla de contenido personalizando las propiedades de los objetos.
• Usar vínculos de hipertexto en la página de tabla de contenido, lo que permite pulsar sobre una entrada para ir a una página específica del documento.

Nota: Si la tabla de contenido sobrepasa la página a la hora de ejecutarse, el contenido restante se ejecuta con el mismo tamaño y dimensiones que los de la primera página, hasta que se haya generado salida para toda la tabla de contenido.

Puede generar marcadores, una página de tabla de contenido, o ambos, incluyendo los objetos BOOKMARKS o TOC en la sintaxis del diseño compuesto. A continuación, en las definiciones de componentes, especifique el nivel y descripción de la tabla de contenido y, opcionalmente, los niveles de BYTOC.

Atributos TOC

COMPOUND LAYOUT PCHOLD FORMAT PDF
[OBJECT=BOOKMARKS, $]
[OBJECT=TOC, NAME='text1', 
   TEXT='<font face="font1" size=sz1>Table of Contents</font>',
   MARKUP=ON, TOC-NUMBERING={OFF|ON}, POSITION=(xy), [TOC-FILL=DOTS,]
   DIMENSION=(mn),
   font='font2', color={color|RGB(rgb)}, size=sz2, 
   METADATA=' TOCTITLE: Table of Contents', $]

donde:

OBJECT=BOOKMARKS

Genera marcadores PDF para las entradas de tabla de contenido especificadas en las declaraciones COMPONENT.

OBJECT=TOC

Genera una página de contenido para las entradas de tabla de contenido especificadas en las declaraciones COMPONENT.

NAME='text1'

Especifica un nombre para el elemento de página de tabla de contenido.

TEXT='<font face="font1" size=sz1>Table of Contents</font>'

Especifica el título y las características del texto de título de la tabla de contenido. Para que esta información se interprete correctamente, el atributo MARKUP=ON debe estar especificado. El texto no quedará ajustado y debe caber dentro de los márgenes del elemento de texto general.

MARKUP=ON

Hacer que las etiquetas de marcado usadas en el título de la tabla de contenido se interpreten como opciones de formato; no como texto.

TOC-NUMBERING={OFF|ON}

Determina si las entradas de la página de tabla de contenido aparecen numeradas. ON es el valor predeterminado.

POSITION=(xy)

Define las coordenadas x e y del objeto sobre la página.

DIMENSION=(ab)

Define el tamaño del cuadro de límite del objeto.

font='font2', color={color|RGB(rgb)}, size=sz2,

Especifica las características del texto del cuerpo de la tabla de contenido. Si está omitido, los atributos se toman del atributo TEXT.

TOC-FILL=DOTS

Especifica los puntos de relleno entre la entrada y el número de página. Si este atributo no está incluido, la entrada y el número de página aparecen separados por un espacio en blanco.

Entradas de componentes

COMPONENT=component1, TITLE='title1', TOC-LEVEL=n, [BYTOC=m,] 
   POSITION=(xy),DIMENSION=(ab), $

donde:

component1

Componente que va a incluirse en la tabla de contenido.

title1

Título del componente utilizado como entrada TOC.

TOC-LEVEL=n

Define n como el nivel de tabla de contenido del objeto de informe, gráfico o diseño de página. Esta opción determina el orden jerárquico de los objetos dentro de la tabla de contenido.

0 = el objeto no aparece en la tabla de contenido.

1 = el objeto aparece como un elemento de primer nivel en la página de contenido.

2 = el objeto aparece como un elemento de segundo nivel en la página de contenido.

BYTOC=m

Especifica el número de campos BY incluido en la entrada de componente actual (m).

POSITION=(xy)

Define las coordenadas x e y del objeto sobre la página.

DIMENSION=(ab)

Define el tamaño del cuadro de límite del objeto.

Apuntes principales

• La entrada Tabla de contenido es un vínculo a la página general, no un vínculo directo a la ubicación del elemento de datos seleccionado en la página.
• No incluya informes utilizados para encabezados o pies en páginas de desbordamiento (DisplayOn=OVERFLOWONLY) en ninguna entrada TOC o BYTOC. Estos componentes generan entradas duplicadas en la tabla de contenido, puesto que aparecen repetidos en la segunda página y en las páginas posteriores de un diseño de página cualquiera, en base al recuento de páginas en lugar de los valores de los campos de clasificación.
• En documentos no coordinados, la tabla de contenido presenta todos los diseños y componentes de páginas designados en los parámetros TOC.
• En documentos coordinados, la tabla de contenido presenta una referencia a cada uno de los campos de clasificación coordinados, con un vínculo a la primera de las páginas asociadas de ese campo de clasificación común.

Apuntes sobre BYTOC

• Si el valor de BYTOC designado es superior al recuento de campos BY en el informe de componente, el valor queda establecido por defecto en el recuento total de campos BY disponibles.
• Puede usar cualquier campo que pueda utilizarse como un campo BY en una entrada BYTOC, incluidos los campos tomados directamente de un origen de datos y los creados en un DEFINE.
• Los campos BY que están designados para no aparecer en el campo del informe de componente (campos NOPRINT) sí aparecen, en cambio, en la tabla de contenido.
• Los valores de nivel TOC definidos no pueden saltarse niveles. Cualquier salto de nivel impedirá que aparezcan los marcadores situados debajo de dicho nivel.

El ejemplo siguiente tiene dos informes de componente. Se generan marcadores PDF y una página de tabla de contenido. Cada componente se encuentra en el nivel 1 de TOC y presenta dos niveles de campos BY, situados bajo las entradas del nivel 1:

COMPOUND LAYOUT PCHOLD FORMAT PDF
OBJECT=BOOKMARKS, $
OBJECT=TOC, NAME='text1', 
  TEXT='<font face="ARIAL" size=10>Table of Contents</font>',
  MARKUP=ON, TOC-NUMBERING=ON, POSITION=(0.854 0.854),
  DIMENSION=(7.000 9.500), font='ARIAL', color=RGB(0 0 0),
  size=10, METADATA=' TOCTITLE: Table of Contents', $
SECTION=S1, LAYOUT=ON, MERGE=OFF, ORIENTATION=PORTRAIT, $
PAGELAYOUT=1, $
COMPONENT=report1, TEXT='Sales By Product', TOC-LEVEL=1, BYTOC=2,
  POSITION=(1 1), DIMENSION=(* *), $
COMPONENT=report2, TEXT='Sales By Region', TOC-LEVEL=1, BYTOC=2,
  POSITION=(+0.00 +0.519), DIMENSION=(* *), RELATIVE-TO='report1',
  RELATIVE-POINT=BOTTOM-LEFT, POSITION-POINT=TOP-LEFT, $
END
SET COMPONENT=report1
TABLE FILE GGSALES
SUM DOLLARS/F8M
BY CATEGORY 
BY PRODUCT
BY REGION 
BY ST
HEADING
"Sales by Category"
ON TABLE HOLD FORMAT PDF
END
SET COMPONENT=report2
TABLE FILE GGSALES
SUM DOLLARS/F8M
BY REGION 
BY ST
BY CATEGORY 
BY PRODUCT
HEADING
"Sales by Region"
ON TABLE HOLD FORMAT PDF
END
COMPOUND END

La salida indica que cada informe de componente está en el nivel 1 de la tabla de contenido, con dos niveles de campos de clasificación debajo. En el informe Ventas por producto, los campos BY son Categoría y Producto. En el informe Ventas por región, los campos BY son Región y Estado. Cada entrada de la tabla de contenido es un vínculo a la página que contiene el valor:

Al pulsar sobre cualquier entrada de la página de tabla de contenido o en el panel de marcadores, se abre la página que contiene esa entrada. Por ejemplo, si pulsa sobre la entrada Ventas por región/Sureste, se abre la página siguiente:

SET COMPOUND= {OPEN|CLOSE} [NOBREAK]

ON TABLE SET COMPOUND {OPEN|CLOSE}

ON TABLE {PCHOLD|HOLD|SAVE} [AS name] FORMAT formatname

ON TABLE {PCHOLD|HOLD|SAVE} [AS name] FORMAT {PDF|PS} {OPEN|CLOSE} [NOBREAK]

• Los informes compuestos no se pueden anidar.
• Puede guardar o demorar la salida de un informe compuesto. Para obtener información detallada, consulte Cómo guardar y reutilizar su salida de informes.
• No se pueden utilizar informes de paneles múltiples en un informe compuesto.

A continuación se explica cómo combinar tres informes PDF separados en uno creando un informe compuesto. Tenga en cuenta que:

• El Informe 1 especifica ON TABLE PCHOLD FORMAT PDF OPEN. Lo que define el informe como el primero y ajusta el formato de todo el informe complejo como PDF.
• El Informe 2 sólo especifica el formato, ON TABLE PCHOLD FORMAT PDF.
• El Informe 3 especifica ON TABLE PCHOLD FORMAT PDF CLOSE. Lo que define al informe como el último informe.

Tenga en cuenta que en este ejemplo, todos los informes han sido ajustados para formato PDF. Sin embargo, cuando crea un informe compuesto, sólo el primer informe debe estar en formato PDF o PS. Los informes posteriores pueden estar en cualquier formato con estilo. Para ver un ejemplo, consulte Cómo Insertar gráficos en un informe compuesto.

Report 1:

SET PAGE-NUM=OFF
TABLE FILE CENTORD
HEADING
"Sales Report"
" "
SUM LINEPRICE
BY PRODCAT
ON TABLE SET STYLE *
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF OPEN NOBREAK
END

Report 2:

TABLE FILE CENTORD
HEADING
"Inventory Report"
" "
SUM QUANTITY
BY PRODCAT
ON TABLE SET STYLE *
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF NOBREAK
END

Report 3:

TABLE FILE CENTORD
HEADING
"Cost of Goods Sold Report"
" "
SUM LINE_COGS
BY PRODCAT
ON TABLE SET STYLE *
TYPE=HEADING, SIZE=18, $
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF CLOSE
END

La salida se muestra como informe PDF. Dado que la sintaxis para los informes 1 y 2 contiene el comando NOBREAK, los tres informes aparecen en una sola página. (Sin NOBREAK, cada informe aparece en una página individual).

Puede insertar un gráfico, como un logo o un gráfico de WebFOCUS capturado como archivo GIF, en un informe compuesto. El archivo gráfico debe estar incrustado en un informe en particular, dentro del conjunto de informes compuestos.

Para guardar un gráfico como imagen gráfica, incluya la siguiente sintaxis en la solicitud:

HOLD FORMAT GIF

Para obtener información detallada acerca de cómo guardar un gráfico como archivo de imagen, vaya a Cómo crear un gráfico.

Para insertar un gráfico en un informe compuesto, debe identificar el archivo de imagen en la declaración de hoja de estilos del informe en que desee incluirlo, junto con las especificaciones de tamaño y posición, si así lo desea. Para obtener información detallada acerca de cómo insertar y posicionar gráficos en un informe, vaya a Cómo añadir una imagen a un informe.

Esta solicitud genera un informe compuesto desde tres tipos de informe diferentes (PDF, HTML, y EXL2K) e inserta un gráfico en cada informe. Observe que cada gráfico queda guardado como un archivo GIF en la solicitud del gráfico. A continuación, el gráfico queda identificado, se modifica su tamaño y se inserta dentro de la declaración de hoja de estilos (TYPE=REPORT, IMAGE=graphname...) del informe en que se está insertando. Las variaciones de la sintaxis SET COMPOUND= (OPEN, NOBREAK, CLOSE) combinan los tres informes en la misma página. En la siguiente solicitud se destacan las líneas clave del código.

Report 1:

SET GRMERGE = ON
GRAPH FILE SHORT
SUM PROJECTED_RETURN AS 'Return on Investment'
BY HOLDER
ACROSS CONTINENT
ON GRAPH SET LOOKGRAPH 3D_BAR
ON GRAPH SET GRAPHEDIT SERVER 
ON GRAPH HOLD AS SLSGRPH1 FORMAT GIF 
END

SET COMPOUND='OPEN NOBREAK' 
TABLE FILE SHORT
SUM PROJECTED_RETURN AS 'Return on Investment'
BY CONTINENT
BY HOLDER
HEADING
"Investment Report"
" "

ON TABLE SET STYLE *
TYPE=DATA, BACKCOLOR=( BY=B2 'SILVER' 'WHITE' ), $
TYPE=HEADING, SIZE=14, STYLE=BOLD, $ 
TYPE=REPORT, IMAGE=SLSGRPH1.gif, POSITION=(4.5 0.5), SIZE=(3.5 2.5), $ 
ENDSTYLE 
ON TABLE PCHOLD FORMAT PDF 

END

Report 2:

GRAPH FILE TRADES
SUM AMOUNT
BY CONTINENT
ON GRAPH SET LOOKGRAPH PIE
ON GRAPH SET GRAPHEDIT SERVER 
ON GRAPH HOLD AS TRDSGR1 FORMAT GIF 
END

SET COMPOUND=NOBREAK 
TABLE FILE TRADES
SUM AMOUNT AS 'Amount'
BY CONTINENT AS 'Continent'
BY REGION AS 'Region'
HEADING
"Trades Report"
" "
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
 TYPE=DATA, BACKCOLOR=( BY=B2 'SILVER' 'WHITE' ), $

TYPE=HEADING, SIZE=14, STYLE=BOLD, $ 
TYPE=REPORT, IMAGE=TRDSGR1.gif, POSITION=(4 3), SIZE=(4 2.5), $ENDSTYLE 
ON TABLE PCHOLD FORMAT HTML 
END

Report 3:

GRAPH FILE SHORT
SUM BALANCE
BY CONTINENT
ON GRAPH SET LOOKGRAPH 3D_BAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET STYLE *
TYPE=DATA, COLOR=RED,$
ENDSTYLE 
ON GRAPH HOLD AS BALGR1 FORMAT GIF 
END

 
SET COMPOUND=CLOSE 
TABLE FILE SHORT
SUM BALANCE AS 'Balance'
BY CONTINENT AS 'Continent'
BY REGION AS 'Region'
HEADING
"Balance by Region"
" "
ON TABLE SET STYLE *
 TYPE=DATA, BACKCOLOR=( BY=B2 'SILVER' 'WHITE' ), $
TYPE=HEADING, SIZE=14, STYLE=BOLD, $
 
TYPE=REPORT, IMAGE=BALGR1.gif, POSITION=(4 6), SIZE=(4 2.5), $ENDSTYLE 
ON TABLE PCHOLD FORMAT EXL2K 
END

La salida es:

SET PAGE-NUM=OFF
TABLE FILE CAR
HEADING
"Sales Report"
" "
SUM SALES
BY COUNTRY
ON TABLE SET STYLE *
type=report, titletext='Sales Rpt', $
type=heading, size=18, $
ENDSTYLE
ON TABLE HOLD AS EX1 FORMAT EXL2K OPEN
END

TABLE FILE CAR
HEADING
"Inventory Report"
" "
SUM RC
BY COUNTRY
ON TABLE SET STYLE *
type=report, titletext='Inv. Rpt', $
type=heading, size=18, $
ENDSTYLE
ON TABLE HOLD FORMAT EXL2K
END

TABLE FILE CAR
HEADING
"Cost of Goods Sold Report"
" "
SUM DC
BY COUNTRY
ON TABLE SET STYLE *
type=report, titletext='Cost Rpt', $
type=heading, size=18, $
ENDSTYLE
ON TABLE HOLD FORMAT EXL2K CLOSE
END

El resultado para cada pestaña en la hoja de trabajo Excel es:

SET PAGE-NUM=OFF
TABLE FILE CAR
HEADING
"Sales Report"
" "
PRINT RCOST
BY COUNTRY
ON TABLE SET STYLE *
type=report, titletext='Sales Rpt', $
type=heading, size=18, $
ENDSTYLE
ON TABLE HOLD AS PIV1 FORMAT EXL2K OPEN
END

TABLE FILE CAR
HEADING
"Inventory Report"
" "
PRINT SALES
BY COUNTRY
ON TABLE SET STYLE *
type=report, titletext='Inv. Rpt', $
type=heading, size=18, $
ENDSTYLE
ON TABLE HOLD AS PPPP FORMAT EXL2K PIVOT
PAGEFIELDS TYPE SEATS
CACHEFIELDS MODEL MPG RPM 
END

TABLE FILE CAR
SUM RCOST
BY COUNTRY BY CAR BY MODEL BY TYPE BY SEATS SUMMARIZE
ON MODEL SUB-TOTAL
ON TABLE HOLD AS XFOCB FORMAT EXL2K FORMULA
END

TABLE FILE CAR
HEADING
"Cost of Goods Sold Report"
" "
PRINT DCOST
BY COUNTRY
ON TABLE SET STYLE *
type=report, titletext='Cost Rpt', $
type=heading, size=18, $
ENDSTYLE
ON TABLE HOLD AS ONE FORMAT EXL2K CLOSE PIVOT
PAGEFIELDS RCOST
CACHEFIELDS MODEL TYPE SALES ACCEL SEATS
END

El resultado para cada pestaña en la hoja de trabajo Excel es:

En este ejemplo, los primeros dos informes están en la primera hoja de trabajo, y los últimos dos informes están en la segunda hoja de trabajo, dado que NOBREAK aparece en ambos el primer y tercer informes.

TABLE FILE GGSALES
HEADING
"Report 1: Coffee - Budget"
SUM BUDDOLLARS BUDUNITS COLUMN-TOTAL AS 'Total'
BY REGION 
IF CATEGORY EQ Coffee
ON TABLE PCHOLD FORMAT EXL2K OPEN NOBREAK
ON TABLE SET STYLE *
type=report, font=Arial, size = 10, style=normal, $
type=title, style=bold, $
type=heading,   size=12, style=bold, color=blue, $
type=grandtotal,  style=bold,  $
END

TABLE FILE GGSALES
HEADING
" "
"Report 2: Coffee - Actual "
SUM DOLLARS UNITS COLUMN-TOTAL AS 'Total'
BY REGION 
IF CATEGORY EQ Coffee
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
type=report, font=Arial, size=10, style=normal, $
type=grandtotal,  style=bold, $
type=heading,  size=12, style=bold, color=blue, $
END

TABLE FILE GGSALES
HEADING
"Report 3: Food - Budget"
SUM BUDDOLLARS BUDUNITS COLUMN-TOTAL AS 'Total'
BY REGION 
IF CATEGORY EQ Food
ON TABLE PCHOLD FORMAT EXL2K NOBREAK
ON TABLE SET STYLE *
type=REPORT, font=Arial, size=10, style=normal, $
type=HEADING,  style=bold, size=12, color=blue, $
type=title, style=bold, $
type=grandtotal,  style=bold,  $
END

TABLE FILE GGSALES
HEADING
" "
"Report 4: Food - Actual"
SUM DOLLARS UNITS COLUMN-TOTAL AS 'Total'
BY REGION 
IF CATEGORY EQ Food
ON TABLE PCHOLD FORMAT EXL2K CLOSE
ON TABLE SET STYLE *
type=report, font=Arial, size=10,  $
type=title, style=bold, $
type=heading,size=12, style=bold,  color=blue,$
type=grandtotal, style=bold,  $
END

La salida es: