Création de paramètres

Si votre rapport de zoom avant dépend d'une valeur de données particulière dans le rapport de base, vous devez créer un paramètre (ou paramètres) qui peut (peuvent) passr une ou plusieurs valeurs au rapport auquel vous faîtes un zoom avant.

Les paramètres sont utiles lorsque vous souhaitez créer un lien dynamique. Par exemple, votre premier rapport est un récapitulatif qui liste le nombre total de produits commandés par une entreprise à une date spécifique. Vous pouvez faire un zoom avant à partir d'un produit particulier du rapport à un rapport plus détaillé qui montre le nom du vendeur du produit et le nombre de produits individuels commandés par numéro de commande. En utilisant un lien dynamique, vous ne créez qu'un rapport de zoom avant qui utilise la valeur lui envoyée par le premier rapport afin de déterminer les informations à afficher, au lieu de plusieurs rapports statiques.

Vous pouvez créer plusieurs paramètres. La chaîne de paramètres entière doit figurer entre paranthèses, qui doivent être séparés les uns des autres par un espace vide, et ne peut pas dépasser 2 400 caractèrs.

Vous pouvez utiliser n'importe laquelle des méthodes suivantes pour créer des paramètres dans votre déclaration de feuille de style. Vous pouvez spécifier :

Syntaxe : Créer des paramètres

parameter=value

où :

paramètre

indique le nom de la variable dans la procédure liée.

Remarque : pour contourner d'éventuels conflits, vous ne devez pas commencer les noms de variables par Date, IBI ou WF, car les variables commençant par ces valeurs sont réservées pour l'utilisation par Information Builders. Les variables commençant par ces valeurs sont réservées pour l'utilisation par Information Builders.

value

identifie la valeur à passer. Les valeurs peuvent être une des suivantes :

'constant_value' identifie une valeur actuelle à passer. La valeur doit figurer entre guillemets simples.

field identifie le champ du rapport dont les valeurs doivent être passées à la procédure. Vous pouvez identifier le champ en utilisant soit le nom de champ soit la position du champ. Pour en savoir plus au sujet de la position du champ, consultez Désignation de composants de rapport dans la syntaxe de feuille de style WebFOCUS.

'&variable' identifie une variable amper dont la valeur doit être passée à la procédure. Le nom de la variable amper doit être entre guillemets simples. Vous ne pouvez utiliser les variables amper que dans les feuilles de style intégrées.

Remarque : une variable amper sert normalement à passer une valeur constante. Si la variable amper correspond à un champ alphanumérique, cette première doit figurer entre guillemets simples, par exemple :

'&ABC'.

La chaîne des noms et valeurs entière doit être entre parenthèses. Toutes les paires spécifiant parameter =value doivent être séparées par un espace vide. Vous pouvez inclure plusieurs paramètres dans votre requête mais la chaîne entière ne peut pas dépasser 2 400 caractères.

Remarque : si le rapport de zoom en profondeur comprend une déclaration -DEFAULTS spécifiant la même variable amper passée du rapport principal comme valeur par défaut, la valeur de cette première remplace la déclaration -DEFAULTS dans la procédure cible.

Haut de page

Exemple : Création de paramètres en spécifiant une valeur constante

L'exemple ci-après illustre la façon de créer des paramètres en spécifiant une valeur constante. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête.

Rapport principal :

SET LOOKGRAPH BAR
SET 3D=OFF
GRAPH FILE SHORT
HEADING
"Sum of Balance Across Short Date"
"Click Any Bar For a Report on Projected Returns Since June 29, 1998 "
SUM BALANCE
ACROSS SHORT_DATE
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=N1,FOCEXEC=PROJRET(Short_Date='06291998'),$ 
ENDSTYLE
END

Rapport de zoom avant (PROJRET) :

TABLE FILE SHORT
HEADING
"Projected Returns Since June 29, 1998 "
SUM PROJECTED_RETURN
BY SHORT_DATE
BY REGION
WHERE SHORT_DATE GE '&Short_Date';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Voici la sortie du rapport principal :

Lorsque vous cliquez sur une barre, la sortie est :

Projected Returns Since June 29, 1998

Date of		Projected
Statement	Region	Annualized
		Return
06/29/1998	CENTRAL AMERICA	1.360
	EASTERN EUROPE	2.300
	FAR EAST	1.300
	MIDDLE EAST	1.140
	NORTH AMERICA	1.780
	SOUTH AMERICA	1.200
	WESTERN EUROPE	1.140
