Einen Freiform-Report erstellen

Sie können einen Freiform-Report von einer TABLE-Anfrage erstellen, die die Anzeigebefehle weglässt, die die Formatierung der Spalten und der Matrix (PRINT, LIST, SUM und COUNT) steuern. Stattdessen enthält die Anfrage die folgenden Report-Features:

Kopfzeile

Enthält den Hauptteil des Reports. Sie zeigt die Textzeichen, grafischen Zeichen und Datenfelder an, aus denen der Report besteht.

Fußzeile

Enthält die Fußzeile des Reports. Dies ist der Text, der im unteren Bereich jeder Reportseite angezeigt wird. Die Fußzeile kann dieselben Zeichen und Datenfelder anzeigen, wie die Kopfzeile.

Präfixoperatoren

Gibt Berechnungen und Manipulation von Feldern an.

Temporärfelder

Leitet neue Werte aus vorhandenen Feldern in einer Datenquelle ab.

BY-Phrasen

Gibt die Sortierreihenfolge des Reports an und bestimmt, wie viele Datensätze sich auf jeder Seite befinden sollen.

WHERE-Kriterien

Wählt Datensätze für den Report aus.

Wenn Sie einen Freiform-Report erstellen, können Sie:


Nach oben

Beispiel: Einen Freiform-Report erstellen

Nehmen wir an, dass es als Personalleiter Ihre Verantwortung ist, die Richtlinien für Lehrgänge in Ihrem Unternehmen zu verwalten. Diese Fortbildungsrichtlinie gibt an, dass die Anzahl der Fortbildungsstunden, die ein Angestellter auf Kosten des Unternehmens außer Haus absolvieren darf, bestimmt wird durch die Anzahl der Fortbildungsstunden, die der Angestellte im Haus absolviert hat.

Um Ihre Arbeit effizient durchführen zu können, möchten Sie einen Report haben, der Ihnen anzeigt, welche Lehrgänge jeder Angestellte im Haus abgeschlossen hat. Die Informationen der einzelnen Angestellten sollten auf einer separaten Seite angezeigt werden, so dass sie in der Personalakte abgeheftet werden können und verwendet werden können, wenn ein Angestellter Lehrgänge außer Haus besuchen möchte.

Hierzu erstellen Sie den EMPLOYEE EDUCATION HOURS REPORT, in dem es für jeden Angestellten eine separate Seite gibt. Beachten Sie, dass die Seiten 1 und 2 des Reports Informationen über Angestellte in der Abteilung MIS enthalten, wohingegen die Seite 6 Informationen für einen Angestellten in der Produktionsabteilung enthalten.

Die folgende Übersicht simuliert die Ausgabe, die Sie sehen würden, wenn Sie die Prozedur ausführen würden in Anfrage für EMPLOYEE EDUCATION HOURS REPORT.


Nach oben

Beispiel: Anfrage für EMPLOYEE EDUCATION HOURS REPORT

Die folgende Anfrage erzeugt den EMPLOYEE EDUCATION HOURS REPORT. Die Zahlen links neben der Anfrage beziehen sich auf die Zahlen in den folgenden Anmerkungen:

1. SET STYLE = OFF
   SET STYLEMODE=FIXED
   SET ONLINE-FMT = PDF 
2. DEFINE FILE EMPLOYEE
      CR_EARNED/I2 = IF ED_HRS GE 50 THEN 9
         ELSE IF ED_HRS GE 30 THEN 6
         ELSE 3;
      END 
3. TABLE FILE EMPLOYEE
   BY DEPARTMENT 
4. HEADING
   " "
   "<13>EMPLOYEE EDUCATION HOURS REPORT" 
5. "<14>FOR THE <DEPARTMENT DEPARTMENT" 
6. "</2"
   "EMPLOYEE NAME:    <23><FIRST_NAME <LAST_NAME>"
   "EMPLOYEE ADDRESS: <23><ADDRESS_LN1>"
   "<23><ADDRESS_LN2>"
   "<23><ADDRESS_LN3>"
   "</1"
   "JOB CODE: <JOBCODE>"
   "JOB DESCRIPTION: <JOB_DESC>"
   "</1" 
