LOOKUP(field);

où :

field

est le nom du champ à récupérer dans le fichier de référence croisée. Si le nom du champ existe déjà dans la source de données hôte, vous devez le spécifier ici. N'introduisez pas d'espace entre LOOKUP et la paranthèse de gauche.

Remarque : LOOKUP n'utilise pas d'argument de sortie.

Vous pouvez utiliser une valeur de champ dans une instance de segment hôte pour rechercher un segment de référence croisée. Réalisez une des actions suivantes :

• Dans la commande MATCH qui sélectionne l'instance du segment hôte, activez le champ hôte avec la commande ACTIVATE.
• Est la même commande MATCH, code LOOKUP après la commande ACTIVATE.

Cette requête affiche l'ID de l'employé, date de l'augmentation de salaire, nom de l'employé et la position de l'employé après que l'augmentation ait été accordée :

• L'ID de l'employé et le nom (EMP_ID) sont dans le segment racine.
• La date d'augmentation (DAT_INC) est dans le segment hôte décroissant.
• La position du travail se trouve dans le segment de référence croisée.
• Le champ partagé est JOBCODE. Vous n'entrez jamais de code de travail, les valeurs sont stockées dans la source de données.

La requête est :

MODIFY FILE EMPLOYEE
PROMPT EMP_ID DAT_INC
MATCH EMP_ID
   ON NOMATCH REJECT
   ON MATCH CONTINUE
MATCH DAT_INC
   ON NOMATCH REJECT
   ON MATCH ACTIVATE JOBCODE
   ON MATCH COMPUTE
      RTN = LOOKUP(JOB_DESC);
   ON MATCH TYPE
      "EMPLOYEE ID:        <EMP_ID"
      "DATE INCREASE:      <DAT_INC"
      "NAME:               <D.FIRST_NAME <D.LAST_NAME"
      "POSITION:           <JOB_DESC"
DATA

Exemple d'exécution :

1. La requête vous invite à saisir l'ID de l'employé et la date d'augmentation. Entrez l'ID de l'employé 071382660 et la date 820101 (1er Janvier 1982).
2. La requête situe l'instance qui contient l'ID 071382660, puis situe l'instance enfant qui contient la date de l'augmentation 820101.
3. Cette instance enfant contient le code de travail A07. La commande ACTIVATE rend cette valeur disponible à LOOKUP.
4. LOOKUP situe le code de la tâche A07 dans le segment de référence croisée. Elle renvoie un 1, la variable RTN et récupère la description SECRETARY du travail correspondant.
5. La commande TYPE affiche les valeurs :

   EMPLOYEE ID:          071382660
   DATE INCREASE:        82/01/01
   NAME:                 ALFRED STEVENS
   POSITION:             SECRETARY

Les champs récupérés par LOOKUP ne nécessitent pas le préfixe D. FOCUS traite les valeurs du champ comme valeurs de transaction.

Vous devrez possiblement activer le champ hôte si vous utilisez LOOKUP dans une commande NEXT. La requête affiche la dernière position tenue par un employé :

MODIFY FILE EMPLOYEE
PROMPT EMP_ID
MATCH EMP_ID
   ON NOMATCH REJECT
   ON MATCH CONTINUE
NEXT DAT_INC
   ON NONEXT REJECT
   ON NEXT ACTIVATE JOBCODE
   ON NEXT COMPUTE
      RTN = LOOKUP(JOB_DESC);
   ON MATCH TYPE
      "EMPLOYEE ID:      <EMP_ID"
      "DATE OF POSITION: <DAT_INC"
      "NAME:             <D.FIRST_NAME <D.LAST_NAME"
      "POSITION:         <JOB_DESC"
DATA

Lorsque vous utilisez LOOKUP, rejetez les transactions qui contiennent des valeurs pour lesquelles il n'existe aucune instance dans le segment de référence croisée. Pour y parvenir, placez la fonction dans une commande VALIDATE. Si la fonction ne peut pas situer l'instance dans le segment de référence croisée, elle définit la valeur de la variable de renvoi à 0, ce qui entraîne le rejet de la transaction par la requête.

La requête suivante met à jour les heures de cours d'un employé (ED_HRS). Si l'employé s'est inscrit en cours le 1er Janvier 1982 ou après, la requête augmente le nombre d'heures de cours par 10%. Les dates d'inscriptions sont stockées dans un segment de référence croisée (champ DATE_ATTEND). Le champ partagé est l'ID de l'employé.

La requête est :

MODIFY FILE EMPLOYEE
PROMPT EMP_ID ED_HRS
VALIDATE
   TEST_DATE = LOOKUP(DATE_ENROLL);
COMPUTE
   ED_HRS = IF DATE_ENROLL GE 820101 THEN ED_HRS * 1.1
         ELSE ED_HRS;
MATCH EMP_ID
   ON MATCH UPDATE ED_HRS 
    ON NOMATCH REJECT
DATA

Si l'enregistrement d'un employé est introuvable dans le segment de référence croisée, cet employé ne s'est jamais inscrit pour un cours. La transaction est rejetée comme erreur.

Si la fonction LOOKUP ne peut pas situer une valeur du champ hôte dans le segment de référence croisée, utilisez la syntaxe avancée pour situer la valeur de champ supérieure ou inférieure suivante de référence croisée dans le segment de référence croisée.

Pour utiliser cette fonction, créez l'index avec le paramètre INDEX défini à NEW (le schéma de l'arborescence binaire). Pour déterminer le type de l'index utilisé par une source de données, entrez la commande FDT.

COMPUTE
LOOKUP(field action);