06/30/1998	CENTRAL AMERICA	1.360
	EASTERN EUROPE	2.350
	FAR EAST	1.300
	MIDDLE EAST	1.140
	NORTH AMERICA	1.780
	SOUTH AMERICA	1.200
	WESTERN EUROPE	1.140
07/01/1998	CENTRAL AMERICA	1.360
	EASTERN EUROPE	2.300
	FAR EAST	1.300
	MIDDLE EAST	1.140
	NORTH AMERICA	1.780
	SOUTH AMERICA	1.200
	WESTERN EUROPE	1.140

Haut de page

Exemple : Création de paramètres en spécifiant un champ

L'exemple ci-après illustre la façon de créer un paramètre en spécifiant un champ, dans ce cas CATEGORY. Le rapport de zoom avant SALES (le rapport lié au rapport principal) met le champ CATEGORY égal à &TYPE. Dans le rapport de base, TYPE est mis à égaler le champ CATEGORY.

Lorsque vous exécutez le rapport, les valeurs du champ CATEGORY (café, nourriture, cadeaux) sont liées à un rapport qui contient les ventilations de produit et régionales de la valeur respective.

Rapport principal :

TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY
HEADING 
"* Click category to see product and regional breakdowns."
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=DATA, COLUMN=CATEGORY, FOCEXEC=SALES (TYPE=CATEGORY), $ 
ENDSTYLE
FOOTING
"This report was created on &DATE ."
END

Rapport de zoom avant (SALES) :

TABLE FILE GGSALES
ON TABLE SET PAGE-NUM OFF
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
ACROSS REGION
WHERE CATEGORY = '&TYPE';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Voici la sortie du rapport principal :

Lorsque vous cliquez sur Coffee, la ventilation de produit et régionale pour « Coffee » s'affiche :

Haut de page

Exemple : Création de paramètres en spécifiant une variable amper

La requête suivante illustre la façon de créer un paramètre en spécifiant une variable amper. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête.

Rapport principal :

SET3D=OFF
GRAPH FILE EMPLOYEE
HEADING
"Salary Report Per Employee ID"
"Click A Bar For The List of Employees in the '&DEPARTMENT' Department"
SUM SALARY
ACROSS EMP_ID AS 'EMPLOYEE ID'
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=SALARY,
FOCEXEC=EMPBYDEP(DEPARTMENT='&DEPARTMENT'), $ 
ENDSTYLE
END

Rapport lié (EMPBYDEP) :

TABLE FILE EMPLOYEE
HEADING
"List Of Employees in the '&DEPARTMENT' Department "
PRINT FIRST_NAME LAST_NAME
BY DEPARTMENT
WHERE DEPARTMENT EQ '&DEPARTMENT';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Lorsque le rapport principal est exécuté, l'invite suivante s'affiche :

Saisissez MIS puis cliquez sur Envoyer. La sortie est :

Lorsque vous cliquez sur une barre dans le graphique, la sortie est :

List Of Employees in the 'MIS' Department
DEPARTMENT	FIRST NAME	LAST NAME
MIS	MARY	SMITH
	DIANE	JONES
	JOHN	MCCOY
	ROSEMARIE	BLACKWOOD
	MARY	GREENSPAN
	BARBARA	CROSS

Haut de page

Exemple : Utilisation de plusieurs paramètres

Lorsque vous utilisez des paramètres multiples, la chaîne entière doit être entre paranthèses et séparée des autres par des espaces. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête.

Rapport principal :

SET 3D=OFF
GRAPH FILE EMPLOYEE
SUM CURR_SAL
ACROSS DEPARTMENT
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=CURR_SAL,
FOCEXEC=REPORT2 (DEPARTMENT='&DEPARTMENT' LAST_NAME='SMITH'), $ 
ENDSTYLE
END

Rapport de zoom avant (REPORT2) :

TABLE FILE EMPLOYEE
PRINT SALARY
BY DEPARTMENT
BY FIRST_NAME
BY LAST_NAME
WHERE DEPARTMENT EQ '&DEPARTMENT'
WHERE LAST_NAME EQ '&LAST_NAME'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Lorsque le rapport principal est exécuté, l'invite suivante s'affiche :

Saisissez MIS puis cliquez sur Envoyer. La sortie est :

Lorsque vous cliquez sur la barre MIS, la sortie est :

DEPARTMENT	FIRST NAME	LAST NAME	SALARY
MIS	MARY	SMITH	$13,200.00