TABLE FILE EMPLOYEE
SUM DED_AMT AND GROSS
BY DEPARTMENT BY PAY_DATE
ON DEPARTMENT RECAP DEPT_NET/D8.2M = GROSS-DED_AMT;
WHEN PAY_DATE GT 820101
ON DEPARTMENT SUBTOTAL
END

x

TYPE=type, [BY=sortfield] [coltype=column]

Hierbei gilt:

type

Identifiziert eine Zwischensumme oder eine Summe. Wählen Sie aus den folgenden Optionen aus:

GRANDTOTAL ist eine Gesamtsumme (erzeugt durch COLUMN-TOTAL, SUBTOTAL, SUB-TOTAL, RECOMPUTE oder SUMMARIZE). Ein Beispiel finden Sie unter Eine Gesamtsumme identifizieren.

SUBTOTAL ist eine Zwischensumme (erzeugt durch SUBTOTAL, SUB-TOTAL, RECOMPUTE oder SUMMARIZE). Ein Beispiel finden Sie unter Zwischensummen identifizieren.

RECAP ist eine Zwischensummenberechnung (erzeugt durch ON sortfield RECAP oder ON sortfield COMPUTE). Ein Beispiel finden Sie unter Eine Zwischensummenberechnung identifizieren (RECAP/COMPUTE).

BY

Falls Sie eine Anfrage mit mehreren BY-Feldern besitzen und zwei oder mehr davon Zwischensummenbefehle mit ihnen assoziiert haben, dann können Sie jedes Feld mit dem BY-Identifikator identifizieren. Dies ist hilfreich, wenn Sie die Zwischensummen unterschiedlich formatieren oder nur eine Zwischensumme formatieren möchten.

Sie müssen den BY-Identifikator nur mit einbeziehen, wenn Sie mehrere BY-Felder in Ihrer Anfrage haben.

sortfield

Gibt das BY-Feld an, das mit mehreren Zwischensummenbefehlen eines Reports assoziiert ist. Verwenden Sie den Feldnamen für den Wert (BY=fieldname).

coltype

Identifiziert eine bestimmte Spalte, auf die Formatierung angewendet werden soll. Wenn Sie die COLUMN- oder ACROSSCOLUMN-Identifikatoren in Ihre Deklaration aufnehmen, werden nur die Zwischensummen-Werte Formatierung erhalten, der bezeichnende Text aber nicht. Dies können die Werte sein:

COLUMN ist eine Anzeigespalte (erzeugt durch PRINT, LIST, SUM oder COUNT) oder eine berechnete Spalte (erzeugt durch COMPUTE).

ACROSSCOLUMN wobei jede Instanz einer Anzeige und einer berechneten Spalte über eine horizontale Sortierungsreihe (ACROSS) wiederholt werden.

Falls es mehrere Spalten gibt, deren Summe oder Zwischensumme durch einen Befehl erstellt wird und Sie im StyleSheet keine Spalte angeben, wird die Formatierung auf die Summen oder Zwischensummen für alle Spalten angewendet. Sie wird auch auf den Labeltext der Summen- und Zwischensummenwerte angewendet.

column

Gibt die Spalte an, deren Summen oder Zwischensummen Sie formatieren möchten. Eine Liste der Werte finden Sie unter Eine gesamte Spalte identifizieren.

Nach oben

Beispiel: Eine Gesamtsumme identifizieren

Das Folgende zeigt, wie Sie eine Gesamtsumme in einer Reportanfrage identifizieren. In diesem Beispiel wollen wir nur den Gesamtsummenwert für das Feld LINE_COGS formatieren, so dass das Attribut COLUMN in der StyleSheet-Deklaration enthalten ist. Die Gesamtsumme in der Anfrage wird durch COLUMN-TOTAL erzeugt. Die relevante StyleSheet-Deklaration ist in der Anfrage markiert.

Hinweis:

