x

fieldname [AND] ROW-TOTAL[/justification][/format] [AS 'label'] 
fieldname [AND] COLUMN-TOTAL[/justification] [AS 'label']

ou

fieldname [AND] COLUMN-TOTAL[/justification] [AS 'label']

où :

fieldname

Est le champ spécifié dans une commande d'affichage.

justification

Est l'alignement du label. Voici les valeurs valables :

L, qui justifie à gauche l'étiquette.

R qui justifie à droite le label.

C qui centre le label.

Pour plus d'informations, consultez Justification d'un label pour un total de rangée ou de colonne.

format

Est le format du total de rangée ou de colonne. Lorsque les champs d'un même format se sont additionnés, le format du total est le même que celui des champs. Lorsque les champs de différents formats se sont additionnés, la valeur par défaut D12.2 est utilisée soit pour le total de colonne soit pour le total de rangée.

étiquette

Est le label de total de rangée ou de colonne personnalisé. Le label par défaut est TOTAL.

Vous pouvez aussi spécifier un total de rangée ou de colonne avec la phrase ON TABLE. Si vous utilisez cette syntaxe, vous ne pouvez pas inclure des noms de champ avec ROW-TOTAL. Les noms de champ sont facultatifs avec COLUMN-TOTAL.

ON TABLE ROW-TOTAL[/justification][/format] [AS 'label']
ON TABLE COLUMN-TOTAL[/justification] [AS 'label']
 [fieldname fieldname fieldname]

Si une requête interroge un champ créé avec COMPUTE, la valeur du champ est compris dans un total de rangée ou de colonne. Gardez cela en tête lorsque vous personnalisez un label qui identifie le total.

Haut de page

Exemple : Création d'un label pour un total de rangée ou de colonne

Cette requête crée le label « Total Population by State » (population totale par état) pour le total de rangée et le label « Total Population by Gender » (population totale par sexe) pour le total de colonne. Le format D12 pour ROW-TOTAL affiche ces données avec des virgules.

TABLE FILE GGDEMOG
PRINT MALEPOP98 FEMPOP98 
ROW-TOTAL/D12 AS 'Total Population by State' 
BY ST
WHERE (ST EQ 'WY' OR 'MT') 
ON TABLE COLUMN-TOTAL AS 'Total Population by Gender' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La sortie est :

Haut de page

Exemple : Création d'un label de total de rangée avec ACROSS

Cette requête additionne la population de deux états, trie les données en utilisant la phrase ACROSS et met le label « Total by Gender » (total par sexe) sur les totaux de rangée. La colonne « Total by Gender » comprend deux totaux de rangée, « Male Population » et « Female Population » (population masculine et population féminine).

TABLE FILE GGDEMOG
SUM MALEPOP98/D12 FEMPOP98/D12 
ROW-TOTAL AS 'Total by Gender'  
ACROSS ST
WHERE ST EQ 'WY' OR 'MT';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La sortie est :

x

{BY|ON} fieldname {SUB-TOTAL|SUBTOTAL|COLUMN-TOTAL} [MULTILINES]
        [field1 [AND] field2...] [AS 'label'] [WHEN expression;]

où :

fieldname

Est un champ de tri spécifié dans une phrase BY ou ON

MULTILINES

Supprime un sous-total lorsque il n'y a qu'une valeur à une rupture de tri. Une fois spécifié, MULTILINES supprime le sous-total de tout saut de tri qui n'a qu'une seule ligne de détail. MULTI-LINES est un synonyme de MULTILINES.

field1 field2

Sont des champs spécifiés qui seront additionnés pour un sous-total. Un champ spécifié supprime la valeur par défaut, qui comprend tous les champs d'affichage numériques.

AS 'label'

Est le label personnalisé pour le sous-total. Vous ne pouvez pas remplacer le label par défaut avec un champ de tri d'un niveau supérieur si vous utilisez SUB-TOTAL.

WHEN expression

Spécifie un sous-total conditionel, comme le détermine une expression logique. Pour plus de renseignements, consultez Utilisation d'expressions.

Haut de page

Exemple : Création d'un label pour un sous-total et un total général

La requête crée un label personnalisé pour le sous-total, qui se compose de la somme totale en dollars retenue du salaire de l'employé pour les impôts, par département, et du total général, qui se compose de la somme totale en dollars pour les deux départements.

TABLE FILE EMPLOYEE
SUM DED_AMT BY DED_CODE BY DEPARTMENT
BY BANK_ACCT
WHERE DED_CODE EQ 'CITY'
WHERE BANK_ACCT NE 0 
ON DEPARTMENT SUBTOTAL AS 'Total City Deduction for'
ON TABLE COLUMN-TOTAL AS '**GRAND TOTAL**' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Dans la sortie, les valeurs de département MIS et PRODUCTION sont incluses par défaut dans le label de sous-total personnalisé.

Haut de page

Exemple : Création d'un label pour le sous-total d'un champ spécifique

Cette requête crée le label personnalisé « Order Total » (total de commande), pour le sous-total de LINEPRICE. Elle utilise le label par défaut TOTAL pour le total général.

TABLE FILE CENTORD
PRINT PNUM QUANTITY LINEPRICE 
BY ORDER_NUM SUBTOTAL LINEPRICE AS 'Order Total' 
WHERE ORDER_NUM EQ '28003' OR '28004';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La sortie est :

x

{BY|ON} fieldname {SUMMARIZE|RECOMPUTE} [MULTILINES]
        [field1 [AND] field2...] [AS 'label'] [WHEN expression;]
ON TABLE {SUMMARIZE|RECOMPUTE}

où :

fieldname

Est un champ de tri spécifié dans une phrase BY ou ON

MULTILINES

Supprime un sous-total lorsque il n'y a qu'une valeur à une rupture de tri. Une fois spécifié, MULTILINES supprime le sous-total de tout saut de tri qui n'a qu'une seule ligne de détail. MULTI-LINES est un synonyme de MULTILINES.

field1 field2

Sont des champs spécifiés qui seront additionnés pour un sous-total. Des champs spécifiés suppriment la valeur par défaut, qui comprend tous les champs d'affichage numériques.

AS 'label'

Est le label personnalisé pour le sous-total. Vous ne pouvez pas remplacer le label par défaut avec un champ de tri d'un niveau supérieur si vous utilisez SUMMARIZE.

WHEN expression

Spécifie un sous-total conditionel, comme le détermine une expression logique. Pour plus de renseignements, consultez Utilisation d'expressions.

Vous pouvez aussi générer un sous-total avec la phrase ON TABLE.

ON TABLE {SUMMARIZE|RECOMPUTE}

Haut de page

Exemple : Création d'un label pour le sous-total d'une valeur calculée

Cette requête crée une étiquette personnalisée pour le sous-total, y compris le calcul pour le champ DG_RATIO, créé avec COMPUTE.

TABLE FILE EMPLOYEE
SUM GROSS DED_AMT AND COMPUTE
DG_RATIO/F4.2 = DED_AMT / GROSS;
BY DEPARTMENT BY BANK_ACCT
WHERE BANK_ACCT NE 0 
ON DEPARTMENT SUMMARIZE AS 'SUBTOTAL FOR ' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Dans la sortie, les valeurs de département MIS et PRODUCTION sont incluses par défaut dans le label de sous-total personnalisé. L'étiquette par défaut du total général est TOTAL.