BAR [AS 'character'] OVER

où :

character

Est soit un trait d'union (-) soit un signe égal (=). Saisissez le caractère entre guillemets simples. Le caractère par défaut est le trait d'union (-).

Cet exemple utilise le caractère de soulignement par défaut (_) .

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR                          OVER 
RECAP TOTCASH = R1 + R2 + R3;
END

La sortie est montrée comme ce qui suit :

                 AMOUNT
                 ------
CASH ON HAND      8,784
DEMAND DEPOSITS   4,494
TIME DEPOSITS     7,961
                 ------
TOTCASH          21,239

Notez que les phrases BAR ... OVER ne soulignent que la colonne contenant le champ d'affichage.

Saisissez la syntaxe suivante dans la requête FML à la place d'une valeur de balise :

PAGE-BREAK OVER

Dans cet exemple, un saut de page est inséré après les deux premières commandes RECAP pour souligner chaque calcul.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'                                    OVER
1020 AS 'DEMAND DEPOSITS'                                 OVER
1030 AS 'TIME DEPOSITS'                                   OVER
BAR                                                       OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH'             OVER 
PAGE-BREAK                                                OVER 
1100 AS 'ACCOUNTS RECEIVABLE' LABEL RECEIVE               OVER
1200 AS 'INVENTORY'  LABEL INVENT                         OVER
BAR                                                       OVER
RECAP TOTASSET = RECEIVE + INVENT; AS 'TOTAL ASSETS'      OVER 
PAGE-BREAK                                                OVER 
RECAP TOTAL = TOTCASH + TOTASSET;
END

La sortie est montrée comme ce qui suit :

TYPE=type, [COLUMN=column] [LABEL={Rn|label}], format_def, $

où :

type

Identifie le composant que vous souhaitez formater. Voici les valeurs valables :

REPORT indique une ligne avec le label spécifié.

DATA indique une ligne avec le label spécifié, qui contient des valeurs de données fournies par l'utilisateur.

FREETEXT indique une ligne de texte libre ou une ligne blanche avec l'étiquette spécifiée.

UNDERLINE indique des soulignements générés par BAR. Le formatage d'un soulignement est supporté pour PDF et PS, mais non pour les rapports HTML.

COLUMN=

Identifie une colonne particulière. Vous pouvez identifier une colonne en fonction de son nom ou sa position dans une ligne.

LABEL

Est le facteur qui contrôle l'identification et le formatage d'une ligne FML.

Notez que le label s'emploie pour identifier une ligne pour le calcul ou le formatage. L'étiquette pour une ligne TAG ou DATA ne s'affiche jamais dans la sortie de rapport. Elle s'emploie uniquement pour identifier des lignes au sein du code FML. Pour une ligne RECAP, le nom de la valeur calculée sert d'étiquette. Il s'affiche dans le rapport, à moins qu'un autre titre soit spécifié.

label est un label de ligne explicite que vous pouvez attribuer pour identifier une ligne plus clairement.

format_def

est la définition de formatage, telle que FONT, SIZE, STYLE et COLOR. Consultez Formatage d'un rapport FML.

Remarque : pour formater une cellule, identifiez la cellule comme l'intersection d'une colonne et d'une ligne en utilisant COLUMN=... et LABEL= ... dans la même déclaration de feuille de style.

Ce qui suit illustre la façon d'identifier et formater une ligne FML entière, qui se compose du label de ligne et des données de ligne. L'attribut LABEL dans la feuille de style identifie les trois lignes TAG, qui sont stylisées ici en italiques.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND' LABEL COH OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD OVER
1030 AS 'TIME DEPOSITS' LABEL TD OVER
BAR OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = COH, STYLE = ITALIC, $ 
TYPE = REPORT, LABEL = DD,  STYLE = ITALIC, $ 
TYPE = REPORT, LABEL = TD,  STYLE = ITALIC, $ 
ENDSTYLE
END

La sortie est montrée ci-dessous.

Cette requête applique des caractères gras au titre de ligne personnalisé, et aux données connexes dans la colonne AMOUNT. La feuille de style utilise l'étiquette explicite CA pour identifier le composant à formater :

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
10$$ AS 'CASH'                LABEL CA   OVER
1100 AS 'ACCOUNTS RECEIVABLE' LABEL AR   OVER
1200 AS 'INVENTORY'           LABEL INV  OVER
RECAP CURASST/I5C = CA + AR + INV;
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = CA, STYLE = BOLD, $ 
ENDSTYLE
END

