x

Utilisez les options de syntaxe suivantes pour ajouter des lignes vierges au-dessus, au-dessous ou à l'intérieur d'un en-tête ou pied de page, où :

</n

Est un signe de localisation qui spécifie le nombre de lignes à sauter. Il est conseillé de mettre le signe de localisation sur la même ligne que le texte dans la requête. Si vous placez le signe de localisation </ n sur une ligne tout seul, le signe de localisation ajoute cette ligne en plus du nombre spécifié de lignes sautées.

" "

indique une ligne différente dans l'en-tête ou le pied de page, avec du contenu vide.

Vous pouvez utiliser ces techniques séparément ou ensemble.

Haut de page

Exemple : Ajout de lignes vierges au-dessus et au-dessous d'un en-tête de rapport

Dans ce rapport HTML créé par la requête, il y a une ligne vierge entre chaque ligne de l'en-tête de la page et deux lignes vierges entre l'en-tête de la page et le rapport même. La première ligne vierge est ajoutée en tant que ligne de texte vide. Les lignes vierges qui suivent sont ajoutées avec le signe de localisation de saut de ligne.

TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"SALES REPORT" 
" "
"**(CONFIDENTIAL)**</1"
"December 2002 </2" 
ON TABLE SET PAGE-NUM OFF 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, TOPMARGIN=0, $
TYPE = TABHEADING, JUSTIFY = CENTER, $
ENDSTYLE
END

La sortie est :

x

Dans un rapport PDF, vous pouvez utiliser les attributs TOPGAP et BOTTOMGAP pour contrôler l'espacement au-dessus ou en-dessous des lignes d'en-tête ou de pied de page ou la distance entre le texte d'en-tête et de pied de page et les lignes de grille qui se trouvent au-dessus ou au-dessous d'elles.

Remarque : vous pouvez utiliser TOPGAP et BOTTOMGAP avec des en-têtes multilignes. Il est important de noter que les espaces d'en haut et d'en bas sont insérés entre les lignes d'en-tête, ce qui rend l'espacement entre les lignes plus grand que l'espacement en haut et en bas de l'en-tête.

TYPE=headfoot, {TOPGAP|BOTTOMGAP}=gap, $

où :

headfoot

Indique le type d'en-tête ou de pied de page. Les valeurs valables sont TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD et SUBFOOT

TOPGAP

Indique la quantité d'espace à ajouter au-dessus d'un composant de rapport.

BOTTOMGAP

Indique la quantité d'espace à ajouter en-dessous d'un composant de rapport.

gap

est la quantité d'espace vide, dans l'unité de mesure spécifiée par l'attribut UNITS (pouces, par défaut).

Dans l'absence de grilles, la valeur par défaut est 0.

En présence de grilles, la valeur par défaut augmente afin de mettre de l'espace entre la grille et le texte.

Haut de page

Exemple : Ajout de lignes vierges pour séparer le texte d'en-tête des lignes de grille dans un rapport PDF

Cette requête génère un rapport PDF avec de l'espace vide ajouté au-dessus et au-dessous de l'en-tête de rapport afin de séparer le texte des lignes de grille d'en haut et d'en bas. L'espace au-dessus est ajouté par l'attribut TOPGAP. L'espace en-dessous est ajouté par l'attribut BOTTOMGAP.

TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"SALES REPORT <+0>December 2001"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET *
TYPE = TABHEADING, GRID=ON, JUSTIFY=CENTER, TOPGAP=.25, BOTTOMGAP=.25, $
TYPE = TABHEADING,  FONT='TIMES', SIZE=12, STYLE=BOLD, $
TYPE = TABHEADING, ITEM=2, SIZE=10, STYLE=ITALIC, $
ENDSTYLE
END

La sortie est :

Haut de page

Exemple : Réglage de l'espacement vertical au-dessous d'un pied de page de tri

La requête génère un rapport PDF dans lequel les pieds de page de tri sont en gras et de l'espace est ajouté au-dessous de chaque pied de page pour lier visuellement le texte du pied de page aux données précédentes.

