Création de liens entre des pages de rapport

Comment :

A l'aide d'une feuille de style, vous pouvez insérer un ou plusieurs hyperliens de navigation dans un rapport HTML multipages. Grâce à cette fonction, vous pouvez lier très facilement les pages consécutives d'un rapport sans avoir à créer de liens hypertexte pour chaque page.

Vous pouvez définir tout composant de rapport comme hyperlien.
Haut de page
x
Syntaxe : Lier des pages de rapport

Utilisez la syntaxe suivante dans un rapport HTML 

URL=#_destination, $

où :

destination
indique une des choses suivantes :

#_next vous déplace vers le haut de la prochaine page de rapport.

#_previous vous déplace vers le haut de la page de rapport précédente.

#_top vous déplace vers le haut de la page de rapport actuelle.

#_start vous déplace vers la première page de rapport.

#_end vous déplace vers la dernière page de rapport.

Remarque : pour utiliser ces destinations dans des applications libre-service, la commande suivante doit être lancée au début de la procédure FOCEXEC :

SET BASEURL=''
Exemple : Création de liens entre les pages de rapport via des images d'en-tête

Cette requête affiche deux images dans l'en-tête d'un rapport long. Elle crée un lien entre BULLET.GIF et la prochaine page du rapport, et entre GOBACK.GIF et la page précédante du rapport. 

TABLE FILE GGORDER
ON TABLE SUBHEAD
"COFFEE GRINDER SALES BY STORE"
" "
HEADING
"Next page or previous page."
PRINT QUANTITY AS 'Ordered Units' BY STORE_CODE BY PRODUCT NOPRINT
BY ORDER_NUMBER
WHERE PRODUCT EQ 'Coffee Grinder'
ON STORE_CODE PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TABHEADING, STYLE=BOLD,$ 
TYPE=HEADING, IMAGE=/IBI_APPS/IBI_HTML/GGDEMO/BULLET, URL=#_next, 
IMAGEALIGN=LEFT,$
TYPE=HEADING, IMAGE=/IBI_APPs/IBI_HTML/GGDEMO/GOBACK, URL=#_previous, 
IMAGEALIGN=RIGHT,$ 
ENDSTYLE
END

L'image s'affiche dans chaque en-tête de page.

Cliquez sur l'image sur la gauche de la page 1 afin d'afficher la page 2 :

Cliquez sur l'image « go back » sur la page 2 afin de réafficher la page 1.

Pour en savoir plus sur l'inclusion et le positionnement des images dans un rapport, consultez Mise en page de la page de rapport.

Notez que si cette procédure fait partie d'une application libre-service, la commande suivante doit être lancée au début de la procédure :

SET BASEURL = ''
Exemple : Liaison de pages avec des numéros de page et des éléments d'en-tête

Cette requête crée des hyperliens du numéro de page à la prochaine page du rapport, et du texte de l'en-tête de la page, qui s'affiche en haut de chaque page de rapport, à la page précédente ou bien à la première page. 

TABLE FILE GGORDER
ON TABLE SUBHEAD
"COFFEE GRINDER SALES BY STORE"
" "
HEADING
"return to previous page"
"return to beginning"
PRINT QUANTITY AS 'Ordered Units' BY STORE_CODE BY PRODUCT NOPRINT
BY ORDER_NUMBER
WHERE PRODUCT EQ 'Coffee Grinder'
ON STORE_CODE PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TABHEADING, STYLE=BOLD,$
TYPE=PAGENUM, URL=#_next, $ 
TYPE=HEADING, LINE=1, URL=#_previous, $
TYPE=HEADING, LINE=2, URL=#_start, $
ENDSTYLE
END

La première page s'affiche ainsi :

Cliquez trois fois sur le numéro de page pour vous déplacer vers PAGE 4.

Cliquez sur previous page pour revenir à la page 3. Cliquez sur return to beginning pour vous déplacer directement vers la page 1.

Notez que si cette procédure fait partie d'une application libre-service, la commande suivante doit être lancée au début de la procédure :

SET BASEURL = ''

WebFOCUS