La sortie est montrée ci-dessous.

Cette requête génère un rapport dans lequel la veleur de données du champ AMOUNT s'affiche en caractères gras dans la colonne CASH. Cependant, le titre de ligne CASH ne s'affiche pas en caractères gras. Cela se fait en indiquant la cellule dans la déclaration de feuille de style : dans ce cas, c'est la colonne (N2) au sein de la ligne (CA).

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
10$$ AS 'CASH'                LABEL CA   OVER
1100 AS 'ACCOUNTS RECEIVABLE' LABEL AR   OVER
1200 AS 'INVENTORY'           LABEL INV  OVER
RECAP CURASST/I5C = CA + AR + INV;
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, COLUMN = N2, LABEL = CA, STYLE = BOLD, $ 
ENDSTYLE
END

La sortie est montrée ci-dessous.

Cette requête identifie la colonne AMOUNT en fonction de son nom et formate son titre et ses données en caractères gras. Le même résultat est obtenu en identifiant la colonne comme N2.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
"---CASH ACCOUNTS---"                   OVER
1010 AS 'CASH ON HAND'                  OVER
1020 AS 'DEMAND DEPOSITS'               OVER
1030 AS 'TIME DEPOSITS'                 OVER
" "                                     OVER
"---OTHER CURRENT ASSETS---"            OVER
1100 AS 'ACCOUNTS RECEIVABLE'           OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, COLUMN = AMOUNT, STYLE = BOLD, $ 
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Cette requête concevoit le texte libre en caractères gras. Comme le même style s'applique aux deux lignes de texte libre dans cet exemple, les étiquettes doivent être identiques.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
"---CASH ACCOUNTS---"  LABEL CA         OVER
1010 AS 'CASH ON HAND'                  OVER
1020 AS 'DEMAND DEPOSITS'               OVER
1030 AS 'TIME DEPOSITS'                 OVER
" "                                     OVER
"---OTHER CURRENT ASSETS---"  LABEL OCA OVER
1100 AS 'ACCOUNTS RECEIVABLE'           OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = FREETEXT, STYLE = BOLD, $ 
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Cette requête utilise l'attribut SIZE (taille du texte) afin de faire la distinction entre deux lignes de texte libre : CASH ACCOUNTS (comptes de moyen de paiements) et OTHER CURRENT ASSETS (autres actifs courants). Les labels CA et OCA s'emploient pour identifier et formater chaque ligne séparément.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT 
" --- CASH ACCOUNTS ---" LABEL CA            OVER 
1010 AS 'CASH ON HAND'                       OVER
1020 AS 'DEMAND DEPOSITS'                    OVER
1030 AS 'TIME DEPOSITS'                      OVER
" "                                          OVER 
" --- OTHER CURRENT ASSETS ---" LABEL OCA    OVER 
1100 AS 'ACCOUNTS RECEIVABLE'                OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = FREETEXT, LABEL = CA, STYLE = BOLD, SIZE = 12, $ 
TYPE = FREETEXT, LABEL = OCA, STYLE = BOLD, SIZE = 10, $ 
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Dans cet exemple, les composants de texte et de variable de la ligne de texte libre sont stylisés séparément. Le texte, Current Assets, est en italique et la valeur dérivée du calcul RECAP est en caractères gras.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT AS 'Amount' FOR ACCOUNT
10$$ AS 'Cash'                   LABEL CA    OVER
1100 AS 'Accounts Receivable'    LABEL AR    OVER
1200 AS 'Inventory'              LABEL INV   OVER
RECAP CURASST/I5C = CA + AR + INV; NOPRINT  OVER
"Current Assets: <CURASST"
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID=OFF, $ 
TYPE = FREETEXT, OBJECT = TEXT, ITEM = 1, SIZE = 12, STYLE = ITALIC, $ 
TYPE = FREETEXT, OBJECT = FIELD, ITEM = 1, STYLE = BOLD, $ 
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Cette requête applique des caractères gras au titre de ligne et à la valeur calculée dans une ligne RECAP. Notez que le label RECAP dans la feuille de style est TOTCASH. Dans le label RECAP, le nom attribué à la valeur calculée sert de label explicite.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = TOTCASH, STYLE = BOLD, $ 
TYPE = REPORT, LABEL = CASH, COLUMN = N1, STYLE = ITALIC, $
TYPE = REPORT, LABEL = DD, COLUMN = N1, STYLE = ITALIC, $
TYPE = REPORT, LABEL = TD, COLUMN = N1, STYLE = ITALIC, $
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Pour demander une bordure d'apparence identique autour d'une ligne ou d'une cellule, saisissez cette syntaxe :

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER=option,
[BORDER-STYLE=line_style,] [BORDER-COLOR={color|RGB® g b)},] $

