Cómo alinear un elemento de encabezado o pie a través de las columnas en un informe HTML o PDF

Cómo:

Con HEADALIGN=BODY, cada elemento de encabezado o pie queda alineado con una columna de datos, en los informes HTML o PDF. Con HEADALIGN=INTERNAL, cada elemento continúa en una columna de una tabla HTML, creada y alineada específicamente para el informe o pie del informe. De forma predeterminada, se coloca cada elemento de un encabezado o pie (ITEM) en la primera columna disponible. Sin embargo, puede colocar un elemento para que ocupe múltiples columnas mediante el atributo COLSPAN. Para obtener información detallada acerca de las opciones HEADALIGN, vaya a Cómo alinear un elemento de ´encabezado o pie en un informe HTML, XLSX, EXL2K o PDF.

Debe especificar los atributos HEADALIGN y COLSPAN en dos declaraciones de hoja de estilo individuales, toda vez que HEADALIGN se aplica a todo el encabezado o el pie, en tanto que COLSPAN se aplica a un elemento específico en un encabezado o pie.


Principio de página

x
Sintaxis: Cómo Alinear un elemento de encabezado o pie a través de las columnas en un informe HTML o PDF
TYPE = headfoot, [subtype,] COLSPAN = n, $

donde:

headfoot

Es el tipo de encabezado o pie. Los valores válidos son TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD y SUBFOOT.

subtype

Son atributos adicionales que identifican el componente de informe. Estas opciones se pueden usar por separado o combinarse, dependiendo del grado de especificidad necesario para identificar el elemento. Los valores válidos son:

  • LINE, que identifica una línea por su posición en el encabezado o pie. La identificación de líneas individuales le permite dar formato a cada línea de manera diferente.

    Si un encabezado o pie consta de múltiples líneas y aplica una declaración de hoja de estilo que no especifica LINE, la declaración pasa a aplicarse en todas las líneas. Los líneas en blanco se cuentan al interpretar el valor de LINE.

  • OBJECT, que identifica un elemento en un encabezado o pie como una cadena de texto o valor de campo. Los valores válidos son TEXT o FIELD. TEXT puede representar texto libre o una variable ampersand "&" de Dialogue Manager.

    No es necesario especificar OBJECT=TEXT a menos que esté dando estilo tanto a las cadenas de texto como a los campos insertados en el mismo encabezado o pie.

  • ITEM, que identifica un elemento por su posición en una línea. Para dividir un encabezado o pie en diferentes elementos, puede utilizar el marcador de posición <+0>. Para más información, consulte Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

Para determinar el ITEM de un OBJECT, siga estas instrucciones:

  • Si lo utiliza con OBJECT=TEXT, cuente sólo las cadenas de texto desde la izquierda hasta la derecha.
  • Si lo utiliza con OBJECT=FIELD, cuente sólo los valores desde la izquierda hasta la derecha.
  • Si lo utiliza con OBJECT, cuente las cadenas de texto y los valores de campo desde la izquierda hasta la derecha.

Si aplica una declaración de hoja de estilo que especifique ITEM, se cuentan los números desde el principio de cada línea en el encabezado o pie de página, no solamente desde el principio de la primera línea.

COLSPAN
Es un atributo que alinea un elemento en el ancho alcanzado por múltiples columnas.
n
Es la columna con que se alinea el elemento especificado.


Ejemplo: Cómo centrar un encabezado de página a través de tres columnas

En esta solicitud, HEADALIGN=INTERNAL crea una tabla HTML insertada de tres columnas para el encabezado. El atributo COLSPAN centra entonces la primera línea del encabezado en el informe, es decir, Gotham Grinds, Inc., abriendo las tres columnas en la tabla HTML insertada.

TABLE FILE GGORDER
HEADING
"Gotham Grinds, Inc."
" "
"Orders Report <+0> <+0> Run on: &DATE"
" "
PRINT ORDER_NUMBER ORDER_DATE STORE_CODE QUANTITY
BY PRODUCT_CODE BY PRODUCT_DESCRIPTION
IF RECORDLIMIT EQ 10
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $
TYPE = HEADING, HEADALIGN = INTERNAL, $ 
TYPE = HEADING, LINE=1, COLSPAN=3, STYLE = BOLD, JUSTIFY=CENTER, $ 
TYPE = HEADING, LINE=3, ITEM=3, JUSTIFY=RIGHT, $
ENDSTYLE
END

La salida es:



Ejemplo: Cómo alinear un valor de campo a través de múltiples columnas

En la solicitud, HEADALIGN=BODY alinea el pie de clasificación en la misma tabla HTML que el cuerpo del informe. COLSPAN = 5 coloca el primer elemento en el pie de clasificación (el texto Total) en la quinta columna de la tabla HTML. El segundo elemento del pie de clasificación (el campo <ST.QUANTITY) se coloca en la próxima columna disponible.

El atributo HEADALIGN se encuentra en una línea independiente de aquella en que se encuentra el atributo COLSPAN porque se aplica a todo el pie de clasificación -y, por consiguiente, a ambos elementos-, en tanto que COLSPAN se aplica al elemento único Total.

TABLE FILE GGORDER
PRINT ORDER_NUMBER ORDER_DATE STORE_CODE QUANTITY
BY PRODUCT_CODE BY PRODUCT_DESCRIPTION
WHERE ORDER_DATE EQ '01/01/96'
WHERE STORE_CODE EQ 'R1019' 
ON PRODUCT_CODE SUBFOOT
"Total: <ST.QUANTITY" 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = SUBFOOT, HEADALIGN = BODY, JUSTIFY = RIGHT, STYLE = BOLD, $
TYPE = SUBFOOT, OBJECT = TEXT, COLSPAN = 5, $ 
ENDSTYLE
END

El resultado parcial es:



Ejemplo: Cómo alinear un valor de campo a través de múltiples columnas de un informe PDF

En esta solicitud, HEADALIGN=BODY alinea el pie de clasificación en la misma cuadrícula que el cuerpo del informe. COLSPAN = 5 coloca el primer elemento del pie de clasificación (el texto Total) en la quinta columna de la salida del informe. El segundo elemento del pie de clasificación (el campo <ST.QUANTITY) se coloca en la próxima columna disponible. Los elementos de subpie están justificados a la derecha.

El atributo HEADALIGN se encuentra en una línea independiente deel atributo COLSPAN porque se aplica a todo el pie de clasificación (y por consiguiente a ambos elementos), mientras que COLSPAN sólo se aplica al elemento de texto Total.

TABLE FILE GGORDER
PRINT ORDER_NUMBER ORDER_DATE STORE_CODE QUANTITY
BY PRODUCT_CODE BY PRODUCT_DESCRIPTION
WHERE ORDER_DATE EQ '01/01/96'
WHERE STORE_CODE EQ 'R1019'
ON PRODUCT_CODE SUBFOOT
"Total:<ST.QUANTITY"
""
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLESHEET *
TYPE=REPORT, FONT=ARIAL, SQUEEZE=ON,$ 
TYPE = SUBFOOT, HEADALIGN = BODY, JUSTIFY = RIGHT, STYLE = BOLD, $
TYPE = SUBFOOT, ITEM=1, COLSPAN = 5, $
ENDSTYLE
END

La salida muestra que el primer elemento del pie de clasificación (el texto Total) está en la quinta columna de la salida del informe. El segundo elemento del pie de clasificación (el campo <ST.QUANTITY) se coloca en la próxima columna disponible.


WebFOCUS