Einen gesamten Report, eine gesamte Spalte oder eine gesamte Zeile identifizieren

Vorgehensweise:

Sie können Formatierung anwenden auf:

Im Folgenden wird dargestellt, wo die REPORT-Komponente und die COLUMN- und ACROSSCOLUMN-Attribute im Report angezeigt werden und welche TYPE-Werte Sie verwenden, um sie zu identifizieren. Obwohl in diesem Beispiel der Wert für COLUMN B1 und der Wert für ACROSSCOLUMN N2 ist, sind dies nicht die einzigen Werte, die Sie verwenden können, um diese Komponenten zu identifizieren.

TABLE FILE CENTORD
SUM LINEPRICE LINE_COGS AS 'Line Cost of,Goods Sold'
BY PLANT AS 'Plant'
ACROSS YEAR
WHERE YEAR EQ 2000 or 2001
HEADING
"Cost Analysis"
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
END

Hinweis: Da diese Anfrage nur zeigt, wo die Komponenten in einem Report angezeigt werden, wird das StyleSheet weggelassen.
Nach oben
x
Syntax: Einen gesamten Report identifizieren

Verwenden Sie dieses Attribut und diesen Wert, um einen ganzen Report mit einem StyleSheet anzusprechen: 

TYPE=REPORT
Beispiel: Einen gesamten Report identifizieren

Im Folgenden wird beschrieben, wie Sie Formatierung identifizieren und auf einen gesamten Report anwenden. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert. 

TABLE FILE CENTINV
HEADING
"Excess Stock Report"
SUM QTY_IN_STOCK  
BY PRODNAME
WHERE QTY_IN_STOCK GT 10000
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, GRID=OFF,$
TYPE=REPORT, STYLE=BOLD,$ 
ENDSTYLE
END

Die Ausgabe ist:
Nach oben
x
Syntax: Eine gesamte Spalte identifizieren
TYPE=REPORT, coltype=column

Hierbei gilt:

coltype

Gibt den Spaltentyp an. Es kann Folgendes sein:

COLUMN gibt eine Sortierspalte (durch BY erzeugt), eine Anzeigespalte (durch PRINT, LIST, SUM oder COUNT erzeugt), eine berechnete Spalte (durch COMPUTE erzeugt) oder eine Spalte mit Zeilensummen (durch ROW-TOTAL erzeugt) an.

ACROSSCOLUMN gibt jede Instanz einer Spalte an, die in einer horizontalen Sortiertzeile (ACROSS) wiederholt wird. Dies trifft auch auf die Formatierung der horizontalen Sortierwerte (ACROSS) zu, die über den Spaltentiteln angezeigt werden.

column

Gibt eine oder mehrere Spalten an. Wenn Sie eine ACROSSCOLUMN identifizieren, sind die einzigen gültigen Nn und Pn, und diese zählen nur ACROSS-Felder, nicht Anzeigefelder.

Dies sind die Optionen für das Identifizieren von Spalten in einem StyleSheet:

Identifikator

Beschreibung

Nn

Identifiziert eine Spalte über ihre Position im Report. Zählen Sie, um diesen Wert zu bestimmen, die vertikalen Sortierfelder (BY), Anzeigefelder und ROW-TOTAL-Felder von links nach rechts, einschließlich der NOPRINT-Felder. Ein Beispiel können Sie unter Eine Datenspalte identifizieren finden. Für ACROSSCOLUMN werden nur ACROSS-Felder gezählt.

Pn

Identifiziert eine Spalte über ihre Position im Report. Zählen Sie, um den Wert von n zu bestimmen, die vertikalen Sortierfelder (BY), Anzeigefelder und ROW-TOTAL-Felder von links nach rechts. Zählen Sie keine NOPRINT-Felder. Für ACROSSCOLUMN werden nur ACROSS-Felder gezählt.

Cn

Identifiziert eine Anzeigespalte über ihre Position im Report. Zählen Sie, um den Wert von n zu bestimmen, nur Anzeigefelder von links nach rechts, einschließlich der NOPRINT-Felder. Zählen Sie keine vertikalen Sortierfelder (BY) oder ROW-TOTAL-Felder.

Verwenden Sie C*, um alle Anzeigefelder auszuwählen.

Bn

Identifiziert eine vertikale Sortierspalte (BY) über ihre Position im Report. Zählen Sie, um den Wert von n zu bestimmen, nur vertikale Sortierfelder (BY) von links nach rechts, einschließlich NOPRINTs.

Verwenden Sie B*, um alle BY-Felder auszuwählen.

field

Identifiziert eine Spalte über ihren Feldnamen.

Verwenden Sie, wenn ein Feld mehr als einmal vorkommt, field(n), um ein bestimmtes Vorkommnis auszuwählen, oder field(*), um alle Vorkommnisse des Feldes auszuwählen.

ROWTOTAL

Identifiziert eine Spalte mit Zeilensummen, die durch ROW-TOTAL erzeugt wurden. Wenn ROWTOTAL mit ACROSS und mehreren Anzeigebefehlen verwendet wird, erzeugt es mehrfache Summenspalten. Verwenden Sie ROWTOTAL(n), um eine bestimmte Summenspalte auszuwählen. Verwenden Sie ROWTOTAL(field), um die Zeilensummenspalte für ein bestimmtes Feld auszuwählen.

Verwenden Sie ROWTOTAL(*), um alle Zeilensummenspalten im Report auszuwählen.

Hinweis: Innerhalb eines StyleSheets müssen alle Spalten auf gleiche Weise angegeben sein (entweder über den Feldnamen oder einen Verweis auf die Position).