Pour spécifier des variantes de formatage pour les bordures du haut, du bas, de gauche et de droite, utilisez cette syntaxe :

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER-position=option,
[BORDER-[position-]STYLE=line_style,]
[BORDER-[position-]COLOR={color|RGB(r g b)},] $

Pour spécifier des variantes de formatage pour les bordures du haut, du bas, de gauche et de droite, utilisez cette syntaxe :

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER-position=option,
[BORDER-[position-]STYLE=line_style,]
[BORDER-[position-]COLOR={color|RGB(r g b)},] $

où :

row_label

est la ligne à laquelle les caractéristiques de bordure spécifiés s'appliquent.

COLUMN=

lorsqu'il est utilisé conjointement avec une étiquette de ligne, il indique une cellule (à l'intersection de la ligne et de la colonne) à laquelle les caractéristiques de bordure spécifiées s'appliquent.

option

Peut être l'une des valeurs suivantes :

ON Active les bordures pour l'en-tête ou le pied de page entiers. ON génère la même ligne que MEDIUM.

OFF désactive les bordures pour l'en-tête ou le pied de page entiers. OFF est la valeur par défaut.

LIGHT indique une ligne légère. Vous pouvez spécifier une ligne légère pour l'en-tête ou le pied de page entiers, ou pour une position ou plus de bordure.

MEDIUM identifie une ligne moyenne (ON définit MEDIUM pour la ligne). Vous pouvez spécifier une ligne légère pour l'en-tête ou le pied de page entiers, ou pour une position ou plus de bordure. Notez que la définition de ligne moyenne garantit la cohérence des lignes créées avec des attributs GRID.

HEAVY identifie une ligne épaisse. Vous pouvez spécifier une ligne épaisse pour l'en-tête ou le pied de page entiers, ou pour une position ou plus de bordure.

width spécifie la largeur de lignes en points (où 72 pts=1 pouce). Vous pouvez spécifier une ligne épaisse pour l'en-tête ou le pied de page entiers, ou pour une position ou plus de bordure. La largeur de lignes spécifiée en points s'affiche différement dans la sortie HTML et PDF. Pour une apparence cohérente, sans tenir compte du format d'affichage, utilisez LIGHT, MEDIUM ou HEAVY.

position

Spécifie quelle ligne de bordure à formater. Les valeurs valables sont TOP, BOTTOM, LEFT, RIGHT.

Vous pouvez spécifier un qualificateur de position pour n'importe lequel des mots clés de bordure (BORDER). Cela permet de formater individuellement la largeur, le style et la couleur des lignes, pour n'importe quel côté de la bordure.

line_style

Définit le style de la ligne de bordure. Les feuilles de style WebFOCUS supportent tous les styles de lignes des feuilles de style en cascade standards. Plusieurs styles tridimensionnels ne sont disponibles que pour le format HTML, ce qui est indiqué par des astérisques. Voici les valeurs valables :

NONE
SOLID
DOTTED
DASHED
DOUBLE*
GROOVE*
RIDGE*
INSET*
OUTSET*

color

Est l'une des valeurs de couleur actuelles. Noir est la couleur par défaut.

Si le périphérique de sortie ou d'affichage ne supporte pas les couleurs, il substitue des tons gris.

RGB

Spécifie la couleur de police en utilisant un mélange de rouge, de vert et de bleu.

(r g b)

est l'intensité de rouge, de vert et de bleu souhaitée, respectivement. Les valeurs sont sur une échelle de 0 à 255, où 0 est la valeur la moins intense et 255 est la valeur la plus intense. Notez que l'utilisation des trois composants de couleur au même niveau d'intensité a pour résultat des tons gris.