7. "MOST RECENT COURSE TAKEN ON: <MAX.DATE_ATTEND>"
   "TOTAL NUMBER OF EDUCATION HOURS: <ED_HRS>"
   "</1" 
8. "<10>|-------------------------------------|" 
9. "<10>| EDUCATION CREDITS EARNED <CR_EARNED>|"
   "<10>|-------------------------------------|" 
10.BY EMP_ID NOPRINT PAGE-BREAK 
11.WHERE ED_HRS GT 0 
12.FOOTING
   "<15>PRIVATE AND CONFIDENTIAL"
   END

Nachfolgend wird die Rolle jeder Zeile in der Anfrage bei der Erzeugung des Musterreports beschrieben:

  1. Es sind zwei SET-Befehle nötig, um die gewünschte Anfrage in einem Browser anzuzeigen. Der Befehl SET STYLE = OFF ermöglicht ein Freiform-Design, indem defaultmäßige StyleSheet-Parameter ignoriert werden. SET STYLEMODE = FIXED deaktiviert HTML-Formatierung und ermöglicht es dem Report-Designer, festzulegen, wo Elemente im Report platziert werden, durch Platzmarkierungen und Zeilensprungbefehle.
  2. Der DEFINE-Befehl erstellt ein virtuelles Feld für den Report. Die Berechnung spiegelt die Unternehmensrichtlinien für Lehrgänge außer Haus wider. Das Ergebnis wird gespeichert in CR_EARNED und wird später im Report angezeigt.
  3. Ein Freiform-Report fängt mit einem standardmäßigen TABLE FILE-Befehl an. Der Musterreport verwendet die EMPLOYEE-Datenquelle.
  4. Der Kopfzeilenabschnitt, der vom HEADING-Befehl initiiert wird, definiert den Hauptteil des Reports. Die meisten Text- und Datenfelder, die im Report angezeigt werden, werden im Abschnitt Kopfzeile angegeben. In der Anfrage geht der Kopfzeilenbereich weiter bis zur zweigen BY-Phrase BY EMP_ID NOPRINT PAGE-BREAK.
  5. Diese Zeile veranschaulicht Folgendes:
  6. Sie können die Lesbarkeit eines Reports verbessern, indem Sie Zeilensprungbefehle verwenden. Der Befehl </2 erzeugt, wenn er alleine auf einer Zeile codiert wird, zwei leere Zeilen, wie es zu sehen ist zwischen der Seitenkopfzeile und dem Angestelltennamen.
  7. Diese Zeile zeigt, wie Sie eine Feldberechnung in einem Freiform-Report mit einem Präfixoperator durchführen. In diesem Fall haben wir das Datum angefordert, an dem der letzte Lehrgang besucht wurde, d.h. der Maximalwert für das Feld DATE_ATTEND.
  8. Die nächsten drei Zeilen zeigen die Verwendung von Sonderzeichen, um eine Grafik in einem Report zu erstellen. Die Box um EDUCATION CREDITS EARNED herum muss eventuell für die angezeigte Ausgabe in einer proportionalen Schriftart angezeigt werden.
  9. Der Wert des Feldes, das durch den DEFINE-Befehl erstellt wurde, wird in der Box angezeigt, wodurch man sehen kann, wie viele Lehrgänge ein Angestellter besucht hat. Diese Zeile zeigt, dass Sie ein virtuelles Feld im Hauptteil Ihres Reports anzeigen können.
  10. In dieser Zeile ist die Verwendung von Sortierung in einem Freiform-Report veranschaulicht. Die Reportspezifikationen erfordern, dass nur die Informationen für einen Angestellten pro Seite angezeigt werden. Dies wird erreicht, indem die Befehle BY und PAGE-BREAK verwendet werden. Beachten Sie, dass, damit ein Report mit Seitenumbrüchen erzeugt werden kann, die Reportausgabe PDF sein muss.
  11. Sie können in einem Freiform-Report Datensatzauswahl angeben. Aufgrund des WHERE-Kriteriums enthält der Report nur Angestellte, die Lehrgänge im Haus besucht haben.
  12. Da wir einen Personalreport entworfen haben, ist es wichtig, dass auf jeder Reportseite am Ende PRIVATE AND CONFIDENTIAL steht. Der Befehl FOOTING erzielt dies.

WebFOCUS