Beispiel: Eine gesamte Spalte identifizieren

Folgendes zeigt, wie Sie eine gesamte Spalte in einem Report identifizieren können, die aus den Spaltendaten und dem Spaltentitel besteht. Die relevante StyleSheet-Deklaration ist in der Anfrage markiert.

Hinweis: Sie können als Alternative auch die Werte P1, B1 oder den Feldnamen (PRODNAME) für das COLUMN-Attribut in der StyleSheet-Deklaration verwenden, um dasselbe Ergebnis zu erhalten.

TABLE FILE CENTINV
HEADING
"Excess Stock Report"
SUM QTY_IN_STOCK  
BY PRODNAME
WHERE QTY_IN_STOCK GT 10000
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=REPORT, COLUMN=N1, STYLE=ITALIC,$ 
ENDSTYLE
END

Die Ausgabe ist:
Beispiel: Eine gesamte horizontale Spalte (ACROSS) identifizieren

Im Folgenden wird beschrieben, wie Sie eine horizontale Spalte (ACROSS) identifizieren. Wenn Sie ACROSSCOLUMN identifizieren und formatieren, werden alle Datenwerte, der Spaltentitel und alle horizontalen Sortierwerte (ACROSS), die mit dem Feld assoziiert sind, für jede Instanz der Spalte in der Reportausgabe formatiert. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert.

Hinweis: Sie können, um dieselben Resultate zu erzielen, alternativ auch die Werte P1 bzw. P2 für das ACROSSCOLUMN-Attribut verwenden. 

TABLE FILE CENTORD
SUM LINEPRICE LINE_COGS AS 'Line Cost of,Goods Sold'
BY PLANT AS 'Plant'
ACROSS YEAR
WHERE YEAR EQ 2000 OR 2001
HEADING
"Cost Analysis"
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=REPORT, ACROSSCOLUMN=N1, STYLE=ITALIC,$
TYPE=REPORT, ACROSSCOLUMN=N2, STYLE=BOLD,$  
ENDSTYLE
END

Die Ausgabe ist:
Nach oben
x
Syntax: Eine gesamte FML-Zeile (Financial Modeling Language) identifizieren
TYPE=REPORT, LABEL=label

Hierbei gilt:

Label

Ist ein explizites Zeilenlabel.

Beispiel: Eine gesamte FML-Zeile identifizieren

Im Folgenden wird beschrieben, wie Sie eine gesamte FML-Zeile, die aus dem Zeilenlabel und den Zeilendaten besteht, identifizieren. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert. 

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND' LABEL COH OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD OVER
1030 AS 'TIME DEPOSITS' LABEL TD OVER
BAR OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, LABEL=COH, STYLE=ITALIC, $
TYPE=REPORT, LABEL=DD, STYLE=ITALIC, $
TYPE=REPORT, LABEL=TD, STYLE=ITALIC, $ 
ENDSTYLE
END

Die Ausgabe ist:
Nach oben
x
Syntax: Eine gesamnte Summen- oder Zwischensummenzeile identifizieren
TYPE=type, [BY=sortcolumn]

Hierbei gilt:

type

Identifiziert eine Zwischensumme oder eine Summe. Wählen Sie aus den folgenden Optionen aus:

GRANDTOTAL ist eine Gesamtsumme (erzeugt durch COLUMN-TOTAL, SUBTOTAL, SUB-TOTAL, RECOMPUTE oder SUMMARIZE).

SUBTOTAL ist eine Zwischensumme (erzeugt durch SUBTOTAL, SUB-TOTAL, RECOMPUTE oder SUMMARIZE).

RECAP ist eine Zwischensummenberechnung (erzeugt durch ON sortfield RECAP oder ON sortfield COMPUTE).

BY

Falls es verschiedene Zwischensummenbefehle gibt, die jeweils mit einer anderen vertikalen Sortierspalte (BY) assoziiert sind, können Sie dadurch bestimmen, welche der Zwischensummenbefehle Sie formatieren möchten.

sortcolumn

Gibt die vertikale Sortierspalte (BY) an, die mit einem der Zwischensummenbefehle im Report assoziiert ist. Verwenden Sie den Feldnamen, um die Sortierspalte zu identifizieren.
Beispiel: Eine gesamte Summenzeile identifizieren

Im Folgenden wird beschrieben, wie Sie eine gesamte COLUMN-TOTAL-Zeile in einem StyleSheet identifizieren. Die relevante StyleSheet-Deklaration ist in der Anfrage markiert. 

TABLE FILE SALES
SUM RETURNS DAMAGED AND ROW-TOTAL AND COLUMN-TOTAL
BY PROD_CODE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $  
TYPE=GRANDTOTAL, STYLE=BOLD, SIZE=12, $ 
ENDSTYLE
END

Die Ausgabe ist:
Beispiel: Eine Zeilensumme identifizieren

Im Folgenden wird beschrieben, wie Sie eine Zeilensumme identifizieren. Die relevante StyleSheet-Deklaration ist in der Anfrage markiert. Beachten Sie, dass Sie, wenn Sie eine Instanz der Zeilensumme formatieren möchten, Ihrem StyleSheet eine WHEN-Anweisung hinzufügen können. Genaueres finden Sie unter Die Reportformatierung steuern. 

TABLE FILE SALES
SUM RETURNS DAMAGED AND ROW-TOTAL
BY PROD_CODE AS 'PRODUCT,CODE'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, COLUMN=ROWTOTAL, STYLE=BOLD, $ 
ENDSTYLE
END

Die Ausgabe ist:

WebFOCUS