Remarque : pour les rapports HTML, la fonctionnalité BORDERS exige que les feuilles de style en cascade soient activées (ON). Ce code n'est pas requis pour les rapports PDF et PS.

Cet exemple applique une bordure de trait-points d'épaisseur moyenne autour de la ligne RECAP identifiée par le label TOTCASH. Pour les rapports HTML, la fonctionnalité BORDERS exige que les feuilles de style en cascade soient actives (ON).

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = TOTCASH, BORDER = MEDIUM, 
  BORDER-STYLE = DASHED, $ 
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Cet exemple applique une bordure épaisse noire au-dessus ou au-dessous de la ligne RECAP identifiée par le label TOTCASH, et il applique une ligne pointillée argent mince à gauche et à droite de chaque colonne dans la ligne.

Pour les rapports HTML, la fonctionnalité BORDERS exige que les feuilles de style en cascade soient actives (ON).

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF,$ 
TYPE = REPORT, LABEL = TOTCASH, 
     BORDER-TOP = HEAVY, 
     BORDER-BOTTOM = HEAVY, 
     BORDER-LEFT = LIGHT, 
     BORDER-RIGHT = LIGHT, 
     BORDER-TOP-STYLE = SOLID, 
     BORDER-BOTTOM-STYLE = SOLID, 
     BORDER-LEFT-STYLE = DOTTED, 
     BORDER-RIGHT-STYLE = DOTTED, 
     BORDER-LEFT-COLOR = 'SILVER', 
     BORDER-RIGHT-COLOR = 'SILVER', $
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

Cet exemple applique une bordure d'épaisseur moyenne autour de la cellule dans la deuxième colonne de la ligne identifiée par le label TOTCASH. Les spécifications LABEL et COLUMN combinées sont identifiées dans la cellule. La fonctionnalité BORDERS exige que les feuilles de style en cascade soient activées (ON).

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF,$ 
TYPE = REPORT, LABEL = TOTCASH, COLUMN = N2, BORDER = MEDIUM, $ 
ENDSTYLE
END

La sortie est montrée dans l'image ci-dessous.

FOR forfield [IN k]
tag [[GET CHILDREN|WITH CHILDREN] n] INDENT m [AS ['text'|CAPTION]] 
[OVER]

ou

RECAP fieldname[/format]=expression; INDENT m [AS 'text']

où :

forfield

Est un champ dans la source de données dont les valeurs sont comprises dans le rapport.

k

Est la colonne de début pour la valeur FOR dans un rapport FML.

balise

est la valeur forfield à afficher sur une ligne du rapport FML.

n

Est le nombre de niveaux d'une hiérarchie FML à afficher dans le rapport FML.

m