TABLE FILE GGPRODS
PRINT PACKAGE_TYPE AND UNIT_PRICE
WHERE UNIT_PRICE GT 50
BY PRODUCT_DESCRIPTION NOPRINT BY PRODUCT_ID
ON PRODUCT_DESCRIPTION SUBFOOT
"Summary for <PRODUCT_DESCRIPTION"
ON TABLE SET PAGE-NUM OFF 
ON TABLE SET ONLINE-FMT PDF 
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET * 
TYPE=SUBFOOT, STYLE=BOLD, BOTTOMGAP=.25, $ 
ENDSTYLE
END

La sortie est :

x

Vous pouvez positionner un pied de page en bas d'une page. Par défaut, un pied de page s'affiche à deux lignes au-dessous des données de rapport.

FOOTING [BOTTOM]
  "content ... "
["content ... "]
.
.
.
["content ... "]

où :

FOOTING

Est la commande requise pour identifier certaines données comme un pied de page.

BAS

Est une commande facultative qui met le pied de page en bas de la page. Si vous souhaitez omettre BOTTOM, le pied de page s'affiche à deux lignes au-dessous des données de rapport. Remarque : FOOTING BOTTOM n'est pas pris en charge dans un rapport HTML ou la Visionneuse WebFOCUS.

content

indique le contenu d'un pied de page, qui peut comprendre les éléments suivants, entourés de guillemets doubles. (Si le guillemet de fin est omis, toutes les lignes subséquentes de la requête sont traitées comme faisant partie du pied de page).

text

Est le texte du pied de page. Vous pouvez spécifier des lignes de texte multiples.

Le texte doit se commencer tout seul sur une ligne, suivi de la commande FOOTING.

Le texte peut être combiné avec des variables et des signes de localisation.

Pour des informations connexes, consultez Limitations des en-têtes et pieds de page.

variable

Peut être un élément ou une combinaison des éléments suivant(s) :

Champs (champs de sources de données réels, champs virtuels crées avec la commande DEFINE dans un fichier Master ou dans une requête de rapport, valeurs calculées créées avec la commande COMPUTE dans une requête, champs de système, tels que TABPAGENO). Vous pouvez qualifier des champs de sources de données avec certains opérateurs préfixes.

Dialogue Manager variables.

Images. Vous pouvez inclure des images dans un en-tête ou pied de page.

Pour plus de détails, consultez Inclure un élément dans un en-tête ou pied de page.

signe de localisation

Vous permet de positionner des éléments, d'identifier des éléments à formater et d'étendre le code au-delà de la limite de 80 caractères de l'éditeur de texte.

<+0> divise un en-tête ou pied de page en éléments à formater. Pour plus d'informations, consultez Désignation de composants de rapport dans la syntaxe de feuille de style WebFOCUS.

</n spécifie les lignes sautées. Pour plus de détails, consultez Contrôle du positionnement vertical d'un en-tête ou d'un pied de page.

<-n positionne le prochain caractère sur la ligne. Consultez Utilisation des signes de localisation pour affiner le positionnement.

<0X continue la spécification d'un en-tête ou d'un pied de page sur la prochaine ligne de la requête. Consultez Extension du code d'en-tête et de pied de page aux lignes multiples dans une requête.

Remarque : lorsqu'une balise de fin est suivie immédiatement par une balise de début (><), un élément de texte est placé entre les deux signes de localisation (> <). Veuillez prendre cela en considération lors du formatage.

Lignes vierges

Si vous omettez tout(e) texte, variable et signe de localisation, vous avez une ligne d'en-tête ou de pied de page vierge (par exemple '' ''), que vous pouvez utiliser pour sauter une ligne dans l'en-tête ou le pied de page. (Vous pouvez aussi sauter une ligne en utilisant un signe de localisation vertical, tel que </1).

Remarque : le nombre maximal d'en-têtes de tri et de pieds de page de tri dans une seule requête est 33.

Haut de page

Exemple : Positionnement d'un pied de page en bas d'une page

Cette requête crée un rapport PDF dans lequel le pied de page s'affiche en bas de la page, plutôt que dans sa position par défaut, à deux lignes au-dessous des données du rapport.

TABLE FILE GGSALES
PRINT UNITS DOLLARS
BY CATEGORY BY STCD
WHERE TOTAL DOLLARS GE 25000
FOOTING BOTTOM
"PRELIMINARY SALES FIGURES"
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE-NUM OFF
END

La sortie suivante montre la fin du rapport, avec le pied de page :