Wenn Sie einen SET-Befehl verwenden, ist die Syntax

Am Anfang einer Anfrage:

SET COMPOUND = 'BYTOC [n]'

In einer Anfrage verwenden Sie die Syntax:

ON TABLE SET COMPOUND 'BYTOC [n]'

Hierbei gilt:

n

Steht für die Anzahl der vertikalen Sortierfelder (BY), die in das TOC aufgenommen werden sollen, beginnend mit dem ersten Sortierfeld (höchste Ebene) in der Anfrage. Die Hierarchie der Sortierfelder wird bestimmt durch die Reihenfolge, in der sie in der Anfrage angegeben werden.

Der Defaultwert ist 1, was bedeutet, dass nur das Sortierfeld der höchsten Ebene und seine Werte im TOC angezeigt werden.

Per Default wird ein Abschnittsumbruch nach dem ersten Sortierfeld (höchste Ebene) platziert, es sei denn es wurde in der Anfrage anders angegeben.

Hinweis: Einfache Anführungszeichen (') sollten verwendet werden, wenn BYTOC mit einer Zahl in einem SET-Befehl angegeben ist.

Wenn Sie einen PCHOLD-Befehl verwenden, ist die Syntax

ON TABLE PCHOLD FORMAT HTML BYTOC [n]

Hierbei gilt:

n

Steht für die Anzahl der vertikalen Sortierfelder (BY), die in das TOC aufgenommen werden sollen, beginnend mit dem ersten Sortierfeld (höchste Ebene) in der Anfrage. Die Hierarchie der Sortierfelder wird bestimmt durch die Reihenfolge, in der sie in der Anfrage angegeben werden.

Der Defaultwert ist 1, was bedeutet, dass nur das Sortierfeld der höchsten Ebene und seine Werte im TOC angezeigt werden.

Per Default wird ein Abschnittsumbruch nach dem ersten Sortierfeld (höchste Ebene) platziert, es sei denn es wurde in der Anfrage anders angegeben.

Hinweis: Einfache Anführungszeichen (') sollten nicht verwendet werden, wenn BYTOC in einem PCHOLD-Befehl mit einer Zahl angegeben wurde.

Die folgende Syntax aktiviert die Inhaltsverzeichnis-Struktursteuerung im StyleSheet:

TYPE=REPORT, TOC='n',$

oder

TYPE=REPORT, TOC='sortfieldname',$

Hierbei gilt:

n

Steht für die Anzahl der vertikalen Sortierfelder (BY), die in das TOC aufgenommen werden sollen, beginnend mit dem ersten Sortierfeld (höchste Ebene) in der Anfrage. Die Hierarchie der Sortierfelder in der Inhaltsverzeichnisstruktur wird bestimmt durch die Reihenfolge, in der sie in der Anfrage aufgelistet sind.

sortfieldname

Gibt die vertikale Sortierspalte (BY) über ihren Feldnamen an.

Hinweis: Einfache Anführungszeichen (') sollten verwendet werden, wenn TOC im StyleSheet angegeben ist.

Sie können ein HTML TOC als Symbol der oberen linken Ecke eines Reports hinzufügen, indem Sie der Anfrage einen SET-Befehl voranstellen, wie es in der folgenden Anfrage zu sehen ist. Das TOC listet Werte des ersten vertikalen Sortierfeldes (höchste Ebene) namens PLANT auf:

SET COMPOUND='BYTOC 2'

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Sie können ein HTML TOC auch als ein Symbol der oberen linken Ecke eines Reports hinzufügen, indem Sie in der Anfrage einen SET-Befehl verwenden.

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 2'
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Im folgenden Beispiel sehen Sie, wie Sie einen PCHOLD-Befehl verwenden können, um die Anfrage auszuführen:

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML BYTOC 2
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

In der folgenden Anfrage ist die Inhaltsverzeichnis-Struktursteuerung im Report-StyleSheet aktiviert:

TABLE FILE CENTORD 
HEADING
"SALES REPORT"
SUM LINEPRICE
BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, TOC='PRODCAT', $ 
ENDSTYLE
END

Hinweis: Einfache Anführungszeichen (') sollten verwendet werden, wenn TOC im StyleSheet angegeben ist.

Führen Sie den Report aus. Das TOC-Objekt wird in der oberen linken Ecke angezeigt.

Doppelklicken Sie auf das Inhaltsverzeichnis-Symbol, um die Inhaltsverzeichnis-Struktursteuerung zu öffnen. Dies zeigt die Werte der Sortierfelder im Report in der Reihenfolge an, in der sie angegeben wurden.

Hinweis: Sie können das TOC verschieben, indem Sie in den blauen Bereich oberhalb des Inhaltsverzeichnisses klicken und es dann in einen anderen Bereich verschieben oder indem Sie auf eine gewünschte Stelle innerhalb des Reports klicken.

Wenn Sie alle verfügbaren Felder (den gesamten Report) anzeigen möchten, klicken Sie auf die Option Gesamten Report anzeigen (Ein/Aus).

Tipp: Sie können außerdem das Design und den Stil des TOC-Objekts nach Belieben verändern, indem Sie die eine .css-Datei bearbeiten. Es wird empfohlen, dass Sie eine Sicherheitskopie erstellen, bevor Sie Änderungen vornehmen.

• Wenn Sie mit den lokalen Developer Studio-Projekten arbeiten, gehe zu

  \ibi\DevStudio##\ibi_apps\ibi_html\javaassist\intl\xx

  Hierbei gilt:

  ##

  Ist das Release des Developer Studio.

  xx

  Ist die Sprachabkürzung für die Version von Developer Studio.

• Navigieren Sie, wenn Sie in einer Self Service- oder Managed Reporting-Umgebung in Developer Studio oder einem Browser arbeiten, zum \ibi\WebFOCUS##\ibi_apps\ibi_html\javaassist\intl\xx-Verzeichnis, wobei ## das WebFOCUS-Release und xx die Sprachabkürzung ist. Für English (EN) ist der .css-Dateiname toc.css. Für alle anderen Sprachen ist der .css-Dateiname xxtoc.css, wobei xx die Sprachabkürzung ist.

Hinweis: Doppelklicken Sie, wenn Sie auf Inhaltsverzeichnis entfernen klicken und dann das TOC erneut betrachten möchten, einfach auf die gewünschte Stelle im Report.

Daten in einem TOC-Report werden basierend auf den Sortierfeldern in Abschnitte unterteilt. TOC-Reports zeigen jeweils nur einen Abschnitt an, um das Betrachten zu vereinfachen. Jeder Abschnitt enthält alle Werte für sein Sortierfeld. Sie können jeden Abschnitt mit einem Seitenumbruch anpassen. Per Default ist im ersten Sortierfeld (höchste Ebene) ein Seitenumbruch enthalten. Sie können Seitenumbrüche hinzufügen, um zusätzliche Abschnitte zu erstellen und Daten zu gruppieren, die auf Sortierfeldern der unteren Ebene basieren.

Fügen Sie, wenn Sie einer Kopfzeile ein TOC hinzufügen, zusätzliche Seitenumbrüche für jedes Sortierfeld der unteren Ebene hinzu. Dies stellt sicher, dass die sortierten Daten richtig gruppiert und angezeigt werden.

TABLE FILE SHORT
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
BY HOLDER
BY TYPE
ON HOLDER PAGE-BREAK
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 5'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
ENDSTYLE
END

Es wird jeweils ein Abschnitt des Reports angezeigt.

Der Report wird basierend auf dem Wert HOLDER in Abschnitte unterteilt. Sie sehen die Details jedes Wertes von HOLDER in einem einzigen Abschnitt.

Wenn Sie im TOC einen Wert auswählen, leuchtet dieser Wert auf (d.h. er wird grau markiert), um im Browserfenster Ihre Aufmerksamkeit auf ihn zu lenken. Wo das Aufleuchten angezeigt wird und ob und wie der Bildschirm Änderungen anzeigt, hängt von den folgenden Faktoren ab:

• Wenn Sie die Sortiergruppe der höchsten Ebene im TOC ändern (entweder in der Hierarchie über dem Report oder in der Dropdown-Liste in einer Kopf- oder Fußzeile), leuchtet der ausgewählte Wert im Browserfenster dreimal auf.
• Wenn Sie in der aktuellen Sortiergruppe der hohen Ebene einen Sortierwert der unteren Ebene ändern, leuchtet der Wert im Fenster dreimal auf. Dies ist so, da Sie sich noch immer in derselben Hauptsortiergruppe befinden, und somit innerhalb des selben Seitenumbruchs. Vom ausgewählten Wert im oberen Bereich des Fensters: Sie können dann schnell zu den zugehörigen Details scrollen.

  Wenn der ausgewählte Sortierwert der unteren Ebene auf dem Bildschirm bereits sichtbar ist, und der Rest des Reports auf den Bildschirm passt, leuchtet der Wert auf, aber es kann im Report nicht gescrollt werden.

Diese Anfrage fügt ein dynamisches HTML TOC als Symbol in der oberen linken Ecke des Reports hinzu, indem ein SET-Befehl in die Anfrage aufgenommen wird. Das Inhaltsverzeichnis zeigt eine Hierarchie, die aus vier Ebenen von Sortierfeldern besteht und mit der ersten (höchsten) Ebene anfängt. Die Sortierfelder sind: CONTINENT, REGION, COUNTRY und TYPE.

TABLE FILE SHORT
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
BY HOLDER
BY TYPE
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 5'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
ENDSTYLE
END

Die Ausgabe wird mit dem TOC-Objekt in der oberen linken Ecke angezeigt.

Doppelklicken Sie auf das Objekt, um das Inhaltsverzeichnis zu erweitern.

Wählen Sie Gesamten Report anzeigen. Scrollen Sie nach unten, um zu sehen, dass der Report Daten für alle Kontinente enthält.

Scrollen Sie wieder zum Anfang des Reportfensters und öffnen Sie das TOC erneut. Wählen Sie diesmal Amerika aus. Ihre Auswahl leuchtet auf, um sie auf dem Bildschirm zu markieren. Obwohl es den Anschein hat, dass die Anzeige des Reports sich nicht geändert hat, sehen Sie jetzt, wenn Sie nach unten scrollen, dass der Report nur Werte für Amerika enthält.

Scrollen Sie wieder nach oben und doppelklicken Sie an einer beliebigen Stelle im Report, um das TOC zu öffnen. Klicken Sie diesmal auf das +-Zeichen neben Amerika und klicken Sie dann auf das +-Zeichen neben Südamerika.

Die Feldwerte (Argentinien und Brasilien) sind im TOC aufgelistet. Dies sind Werte des Feldes COUNTRY. Wenn Sie den Feldnamen eines Wertes im TOC sehen möchten, fahren Sie mit dem Cursor über diesen Wert.

Wählen Sie Brasilien aus. Ihre Auswahl leuchtet auf und wird an den Anfang des Fensters verschoben, wie es nachfolgend zu sehen ist.

Scrollen Sie nach unten, um die Daten für Brasilien zu sehen.

Navigieren Sie weiter zu dem Detail, das Sie sehen möchten, indem Sie Werte auf einer beliebigen Sortierebene im TOC auswählen.

• Wenn Sie auf ein +-Zeichen klicken, wird das Feld erweitert und zeigt seine Werte im TOC an.
• Wenn Sie auf einen tatsächlichen Wert (Hyperlink) im TOC klicken, wird dieser Wert sofort markiert und, falls nötig, die Anzeige des Reports angepasst, so dass der Wert sichtbar ist.

  Das Inhaltsverzeichnis wird auf das Symbol minimiert, wenn Sie auf Inhaltsverzeichnis klicken. Danach können Sie scrollen, erweitern und eine weitere Auswahl treffen.

TYPE=heading, [subtype,] TOC=sort_column, $

TABLE FILE SHORT
HEADING
"Projected Returns Report for Region:  <REGION in Continent:  <CONTINENT "
" "
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=1, TOC=CONTINENT, $
ENDSTYLE
END

TABLE FILE SHORT
"Projected Return"
" "
"For:<CONTINENT For:<REGION "
SUM PROJECTED_RETURN
BY CONTINENT BY REGION BY COUNTRY BY TYPE
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON CONTINENT PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
TYPE=HEADING, LINE=1, STYLE=BOLD, $
TYPE=HEADING, LINE=3, OBJECT=FIELD, ITEM=1, TOC=B1,$
TYPE=HEADING, LINE=3, OBJECT=FIELD, ITEM=2, TOC=REGION,$
ENDSTYLE
END