Est un nombre entier positif (zéro n'est pas pris en charge) qui spécifie le nombre d'espaces à mettre en retrait la valeur de balise, l'étiquette ou la légende d'une ligne ou d'une hiérarchie FML. La mise en retrait commence dans la première colonne s'il n'existe pas de phrase IN spécifiée dans la commande FOR. Par contre, s'il y en a une, la mise en retrait commence dans la colonne spécifiée par cette phrase. La mise en retrait maximale est la même que la longueur maximale d'un nom AS.

Si vous mettez en retrait une hiérarchie FML, la ligne parent de la hiérarchie est mise en retrait le nombre d'espaces spécifiés pour la mise en retrait. Les niveaux de hiérarchie sont mis en retrait deux espaces l'un de l'autre. Si la phrase GET CHILDREN est utilisée, la première ligne de la hiérarchie est mise en retrait de deux espaces car la sortie de la hiérarchie commence par le premier enfant et non par le parent. Pour plus d'informations sur l'utilisation de GET CHILDREN, consultez Afficher une hiérarchie FML.

'text'

Est un label à afficher dans une colonne du rapport FML.

LEGENDE

Indique qu'un champ de légende a été défini dans le fichier Master.

OVER

Indique que cette ligne n'est pas la dernière ligne à afficher.

fieldname

Est le nom que vous attribuez à la valeur calculée par la commande RECAP.

format

Est le format USAGE pour le champ RECAP. Il ne peut pas dépasser la largeur de la colonne. Le format par défaut est celui de la colonne dans laquelle la valeur calculée s'affiche.

expression

Est l'expression qui décrit comment calculer la valeur de champ pour RECAP.

Dans la requête suivante, le label de la deuxième ligne pour la valeur de balise 3000 est indenté cinq espaces. Comme la phrase GET CHILDREN est utilisée, la première ligne de l'hiérarchie FML est indentée sept espaces (cinq + deux) dans la troisième ligne de la valeur de balise 3000 :

SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                           AS 'Not Indented'        OVER
3000                 INDENT 5  AS 'Indented 5'          OVER
3000 GET  CHILDREN 2 INDENT 5  AS 'Hierarchy Indented 5'
END

La sortie est montrée comme ce qui suit :

                               Parent
                               ------
Not Indented                   3000
     Indented 5                3000
       Hierarchy Indented 5    3000
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3000
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200

La requête suivante additionne le prix, le coût et la quantité en stock des types de produits analogues et numériques. La première commande RECAP calcule le total de chaque colonne, et elle indente le label cinq espaces. La deuxième commande RECAP calcule le profit et indente l'étiquette dix espaces.

SET FORMULTIPLE=ON
TABLE FILE CENTINV
SUM PRICE COST QTY_IN_STOCK
FOR PRODTYPE
Digital                                          OVER
Analog                                           OVER
BAR                                              OVER
RECAP TOTAL = R1 + R2; INDENT 5  AS 'Total:'     OVER
BAR                                              OVER
RECAP PROFIT(2) = TOTAL(1) - TOTAL(2); AS 'Profit:' INDENT 10
END

La sortie est montrée comme ce qui suit :

                                        Our    Quantity 
                         Price:         Cost:  In Stock:
                         ------         -----  ---------
Digital                4,080.00      3,052.00     119143
Analog                 1,883.00      1,371.00     139345
                   ------------  ------------    -------
     Total:            5,963.00      4,423.00     258488
                   ------------  ------------    -------
          Profit:                    1,540.00

Pour clarifier les relations au sein d'une hiérarchie FML, les légendes (titres) des valeurs sont mises en retrait à chaque niveau. Utilisez le paramètre BLANKINDENT dans les rapports HTML, PDF ou PostScript pour spécifier la mise en retrait entre chaque niveau de la hiérarchie. Vous pouvez utiliser la mise en retrait par défaut pour chaque niveau de hiérarchie, ou choisir une valeur de mise en retrait personnalisée. Pour imprimer des légendes mises en retrait dans un rapport HTML, vous devez d'abord mettre le paramètre BLANKINDENT à ON ou à un numéro.

Le paramètre SET BLANKINDENT n'augmente pas la largeur de la colonne mise en retrait si celle-ci n'est pas assez large pour contenir les champs mis en retrait. Bien que cela soit possible dans un rapport HTML, dans un rapport PDF ou PostScript, il peut faire sortir de l'alignement les données des colonnes qui suivent la colonne indentée. Vous devez peut-être utiliser la syntaxe de feuille de style pour rendre la colonne assez large pour contenir les valeurs mises en retrait ou pour déplacer les colonnes qui la suivent. Pour changer la largeur d'une colonne, il suffit d'utiliser l'attribut SQUEEZE de feuille de style, et pour spécifier une position de début pour une colonne, il suffit d'utilier l'attribut POSITION. Vous pouvez aussi déplacer une colonne dans un rapport PostScript avec la phrase IN.

Une fonctionnalité similaire vous permet de changer le nombre d'espaces blancs avant la ligne parent d'une hiérarchie ou avant toute balise FML ou balise RECAP dans une requête FML quelconque. Pour plus d'informations, consultez Formatage d'un rapport FML.

SET BLANKINDENT={ON|OFF|n}
ON TABLE SET BLANKINDENT {ON|OFF|n}

SET PAGE-NUM=NOPAGE
SET BLANKINDENT=ON
SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                  AS CAPTION      OVER
3000 GET  CHILDREN 2  AS CAPTION  
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE = REPORT, GRID = OFF, $
ENDSTYLE
END

SET PAGE-NUM=NOPAGE
SET BLANKINDENT=.25
SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                 AS CAPTION          OVER
3000 GET  CHILDREN 2 AS CAPTIONON TABLE SET STYLE *
TYPE = REPORT, GRID = OFF, $
ENDSTYLE
END