x

Quando si distribuiscono prospetti che contengono collegamenti dinamici o collegamenti a prospetti WebFOCUS (drill down), il contesto dell'URL deve essere completamente qualificato e l'utente deve avere connettività al server web o delle applicazioni, per poter eseguire il prospetto o per accedere al contenuto del collegamento. È possibile qualificare completamente il collegamento dinamico utilizzando i comandi SET FOCHTMLURL o SET BASEURL. Utilizzare SET FOCHTMLURL per accedere alle risorse che risiedono nell'alias ibi_apps/ibi_html. Per le procedure di non Managed Reporting, utilizzare SET BASEURL per specificare una posizione predefinita per un URL relativo che fa riferimento a documenti (file ed immagini HTML) creati da WebFOCUS. È possibile qualificare completamente il drill down utilizzando il comando SET FOCEXURL.

Inizio pagina

Esempio: Utilizzo di SET FOCEXURL per eseguire il drill down in una procedura Managed Reporting di WebFOCUS

Per eseguire il drill down su una procedura di WebFOCUS Reporting Server, la procedura originale che si sta pianificando deve includere il seguente comando:

SET FOCEXURL=http://hostname[:port]/wf_context_root/WFServlet;

dove:

hostname[:porto]

Si tratta del nome host e del numero di porta opzionale del server web o delle applicazioni sui cui è stato installato WebFOCUS Client.

wf_context_root

Si tratta del root di contesto, personalizzato in base al sito, dell'applicazione web di WebFOCUS distribuita sul proprio server delle applicazioni. Il valore predefinito è ibi_apps.

Il seguente illustra un esempio del comando FOCEXURL in un FEX.

-* FEX that is scheduled and distributed to the Report Library
-* Set FOCEXURL value for navigation back to WF Client and MR context
-* for execution of drill down request. Must be coded using
-* concatenation of so that WF describe (auto prompting) is not invoked 
-* and also for character encoding within URL to be done correctly.
-* Protocol, host and port to WF client. 
-* Do not use localhost for the host value!
-SET &FOCEXURL='http://host:port';
-*
-* Call to WF Client.  /ibi_apps is the default URL context 
-* but can be customized
-SET &FOCEXURL=&FOCEXURL | '/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps'  '&';
-* If report contains a drilldown the next set of lines are also needed.
-* Set WF Reporting Server to run request on
-SET &FOCEXURL=&FOCEXURL | 'IBIC_server=EDASERVE' | '&';
-*
-* Set whether the message viewer feature is ON or OFF.
-* When message viewer feature is ON the browser window displaying the 
-* report will have multiple frames. The top frame displays 
-* the report and the bottom frame displays any messages returned 
-* from the WF Server from the report execution.
-* Most often utilized during report development or to debug a problem.
-SET &FOCEXURL=&FOCEXURL | 'IBIWF_msgviewer=OFF' | '&';
-*
-* IBIMR_drill tells WF client subsequent request is a drill down and the 
-* information after X, is the HREF of the MR domain that the 
-* drill down FEX
-* is located in. In this example 'salesrpt' is the internal 
-* domain directory and salesrpt.htm is the HTML file 
-* containing the metadata information for the contents
-* within the salesrpt domain.
-SET &FOCEXURL=&FOCEXURL | 'IBIMR_drill=X,salesrpt/salesrpt.htm'| '&';
-*
-* SET environmental variable FOCEXURL

SET FOCEXURL='&FOCEXURL'
-*
TABLE FILE CAR
SUM CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
ON TABLE SET STYLE *
TYPE=DATA, COLUMN=CAR.ORIGIN.COUNTRY,
 FOCEXEC=salesrpt/app/carmodel.fex,
 $
ENDSTYLE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END

Il seguente è un esempio del FEX drill down the risiede in Managed Reporting.

-* HTML Tool
-* Created by Report Assistant
-* FF Line do not change this line! Field Name
-* FF Line do not change this line! Alias
-* FF Line do not change this line! Format
-* FF Line do not change this line! Segment
-* FF Line do not change this line! displayTree=0
TABLE FILE CAR
SUM CAR.SPECS.MPG
CAR.SPECS.RPM
CAR.BODY.SEATS
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
BY CAR.BODY.BODYTYPE
ON TABLE SET HTMLCSS ON
ON TABLE NOTOTAL
END
-* End Report Assistant