Microsoft a modifié le format et la structure du classeur Excel dans Excel 2007. Le nouveau fichier .xlsx est une compilation binaire d'un ensemble de fichiers xml. Générer ce nouveau format de fichier avec WebFOCUS est un processus de deux étapes qui consiste en la génération de fichiers xml qui contiennent la sortie de rapport et le compactage des documents xml sous le format binaire .xlsx. Le serveur de rapports effectue le processus de génération xml. Le processus de compactage peut être réalisé soit par le client (Servlet WebFOCUS) ou le serveur (JSCOM3) :

• Servlet WebFOCUS. Le client WebFOCUS dans le serveur d'applications effectue le processus de compactage. Cette action peut être réalisée dans le client local ou via un client distant. La méthode du servlet est l'approche par défaut définie pour chaque client WebFOCUS, avec le client par défaut qui pointe vers lui-même.
• JSCOM3. La couche java du serveur de rapports exécute l'opération de compactage. Cette option peut être utilisée dans des environnements sécurisés parcequ'elle ne nécessite pas d'accès URL à un client distant.

Désignez la méthode et l'emplacement où sera réalisé le compactage en définissant EXCELSERVURL à une adresse URL (pour le Servlet WebFOCUS) ou à un espace vide (pour JSCOM3). Définissez cette valeur pour une procédure spécifique ou pour l'environnement entier :

• Pour une procédure. Lancez la commande SET EXCELSERVURL dans la procédure.
• Pour l'environnement entier. Modifiez la variable IBIF_excelservurl dans la Console d'administration WebFOCUS en sélectionnant :

  Configuration/Paramètres du client/General/IBIF_excelservurl

  Pour plus d'informations sur l'accès à la console d'administration WebFOCUS et sur la définition de la variable IBIF_excelservurl, consultez le manuel Sécurité et Administration WebFOCUS.

La valeur que vous attribuez à EXCELSERVURL détermine si le Servlet WebFOCUS ou JSCOM3 réalise l'opération de compactage :

• Spécifier le Servlet. Pour spécifier que le Servlet WebFOCUS devrait être utilisé, définissez le paramètre EXCELSERVURL ou IBIF_variable à l'adresse URL de la configuration client WebFOCUS, version 7.7.02 ou supérieure. Par exemple,

  Dans une procédure:

  SET EXCELSERVURL = http://servername:8080/ibi_apps									

  Dans la console d'administration WebFOCUS :

  IBIF_excelservurl = http://servername:8080/ibi_apps									

• Spécifier JSCOM3. Pour spécifier que JSCOM3 devrait être utilisé dans le serveur de rapports actuel, définissez EXCELSERVURL à un espace ou une chaîne vide.

  Dans une procédure:

  SET EXCELSERVURL = ''

  Dans la console d'administration WebFOCUS :

  IBIF_excelservurl = ''

Par défaut, chaque client WebFOCUS contient la définition URL suivante qui pointe vers elle-même.

&URL_PROTOCOL://&SERVER_NAME:&SERVER_PORT&IBIF_webapp

Vous pouvez spécifier qu'un rapport devrait être enregistré vers un classeur Excel 2007/2010, affiché sur le navigateur, ou affiché dans l'application Excel 2007/2010.

ON TABLE {PCHOLD|HOLD} AS name FORMAT EXL07

où :

PCHOLD

Affiche le classeur généré soit sur le navigateur ou dans l'application Excel 2007/2010, en fonction des paramètres de votre bureau. Pour plus d'informations, consultez Visualiser les classeurs Excel dans le navigateur vs. l'application Excel .

HOLD

Enregistre un classeur avec une extension .xlsx vers l'emplacement désigné.

name

Spécifie un nom de fichier pour le classeur généré.

Remarque : le nom ne sera utilisé pour PCHOLD que lorsque l'option Enregistrer le rapport est réglée à YES pour l'extension .xlsx du fichier dans les Paramètres de redirection du client WebFOCUS. Lorsque le rapport est ouvert dans le navigateur, les utilisateurs sont invités à ouvrir ou enregistrer la sortie du rapport avec le nom de fichier désigné. Pour les rapports ouvert dans l'application Excel 2007/2010, le classeur généré conservera le nom AS désigné. Pour plus d'informations, consultez le manuel Administration et Sécurité WebFOCUS.