• Entfernen Sie, um die gesamte Gesamtsummenzeile zu formatieren, das COLUMN-Attribut aus der StyleSheet-Deklaration.
• Hinweis: Sie können als Alternative auch die Werte P5, oder den Feldnamen (PRODNAME) für das COLUMN-Attribut in der StyleSheet-Deklaration verwenden um dasselbe Ergebnis zu erhalten.

TABLE FILE CENTORD
SUM QUANTITY LINEPRICE LINE_COGS AND COLUMN-TOTAL
BY ORDER_NUM BY PRODNAME
WHERE ORDER_NUM EQ '48053' OR '48798'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=GRANDTOTAL, COLUMN=LINE_COGS, STYLE=BOLD, SIZE=11,$ 
ENDSTYLE
END

Die Ausgabe ist:

Nach oben

Beispiel: Zwischensummen identifizieren

Nachfolgend sehen Sie, wie Sie Zwischensummen in einer Reportanfrage identifizieren. In diesem Beispiel werden nur Zwischensummenwerte in den Feldern und QUANTITY und LINE_COGS formatiert. Das COLUMN-Attribut wird so in die StyleSheet-Deklaration aufgenommen.

Da zwei SUBTOTAL-Befehle mit zwei der drei BY-Felder assoziiert werden (PLANT und ORDER_NO), wird das BY-Attribut ebenfalls in jede Deklaration mit einbezogen, um sicherzustellen, dass die Formatierung auf den richtigen Wert angewendet wird. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert.

Hinweis:

• Entfernen Sie, um eine gesamte Zwischensummenzeile zu formatieren, die Attribute COLUMN und BY aus der StyleSheet-Deklaration.
• Sie können, um dasselbe Ergebnis zu erzielen, alternativ die Werte COLUMN=N6, COLUMN=P6 oder COLUMN=C3 für das COLUMN=LINE_COGS-Attribut verwenden.
• Sie können, um dasselbe Ergebnis zu erzielen, alternativ die Werte COLUMN=N4, COLUMN=P4 oder COLUMN=C1 für das COLUMN=QUANTITY-Attribut verwenden.

TABLE FILE CENTORD
SUM QUANTITY LINEPRICE LINE_COGS AS 'Line Cost of, Goods Sold'
BY PLANT
BY ORDER_NUM
BY PRODNAME
ON PLANT SUBTOTAL
ON ORDER_NUM SUBTOTAL
WHERE ORDER_NUM EQ '35774' OR '48041'
WHERE PLANT EQ 'BOS'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=SUBTOTAL, BY=PLANT, COLUMN=LINE_COGS, STYLE=BOLD+ITALIC,
    COLOR=BLUE,$
TYPE=SUBTOTAL, BY=ORDER_NUM, COLUMN=QUANTITY, STYLE=BOLD, SIZE=11,$ 
ENDSTYLE
END

Die Ausgabe ist:

Nach oben

Beispiel: Eine Zwischensummenberechnung identifizieren (RECAP/COMPUTE)

Im Folgenden wird beschrieben, wie Sie eine Zwischensummenberechnung, die mit einer RECAP- oder COMPUTE-Phrase erstellt wurde, identifizieren. In diesem Beispiel wird die Zwischensummenberechnung mit ON PLANT RECAP QTY/F6=QUANTITY erzeugt. Die relevante StyleSheet-Deklaration ist in der Anfrage markiert.

Hinweis: Falls es mehr als ein RECAP- oder COMPUTE-Feld in Ihrer Anfrage gibt, können Sie diese unterscheiden, indem Sie der StyleSheet-Deklaration BY=fieldname hinzufügen.

TABLE FILE CENTORD
SUM QUANTITY LINEPRICE LINE_COGS AS 'Line Cost of, Goods Sold'
BY PLANT BY ORDER_NUM
ON PLANT RECAP QTY/F6=QUANTITY;
WHERE PLANT EQ 'BOS'
WHERE ORDER_NUM LT '56098'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=RECAP, STYLE=BOLD+ITALIC, $ 
ENDSTYLE
END

						
Die Ausgabe ist: