FIELD[NAME] = field_name

where:

Note the following rules when using FIELDNAME:

• Alias. FIELDNAME has an alias of FIELD.
• Changes. In a FOCUS data source, if the INDEX attribute has been set to I (that is, if an index has been created for the field), you cannot change the field name without rebuilding the data source. You may change the name in all other situations.

In Master Files, field names and aliases can have a maximum length of 66 characters. However, before defining a field name longer than 48 characters, you must consider how the name will be referenced in requests.

Requests can qualify all referenced field names and aliases with file and/or segment names, a useful technique when duplicate field names exist across segments in a Master File or in joined data sources. But, although the qualifiers and qualification characters are valid only in requests, not in Master Files, the 66-character maximum includes any qualifiers and qualification characters used with the field name in requests. Therefore, if you define a 66-character name in the Master File, you cannot use qualifiers with the name in a request.

The maximum of 66 characters includes the name of the field or alias, plus each field qualifier (Master File name and segment name), plus a qualification character (usually a period) for each qualifier. You may use a unique truncation of a 66-character name with a qualifier.

Temporary field names may also contain up to 66 characters. The names of text fields and indexed fields in FOCUS Master Files are limited to 12 characters. Text fields and indexed fields in XFOCUS Master Files are not subject to this 12 character limitation. However, the aliases for text and indexed fields may be up to 66 characters. Field names up to 66 characters appear as column titles in TABLE reports if there is no TITLE attribute or AS phrase.

The default value for the SET FIELDNAME command, SET FIELDNAME=NEW, activates long and qualified field names. The syntax is described in the Developing Reporting Applications manual.

Field names are considered duplicates when you can reference two or more fields with the same field name or alias. Duplication may occur:

• If a name appears multiple times within a Master File.
• In a JOIN between two or more Master Files, or in a recursive JOIN.
• If you issue a COMBINE and do not specify a prefix.

Duplicate fields (those having the same field name and alias) are not allowed in the same segment. The second occurrence is never accessed, and the following message is generated when you issue CHECK and CREATE FILE:

(FOC1829) WARNING. FIELDNAME IS NOT UNIQUE WITHIN A SEGMENT: fieldname

Duplicate field names may exist across segments in a Master File. To retrieve such a field, you must qualify its name with the segment name in a request. If a field that appears multiple times in a Master File is not qualified in a request, the first field encountered in the Master File is the one retrieved.

Note: If a Master File includes duplicate field names for real fields and/or virtual fields, the following logic is used when retrieving a field:

• If only virtual fields are duplicated, the last virtual field is retrieved.
• If only real fields are duplicated, the first real field is retrieved.
• If a Master File has both a real field and one or more virtual fields with the same name, the last virtual field is retrieved.
• If a field defined outside of a Master File has the same name as a virtual or real field in a Master File, the last field defined outside of the Master File is retrieved.

Reports can include qualified names as column titles. The SET QUALTITLES command, discussed in the Developing Reporting Applications manual, determines whether reports display qualified column titles for duplicate field names. With SET QUALTITLES=ON, they display qualified column titles for duplicate field names even when the request itself does not specify qualified names. The default value, OFF, disables qualified column titles.

The following rules are used to evaluate qualified field names:

• The maximum field name qualification is filename.segname.fieldname. For example:

  TABLE FILE EMPLOYEE 
  PRINT EMPLOYEE.EMPINFO.EMP_ID 
  END

  includes EMP_ID as a fully qualified field. The file name, EMPLOYEE, and the segment name, EMPINFO, are the field qualifiers.

  Qualifier names can also be duplicated. For example:

  FILENAME=CAR, SUFFIX=FOC 
    SEGNAME=ORIGIN, SEGTYPE=S1 
        FIELDNAME=COUNTRY, COUNTRY, A10, $    
    SEGNAME=COMP, SEGTYPE=S1, PARENT=ORIGIN 
        FIELDNAME=CAR, CARS, A16, $  
          .   
          . 
          .  
  TABLE FILE CAR 
  PRINT CAR.COMP.CAR 
  END

  This request prints the field with alias CARS. Both the file name and field name are CAR.

  A field name can be qualified with a single qualifier, either its file name or its segment name. For example:

  FILENAME=CAR, SUFFIX=FOC 
     SEGNAME=ORIGIN, SEGTYPE=S1 
        FIELDNAME=COUNTRY, COUNTRY, A10, $ 
     SEGNAME=COMP, SEGTYPE=S1, PARENT=ORIGIN 
        FIELDNAME=CAR, CARS, A16, $  
          . 
          . 
          .  
  TABLE FILE CAR 
  PRINT COMP.CAR AND CAR.CAR 
  END

  This request prints the field with alias CARS twice.

  When there is a single qualifier, segment name takes precedence over file name. Therefore, if the file name and segment name are the same, the field qualified by the segment name is retrieved.

• If a field name begins with characters that are the same as the name of a prefix operator, it may be unclear whether a request is referencing that field name or a second field name prefixed with the operator. The value of the first field is retrieved, not the value calculated by applying the prefix operator to the second field. In the next example, there is a field whose unqualified field name is CNT.COUNTRY and another whose field name is COUNTRY:

  FILENAME=CAR, SUFFIX=FOC 
     SEGNAME=ORIGIN, SEGTYPE=S1 
        FIELDNAME=CNT.COUNTRY, ACNTRY, A10, $ 
        FIELDNAME=COUNTRY, BCNTRY, A10, $ 
  TABLE FILE CAR 
  SUM CNT.COUNTRY 
  END

  In this request, the string CNT.COUNTRY is interpreted as a reference to the field named CNT.COUNTRY, not as a reference to the prefix operator CNT. applied to the field named COUNTRY. Therefore, the request sums the field whose alias is ACNTRY. Although the field name CNT.COUNTRY contains a period as one of its characters, it is an unqualified field name. It is not a qualified name or a prefix operator acting on a field name, neither of which is allowed in a Master File. The request does not count instances of the field whose alias is BCNTRY.

• If a Master File has either a file name or segment name that is the same as a prefix operator, the value of the field within the segment is retrieved in requests, not the value calculated by applying the prefix operator to the field.

  For example:

  FILENAME=CAR, SUFFIX=FOC 
     SEGNAME=ORIGIN, SEGTYPE=S1 
        FIELDNAME=COUNTRY, COUNTRY, A10, $ 
     SEGNAME=PCT, SEGTYPE=S1, PARENT=ORIGIN 
        FIELDNAME=CAR, CARS, I2, $ 
   TABLE FILE CAR 
  SUM PCT.CAR PCT.PCT.CAR 
  BY COUNTRY 
  END

  This request sums the field with alias CARS first, and then the percent of CARS by COUNTRY.

• When a qualified field name can be evaluated as a choice between two levels of qualification, the field name with the higher level of qualification takes precedence.

  In the following example, the choice is between an unqualified field name (the field named ORIGIN.COUNTRY in the ORIGIN segment) and a field name with segment name qualification (the field named COUNTRY in the ORIGIN segment). The field with segment name qualification is retrieved:

  FILENAME=CAR, SUFFIX=FOC 
     SEGNAME=ORIGIN, SEGTYPE=S1 
        FIELDNAME=ORIGIN.COUNTRY, OCNTRY, A10, $ 
        FIELDNAME=COUNTRY, CNTRY, A10, $ 
  TABLE FILE CAR 
  PRINT ORIGIN.COUNTRY 
  END

  This request prints the field with alias CNTRY. To retrieve the field with alias OCNTRY, qualify its field name, ORIGIN.COUNTRY, with its segment name, ORIGIN:

  PRINT ORIGIN.ORIGIN.COUNTRY

• When a qualified field name can be evaluated as a choice between two field names with the same level of qualification, the field with the shortest basic field name length is retrieved. For example:

  FILENAME=CAR, SUFFIX=FOC
     SEGNAME=CAR, SEGTYPE=S1
        FIELDNAME=CAR.CAR, CAR1, A10, $
     SEGNAME=CAR.CAR, SEGTYPE=S1, PARENT=CAR
        FIELDNAME=CAR, CAR2, A10, $
  TABLE FILE CAR
  PRINT CAR.CAR.CAR
  END

  In this example, it is unclear if you intend CAR.CAR.CAR to refer to the field named CAR.CAR in the CAR segment, or the field named CAR in the CAR.CAR segment. (In either case, the name CAR.CAR is an unqualified name that contains a period, not a qualified name. Qualified names are not permitted in Master Files.)

  No matter what the intention, the qualified field name is exactly the same and there is no obvious choice between levels of qualification.

  Since the field with alias CAR2 has the shortest basic field name length, CAR2 is printed. This is different from the prior example, where the choice is between two levels of qualification. To retrieve the CAR1 field, you must specify its alias.