Excel 2000 et Excel 2003 peuvent être mis à jour pour lire les feuilles de calcul Excel 2007 ou 2010 à l'aide de l'installation du Pack de compatibilité Microsoft Office disponible à partir du site de téléchargment de Microsoft (http://www.microsoft.com/downloads/en/default.aspx). Lorsque l'extension du fichier ouvert est .xlsx (classeur Excel 2007/2010), le Pack de compatibilité Microsoft Office effectue la conversion nécessaire pour permettre à Excel 2000/2003 de le lire et de l'ouvrir.

En plus du Pack de compatibilité Microsoft Office, il est important d'activer les paramètres de redirection du client WebFOCUS Enregistrer sous afin qu'Excel 2000/2003 puisse ouvrir la sortie du rapport Excel 2007/2010 sans que les utilisateurs aient à l'enregistrer sur leur ordinateur avec l'entension de fichier .xlsx. L'option Enregistrer sous des paramètres de redirection du client WebFOCUS configure la façon dont le client WebFOCUS envoie chaque sortie de rapport à l'ordinateur de l'utilisateur. Cette option peut être définie de la façon suivante :

• Option Enregistrer sous désactivée (NO).Le paramètre de redirection du client WebFOCUS Enregistrer sous est désactivé par défaut. Lorsque l'option Enregistrer sous est désactivée, le client WebFOCUS envoie la sortie du rapport vers l'ordinateur de l'utilisateur dans la mémoire avec l'association d'application spécifiée pour le format de rapport dans le fichier de configuration Paramètres de redirection du client WF (mime.wfs).

  L'association d'application pour Excel 2007/2010 est :

  application/vnd.openxmlformats-officedocument.spreadsheetml.sheet

  L'ordinateur d'un utilisateur sans Excel 2007/2010 installé ne reconnaîtra pas l'association de l'application pour Excel 2007/2010 et affichera le message suivant :

  

  L'utilisateur Excel 2000/2003 peut sélectionner Enregistrer et fournir un nom de fichier avec l'extension .xlsx pour enregistrer la sortie du rapport vers leur ordinateur. L'utilisateur peut ensuite ouvrir le fichier .xlsx directement à partir de Excel 2000/2003.

• Option Enregistrer sous activée (YES). Lorsque l'option Enregistrer sous du paramètre de redirection WebFOCUS est activée, le client WebFOCUS envoie la sortie du rapport vers l'utilisateur comme fichier avec l'extension spécifiée dans le fichier de configuration Paramètres de redirection du client webFOCUS (mime.wfs).

  A la réception du fichier, Windows affiche Télécharger le fichier qui invite l'utilisateur à Ouvrir ou Enregistrer le fichier avec le type d'application identifié. Comme le montre l'image suivante, l'invite Télécharger le fichier affiche le nom avec l'extension du fichier xlsx pour la sortie du rapport reconnue comme type de fichier Excel 2007/2010.

  

  Remarque : l'invite de téléchargement s'affiche pour tous les utilisateurs, y compris ceux qui ont Excel 2007/2010 installé sur leur ordinateur.

  Si un utilisateur Excel 2000/2003 choisit d'ouvrir le fichier, le Pack de compatibilité Microsoft Office reconnaît l'extension du fichier .xlsx et effectue la conversion nécessaire pour permettre à 2000/2003 de lire le classeur Excel 2007/2010.

  Si un utilisateur Excel 2007/2010 choisit d'ouvrir le fichier,Excel 2007/2010 reconnaît l'extension du fichier .xlsx et lit le classeur Excel 2007/2010.

Pour plus d'informations sur les paramètres de redirection du client WebFOCUS, consultez le manuel Administration et Sécurité WebFOCUS.

Chaque format numérique WebFoCUS est converti en format numérique Excel personnalisé. La valeur numérique est affichée dans la barre de formule Excel pour la cellule sélectionnée. Dans la cellule réelle, la valeur s'affiche avec le masque de format appliqué.

Les formats WebFOCUS pour les types de données numériques suivants sont convertis en masques de format Excel 2007/2010 qui prennent en charge la modification complète dans le classeur résultant :

• Types de données : E, F, D , I, P.
• Option de modification de la virgule (C).
• Suppression des zéro (S).
• Zéro non significatif (L).
• Symbole monétaire flottant (M).

  Remarque : Excel ne prend pas automatiquement en charge la position des symboles monétaires ou d'autres formatage uniquement sur la première ligne de données. Bien que différents formats peuvent être définis par cellule, si l'utilisateur trie les données, le premier format sera déplacé avec la première ligne en fonction de la valeur de tri. Toutefois, les symboles monétaires fixes sont présentés sur chaque ligne de données de manière semblable à celle des symboles flotants :

• Suppression de la virgule (c).
• Signe moins de droite (-).
• Crédit négatif (CR).
• Crochet négatif (B).
• Symbole monétaire fixe étendu (!d, !e, !l, !y).
• Symbole monétaire flottant étendu (!D, !E, !L, !Y).
• Pourcentage (%).

Dans l'exemple suivant, le champ DOLLARS est attribué différents formats numériques pour démontrer différentes options disponibles. Les titres de colonne ont été modifiés pour afficher les options de format WebFOCUS appliquées :

TABLE FILE GGSALES
SUM DOLLARS/D12.2 AS 'D12.2'
    DOLLARS/D12C  AS 'D12C'
    DOLLARS/D12CM AS 'D12CM'
BY REGION
BY CATEGORY
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET BYDISPLAY ON
END

Dans la feuille de calcul, vous remarquerez que la cellule C2 qui contient la valeur DOLLAR pour Midwest Coffee présente la valeur avec le format WebFOCUS D12.2, qui présente la virgule et deux décimales. Sur la barre de formule, la valeur réelle est présentée sans formatage. Examinez chaque valeur de DOLLAR dans chaque ligne pour noter que la valeur affichée dans la barre de formule reste la même, et seules les valeurs d'affichage sont présentées dans chaque modification de la celulle.

Notez également qu'avec SET BYDISPLAY ON, les valeurs du champ BY se répètent pour chaque ligne sur la feuille de calcul. Ce phénomène crée des lignes de données pleinement qualifiées qui peuvent être utilisées avec divers tris, filtrages de données, et des fonctionnalités de tables Excel sans perdre de précieuses informations. Ce réglage est recommandé comme pratique exemplaire pour toutes les feuilles de calcul :

L'exemple suivant utilise le format Dollar fixe (N), ainsi que plusieurs options de format combinées. Chaque option du format Excel est convertie en masque de format Excel 2007/2010 et appliquée à la valeur de la cellule :

TABLE FILE GGSALES
SUM BUDDOLLARS/D12N
    DOLLARS/D12M
COMPUTE OVERBUDGET/D12BMc=BUDDOLLARS-DOLLARS; AS 'Over Budget'
BY REGION
BY CATEGORY
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET BYDISPLAY ON
END

Notez que le format numérique fixe défini pour la colonne BUDDOLLARS (colonne C) présente le symbole monétaire local dans une position fixe dans chaque cellule, quelle que soit la taille de la valeur des données. Sur la barre de formule, les valeurs dans le champ calculé Dépasse le budget sont passées comme valeur négative, le cas échéant. Dans les cellules réelles, le style entre crochets est appliqué aux valeurs négatives dans le cadre du masque de format Excel 2007/2010 :

Remarque : Excel ne prend pas automatiquement en charge la position des symboles monétaires ou d'autres formatage uniquement sur la première ligne de données. Bien que différents formats peuvent être définis par cellule, si l'utilisateur trie les données, le premier format sera déplacé avec la première ligne en fonction de la valeur de tri. Toutefois, les symboles monétaires fixes sont présentés sur chaque ligne de données de manière semblable à celle des symboles flotants.

Par défaut, les en-têtes et pieds de page sont passés à Excel en tant que chaîne de caractères unique. Les signes de localisation ne sont pas pris en charge pour le positionnement dans chaque ligne. Les champs et dates numériques ne sont pas passées dans les en-têtes et pieds de page en tant que chaînes dans le contenu général des en-têtes et pieds de page.

Pour afficher les champs et dates numériques dans les en-têtes et pieds de page en tant que valeurs numériques ou de date, utilisez HEADALIGN=BODY dans la feuille de style pour définir chacun des éléments dans l'en-tête en tant que cellule individuelle. Chaque cellule contenant des valeurs numériques ou de date sera alors passée en tant que valeur adéquate avec le masque de format associé. Pour plus d'informations sur l'attribut HEADALIGN, consultez Aligner un élément d'en-tête ou de pied de page dans un rapport HTML, EXL07, EXL2K ou PDF..

Remarque : les paramètres CDN (notation décimale continentale) dans le corps du rapport sont activés avec les paramètres régionaux sur l'ordinateur du client. Dans les en-têtes et pieds de page où HEADALIGN n'est pas spécifié, les valeurs numériques sont converties en en-têtes de texte avec les paramètres CDN, comme le définit la procédure car l'application ne peut pas accéder aux valeurs du texte incorporé. Pour les situations HEADALIGN où les éléments dans l'en-tête sont placés dans des cellules individuelles semblables à la table de données, les paramètres CDN ne sont pas appliqués par le Serveur de rapports, mais rétablissent aussi les paramètres régionaux.

Pour les colonnes de données, tous les formats sont convertis à l'aide des masques de format Excel 2007/2010 qui utilisent les règles de ponctuation définies par les paramètres régionaux du bureau.

Dans les langues qui utilisent notation décimale continentale, les définitions de devise désignent qu'une virgule est utilisée comme séparateur décimal, et un point comme séparateur des milliers, de sorte que D12.2CM puisse présenter la valeur 9.999,99 $ plutôt que la valeur utilisée en anglais (Etats-Unis) 9,999.99 $. Dans les titres et les pieds de pages, vous pouvez indiquer que la ponctuation soit convertie en notation décimale continentale en lançant la commande SET CDN=ON. Avec ce paramêtre en vigueur, les données incorporées avec les chaînes de texte de l'en-tête et du pied de page seront mises en forme avec la ponctuation convertie. Spécifiez HEADALIGN=BODY pour délimiter les éléments en tant que cellules et conserver le format numérique dans le champ qui suivra les mêmes règles que les données du rapport dans les colonnes de données.

La plupart des dates traduites et intelligentes peuvent être envoyées vers Excel 2007/2010 comme valeurs de date standards avec des masques de format, permettant à Excel de les utiliser dans des fonctions, formules et séquences de tri.

La requête suivante contre la source de données GGSALES crée la date 1 Janvier 2010 et la convertit en quatre formats de date avec un texte traduit :

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
WRMtrDY/WRMtrDY = NEWDATE;
wDMTY/wDMTY= NEWDATE;
wrDMTRY/wrDMTRY= NEWDATE;
wrYMtrD/wrYMtrD= NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE WRMtrDY wDMTY wrDMTRY wrYMtrD
ON TABLE PCHOLD FORMAT EXL07
END

Les tables suivantes affichent la façon dont les dates devraient s'afficher :

Les formats date qui ne spécifient pas explicitement la valeur du jour sont définis comme la valeur du jour du premier jour du mois. Par conséquent, la valeur placée dans la cellule peut être différente de la valeur du composant de jour dans le champ de données sources et peut produire des résultats inattendus lorsque utilisé pour des tris ou pour des calculs de date dans une formule Excel.

La table suivante affiche comment les formats de date WebFOCUS sont représentés dans EXL07. La table affiche comment la valeur est préservée dans la cellule et comment l'affichage est générée en utilisant le masque de format qui correspond au format de date WebFOCUS.

DATEFLD/MDYY = '01/02/2010'

La requête suivante contre la source de données GGSALES crée la date 2 Janvier, 2010 et la passe vers Excel 2007/2010 avec les formats MDYY, DMYY, MY et MTDY :

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/02/2010';
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE AS 'MDYY' NEWDATE/DMYY AS 'DMYY' NEWDATE/MY AS 'MY' 
        NEWDATE/MTY AS 'MTY' NEWDATE/MTDY AS 'MTDY'
ON TABLE PCHOLD FORMAT EXL07 
END

Les colonnes D et E ont des valeurs de date réelles avec des masques de format, affichées par Excel 2007/2010 en casse mixte. Puisque le format MTY n'a pas de composant de date, la valeur de date stockée est le premier choix de Janvier 2010 (1/1/2010), et non le deuxième choix de Janvier 2010 (1/2/2010) :

Les dates mises en forme comme des composants individuels (par exemple, D, Y, M, W) sont passées vers Excel en tant que valeurs numériques qui peuvent être utilisées comme des paramètres aux fonctions de date Excel. Les valeurs sont passées comme format général qui sont reconnues par Excel en tant que nombres.

La requête suivante contre la source de données GGSALES crée la date 1er Janvier, 2010 et extrait des composants de date numériques, puis les passent vers Excel 2007/2010 :

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
D/D= NEWDATE;
Y/Y = NEWDATE;
W/W=NEWDATE;
w/w=NEWDATE;
M/M = NEWDATE;
YY/YY = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE D Y W w M YY
ON TABLE PCHOLD FORMAT EXL07 
END

La sortie est :

Les formats de date qui contiennent un composant Trimestre sont toujours passés vers Excel comme des chaînes de texte puisque Excel ne prend pas en charge les formats Trimestre.

La requête suivante contre la source de données GGSALES crée la date 1 janvier 2010 et la convertit en formats de date qui contiennent un composant Trimestre :

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
Q/Q= NEWDATE;
QY/QY = NEWDATE;
YBQ/YBQ=NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE Q QY YBQ
ON TABLE PCHOLD FORMAT EXL07 
END

Dans Excel 2007 ou 2010, les cellules qui contiennent des dates avec des composants Trimestre sont sous le format Général. Pour voir cela, ouvrez la fenêtre de dialogue Format de cellules.

La sortie est :

Les formats de date qui ne contiennent pas suffisamment d'information pour présenter le résultat de date valide dans Excel ne sont pas traduits en valeur, y compris les formats qui ne contiennent pas l'information de l'année et/ou du mois. Ces dates seront envoyées à Excel comme texte. Dans l'absence d'informations complètes, l'année prend par défaut l'année en cours, de sorte que la valeur envoyée serait incorrect si ce type de format a été passé comme une valeur de date. Les formats suivants ne sont pas envoyés comme des valeurs :

• MT, MTR, Mt, Mtr
• W, w, WR, wr

Lorsque les formats de date sont passés à Excel 2007/2010 avec les masques de format, tous les noms de mois et de jour sont en casse mixte, qu'elle que soit la casse spécifiée dans le format WebFOCUS. Toutefois, puisque les valeurs de cet exemple sont toujours envoyées comme texte, la casse définie dans le format WebFOCUS est appliquée dans la cellule résultante.

La requête suivante contre la source de données GGSALES crée la date 1 janvier 2010 et la convertit en formats de date qui sont définis comme un nom du mois ou comme un nom du jour :

DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
MT/MT= NEWDATE;
MTR/MTR= NEWDATE;
Mtr/Mtr = NEWDATE;
WR/WR = NEWDATE;
wr/wr = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE MT MTR Mtr WR wr
ON TABLE PCHOLD FORMAT EXL07 
END

Dans Excel 2007 ou 2010, les cellules qui contiennent les jours ont un format Général. Pour voir cela, ouvrez la fenêtre de dialogue Format de cellules.

La sortie est :

[TYPE=REPORT,] XLSXPAGESETS={ON|OFF} [,PAGESIZE={pagesize|LETTER}]
 [,ORIENTATION={PORTRAIT|LANDSCAPE}] [,TOPMARGIN=n] [,BOTTOMMARGIN=m],$

où :

XLSPAGESETS={ON|OFF}

ON entraîne l'application des paramètres de page définis dans la requête WebFOCUS aux paramètres de page du classeur Excel. OFF conserve les paramètres par défaut de la page définis dans le classeur Excel standard. OFF est la valeur par défaut.

n

Définit la marge supérieure pour la feuille de calcul dans les unités identifiées par le paramètre UNITS (en pouces, par défaut). La valeur par défaut est .25.

m

Définit la marge inférieure pour la feuille de calcul dans les unités identifiées par le paramètre UNITS (en pouces, par défaut). La valeur par défaut est .25.

pagesize

Si une des valeurs de PAGESIZE est prise en charge dans une feuille de calcul WebFOCUS, comme décrit dans Sélection de taille de page, orientation et couleur. LETTER est la taille par défaut de la page.

PORTRAIT|LANDSCAPE

PORTRAIT affiche le rapport à travers la dimension la plus étroite d'une page verticale, produisant ainsi une page qui est plus longue que large. PORTRAIT est la valeur par défaut.

LANDSCAPE affiche le rapport à travers la dimension la plus large d'une page horizontale, produisant ainsi une page qui est plus large que longue.

TYPE={PAGEHEADER|PAGEFOOTER},OBJECT=IMAGE,
 IMAGE=imagename, JUSTIFY={LEFT|CENTER|RIGHT} 
 [,DISPLAYON={FIRST|NOT-FIRST}] [,SIZE=(w								h)],$

où :

PAGEHEADER

Place l'image dans l'en-tête de la feuille de calcul.

PAGEFOOTER

Place l'image dans le pied de page de la feuille de calcul.

imagename

Est le nom d'un fichier image valide à placer dans l'en-tête ou pied de page. L'image doit être située dans un chemin de l'application défini. Les types d'image pris en charge sont GIF et JPEG.

JUSTIFY={LEFT|CENTER|RIGHT}

Identifie la zone dans l'en-tête ou le pied de page qui contiendera l'image et la justification ou le placement dans la zone définie.

DISPLAYON

Définit si l'image devrait être placée sur la première page seule ou sur toutes les pages sauf la première. Ignore cet attribut pour placer l'image sur toutes les pages.

Voici les valeurs valables :

FIRST place l'image uniquement sur la première page.

NOT-FIRST place l'image sur toutes les pages sauf la première.

SIZE=(w h)

Indique la taille de l'image. Par défaut, une image est ajoutée à sa taille originale.

w indique la largeur de l'image, exprimée dans l'unité de mesure spécifiée par le paramètre UNITS.

h indique la hauteur de l'image, exprimée dans l'unité de mesure spécifiée par le paramètre UNITS.

La requête suivante contre la source de données GGSALES place l'image ibi_logo.gif dans la zone de l'en-tête de gauche sur la première page et la zone de l'en-tête de droite de toutes les autres pages de la feuille de calcul qui en résulte. Elle place l'image webfocus1.gif dans la zone centrale du pied de page sur chaque page :

TABLE FILE GGSALES
SUM DOLLARS UNITS BUDDOLLARS BUDUNITS 
BY REGION
BY ST
BY CATEGORY
BY PRODUCT
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL07 
ON TABLE SET STYLE *
FONT=ARIAL,SIZE=12,
XLSXPAGESETS=ON,TOPMARGIN=1,BOTTOMMARGIN=1,ORIENTATION=LANDSCAPE,
PAGESIZE=LETTER,$
TYPE=TITLE, COLOR=WHITE, BACKCOLOR=GREY,$
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=LEFT, IMAGE=IBI_LOGO.GIF, DISPLAYON=FIRST,$
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=RIGHT, IMAGE=IBI_LOGO.GIF,  DISPLAYON=NOT-FIRST,$
TYPE=PAGEFOOTER, OBJECT=IMAGE, JUSTIFY=CENTER, IMAGE=webfocus1.gif, $
END

La première page de la sortie contient l'image ibilogo.gif dans la zone de gauche de l'en-tête et l'image webfocus1.gif dans la zone centrale du pied de page.

La deuxième page de la sortie contient l'image ibilogo.gif dans la zone de droite de l'en-tête et l'image webfocus1.gif dans la zone centrale du pied de page.

• Les en-têtes et pieds de page Excel ne sont pas automatiquement dimensionnés en fonction du contenu des zones. Définissez les marges de page dans les paramètres de page pour tenir compte de l'espace requis pour afficher les images dans chaque page du rapport.
• Le dimensionnement d'image en fonction de la hauteur et de la largeur spécifiée n'est pas proportionnel. Le dimensionnement peut causer une distortion de l'image.
• Les champs d'image de type BLOB sont pas pris en charge dans cette version.

Les images en filigrane peuvent être placées dans les en-têtes Excel pour qu'elle s'affichent sur chaque page imprimée de la feuille de calcul générée.

Excel place des images sur la page de démarrage dans l'en-tête de gauche à droite, puis le pied de page de gauche à droite. Les images de grande taille placées dans l'en-tête peuvent chevaucher d'autres images devant elles dans l'ordre de présentation et superposer les images précédentes. Pour les mises en page avec un logo dans la zone de gauche et le filigrane centré sur la page, l'arrière-plan de l'image en filigrane doit être transparent afin qu'il ne superpose pas l'image du logo.

Dans Excel, les images sont placées en premier sur la page. Tout autre contenu de la feuille de calcul est ensuite placé au-dessus des images. Le texte dans des cellules et un style comme par exemple la couleur de l'arrière-plan et des objets de dessin est placé au-dessus des images. Excel prend en charge la transparence des objets de dessin et images, mais de la couleur de l'arrière-plan. BACKCOLOR couvrira les images placées sur la page.

La demande suivante contre la source de données GGSALES utilise l'image internaluseonly.gif comme filigrane à afficher dans l'arrière-plan pour chaque page de la feuille de calcul. Bien que l'image est placée dans la zone centrale de l'en-tête, elle est assez grande pour couvrir toute la page de la feuille de calcul. Son arrière-plan est transparent, de sorte qu'il ne recouvre pas les images de logo placées à gauche de l'en-tête et au centre du pied de page :

TABLE FILE GGSALES
SUM DOLLARS UNITS BUDDOLLARS BUDUNITS 
BY REGION
BY ST
BY CATEGORY
BY PRODUCT
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL07 
ON TABLE SET STYLE *
XLSXPAGESETS=ON,
TOPMARGIN=1,BOTTOMMARGIN=1,LEFTMARGIN=1, RIGHTMARGIN=1, ORIENTATION=LANDSCAPE,PAGESIZE=LETTER,$
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=LEFT, IMAGE=IBI_LOGO.GIF, DISPLAYON=FIRST, $
TYPE=PAGEHEADER, OBJECT=IMAGE, JUSTIFY=CENTER, IMAGE=INTERNALUSEONLY.GIF, $
TYPE=PAGEFOOTER, OBJECT=IMAGE, JUSTIFY=RIGHT, IMAGE=WEBFOCUS1.GIF, $
END

La première page de la feuille de calcul générée affiche l'image en filigrane en-dessous des données. Cette image est affichée sur chaque page de la feuille de calcul.

La redirection est désactivée par défaut pour l'extension de fichier .xlsx parce que cela permet à l'extraction de s'exécuter avec succès si l'ordinateur de l'utilisateur est configuré pour lancer Excel dans le navigateur ou une application en dehors du navigateur.

Pour plus d'informations sur la redirection du client WebFOCUS et les Rapports Excel d'extraction et de redirection, consultez Rapports Excel d'extraction et de redirection.

Pour prendre en charge les types de fichiers de modèles, l'attribut du nom de fichier modèle a été amélioré pour permettre l'ajout de l'extension de fichier. Si aucune extensio n'est specifié dans le nom du modèle, l'extension du fichier sera .XLTX par défaut.

ON TABLE PCHOLD FORMAT EXL07 TEMPLATE template_name SHEETNUMBER n							

où :

template_name

Est le nom du fichier de modèle Excel (classeur), y compris Par exemple, IPOLICY.XLTX, PRINTSHEETS.XLTM, ou DASHBOARD.XLSM. Si l'extension n'est pas fournie, elle sera .XLTX par défaut.

n

Est le nombre de feuilles de calcul Excel remplacés dans le fichier du modèle (classeur).

Le modèle du classeur utilisé par la procédure WebFOCUS doit contenir des feuilles de calcul valides.

• La feuille mise à jour doit exister dans le classeur, puisque WebFOCUS remplace la feuille de calcul à défaut d'en insérer une. Si la feuille désignée n'existe pas, la procédure revoie une erreur.
• Dans tout modèle de fichier, au moins une des feuilles du classeur doit contenir une cellule avec une valeur valide (vide ou tout autre valeur). Pour remplacer une feuille de calcul dans un modèle qui contient uniquement des feuilles de calcul vides, remplacez un des cellules dans une des feuilles ayant un espace, puis enregistrez. Les feuilles de calcul seront alors instanciées de façon à ce qu'elles soient accessibles à WebFOCUS pour la mise à jour.

Ajoutez l'attribut ROWOVERFLOW à votre feuille de style WebFOCUS

TYPE=REPORT, ROWOVERFLOW={ON|OFF|PBON}, [ROWLIMIT={n|MAX}...

où :

ON

Active les feuilles de style de dépassement.

OFF

Désactive les feuilles de style de dépassement. OFF est la valeur par défaut.

PBON

Insère des ruptures de page WebFOCUS qui affichent l'en-tête, le pied de page et les titres de colonne de la page aux endroits approximatifs dans les lignes de la feuille de calcul. Cette option n'entraîne pas le démarrage d'une nouvelle feuille de calcul lorsqu'une rupture de page WebFOCUS survient.

ROWLIMIT=n

Définit une valeur cible pour le nombre de lignes à inclure sur une feuille de calcul à n lignes. La valeur par défaut est la valeur LINES (par défaut, 57).

ROWLIMIT=MAX

Définit une valeur cible pour le nombre de lignes à inclure sur une feuille de calcul à 1,048,000 lignes pour la sortie EXL07.

L'attribut fonctionne avec tous les formats de sortie Excel. Pour tous les autres types de sortie, l'attribut de feuille de style ROWOVERFLOW est ignoré, et le flux de données n'est pas affecté.

• L'en-tête de rapport est placé une fois au début de la première feuille. Le pied de page du rapport est placé une fois en bas de la dernière feuille de débordement.
• A moins que le paramètre PBON ne soit utilisé, les en-têtes et les titres de colonnes de la feuille de calcul sont répétés en haut de la feuille d'origine et sur chaque feuille de dépassement qui suit. Les pieds de page des Feuilles de calcul sont placés en bas de la feuille originale et en bas de chaque feuille de débordement subséquente. Les valeurs de données sont affichées sur la première ligne de données de chaque feuille de débordement comme dans une nouvelle page standard.
• Le nombre total de lignes du rapport est affiché en bas de la dernière page de débordement directement au-dessus de la dernière page et des pieds de page de table.
• Les lignes des en-têtes secondaires, des pieds de page secondaires, et de sous-total s'affichent dans le flux de données comme normal. Aucune considération spéciale est faite pour conserver des groupements dans une feuille donnée.
• Si ROWOVERFLOW=PBON est défini, les en-têtes, pieds de pages, et titres de colonnes s'affichent dans la feuille de calcul lorsqu'une commande WebFOCUS entraîne une rupture de page.
• Pour la sortie EXL07, si l'attribut ROWOVERFLOW est spécifié dans la feuille de style et que ROWLIMIT est supérieure à 1Ko, le message suivant est affiché et aucun fichier de sortie n'est généré :

  (FOC3338) The row limit for EXCEL XLSX worksheets is 1048576.

• Les types de sortie qui contiennent des références de formule (EXL2K PIVOT et EXL2K FORMULA) ne sont pas pris en charge, puisque les références de formule ne sont pas automatiquement mises à jour pour refléter le positionnement sur de nouvelles feuilles de calcul de dépassement.
• La fonctionnalité de la feuille de calcul de dépassement s'applique aux lignes seulement, pas aux colonnes. Une nouvelle feuille de calcul n'est pas automatiquement créée si un rapport génère plus que la limite de 16,384 colonnes de Excel 2007/2010.
• ROWOVERFLOW est pris en charge par les rapports BYTOC pour EXL07.
• Comme les plages nommées dans Excel ne peuvent pas s'afficher sur des feuilles de travail multiples, la phrase IN-RANGES qui définit les plages nommées dans le classeur résultant n'est pas prise en charge avec la fonctionnalité ROWOVERFLOW. Lorsque les fonctionnalités existent ensemble dans la même requête, ROWOVERFLOW est prioritaire et la phrase IN-RANGES est ignorée.

La requête suivante crée une sortie de rapport EXL07 avec des feuilles de calcul de dépassement. L'attribut ROWOVERFLOW=ON dans la feuille de style active la fontionnalité de dépassement. Sans cet attribut, une feuille de calcul serait générée au lieu de trois :

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
-* ****Worksheet Heading****
HEADING
"SALES REPORT WORKSHEET <TABPAGENO"
" "
-* ****Worksheet Footing****
FOOTING
" "
"END OF WORKSHEET <TABPAGENO"
PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION
BY CATEGORY
BY PRODUCT
BY DATE

-* ****Subfoot****
ON REGION SUBFOOT
" "
" End of Region <REGION"
" "
-* ****Subhead****
ON REGION SUBFOOT
" "
" End of Region <REGION"
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT=EXLOVER, ROWOVERFLOW=ON, ROWLIMIT=2000,$
ENDSTYLE
END

L'en-tête de rapport s'affiche seulement sur la première feuille de calcul, l'en-tête de page de titre et les titres de colonne s'affichent sur chaque feuille de calcul, et l'en-tête secondaire et le pied de page secondaire s'affichent chaque fois que le critère de tri associé change de valeur. L'image suivante affiche le haut de la première feuille de calcul, qui affiche l'en-tête de rapport, l'en-tête de page, les titres de colonne, et le premier en-tête secondaire :

Notez que l'attribut TITLETEXT dans la feuille de style a spécifié le nom EXLOVER, donc les trois feuilles de calcul ont été générées avec les noms EXLOVER1, EXLOVER2, et EXLOVER3. S'il n'y avait eu aucun attribut TITLETEXT, les feuilles auraient été nommées SHEET1, SHEET2, et SHEET3.

Le pied de page de la feuille de calcul s'affiche en bas de chaque feuille de calcul et le pied de page de rapport s'affiche en bas de la dernière feuille de calcul. L'image suivante affiche le bas de la dernière feuille de calcul, qui affiche le dernier pied de page secondaire, le pied de page et le pied de page de rapport.

La requête suivante crée une sortie de rapport EXL07 avec des feuilles de calcul de dépassement. L'attribut ROWOVERFLOW=PBON dans la feuille de style active la fonctionnalité Feuille de style, et ROWLIMIT=250 définit le nombre maximal de lignes pour chaque feuille de calcul à environ 250. Sans cet attribut, une feuille de calcul serait générée. La phrase de tri PRODUCT spécifie une rupture de page.

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION 
BY HIGHEST CATEGORY 
BY PRODUCT PAGE-BREAK
BY DATE
WHERE DATE GE '19971001'
-* ****Page Heading****
HEADING
" Product: <PRODUCT in Category: <CATEGORY for Region: <REGION"
-* ****Page Footing****
FOOTING
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET STYLE *
INCLUDE=endeflt,TITLETEXT=EXLOVER, ROWOVERFLOW=PBON, ROWLIMIT=250,
$
ENDSTYLE
END

L'en-tête du rapport s'affiche sur la première feuille de calcul uniquement, l'en-tête, le pied de page et les titres de colonnes de la page s'affichent sur chaque feuille de calcul à chaque rupture de page WebFOCUS (à chaque chagement de produit), et l'en-tête et pied de page secondaires s'affichent à chaque changement de valeur du champ de tri associé. L'image suivante affiche le haut de la première feuille de calcul.

La syntaxe de table des matières d'Excel est identique à celle des rapports TOC de HTML, sauf que seul un champ BY est autorisé dans EXL07, tandis que des champs BY multiples sont autorisés dans HTML.

ON TABLE {HOLD|PCHOLD} FORMAT EXL07 BYTOC

Comme seulement un niveau de table des matières est autorisé dans les rapports EXL07, le numéro facultatif suivant le mot-clé BYTOC ne peut être que 1.

Comme dans HTML, la syntaxe SET COMPOUND, qui précède la commande TABLE, peut aussi être utilisée pour spécifier la création d'une table des matières :

SET COMPOUND=BYTOC

Comme le rapport d'une table des matières génère une feuille de calcul distincte selon la valeur du premier champ BY dans le rapport, le rapport doit contenir au moins un champ BY. Le champ de segmentation peut être un champ NOPRINT.

La fonctionnalité BYTOC n'est pas prise en charge avec le format EXL07 TEMPLATE.

• Les noms de balise des feuilles de calcul sont les valeurs des champs BY qui correspondent aux données sur la feuille de calcul actuelle. Si l'utilisateur spécifie le mot-clé TITLETEXT dans la feuille de calcul, celui-ci sera ignoré.
• La longueur des feuilles de calcul dans Excel est limitée à 31 caractères. Vous ne pouvez pas utiliser les caractères spéciaux suivants : « : », « ? », « * », et « / ».
• Si vous souhaitez utiliser un champ de date comme champ BY, vous pouvez inclure un tiret (-) au lieu d'une barre oblique (/). Le tiret (-) est valide dans un titre de balise Excel. Cependant, si vous utilisez la barre oblique (/), WebFOCUS la remplacera par un tiret (-).

La requête suivante contre la source de données GGSALES crée des onglets distincts en fonction du critère de tri REGION :

TABLE FILE GGSALES
SUM UNITS/D12C DOLLARS/D12CM
BY REGION NOPRINT
BY CATEGORY
BY PRODUCT
HEADING
"<REGION Region Sales"
ON TABLE PCHOLD FORMAT EXL07
ON TABLE SET BYDISPLAY ON
ON TABLE SET COMPOUND BYTOC
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL,SIZE=9,$
TYPE=HEADING, SIZE=12,$
TYPE=TITLE, BACKCOLOR=GREY,COLOR=WHITE, $
ENDSTYLE
END

La sortie est :

Pour identifier les valeurs nulles dans les rapports EXL2K, utilisez

ON TABLE SET NODATA character_string							

ON TABLE SET EMPTYCELLS [ON|OFF]

où :

character_string

est la chaîne de caractères affichée dans les cellules du rapport pour chaque champ où des valeurs nulles sont récupérées de la source de données. Le nombre maximal de caractères autorisés est 11. Si le nombre de caractères dans la chaîne dépasse la longueur du champ de sortie, les caractères additionnels ne s'affichent pas. Si des caractères spéciaux sont utilisés, la chaîne doit être saisie entre guillemets simples. La commande SET EMPTYCELLS OFF doit être spécifiée pour activer la commande SET NODATA.

ON

indique que les espaces blancs s'affichent dans les cellules du rapport pour chaque champ où des valeurs nulles sont récupérées de la source de données. ON est la valeur par défaut.

OFF

indique que des zéros, ou la chaîne de caractères spécifiée avec la commande SET NODATA, s'affichent dans les cellules du rapport pour chaque champ où des valeurs nulles sont récupérées de la source de données. OFF doit être spécifié lorsque vous utilisez SET NODATA.

La syntaxe suivante utilise le comportement par défaut de ON TABLE SET EMPTYCELLS ON, qui est définie dans l'arrire-plan :

TABLE FILE CAR
   SUM SALES BY COUNTRY ACROSS SEATS
   ON TABLE PCHOLD FORMAT EXL2K
END

La sortie suivante affiche des espaces blancs dans les cellules du rapport pour chaque champ où des valeurs nulles sont récupérées de la source de données :

La syntaxe suivante utilise la commande SET NODATA :

TABLE FILE CAR
   SUM SALES BY COUNTRY ACROSS SEATS
   ON TABLE SET NODATA 'n/a'
   ON TABLE SET EMPTYCELLS OFF
   ON TABLE PCHOLD FORMAT EXL2K
END

Remarque : si vous n'ajoutez pas la commande SET EMPTYCELLS OFF à la syntaxe, la commande SET NODATA est ignorée.

La sortie présentée ci-après affiche les caractères 'n/a' dans les cellules du rapport pour chaque champ où des valeurs nulles sont récupérées de la source de données.

Comme la syntaxe suivante désactive l'opération SET EMPTYCELLS (OFF) et n'utilise pas la commande SET NODATA, il est impossible de faire la distinction entre les valeurs nulles les quantités nulles :

TABLE FILE CAR
   SUM SALES BY COUNTRY ACROSS SEATS
   ON TABLE SET EMPTYCELLS OFF
   ON TABLE PCHOLD FORMAT EXL2K
END

La sortie présentée ci-après affiche des zéros dans les cellules du rapport pour chaque champ où des valeurs nulles sont récupérées de la source de données ou la quantité est zéro :

Les formats suivants ne sont pas pris en charge dans EXL2K. Ils seront transcrits en format général Excel et pourraient engendrer des résultats imprévisibles :

• Tout format avec un symbole dollar fixe (N).
• Les options de formats multiples. Seulement les options de format unique sont supportées avec FORMAT EXL2K. Par exemple, les formats I9C et I9B sont supportés mais I9BC ne l'est pas.

Les fonctions suivantes s'appliquent aux en-têtes et aux pieds de page comprenant des champs numériques incorporés

• Si vous incorporez un champ numérique dans un en-tête, en-tête secondaire, pied de page, ou pied de page secondaire d'un rapport dans un rapport EXL2K, le champ numérique s'affiche sous le format général Excel (texte). Pour afficher un champ numérique dans un numéro de format Excel, vous devez définir le paramètre HEADALIGN=BODY dans la feuille de style.

  Remarque : les paramètres CDN (notation décimale continentale) dans le corps du rapport sont activés avec les paramètres régionaux sur l'ordinateur du client. Dans les en-têtes et pieds de page où HEADALIGN n'est pas spécifié, les valeurs numériques sont converties en en-têtes de texte avec les paramètres CDN, comme le définit la procédure car l'application ne peut pas accéder aux valeurs du texte incorporé. Pour les situations HEADALIGN où les éléments dans l'en-tête sont placés dans des cellules individuelles semblables à la table de données, les paramètres CDN ne sont pas appliqués par le Serveur de rapports, mais rétablissent aussi les paramètres régionaux.

Les formats suivants ne sont pas pris en charge dans EXL2K. Ils seront transcrits en format général Excel et pourraient engendrer des résultats imprévisibles :

• YY, Y, M, D, JUL et I2MT.
• Tout format de date avec la lettre Q (trimèstre).
• Tout format de décimale condensée (P).
• Tout format de date alphanumérique (A).

Pour utiliser un séparateur "-" entre le mois, le jour et l'année dans Excel 2000/2003, vous devez changer le séparateur de date par défaut pour Windows. Cette définition peut se trouver sous « Options régionales » dans le panneau de commande.

Certaines dates traduites peuvent être envoyées à Excel 2000/2003 comme des valeurs de date standards avec des masques de format, permettant à Excel de les utiliser dans des fonctions, formules et séquences de tri. La commande SET EXL2KTXTDATE vous permet de spécifier que les dates traduites devraient être envoyées comme des valeurs de date avec des masques de format au lieu des valeurs de texte.

SET EXL2KTXTDATE = {TEXT|VALUE}

SET EXL2KTXTDATE=TEXT
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
WRMtrDY/WRMtrDY = NEWDATE;
wDMTY/wDMTY= NEWDATE;
wrDMTRY/wrDMTRY= NEWDATE;
wrYMtrD/wrYMtrD= NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE WRMtrDY wDMTY wrDMTRY wrYMtrD
ON TABLE PCHOLD FORMAT EXL2K
END

Les formats date qui ne spécifient pas explicitement la valeur du jour sont définis comme la valeur du jour du premier jour du mois. Par conséquent, la valeur placée dans la cellule peut être différente de la valeur du composant de jour dans le champ de données sources et peut produire des résultats inattendus lorsque utilisé pour des tris ou pour des calculs de date dans une formule Excel.

La table suivante affiche la façon dont les formats de date WebFOCUS sont représentés dans la sortie de rapport EXL2K. La table affiche la façon dont la valeur est préservée dans la cellule et comment l'affichage est généré en utilisant le masque de format qui correspond au format de date WebFOCUS.

DATEFLD/MDYY = '01/02/2010'

La requête suivante contre la source de données GGSALES crée la date de 2 Janvier, 2010 et la passe vers Excel 2000/2003 avec les formats MDYY, DMYY, MY et MTDY :

SET EXL2KTXTDATE=TEXT
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/02/2010';
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE AS 'MDYY' NEWDATE/DMYY AS 'DMYY' NEWDATE/MY
        AS 'MY' NEWDATE/MTY AS 'MTY' NEWDATE/MTDY AS 'MTDY'
ON TABLE PCHOLD FORMAT EXL2K 
END

Avec EXL2KTXTDATE=TEXT, les colonnes D et E ont des valeurs de texte, et non des valeurs de date. Les valeurs sont affichées en majuscules tel que spécifié par les formats WebFOCUS (MTY and MTDY) :

Avec EXL2KTXTDATE=VALUE, les colonnes D et E ont des valeurs de date réelles avec des masques de format, affichées par Excel 2000 en casse mixte. Puisque le format MTY n'a pas de composant de date, la valeur de date stockée est le premier choix de Janvier 2010 (1/1/2010), et non le deuxième choix de Janvier 2010 (1/2/2010) :

Les dates mises en forme comme composants individuels (par exemple, D, Y, M, W) sont passées vers Excel en tant que valeurs numériques qui peuvent être utilisées comme paramètres aux fonctions de date Excel. Les valeurs sont passées comme format de texte général reconnues par Excel 2000/2003 comme nombres. Ces valeurs sont passées vers Excel dans le même format en dépit du paramètre pour EXL2KTXTDATE.

La requête suivante contre la source de données GGSALES crée la date de 1er Janvier, 2010 et extrait les composants de date numériques, les passent vers Excel 2000/2003 :

SET EXL2KTXTDATE=VALUE
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
D/D= NEWDATE;
Y/Y = NEWDATE;
W/W=NEWDATE;
w/w=NEWDATE;
M/M = NEWDATE;
YY/YY = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE D Y W w M YY
ON TABLE PCHOLD FORMAT EXL2K 
END

Avec SET EXL2KTXTDATE=VALUE, la sortie est :

Les formats de date qui contiennent un composant Trimestre sont toujours passés vers Excel comme des chaînes de texte puisque Excel ne prend pas en charge les formats Trimestre.

La requête suivante contre la source de données GGSALES crée la date 1 janvier 2010 et la convertit en formats de date qui contiennent un composant Trimestre :

SET EXL2KTXTDATE=VALUE
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
Q/Q= NEWDATE;
QY/QY = NEWDATE;
YBQ/YBQ=NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE Q QY YBQ
ON TABLE PCHOLD FORMAT EXL2K 
END

Même avec SET EXL2KTXTDATE=VALUE, dans la sortie de rapport EXL2K, les cellules contenant des dates avec des composants Trimestre ont le format Général. Pour voir cela, ouvrez la fenêtre de dialogue Format de cellules.

La sortie est :

Les formats de date qui ne contiennent pas suffisamment d'information pour présenter le résultat de date valide dans Excel ne sont pas traduits en une valeur, y compris les formats qui ne contiennent pas l'information de l'année et/ou du mois. Ces dates continuent d'être envoyées vers Excel 2000/2003 comme un texte en dépit du paramètre SET EXL2KTXTDATE. Dans l'absence d'informations complètes, l'année prend par défaut l'année en cours, de sorte que la valeur envoyée serait incorrect si ce type de format a été passé comme une valeur de date. Les formats suivants ne sont pas envoyés comme des valeurs :

• MT, MTR, Mt, Mtr
• W, w, WR, wr

Notez que puisque ces valeurs sont toujours envoyées sous forme de texte, la casse définie dans le format WebFOCUS est appliquée dans la cellule résultante.

La requête suivante contre la source de données GGSALES crée la date 1 janvier 2010 et la convertit en formats de date qui sont définis comme un nom du mois ou comme un nom du jour :

SET EXL2KTXTDATE=VALUE
DEFINE FILE GGSALES
NEWDATE/MDYY = '01/01/2010';
MT/MT= NEWDATE;
MTR/MTR= NEWDATE;
Mtr/Mtr = NEWDATE;
WR/WR = NEWDATE;
wr/wr = NEWDATE;
END
TABLE FILE GGSALES
SUM DATE NOPRINT
NEWDATE MT MTR Mtr WR wr
ON TABLE PCHOLD FORMAT EXL2K 
END

Dans Excel 2000/2003, les cellules qui contiennent les jours ont le format Général. Pour voir cela, ouvrez la fenêtre de dialogue Format de cellules.

La sortie est :

TYPE=REPORT, [COLUMN=column,] WRAP=value, $

où :

COLUMN=

Spécifie une colonne particulière à laquelle l'habillage s'applique. Où COLUMN n'est pas compris dans la déclaration, l'habillage s'applique au rapport entier.

value

indique une des choses suivantes :

ON

Active l'habillage. ON est la valeur par défaut. Cette définition implique que la largueur de colonnes est déterminée par le client (Excel). L'habillage s'effectue lorsque les données dépassent la largueur de la colonne ; la hauteur de la ligne élargit pour satisfaire à la hauteur des données habillées.

OFF

Désactive l'habillage. L'habillage ne s'effectue dans aucune cellule de la colonne.

n

représente une valeur numérique particulière à laquelle la largeur de colonne peut être définie. Cette valeur représente la dimension indiquée par le paramètre UNITS (en pouces, par défaut).

Cette définition implique la valeur ON. Toutefois, la largeur de colonnes est mise à la largeur spécifiée à moins que les données soient plus larges que la largeur de colonnes, auquel cas l'habillage s'effectue.

TYPE=REPORT, [COLUMN=column,] SQUEEZE={ON|OFF|n}, $

où :

COLUMN=

Identifie une colonne particulière. Si COLUMN n'est pas compris dans la déclaration, l'habillage SQUEEZE s'applique au rapport complet.

n

représente une valeur numérique particulière à laquelle la largeur de colonne peut être définie. Cette valeur représente la dimension indiquée par le paramètre UNITS (en pouces, par défaut).

La définition SQUEEZE est la plus utilisée dans un rapport EXL2K.

Remarque :

• Les paramètres ON/OFF pour SQUEEZE ne sont pas significatifs pour EXL2K, et les deux produisent le comportement par défaut.
• SQUEEZE = n désactive l'habillage des données. Si une valeur de données est plus large que la largueur de colonnes spécifiée, celle-là est cachée. Vous pouvez régler la largeur dans Excel après que la feuille de calcul soit générée.
• SQUEEZE n'est pas supporté pour les colonnes créées avec l'expression OVER ou avec TABLEF.

L'exemple suivant illustre la façon d'activer et de désactiver l'habillage dans une colonne et la façon de définir la largueur de colonnes pour une colonne particulière. Les unités (UNITS) de cet exemple sont en pouces par défaut.

  DEFINE FILE CAR
  MYDATE/MDY='10/22/60';
  RCD/D14.3=RETAIL_COST;
  VERYLONG/A80='Subtract dealer cost from retail cost to calculate
  profit.';
  END

   TABLE FILE CAR
   PRINT MYDATE RCD 
   VERYLONG AS 'Default' VERYLONG AS 'WRAP=OFF'
   VERYLONG AS 'WRAP=4.1' VERYLONG AS 'WRAP=2'
   VERYLONG AS 'SQUEEZE=2' SALES   BY COUNTRY
   ON TABLE PCHOLD FORMAT EXL2K
   ON TABLE SET STYLE *
   TYPE=DATA, COLUMN=MYDATE, JUSTIFY=CENTER, $ 
1. TYPE=REPORT, COLUMN=VERYLONG(2), WRAP=OFF, $
2. TYPE=REPORT, COLUMN=VERYLONG(3), WRAP=4.1, $
3. TYPE=REPORT, COLUMN=VERYLONG(4), WRAP=2, $
4. TYPE=REPORT, COLUMN=VERYLONG(5), SQUEEZE=2, $ 
   END

où :

1. identifie la colonne « WRAP=OFF » et désactive l'habillage pour cette colonne.
2. identifie la colonne « WRAP=4.1 » et définit sa largueur de colonne comme 4,1 pouces, avec l'habillage activée.
3. identifie la colonne « WRAP=2 » et définit la largueur de colonne comme 2 pouces, avec l'habillage activée.
4. identifie la colonne « SQUEEZE=2 » et définit la larguer de colonne commme 2 pouces, avec l'habillage désactivée.

Remarque : la colonne Default illustre la largeur de colonne par défaut et le renvoi à la ligne.

Comme la sortie est plus large que la page, elle s'affiche en deux parties. La sortie suivante affiche les colonnes « Default »,« WRAP=OFF » et « WRAP=4.1 » :

La sortie suivante affiche les colonnes « WRAP=2 » et « SQUEEZE=2 » :

Pour activer le verrouillage, servez-vous des attributs suivants :

TYPE=REPORT, PROTECTED={ON|OFF}, [LOCKED={ON|OFF}],$

où :

TYPE=REPORT, PROTECTED=ON

Nécessaire pour activer le verrouillage de la feuille de calcul. La paramètre par défaut est PROTECTED=OFF. Si vous ignorez l'attribut LOCKED=OFF, la feuille de calcul entière est verrouillée.

LOCKED=ON

Verrouille la feuille de calcul entière. ON est la valeur par défaut.

LOCKED=OFF

Déverrouille la feuille de calcul en entier, mais vous permet de verrouiller ou de déverrouiller des cellules ou groupes de cellules spécifiques.

Après l'insertion de la déclaration suivante dans votre feuille de style, vous pouvez spécifier l'attribut LOCKED pour des cellules ou des groupes de cellules spécifiques :

TYPE=REPORT, PROTECTED=ON, LOCKED=OFF,$

Pour verrouiller des sections spécifiques de la feuille de style, ajoutez l'attribut LOCKED=ON à la déclaration de la feuille de style pour les cellules que vous souhaitez verrouiller.

TYPE=type, [ COLUMN=columnspec ] ,LOCKED={ON|OFF},$

où :

type

Est le type d'élément qui décrit les cellules à verrouiller.

columnspec

Est une spécification de colonne valide.

La requête suivante verrouille le classeur entier parceque les déclarations de la feuille de style comprennent les déclarations suivantes :

TYPE=REPORT, PROTECTED=ON, $

La requête est :

TABLE FILE CAR
HEADING
"Profit By Car "
" "
SUM RETAIL_COST AND DEALER_COST AND
COMPUTE PROFIT/D12.2 = RETAIL_COST - DEALER_COST;
BY CAR
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD AS EXLFORM1 FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=REPORT, PROTECTED=ON,            $
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
ENDSTYLE                                          
END

Vous ne pouvez pas modifier de valeurs sur la feuille de style. Si vous tentez de le faire, un message apparaît indiquant que la feuille est protégée :

Le requête suivante verrouille la deuxième colonne (RETAIL_COST) parceque les déclarations de la feuille de style comprennent les déclarations suivantes :

TYPE=REPORT, PROTECTED=ON, LOCKED=OFF, $
TYPE=DATA, COLUMN=2, LOCKED=ON,$

La requête est :

TABLE FILE CAR
HEADING
"Profit By Car "
" "
SUM RETAIL_COST AND DEALER_COST AND
COMPUTE PROFIT/D12.2 = RETAIL_COST - DEALER_COST;
BY CAR
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD AS EXLFORM2 FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=REPORT, PROTECTED=ON, LOCKED=OFF,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
TYPE=DATA, COLUMN=2, LOCKED=ON,$
ENDSTYLE
END

Vous ne pouvez pas modifier de valeurs dans la colonne 2, bien que vous puissiez modifier les valeurs dans d'autres colonnes. Si vous tentez de modifier une valeur de la deuxième colonne, un message apparaît indiquant que les cellules sont protégées :

Ajoutez la syntaxte suivante à votre requête pour mettre en avant les formules Excel dans votre feuille de calcul :

ON TABLE {PCHOLD|HOLD}  FORMAT EXL2K FORMULA

où :

PCHOLD

Affiche la sortie dans un classeur EXL2K.

HOLD

Sauvegarde la sortie pour la réutilisation dans une feuille de calcul Excel 2000/2003. Pour plus de détails, consultez Enregistrer et réutiliser la sortie de rapport.

L'exemple suivant illustre la façon dont un total de colonne dans une requête de rapport est traduit en formule Excel au moyen du format EXL2K FORMULA. Notez que le formatage du total de colonne (TYPE=GRANDTOTAL) est retenu dans la feuille de calcul Excel 2000/2003.

Lorsque vous sélectionnez le total dans le rapport, l'équation =SUM(B4:B10) s'affiche dans la barre de formule, représentant le total de colonne en tant que somme des cellules.

TABLE FILE SHORT
HEADING
"Projected Return By Region"
" "
SUM PROJECTED_RETURN AS 'RETURN'
BY REGION AS 'REGION'
ON TABLE COLUMN-TOTAL
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD+UNDERLINE, SIZE=10,$
TYPE=GRANDTOTAL, STYLE=BOLD, $
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

La sortie est :

Vous pouvez traduire tout total (sous-total, total de rangée ou total de colonne) en formule Excel. Pour plus d'informations, consultez Prise en charge de traduction pour le format EXLK FORMULA.

Cette requête calcule les totaux des renvois et des bilans à travers les continents. Les totaux de rangées sont représentés comme sommes des rangées de cellules.

TABLE FILE SHORT
HEADING
"Projected Return Across Continent"
" "
SUM PROJECTED_RETURN AS 'RETURN' AND BALANCE AS 'BALANCE'
ACROSS CONTINENT AS 'CONTINENT'
BY REGION AS 'REGION'
ON CONTINENT ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
TYPE=SUBTOTAL,STYLE=BOLD, $
TYPE=GRANDTOTAL,STYLE=BOLD,SIZE=11,$
TYPE=ACROSSTITLE,STYLE=BOLD,SIZE=11,JUSTIFY=LEFT,$
TYPE=ACROSSVALUE,STYLE=BOLD,SIZE=10,JUSTIFY=CENTER,$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K FORMULA 
END

La sortie suivante met l'accent sur la formule qui calcule le total de rangée dans une cellule I12=C12+E12+G12 :

Cette requête additionne les colonnes des prix de vente en détail et des prix des revendeurs, et elle calcul la valeur du champ PROFIT en soustrayant le prix de revendeur du prix de vente en détail.

La formule de la valeur calculée est générée en traduisant la forme interne de l'expression WebFOCUS (COMPUTE PROFIT/D12.2 = RC - DC;) en une formule Excel. Dans cet exemple, les formules s'affichent dans les cellules B14, C14 et D14.

Tous les champs référencés dans le calcul devraient être affichés dans le rapport pour qu'une formule valide soit créée avec les références des cellules, autrement, elle pourait être créée avec des valeurs n'étant pas dans le rapport. Si les champs utilisés dans le calcul ne sont pas présents dans le rapport et qu'un nouveau calcul est prévu, la formule créée pour le recalcul ne sera pas correcte.

TABLE FILE CAR
ON TABLE SET PAGE-NUM OFF
SUM RC AND DC AND
COMPUTE PROFIT/D12.2 = RC - DC;
BY CAR
HEADING
"Profit By Car"
" "
ON TABLE COLUMN-TOTAL
ON TABLE PCHOLD FORMAT EXL2K FORMULA
ON TABLE SET STYLE *
TYPE=REPORT, COLOR=BLUE, BACKCOLOR=SILVER, SIZE=9,$
TYPE=HEADING, STYLE=BOLD, SIZE=14, $
TYPE=TITLE, STYLE=BOLD, SIZE=11,$
TYPE=GRANDTOTAL, STYLE=BOLD, SIZE=11,$
ENDSTYLE
END

La sortie suivante met en évidence la formule qui calcule le total de la colonne de PROFIT: D14=SUM(D4:D13).

L'exemple suivant illustre la façon dont les fonctions sont traduites en rapports Excel 2000/2003. La fonction IMOD divise ACCTNUMBER par 1000 et renvoie le reste à LAST3_ACCT. La formule Excel correspond à cela, =TRUNC((MOD($C3,(1000)))). TRUNC est utilisé lorsque la réponse d'une équation est placée dans un champ Entier, pour assurer qu'il n'y ait pas de décimaux :

TABLE FILE EMPLOYEE
PRINT ACCTNUMBER AS 'Account Number' AND COMPUTE
LAST3_ACCT/I3L = IMOD(ACCTNUMBER, 1000, LAST3_ACCT);
BY LAST_NAME AS 'Last Name' 
BY FIRST_NAME AS 'First Name'
WHERE (ACCTNUMBER NE 000000000) AND (DEPARTMENT EQ 'MIS');
ON TABLE PCHOLD FORMAT EXL2K FORMULA
ON TABLE SET STYLE *
TYPE=TITLE, SIZE=12, STYLE=BOLD, $
END

La sortie est :

Si votre rapport comprend une valeur calculée (générée par la commande COMPUTE ou RECOMPUTE), tous les champs référencés par la valeur calculée doivent être affichés dans le rapport afin que les références aux cellules soient incluses dans la formule. Si une colonne référencée n'est pas affichée dans le classeur, la valeur de la donnée sera placée dans la formule plutôt que dans la référence de cellule. Dans le cas d'un recalcul, il se peut que la valeur utilisée soit une valeur incorrecte pour le dernier enregistrement du saut de tri.

La requête suivante calcul la différence (DIFF) en soustrayant les dollars budgétés des ventes en dollars. Le champ dollars budgétés utilisé dans l'expression n'est pas inclus dans la commande SUM. La valeur de DIFF est recalculée au niveau de la région :

TABLE FILE GGSALES
HEADING
"Profit By Region"
" "
SUM DOLLARS 
COMPUTE DIFF/I9=DOLLARS - BUDDOLLARS;
BY REGION
BY CATEGORY
ON REGION RECOMPUTE
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

La sortie montre que la formule soustrait une valeur de donnée qui n'est pas affichée sur la feuille de calcul. Il s'agit en effet de la valeur BUDDOLLARS de la ligne précédente :

Si vous modifiez la commande SUM avec ce qui suit, la formule peut être recalculée correctement :

SUM DOLLARS BUDDOLLARS

La formule générée avec la nouvelle commande SUM contient les références de cellule pour les champs utilisés dans le calcul :

Cette rubrique décrit la prise en charge de la traduction pour FORMAT EXL2K FORMULA. L'utilisation de fonctionnalités WebFOCUS non prises en charge peut entraîner des résultats non souhaités.

• Tout opérateur standard est pris en charge. Parmi les opérateurs pris en charge sont les opérateurs relationnels, les opérateurs de chaîne, IF/THEN/ELSE et les opérateurs logiques. Cependant, la notation de colonne n'est pas prise en charge.

  Les opérateurs IS-PRESENT, IS-MISSING, IS-FROM, FROM, NOT-FROM, IS-MORE-THAN, IS---LESS-THAN, CONTAINS, et OMITS ne sont pas pris en charge.

  Les opérateurs logiques AND et OU ne sont pas pris en charge avec des expressions logiques conditionnelles (IF-THEN-ELSE).

• Les fonctions suivantes sont prises en charge :

  ABS, ARGLEN, ATODBL, BYTVAL, CHARGET, CTRAN, DMOD, DOWK, DOWK, DOWKL, EXP, FMOD, HEXBYT, HHMMSS, IMOD, LCWORD, LOCASE, LOG, MAX, MIN, OVRLAY, POSIT, RDUNIF, SQRT, SUBSTR, TODAY, UPCASE. La fonction EDIT est prise en charge pour la conversion des formats (une variante d'argument). Elle ne l'est pas pour l'édition des chaînes.

  Les fonctions CTRFLD, LJUST, et RJUST ne sont pas recommandées pour la justification des données dans les colonnes Excel. Avec l'utilisation de polices Excel proportionnelles, l'attribut JUSTIFY de la feuille de stype est plus appropriée.

  Vous devez faire attention lorsque vous utilisez des fonctions qui utilisent des valeurs décimales comme argument (BYTVAL, CTRAN, HEXBYT). En fonction de la définition de l'environnement d'exploitation sur EBCDIC ou ASCII, les résultats peuvent différer.

• EXL2K FORMULA n'est pas pris en charge par les commandes et les phrases WebFOCUS suivantes :
  • DEFINE.
  • OVER.
  • FOR.
  • NOPRINT.
  • Des commandes d'affichage multiples (PRINT, LIST, SUM et COUNT).
  • Attribut de la feuille de style SEQUENCE.
  • RECAP.
  • SET HIDENULLACRS.
  • SET SUBTOTALS = ABOVE.
  • LAST.
• Si votre rapport comprend une valeur calculée (générée par la commande COMPUTE ou RECOMPUTE), tous les champs référencés par la valeur calculée doivent être affichés dans le rapport afin que la référence de cellule soit incluse dans la formule. Si la colonne référencée n'est pas affichée dans le classeur, la valeur de la donnée sera placée dans la formule plutôt que dans la référence de cellule.
• Le paramètre BYDISPLAY ON est recommandé, sinon la valeur de critère de tri n'est pas disponible sur toutes les lignes pour les nouveaux calculs.
• Si une expression nécessite plus de 1024 caractères, WebFOCUS placera la valeur dans la cellule, et pas la formule.
• Le style conditionnel dépend des valeurs du rapport original. Si les valeurs de la feuille de calcul sont modifiées et que les formules sont recalculées, le style ne reflète pas les informations mises à jour.

La sortie EXL2K FORMULA prend en charge les opérateurs préfixes utilisés sur des lignes récapitulatives générées par des commandes WebFOCUS, comme par exemple SUBTOTAL et RECOMPUTE. Là où existe une formule correspondante dans Excel, ces opérateurs préfixes sont traduits en formule récapitulative Excel équivalente. Les résultats des opérateurs préfixes utilisé contre les données récupérées continuent d'être passées vers Excel comme valeurs, et pas comme formules.

La table suivante identifie les opérateurs préfixes pris en charge par EXL2K FORMULA lorsqu'ils sont utilisés sur des lignes récapitulatives, et la formule Excel équivalente placée dans la feuille de calcul générée.

Dans la requête suivante sur la source de données GGSALES, la commande RECOMPUTE pour le champ de tri REGION calcule le maximum du champ DOLLARS agrégé et le minimum du champ BUDDOLLARS agrégé :

TABLE FILE GGSALES
SUM UNITS DOLLARS BUDDOLLARS
AND COMPUTE DIFF/I10= DOLLARS-BUDDOLLARS;
BY REGION
BY CATEGORY
WHERE CATEGORY EQ 'Food' OR 'Coffee'
WHERE REGION EQ 'West' OR 'Midwest'
ON REGION RECOMPUTE MAX. DOLLARS MIN. BUDDOLLARS DIFF
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

Sur la sortie, la cellule qui représente les DOLLARS recalculées pour la région Midwest a été générée comme la formule suivante:

=MIN(E2:E3)

Dans la requête suivante contre la source de données GGSALES, les opérateurs préfixes CNT., AVE., et PCT. sont utilisés dans la commande d'affichage SUM :

TABLE FILE GGSALES
SUM UNITS
CNT.UNITS
AVE.UNITS
PCT.UNITS
BY REGION 
BY ST 
ON TABLE PCHOLD FORMAT EXL2K FORMULA
END

La sortie montre que les opérateurs préfixes n'ont pas été transmis à Excel sous forme de formules, elles ont été transmises comme valeurs de données.

Il se peut que la barre d'outils du tableau croisé ne s'affiche pas lors de la création d'un tableau croisé. Pour afficher la barre d'outils du tableau croisé dynamique, utilisez la procédure suivante :

1. Cliquez sur Affichage dans la barre d'outils Excel.
2. Soulignez Barre d'outils.
3. Cliquez sur Tableau croisé dynamique.

   Excel 2000/2003 affiche la barre d'outils du tableau croisé, qui liste les champs disponibles à faire glisser dans le corps du rapport de tableau croisé. Une cellule dans le tableau croisé doit être sélectionnée pour que la barre d'outils du tableau croisé affiche tous les champs.

Le tableau croisé est généré par la commande PRINT conjointement avec les phrases BY, ACROSS, PAGEFIELDS et CACHEFIELDS. Il comprend toutes les options utilisées pour concevoir et formater le rapport, ainsi que les champs spécifiés dans la requête PIVOT. Les champs peuvent être glissés au rapport à partir de la barre d'outils. Le graphique suivant montre la sortie du tableau croisé dynamique avec les éléments principaux identifiés.

Le tableau récapitulatif suivant montre des éléments de tableau croisé dynamique et la syntaxe FOCUS associée.

Le tableau suivant récapitule les éléments de la syntaxe TABLE supportés dans EXL2K PIVOT. L'influence de chaque commande sur votre requête de tableau croisé est listée, ainsi que son utilisation prévue.

Ce qui suit sont des variations de syntaxe pouvant être utilisées pour activer FORMAT EXL2K PIVOT.

• Pour voir la sortie immédiatement dans Excel 2000/2003 :

  ON TABLE PCHOLD FORMAT EXL2K PIVOT

• Pour stocker la sortie sur disque à visualiser plus tard

  ON TABLE HOLD FORMAT EXL2K PIVOT AS mypivot									

  où :

  mypivot

  Est un nom que vous attribuez au fichier HOLD.

  Deux fichiers sont générés avec cette syntaxe :

  • MYPIVOT.XHT est le fichier principal qui s'affiche dans le navigateur ou la fenêtre Excel.
  • MYPIVO$.XML est le fichier cache croisé.

Prenez en considération les choses suivantes en écrivant des requêtes de sortie à un tableau croisé :

• Les requêtes doivent utiliser la commande PRINT. Cela est nécessaire pour extraire toutes les données (chaque enregistrement individuel) au fichier cache croisé. Le champ suivant la commande PRINT est désigné le champ de données de tableau croisé dynamique et doit être numérique.

  Notez que les commandes SUM et COUNT ne sont pas prises en charge pour EXL2K PIVOT. Néanmoins, vous pouvez employer ce comportement de tableau croisé natif dans Excel suivant la sortie des données à un tableau croisé Excel.

• Un champ utilisé dans un tableau croisé ne peut pas être listé plus qu'une fois dans la requête de rapport. Chaque champ ne peut fonctionner que sous un seul rôle dans une requête FORMAT EXL2K PIVOT. Par exemple, un champ de page ne peut pas s'afficher simultanément comme colonne et comme champ de rangée.
• Le style est basé sur l'état du début de votre rapport et ne peut être retenu que sous des conditions limitées lorsque vous faites pivoter la sortie.
• Les champs NODATA s'affichent sous forme de cellules blanches dans le tableau croisé.
• Vous ne devez pas utiliser de champs d'estampille temporelle ou de champs de texte dans les tableaux croisés Excel. En outre, assurez-vous des données ne manquent dans aucun champ.
• Un tableau croisé peut comprendre des totaux de colonne et de rangée, des totaux généraux et des sous-totaux. Si aucun total n'est spécifié dans une requête, aucun total ne s'affiche dans Excel 2000/2003.
• Les bordures ne sont pas prises en charge avec les Tableaux croisés dynamiques Excel.

L'exemple suivant illustre la façon de générer un tableau croisé :

TABLE FILE CAR
HEADING
"CAR File PivotTable"
"Sum of Sales by Car Across Model"
PRINT SALES
BY CAR
ACROSS MODEL
ON TABLE COLUMN-TOTAL
ON TABLE SET STYLE *
TYPE=HEADING, LINE=1, FONT='ARIAL', COLOR=PURPLE, SIZE=16, STYLE=BOLD,$
TYPE=HEADING, LINE=2, FONT='ARIAL', COLOR=PURPLE, SIZE=12, STYLE=BOLD,$
TYPE=DATA, FONT='ARIAL', COLOR=PURPLE,$
TYPE=GRANDTOTAL, FONT='ARIAL', COLOR=PURPLE, SIZE=16, STYLE=BOLD,$
ENDSTYLE 
ON TABLE PCHOLD AS CARPIVOT FORMAT EXL2K PIVOT
PAGEFIELDS COUNTRY
CACHEFIELDS RETAIL_COST TYPE  
END

La commande ON TABLE PCHOLD FORMAT EXL2000K PIVOT affiche le tableau croisé dans Excel 2000/2003. Tous les champs (y compris PRINT, BY et ACROSS, et PAGEFIELDS et CACHEFIELDS) s'affichent dans la barre d'outils.

Les champs désignés comme CACHEFIELDS doivent être placés immédiatement après le mot clé PIVOT dans la syntaxe ON TABLE PCHOLD FORMAT EXL2K PIVOT ou après une phrase PAGEFIELDS. Un tel champ ne peut être spécifié d'autre part dans la requête. Une liste de CACHEFIELDS est terminée par les mêmes mots clé qui terminent une requête de rapport normale, tels que END ou toute autre phrase ON.

L'exemple suivant illustre la façon de spécifier CACHEFIELDS afin de charger la barre d'outils du tableau croisé.

TABLE FILE CAR
HEADING
"My PivotTable"
PRINT SALES 
BY COUNTRY BY CAR
ON COUNTRY SUB-TOTAL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=COUNTRY, COLOR=RED, $
type=heading,color=blue,style=bold, size=14, $
ENDSTYLE 
ON TABLE PCHOLD FORMAT EXL2K PIVOT
CACHEFIELDS MODEL TYPE  
END

La sortie est :

Les modèles Excel prennent seulement en charge les formats EXL2K et EXL2K FORMULA et ne fonctionnent qu'avec Excel 2002 et supérieur.

Les éléments suivants ne sont pas pris en charge avec les modèles Excel : EXL2K PIVOT, rapports EXL2K BYTOC, EXL97, EXCEL et les rapports composés Excel.

Avec le format EXL2K TEMPLATE, le paramètre WEBARCHIVE est automatiquement activé.

La commande PCHOLD retourne un fichier .xmh, lequel est converti par le niveau intermédiaire à un format .mht. HOLD crée un fichier .xht.

Pour créer un rapport à l'aide d'un modèle Excel, veuillez spécifier les éléments suivants :

ON TABLE PCHOLD FORMAT EXL2K TEMPLATE template_name SHEETNUMBER #

où :

template_name

est le nom du fichier de modèle (classeur) résidant sur le serveur d'applications WebFOCUS.

#

est le nombre de classeurs Excel remplacés dans le fichier de modèle (classeur).

Pour créer de plages nommées Excel, utilisez

TYPE=type, IN-RANGES=rangename, $

où :

type

Identifie le composant du rapport WebFOCUS à inclure dans la plage. D'habitude, les deux éléments suivants sont utilisés ensemble :

DATA ajoute l'élément DATA du rapport à la plage nommée (mis à part les en-têtes, pieds de page et titres de colonne).

TITLE ajoute l'élément TITLE du rapport à la plage nommée (y compris les titres de colonne).

Remarque : des éléments multiples peuvent être ajoutés à la même plage.

rangename

Est le nom donné à la sortie dans le classeur Excel créé par votre application, ainsi que le nom référencé par les autres applications WebFOCUS.

L'exemple suivant crée un seul rapport sur une seule feuille d'un classeur Excel. Le code spécifique des plages nommées Excel s'affiche en caractères gras dans la syntaxe suivante.

TABLE FILE GGSALES
PRINT
     PRODUCT
     DATE
     UNITS
BY REGION
BY DOLLARS
ON TABLE SET PAGE-NUM OFF
ON TABLE SET BYDISPLAY ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
     UNITS=IN, SQUEEZE=ON, ORIENTATION=PORTRAIT, $
TYPE=REPORT, FONT='ARIAL', SIZE=9, COLOR='BLACK', BACKCOLOR='NONE',
STYLE=NORMAL, $ 
TYPE=DATA, IN-RANGES='RegionalSales', $
TYPE=TITLE, STYLE=BOLD, IN-RANGES='RegionalSales', $  
ENDSTYLE
END

La sortie Excel est :

Le nom donné à cette plage nommée Excel est RegionalSales. Si d'autres lignes de données sont ajoutées, ou des colonnes de données insérées, la plage nommée s'élargit pour contenir les nouvelles données et les données existantes.

• La zone de données Excel associée à une plage nommée doit être ininterrompue et ne peut pas contenir de coupures parmi les données. SUBHEAD et SUBFOOT sont deux exemples de composants de rapport contenant des coupures parmi les données et qui ne peuvent pas être compris dans une plage nommée.
• Il vous est conseillé d'utiliser la commande ON TABLE SET BYDISPLAY ON. Cela active l'option pour afficher les valeurs de tri répétées, produisant une sortie homogène sans coupures parmi les données.
• Deux feuilles différentes dans la même feuille de calcul ne peuvent pas comporter le même nom de plage.
• En créant des rapports Excel composés (la sortie de plusieurs requêtes TABLE envoyée au même classeur Excel), chaque rapport doit avoir un nom de plage unique qui est stocké au niveau du classeur.

Les plages nommées Excel ne sont pas prises en charge pour les formats Excel suivants :

EXL2K, EXL2K FORMULA, EXL2K TEMPLATE

Les plages nommées Excel ne sont pas prises en charge pour les formats Excel suivants :

EXL2K BYTOC, EXCEL PIVOT

Les plages nommées Excel ne sont prises en charge pour aucune syntaxe de rapport qui produit des données interrompues ou qui utilise des références en colonne s'affichant sur plusieurs colonnes, y compris :

ACROSSCOLUMN, RECAP, RECOMPUTE, SUBHEAD, SUBFOOT, SUBTOTAL, SUB-TOTAL

La syntaxe de table des matières d'Excel est identique à celle des rapports TOC de HTML, sauf que seul un champ BY est autorisé dans EXL2K, tandis que des champs BY multiples sont autorisés dans HTML.

ON TABLE {HOLD|PCHOLD} FORMAT EXL2K BYTOC

Comme seulement un niveau de table des matières est autorisé dans les rapports EXL2K, le numéro facultatif suivant le mot-clé BYTOC ne peut être que 1.

Comme dans HTML, la syntaxe SET COMPOUND, qui précède la commande TABLE, peut aussi être utilisée pour spécifier la création d'une table des matières :

SET COMPOUND=BYTOC

Comme un rapport avec table des matières est segmenté en feuilles de calcul selon la valeur du premier champ BY dans le rapport, le rapport doit contenir au moins un champ BY. Le champ de segmentation peut être un champ NOPRINT.

• Un rapport avec table des matières ne peut pas être incorporé dans un rapport composé.
• Un rapport avec table des matières ne peut pas être un rapport de tableau croisé dynamique.
• Il est impossible de générer un rapport TDM contre une requête à verbes multiples.

Remarque : FORMULA n'est pas pris en charge avec la segmentation.

La requête suivante contre la source de données GGSALES crée des onglets distincts en fonction du critère de tri REGION :

TABLE FILE GGSALES
SUM UNITS/D12C DOLLARS/D12CM
BY REGION NOPRINT
BY CATEGORY
BY PRODUCT
HEADING
"<REGION Region Sales"
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET BYDISPLAY ON
ON TABLE SET COMPOUND BYTOC
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL,SIZE=9,$
TYPE=HEADING, SIZE=12,$
TYPE=TITLE, BACKCOLOR=GREY,COLOR=WHITE, $
ENDSTYLE
END

La sortie est :

• Les noms de balise des feuilles de calcul sont les valeurs des champs BY qui correspondent aux données sur la feuille de calcul actuelle. Si l'utilisateur spécifie le mot-clé TITLETEXT dans la feuille de calcul, celui-ci sera ignoré.
• La longueur des feuilles de calcul dans Excel est limitée à 31 caractères. Vous ne pouvez pas utiliser les caractères spéciaux suivants : « : », « ? », « * », et « / ».
• Si vous souhaitez utiliser des champs de date comme le champ de segmentation BY, vous pouvez inclure un tiret (-) au lieu d'une barre oblique (/). Le tiret (-) est valide dans un titre de balise Excel. Cependant, si vous utilisez la barre oblique (/), WebFOCUS la remplacera par un tiret (-).

L'option BYTOC du format EXL2K WebFOCUS génère un classeur contenant une feuille individuelle pour chaque critère de tri primaire (BY) dans le rapport. Chaque feuille est nommée avec la valeur du critère de tri primaire pour identifier les données qu'elle contient.

Excel exige que chaque nom de feuille soit unique. Excel est sensible à la casse ce qui signifie qu'il évalue deux valeurs considérées comme semblables mêmes lorsque les valeurs contiennent les mêmes caractères, mais une casse différente. Par exemple, Excel évalue les valeurs COFFEE et Coffee comme étant les mêmes valeurs et, par conséquent, elles ne peuvent pas être utilisées comme noms de feuille pour deux feuilles différentes.

Par défaut, le traitement de tri WebFOCUS est sensible à la casse, donc la même valeur du champ avec une casse différente est considérée comme étant deux valeurs différentes lorsqu'elle est utilisée comme critère de tri (BY). Dans un rapport BYTOC Excel, WebFOCUS va générer des feuilles avec des noms de feuille pour chaque valeur du tri primaire (BY) en fonction de la sensibilité de la casse. Pour les valeurs de tri qui diffèrent uniquement par la casse, la feuille initiale recevra la valeur de tri et Excel rencontrera des difficultés avec n'importe quelle feuille générée ultérieurement avec le même nom. Le deuxième nom de la feuille s'affichera sous Recovered_Sheet1 plutôt que la valeur Excel soit considérée comme duplicat.

Dans l'exemple suivant, WebFOCUS va générer des feuilles de style distinctes pour les valeurs Coffee et COFFEE. La feuille de travail initiale sera nommée COFFEE, mais pour la feuille qui suit représentant la valeur Coffee, Excel ne pourra pas utiliser la valeur comme le nom de la feuille de calcul et affichera la valeur récupérée.

DEFINE FILE GGSALES
SHOWCAT/A15=IF PRODUCT EQ 'Espresso' THEN 'COFFEE' ELSE CATEGORY;
END
TABLE FILE GGSALES
BY SHOWCAT 
BY PRODUCT
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET COMPOUND 'BYTOC 1'
END

Sur la sortie, le deuxième onglet contient le nom Recovered_Sheet1 plutôt que la valeur sensible à la casse Coffee :

DEFINE FILE GGSALES
SHOWCAT/A15=IF PRODUCT EQ 'Espresso' THEN 'COFFEE' ELSE CATEGORY;
END
TABLE FILE GGSALES
PRINT SHOWCAT NOPRINT
COMPUTE CNTR/I2 = IF SHOWCAT EQ LAST SHOWCAT THEN LAST CNTR ELSE CNTR + 1; NOPRINT
BY TOTAL COMPUTE SHOWCAT2/A20 = EDIT(CNTR) | '-' | SHOWCAT; NOPRINT
BY SHOWCAT 
BY PRODUCT
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET COMPOUND BYTOC
ON TABLE SET STYLE *
GRID=OFF, $
ENDSTYLE
END

Ajouter l'attribut ROWOVERFLOW à votre feuille de style WebFOCUS

TYPE=REPORT, ROWOVERFLOW={ON|OFF|PBON}, [ROWLIMIT={n|MAX}...

où :

ON

Active les feuilles de style de dépassement.

OFF

Désactive les feuilles de style de dépassement. OFF est la valeur par défaut.

PBON

Insère des ruptures de page WebFOCUS qui affichent l'en-tête, le pied de page et les titres de colonne de la page aux endroits approximatifs dans les lignes de la feuille de calcul. Cette option n'entraîne pas le démarrage d'une nouvelle feuille de calcul lorsqu'une rupture de page WebFOCUS survient.

ROWLIMIT=n

Définit une valeur cible pour le nombre de lignes à inclure sur une feuille de calcul à n lignes. La valeur par défaut est la valeur LINES (par défaut, 57).

ROWLIMIT=MAX

Définit une valeur cible pour le nombre de lignes à inclure sur une feuille de calcul à 65,000 lignes pour la sortie EXL2K.

Cet attribut fonctionne avec la sortie EXL2K ou EXL07. Pour tous les autres types de sortie, l'attribut de feuille de style ROWOVERFLOW est ignoré, et le flux de données n'est pas affecté.

• L'en-tête de rapport est placé une fois au début de la première feuille. Le pied de page du rapport est placé une fois en bas de la dernière feuille de débordement.
• A moins que le paramètre PBON ne soit utilisé, les en-têtes et les titres de colonnes de la feuille de calcul sont répétés en haut de la feuille d'origine et sur chaque feuille de dépassement qui suit. Les pieds de page des Feuilles de calcul sont placés en bas de la feuille originale et en bas de chaque feuille de débordement subséquente. Les valeurs de données sont affichées sur la première ligne de données de chaque feuille de débordement comme dans une nouvelle page standard.
• Le nombre total de lignes du rapport est affiché en bas de la dernière page de débordement directement au-dessus de la dernière page et des pieds de page de table.
• Les lignes des en-têtes secondaires, des pieds de page secondaires, et de sous-total s'affichent dans le flux de données comme normal. Aucune considération spéciale est faite pour conserver des groupements dans une feuille donnée.
• Si ROWOVERFLOW=PBON est défini, les en-têtes, pieds de pages, et titres de colonnes s'affichent dans la feuille de calcul lorsqu'une commande WebFOCUS entraîne une rupture de page.
• Pour la sortie EXL2K, si l'attribut ROWOVERFLOW est spécifié dans la feuille de style et que SET LINES est supérieure à 65K, le message suivant est présenté et aucun fichier de sortie est généré :

  (FOC3313) The line number limit per EXCEL 2003 worksheet is 65536.

• Les types de sortie qui contiennent des références de formule (EXL2K PIVOT et EXL2K FORMULA) ne sont pas pris enn charge. Les références de formule ne sont pas mis à jour automatiquement pour refléter l'emplacement sur les nouvelles feuilles de calcul de dépassement.
• La fonctionnalité de la feuille de calcul de dépassement s'applique aux lignes seulement, pas aux colonnes. Une nouvelle feuille de calcul n'est pas automatiquement créée si un rapport génère plus que la limite de 256 colonnes de Excel 2003.
• ROWOVERFLOW est prise en charge pour les rapports de disposition composée et les rapports BYTOC.
• Comme les plages nommées dans Excel ne peuvent pas s'afficher sur des feuilles de travail multiples, la phrase IN-RANGES qui définit les plages nommées dans le classeur résultant n'est pas prise en charge avec la fonctionnalité ROWOVERFLOW. Lorsque les fonctionnalités existent ensemble dans la même requête, ROWOVERFLOW est prioritaire et la phrase IN-RANGES est ignorée.

La requête suivante crée une sortie de rapport EXL2K avec des feuilles de calcul de dépassement. La commande SET LINES définit le nombre maximum de lignes dans chaque feuille de calcul à approximativement 2000, et l'attribut ROWOVERFLOW=ON dans la feuille de style active la fonction de dépassement. Sans cet attribut, une feuille de calcul serait générée au lieu de trois :

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
-* ****Worksheet Heading****
HEADING
"SALES REPORT WORKSHEET <TABPAGENO"
" "
-* ****Worksheet Footing****
FOOTING
" "
"END OF WORKSHEET <TABPAGENO"

PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION
BY CATEGORY
BY PRODUCT
BY DATE
-* ****Subfoot****
ON REGION SUBFOOT
" "
" End of Region <REGION"
" "
-* ****Subhead****
ON CATEGORY SUBHEAD
" "
" Category <CATEGORY for Region <REGION"
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE SET LINES 2000
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, TITLETEXT=EXLOVER, ROWOVERFLOW=ON,$
ENDSTYLE
END

L'en-tête de rapport s'affiche seulement sur la première feuille de calcul, l'en-tête de page de titre et les titres de colonne s'affichent sur chaque feuille de calcul, et l'en-tête secondaire et le pied de page secondaire s'affichent chaque fois que le critère de tri associé change de valeur. L'image suivante affiche le haut de la première feuille de calcul, qui affiche l'en-tête de rapport, l'en-tête de page, les titres de colonne, et le premier en-tête secondaire :

Notez que l'attribut TITLETEXT dans la feuille de style a spécifié le nom EXLOVER, donc les trois feuilles de calcul ont été générées avec les noms EXLOVER1, EXLOVER2, et EXLOVER3. S'il n'y avait eu aucun attribut TITLETEXT, les feuilles auraient été nommées SHEET1, SHEET2, et SHEET3.

Le pied de page de la feuille de calcul s'affiche en bas de chaque feuille de calcul et le pied de page de rapport s'affiche en bas de la dernière feuille de calcul. L'image suivante affiche le bas de la dernière feuille de calcul, qui affiche le dernier pied de page secondaire, le pied de page et le pied de page de rapport :

La requête suivante crée une sortie de rapport EXL2K avec des feuilles de calcul de dépassement. L'attribut ROWOVERFLOW=PBON dans la feuille de style active la fonctionnalité Feuille de style, et ROWLIMIT=250 définit le nombre maximal de lignes pour chaque feuille de calcul à environ 250. Sans cet attribut, une feuille de calcul serait générée. La phrase de tri PRODUCT spécifie une rupture de page.

TABLE FILE GGSALES
-* ****Report Heading****
ON TABLE SUBHEAD
"SALES BY REGION, CATEGORY, AND PRODUCT"
" "
PRINT DOLLARS UNITS BUDDOLLARS BUDUNITS
BY REGION 
BY HIGHEST CATEGORY 
BY PRODUCT PAGE-BREAK
BY DATE
WHERE DATE GE '19971001'
-* ****Page Heading****
HEADING
" Product: <PRODUCT in Category: <CATEGORY for Region: <REGION"
-* ****Page Footing****
FOOTING
" "
-* ****Report Footing****
ON TABLE SUBFOOT
" "
"END OF REPORT"
ON TABLE SET BYDISPLAY ON
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
INCLUDE=endeflt,TITLETEXT=EXLOVER, ROWOVERFLOW=PBON, ROWLIMIT=250,
$
ENDSTYLE
END

L'en-tête du rapport s'affiche sur la première feuille de calcul uniquement, l'en-tête, le pied de page et les titres de colonnes de la page s'affichent sur chaque feuille de calcul à chaque rupture de page WebFOCUS (à chaque chagement de produit), et l'en-tête et pied de page secondaires s'affichent à chaque changement de valeur du champ de tri associé. L'image suivante affiche le haut de la première feuille de calcul.

Un lien hypertexte pour effectuer un zoom en profondeur vers un FOCEXEC :

TYPE=type, [subtype], FOCEXEC=fex[(parameters ...)], [TARGET=frame,]
 [ALT='tooltip_text',] $

Un lien hypertexte pour effectuer un zoom en profondeur vers une adresse URL :

TYPE=type, [subtype], URL=url[(parameters ...)], [TARGET=frame,] [ALT='tooltip_text',] $

où :

type

Identifiez le composant de rapport que vous sélectionnez dans le navigateur web pour exécuter le lien. L'attribut TYPE et sa valeur doivent apparaître au début de la déclaration.

subtype

sont des attributs supplémentaires, tels que COLUMN, LINE ou ITEM, nécessaires pour identifier le composant de rapport que vous formatez.

FOCEXEC=

Identifie le nom de fichier de la procédure liée, à exécuter lorsque vous sélectionnez le composant de rapport.

url

identifie toute adresse URL valable, y compris celle qui spécifie un programme servlet WebFOCUS, ou le nom d'une colonne de rapport entre parenthèses dont la valeur est une adresse URL valable pour le lien.

GET

les valeurs qui sont transmis au rapport ou à l'URL.

cadre

Identifie le cadre cible dans la page web dans laquelle la sortie du lien de zoom en profondeur est affiché.

tooltip_text

est le texte informatif à afficher lorsque le curseur est positionné sur le lien hypertexte.

Les options zoom en profondeur de JAVASCRIPT et d'IMAGE ne sont pas prises en charge avec le format EXL2K.

La requête de rapport suivante résume les chiffres des ventes et trie les données selon région, état et code de magasin. Le code du magasin s'affiche aussi dans les sous-pieds de page où s'affichent les liens, vers les rapports détaillés comprenant les ventes pour le magasin (par produit ou par date). Chaque ligne du sous-pied de page comporte deux objets de texte et un champ incorporé.

TABLE FILE GGSALES
HEADING
"Sales Report"
SUM DOLLARS/I08M
BY REGION BY ST BY STCD
ON STCD SUBFOOT
"View Store <STCD Sales By Product"
" "
"View Store <STCD Sales By Date"
ON TABLE PCHOLD FORMAT EXL2K
ON REGION PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=HEADING, SIZE=12, STYLE=BOLD, $
TYPE=SUBFOOT, LINE=1, OBJECT=TEXT, ITEM=2, 
FOCEXEC=PRDSALES(STOREID=STCD), ALT='Product Sales',$
TYPE=SUBFOOT, LINE=3, OBJECT=TEXT, ITEM=2, 
FOCEXEC=HSTSALES(STOREID=STCD),ALT='Sales History', $
ENDSTYLE
END

En utilisant des déclarations de feuille de style, la phrase de sous-pied Sales By Product est liée vers une deuxième procédure appelée PRDSALES et lui passe la valeur de STCD affichée dans le pied de page. La phrase de sous-pied Sales By Date est liée vers une procédure appelée HSTSALES et lui passe la valeur de STCD affichée dans le sous-pied. Les attributs ALT dans les déclarations de feuille de style pour les liens hypertexte fournit des messages d'informations.

Le rapport PRDSALES lié suit :

TABLE FILE GGSALES
SUM UNITS
BY STCD
BY PRODUCT
WHERE STCD = '&STOREID'
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Le rapport HSTSALES lié suit :

TABLE FILE GGSALES
SUM UNITS
BY STCD
BY DATE
WHERE STCD = '&STOREID'
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La première page du rapport principal est présentée ci-après. Si vous passez la souris sur le lien Ventes par Date, le texte informatif Historique des ventes s'affiche :

En plus de la méthode décrite dans l'exemple Incorporer un rapport WebFOCUS dans un classeur Excel 2000/2003, vous pouvez utiliser d'autres techniques pour tirer parti de Web Query dans votre feuille de calcul. Par exemple, si vous avez une feuille de calcul existante contenant beaucoup d'éléments prédéfinis, vous devrez potentiellement exécuter la requête dans une feuille de calcul distincte et voir combien d'espace elle prendra avant de l'ajouter à la "zone de travail" principale de la feuille de calcul. Il est préférable de désigner une feuille de calcul particulière pour votre interrogation et d'avoir tout ce qui reste faire référence aux données via des formules sur une autre feuille de calcul.

Une autre façon s'agit d'inclure tout dans une même feuille de calcul. Normalement, d'autres éléments environnants dans la feuille de calcul se repositionnent lorsque les données sont renvoyées, mais vous pouvez sécuriser une zone tampon pour vous assurer qu'il y a assez d'espace pour la sortie de rapport.

Un fichier IQY est construit comme suit

Type_of_query     [CR ]Version_of_query  [CR]URL               [CR]
{POST|GET} parameters   [CR]

où :

Type_of_query

Le type d'interrogation est Web. Comme Web est la valeur par défaut, cette saisie est facultative.

Version_of_query

Est la version actuelle du logiciel d'interrogation Web. La valeur par défaut est 1. Cette saisie est facultative.

URL

Est une saisie obligatoire qui fait pointer au serveur WebFOCUS. L'URL doit être construit comme un appel au CGI WebFOCUS ou au servlet et doit contenir tous les paramètres appropriés qui doivent être passé.

POST parameters

Est la méthode favorite pour récupérer de grandes quantités de données et de les renvoyer en tant que ligne de texte différente. Par exemple :

http://WFserver/ibi_apps/WFServlet[CR]
PARAM1=value & PARAM2=value

GET parameters

Est la méthode préférée pour récupérer des quantités de données plus petites et les ajouter à l'URL. Par exemple :

http://server/ibi_apps/WFServlet?PARAM1=value&PARAM2=value

[CR]

Désigne des renvois chariot requis.

Etape 1 : Créer le rapport WebFOCUS

Créez et sauvegardez le rapport stylisé WebFOCUS comme webq97. Vous intégrez ce rapport dans une feuille de calcul Excel 97. (Pour garantir le style et l'exécution corrects de la requête dans Excel 97, assurez-vous que les feuille de style en cascade ne sont pas activées ; SET HTMLCSS=OFF est la valeur par défaut).

Les numéros à gauche de chaque ligne de code correspondent aux annotations qui suivent la requête.

1.  TABLE FILE CENTORD 
2.  SUM LINEPRICE AS 'Sales' 
3.  BY YEAR AS 'Year' 
4.  BY PRODCAT AS 'Category' 
5.  BY PRODNAME AS 'Product' 
6.  WHERE YEAR EQ '&YEAR'; 
7.  ON TABLE SET BYDISPLAY ON 
8.  ON TABLE PCHOLD FORMAT HTML 
9.  ON TABLE SET PAGE-NUM TOP 
10. ON TABLE SET STYLE * 
11. TYPE=REPORT, FONT=ARIAL, SIZE=10, GRID=OFF, BACKCOLOR=YELLOW, $ 
12. TYPE=TITLE, SIZE=11, STYLE=BOLD, $ 
13. TYPE=DATA, COLOR=RED, WHEN=LINEPRICE LT 15000000, $ 
14. TYPE=DATA, COLUMN=PRODCAT, FOCEXEC=webq2(PRODCAT=N1), $ 
15. ENDSTYLE 
16. END

Ligne 1

Lignes 2 à 5 définissent les conditions d'affichage et de tri pour le rapport.

Ligne 6

Ligne 7 Cette définition fait en sorte que les valeurs de tri répétées dans le rapport soient chargées de données.

Par défaut, les valeurs de tri répétées dans les colonnes verticales (ou champs BY), sont supprimées dans un rapport WebFOCUS, ce qui laisse des champs blancs dans de rapport. Ce comportement n'est pas souhaitable des rapports Excel, qui sont conçus pour utiliser des données répétées dans chaque rangée à laquelle elles s'appliquent. Une colonne ou une rangée blanches peuvent entraîner des résultats trompeurs lors du tri de données.

Ligne 8 définit HTML comme format de sortie.

Important : le rapport doit être au format HTML et non pas EXL97. Ceci parce que l'interrogation Microsoft importe des pages HTML entièrement mises en forme ou des tableaux HTML dans une feuille de calcul. Exécuter une requête EXL97 à partir d'une interrogation ne renvoie pas de données à la feuille de calcul.

Ligne 9

Lignes 10 à 15 spécifient les attributs de style pour le rapport : la couleur d'arrière-plan, le style conditionnel, un zoom en profondeur vers une autre procédure, et certains d'autres styles divers. Le style, y compris les zoom en profondeur, s'applique également à Excel.

Etape 2 : Créer un fichier d'interrogation Web (IQY)

Ouvrez un éditeur de texte et créez le fichier d'interrogation Web suivant

1.  WEB 
2.  1 
3.  http://WFserver/ibi_apps/WFServlet?IBIF_ex=webq97
       &YEAR=["YEAR","Select Year"]

où :

Ligne 1

Ligne 2

Ligne 3 est une requête WebFOCUS typique utilisant la méthode GET. Le nom de la procédure est webq97. La ligne URL passe un paramètre de YEAR à la procédure. L'utilisateur est invité à saisir une valeur pour YEAR. Passer des pararmètres est facultatif. Dans l'exemple ci-dessous, un des paramètres est dynamique, mais les paramètres peuvent également être statiques. En d'autres termes, codé en dur dans le fichier IQY.

Notez que les renvois chariot sont requis entre les lignes de ce fichier.

Une fois l'interrogation construite, sauvegardez le document, avec une extension .iqy, dans le répertoire d'interrogation sous Microsoft Office. Par exemple,

<drive>:\Program Files\Microsoft Office\Queries\webq97.iqy

Comme le fichier IQY est prêt, vous pouvez maintenant créer la feuille de calcul et y intégrer l'interrogation.

Etape 3 : Incorporer la requête dans une feuille de calcul Excel 97

Cet exemple commence par une feuille de calcul vierge, puis il intègre l'interrogation et finalement il ajoute les options.

1. Ouvrez une feuille de calcul vierge. Dans le menu Données, sélectionnez « Get External Data », suivi de « Run Web Query ». La boîte de dialogue « Run Query » s'ouvre.
2. Recherchez le fichier IQY, webq97.icy, et cliquez sur le bouton Obtenir les données. La boîte de dialogue « Run Query » s'ouvre.

   

3. Spécifiez l'emplacement des données dans votre feuille de calcul. Vous pouvez choisir un éventail dans la feuille de calcul actuelle ou vous pouvez choisir de remettre les données dans une nouvelle feuille de calcul. Dans ce cas, spécifiez l'éventail comme indiqué :

   

   Il n'est pas nécessaire de définir la plage d'une feuille de calcul vide, cependant, vous pouvez exporter les données dans une nouvelle feuille de calcul et utiliser des références de formule pour travailler avec les données.

4. Cliquez sur le bouton Propriétés dans la boîte de dialogue Renvoi de données externes vers Excel. La fenêtre de dialogue Propriétés de la plage de données externes s'affiche. Nommez l'interrogation et définissez son comportement. Par exemple, vous pouvez définir l'interrogation d'actualiser la feuille de calcul chaque fois qu'elle s'ouvre. (Notez que vous pouvez également définir les propriétés suivant la première exécution).

   

   Cliquez sur OK.

5. Cliquez sur le bouton Paramètres dans la boîte de dialogue Renvoi de données externes vers Excel afin de définir le comportement de tout paramètre qui se trouve dans votre requête. Vous pouvez inviter l'utilisateur, définir une valeur fixe ou utiliser une valeur d'une cellule dans la feuille de calul. Dans cet exemple, vous invitez l'utilisateur à saisir l'année (YEAR).

   Saisissez la valeur 1999.

   

6. Une fois la plage sélectionnée et toutes les propriétés de la requête définies, cliquez sur le bouton OK.

   L'interrogation exécute et importe les données. Le message suivant s'affiche dans la feuille de calcul :

   webq97: Getting Data...

   Les données s'affichent dans la feuille de calcul :

   

7. L'introduction des données dans la feuille de calcul étant terminée, vous pouvez y ajouter des fonctionnalités, telles que des formules, des images, des graphiques, des macros, etc.

   

Vous pouvez maintenant sauvegarder cette feuille de calcul localement sur votre PC, la sauvegarder sur une unité de réseau partagée où les informations sont accessibles par des utilisateurs multiples, ou la déployer dans votre application Web. Consultez Déploiement d'une feuille de calcul avec une requête WebFOCUS Web Query.