x

Pour insérer le nombre de pages total, ajoutez ce qui suit à votre requête :

<TABLASTPAGE

x

• La variable de système TABLASTPAGE ne s'adapte pas en fonction des changements à FOCFIRSTPAGE ou à la commande REPAGE. Par exemple, si un rapport comprend dix pages et que l'utilisateur utilise FOCFIRSTPAGE pour définir le premier numéro de page à 3, et non pas 1, la valeur de TABLASTPAGE est toujours 10.
• TABLASTPAGE n'est pris en page que pour un rapport simple, et non pas pour les rapports composés. Un nombre de pages total différent est généré pour chaque rapport d'un rapport composé.
• TABLASTPAGE n'est pris en charge que pour les rapports stylés, tels que HTML, PDF, et PS. Il n'est pas pris en charge pour EXL2K, WP, DOC ou HTML, où STYLE=OFF et STYLEMODE=FIXED.
• TABLASTPAGE provoque un deuxième traitement des résultats du rapport, premièrement pour calculer la dernière page et deuxièmement pour imprimer le rapport avec TABPAGENO (même où SQUEEZE=OFF).
• TABLASTPAGE ne supporte pas le tri de système externe.
• GRAPH FILE ne supporte pas TABLASTPAGE.
• TABLASTPAGE ne supporte pas TABLEF.

Haut de page

Exemple : Ajout du numéro de page actuel à un pied de page de tri

Ce qui suit illustre la façon d'ajouter le numéro de page actuel et le nombre de pages total à un rapport. La syntaxe pertinente est soulignée dans la requête.

TABLE FILE EMPLOYEE
PRINT EMP_ID AS 'Employee ID'
BY SALARY IN-GROUPS-OF 5000 AS 'Salary'
BY PCT_INC AS 'Percent,Increase'
BY DAT_INC AS 'Date of,Increase'
ON SALARY PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TITLE, STYLE=BOLD, SIZE=11, $
ENDSTYLE
FOOTING 
"Page <TABPAGENO of <TABLASTPAGE" 
END

Voici les deux premières pages de sortie :

x

La requête doit comprendre la syntaxe suivante et rendre la sortie dans un format de sortie stylé :

BY sortfield REPAGE

L'en-tête ou le pied de page peut utiliser la syntaxe suivante afin d'afficher “Page x sur y”

{HEADING|FOOTING} 
"Page <TABPAGENO of <BYLASTPAGE"

où :

sortfield

est le critère de tri qui contient l'option REPAGE. Un saut de page (PAGE-BREAK) est nécessaire pour le même critère de tri ou un qui serait inférieur. L'option PAGE-BREAK démarre un nouvelle page pour chaque saut de tri. L'option REPAGE réinitialise le numéro de page à 1 pour chaque saut de tri.

<TABPAGENO

est le numéro de page actuel.

<BYLASTPAGE

est le dernier numéro de page avant la repagination.

Haut de page

Exemple : Pagination dans un groupe de tri

La requête suivante contre la source de données GGSALES trie par produit, région, catégorie et par ville. Elle réinitialise la pagination chaque fois que le produit change. L'en-tête imprime le numéro de page actuel et le total dans chaque groupe de produit.

Notez que par défaut, les variables TABPAGENO et BYLASTPAGE ont le format I5, qui laisse un espace vide assez large avant le numéro de page. Ainsi donc, vous pouvez utiliser les délimiteurs d'espace ou les commandes COMPUTE pour déplacer les numéros de page vers la gauche.

Dans l'exemple suivant, une commande COMPUTE crée un champ nommé X qui a la valeur TABPAGENO mais la stocke dans un champ I2, et le délimiteur d'espace dans l'en-tête déplace le numéro de page BYLASTPAGE, 4 pouces vers la gauche. La commande d'en-tête doit suivre la commande COMPUTE ou le champ nommé X ne sera pas reconnu :

TABLE FILE GGSALES                          
SUM UNITS                                   
COMPUTE X/I2 = TABPAGENO;
BY PRODUCT NOPRINT REPAGE        
BY REGION PAGE-BREAK                        
BY CATEGORY                                 
BY CITY                                     
HEADING CENTER  
"<PRODUCT : Page <X of <-4> <BYLASTPAGE "
ON TABLE PCHOLD FORMAT PDF           
END                                         

La sortie partielle suivante montre que le numéro de page est réinitialisé à 1 lorsque le produit change et que la variable BYLASTPAGE affiche le nombre de pages total pour chaque produit :

x

Pour toutes les requêtes de rapport dans une procédure

SET FOCFIRSTPAGE = {n|1|&FOCNEXTPAGE}

Pour une requête de rapport

ON TABLE SET FOCFIRSTPAGE {n|1|&FOCNEXTPAGE}

où :

n

Est un numéro entier entre 1 et 999999 qui est attribué à la première page du rapport.

1

Attribut le numéro « 1 » à la première page. La valeur par défaut est 1.

&FOCNEXTPAGE

Est une variable dont la valeur est supérieure au dernier numéro de page du rapport précédent dans une requête multiple. La valeur est calculée lors de l'exécution.

Haut de page

Exemple : Attribution d'un numéro de page à la première page

Cette requête attribue le numéro « 3 » à la première page du rapport.

SET FOCFIRSTPAGE = 3 
TABLE FILE CENTORD
HEADING
"Sales By Store"
SUM LINEPRICE AS 'Sales'
BY SNAME
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Voici le rapport :

Haut de page

Exemple : Contrôle de numéros de page dans les rapports consécutifs

Cette procédure comprend deux requêtes de rapport. La deuxième requête définit la valeur de &FOCNEXTPAGE pour FOCFIRSTPAGE.

SET FOCFIRSTPAGE = 3
TABLE FILE CENTORD
HEADING
"Sales By Store"
SUM LINEPRICE AS 'Sales'
BY SNAME
WHERE SNAME EQ 'eMart'
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END
-RUN

SET FOCFIRSTPAGE = &FOCNEXTPAGE 
TABLE FILE CENTORD
HEADING
"Sales By Product"
SUM LINEPRICE AS 'Sales'
BY PRODCAT AS 'Product'
WHERE PRODCAT EQ 'VCRs'
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La première page du deuxième rapport est numéroté « 4 », qui est supérieur par un numéro à celui du rapport précédent :

x

Pour toutes les requêtes de rapport dans une procédure

SET PAGE[-NUM] = num_display

Pour une requête de rapport

ON TABLE SET PAGE[-NUM] num_display

où :

-NUM

Est facultatif. PAGE et PAGE-NUM sont synonymes.

num_display

indique une des choses suivantes :

ON affiche les numéros de page dans le coin supérieur gauche, suivis d'une ligne réservée blanche. ON est la valeur par défaut.

OFF supprime les numéros de page par défaut.

Vous pouvez utiliser la variable de système TABPAGENO.

Cette définition lance l'éjection de pages.

NOPAGE supprime les numéros de page par défaut et rend les deux premières lignes d'une page disponibles pour l'utilisation.

Vous pouvez utiliser la variable de système TABPAGENO.

Cette définition ne lance pas d'éjections de pages.

TOP enlève la ligne supérieure de chaque page réservée pour le numéro de page, ainsi que la ligne blanche qui la suit. La première ligne du rapport comprend l'en-tête de rapport, s'il est spécifié, ou les titres de colonne, s'il n'y a pas d'en-tête.

Vous pouvez utiliser la variable de système TABPAGENO pour afficher les numéros de page autre part dans le rapport.

Haut de page

Exemple : Supression de numéros de page par défaut

Cette requête utilise la commande SET PAGE-NUM = NOPAGE pour supprimer les numéros de page par défaut. Elle met l'en-tête de rapport sur la première ligne de la première page du rapport.

SET PAGE-NUM = NOPAGE 
TABLE FILE GGPRODS
ON TABLE SUBHEAD
"PACKAGING INFORMATION"
" "
PRINT PACKAGE_TYPE AND SIZE AND UNIT_PRICE
BY PRODUCT_DESCRIPTION
ON PRODUCT_DESCRIPTION PAGE-BREAK SUBFOOT
"PRODUCT ID <PRODUCT_ID"
"Page <TABPAGENO "
ON TABLE SET ONLINE-FMT PDF
END

TABPAGENO insère le numéro de page dans le pied de page de tri. Voici la première page du rapport :