Désignation du rapport complet, d'une colonne ou d'une ligne pour l'application d'un style

Comment :

Vous pouvez formater un(e) :

L'exemple suivant montre les parties du rapport qui correspondent au composant REPORT et aux attributs COLUMN et ACROSSCOLUMN. Il indique également quelles valeurs pour l'attribut TYPE vous pouvez utiliser pour désigner ces composants dans la syntaxe de feuille de style. Veuillez noter que les valeurs spécifiées dans cet exemple (B1 pour le composant COLUMN et N2 pour le composant ACROSSCOLUMN) ne sont pas les seules valeurs valables que vous pouvez utiliser.

TABLE FILE CENTORD
SUM LINEPRICE LINE_COGS AS 'Line Cost of,Goods Sold'
BY PLANT AS 'Plant'
ACROSS YEAR
WHERE YEAR EQ 2000 or 2001
HEADING
"Cost Analysis"
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
END

Remarque : la requête de rapport présentée ci-dessus ne sert qu'à illustrer où figurent certains composants dans le rapport ; la feuille de style en a été omise.
Haut de page
x
Syntaxe : Désigner le rapport complet

Pour désigner le rapport complet dans la syntaxe de feuille de style, utilisez l'attribut et la valeur suivants : 

TYPE=REPORT
Exemple : Désigner le rapport complet

L'exemple de requête de rapport suivant illustre comment désigner le rapport complet pour l'application d'un style. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête. 

TABLE FILE CENTINV
HEADING
"Excess Stock Report"
SUM QTY_IN_STOCK  
BY PRODNAME
WHERE QTY_IN_STOCK GT 10000
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, GRID=OFF,$
TYPE=REPORT, STYLE=BOLD,$ 
ENDSTYLE
END

La sortie est :
Haut de page
x
Syntaxe : Désigner une colonne
TYPE=REPORT, coltype=column

où :

coltype

spécifie le type de colonne. Il peut s'agir de :

COLUMN spécifie une colonne de tri (générée par BY), une colonne d'affichage (générée par PRINT, LIST, SUM ou COUNT), une colonne composée (générée par COMPUTE), ou une colonne comprenant des totaux de ligne (générée par ROW-TOTAL).

ACROSSCOLUMN spécifie toute instance d'une colonne qui se répète dans une ligne de tri horizontal (ACROSS). Cet attribut sert également à formater les valeurs de tri horizontal (ACROSS) qui s'affichent au-dessus des titres de colonne.

COLUMN=

spécifie une ou plusieurs colonnes. Si vous définissez ACROSSCOLUMN, les seuls identificateurs valides sont Nn et Pn, et ne compte que les champs ACROSS, pas les champs d'affichage.

Le tableau suivant présent les options pour la désignation d'une colonne dans la déclaration de feuille de style.

Identificateur

Description

Nn

désigne une colonne en fonction de sa position dans le graphique. Pour déterminer cette valeur, comptez les critères de tri vertical (BY), les champs d'affichage et les champs ROW-TOTAL, de gauche à droite, y compris les champs NOPRINT. Pour en voir un exemple, consultez Désigner une colonne de données. Pour ACROSSCOLUMN, seuls les champs ACROSS sont comptés.

Pn

désigne une colonne en fonction de sa position dans le graphique. Pour déterminer la valeur de n, comptez les critères de tri vertical (BY), les champs d'affichage et les champs ROW-TOTAL, de gauche à droite. Vous ne devez pas compter les champs NOPRINT. Pour ACROSSCOLUMN, seuls les champs ACROSS sont comptés.

Cn

désigne une colonne d'affichage en fonction de sa position dans le rapport. Pour déterminer la valeur de n, comptez uniquement les champs d'affichage de gauche à droite, y compris les champs NOPRINT. Vous ne devez compter ni les critères de tri vertical (BY) ni les champs ROW-TOTAL.

Pour sélectionner tous les champs d'affichage, utilisez la commande C*.

Bn

désigne une colonne de tri vertical (BY) en fonction de sa position dans le rapport. Pour déterminer la valeur de n, comptez uniquement les critères de tri vertical (BY), y compris les champs NOPRINT, de gauche à droite.

Pour sélectionner tous les champs BY, utilisez la commande B*.

field

désigne une colonne en fonction de son nom de champ.

Lorsqu'il y a plusieurs instances d'un champ, utilisez la commande champ(n) pour sélectionner une instance particulière du champ ou bien la commande champ(*) pour sélectionner toutes les instances du champ.

ROWTOTAL

désigne une colonne de totaux de ligne générée avec ROW-TOTAL. Lorsque ROW-TOTAL est utilisé avec des commandes ACROSS et des commandes d'affichage multiples, il génère des colonnes de total multiples. Utilisez ROWTOTAL (n) pour sélectionner une colonne de total particulière. Utilisez ROWTOTAL (champ) pour sélectionner la colonne de total de ligne d'un champ particulier.

Utilisez ROWTOTAL(*) pour sélectionner toutes les colonnes de total du rapport.

Remarque : dans une Feuille de style, toutes les colonnes doivent être spécifiées de la même façon, soit en entrant un nom de champ ou une référence de position.

Exemple : Désignation d'une colonne

L'exemple de requête de rapport suivant illustre comment désigner une colonne, y compris son titre et ses données associés, pour l'application d'un style. La déclaration de feuille de style pertinente est mise en surbrillance dans la requête.

Remarque : pour produire les mêmes résultats que la requête de rapport ci-dessous, vous pouvez spécifier les valeurs P1, B1 ou le nom de champ (PRODNAME) pour l'attribut COLUMN dans la déclaration de feuille de style.

TABLE FILE CENTINV
HEADING
"Excess Stock Report"
SUM QTY_IN_STOCK  
BY PRODNAME
WHERE QTY_IN_STOCK GT 10000
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=REPORT, COLUMN=N1, STYLE=ITALIC,$ 
ENDSTYLE
END

La sortie est :
Exemple : Désignation d'une colonne de tri horizontal (ACROSS)

L'exemple de requête de rapport suivant illustre comment désigner une colonne de tri horizontal (ACROSS) pour l'application d'un style. Lorsque vous désignez une colonne de tri horizontal (ACROSSCOLUMN) pour le formatage, toutes ses valeurs de données, son titre, et toutes les valeurs de tri horizontal (ACROSS) associées sont formatées pour toute instance de la colonne dans la sortie de rapport. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête.

Remarque : pour produire les mêmes résultats que la requête de rapport ci-dessous, vous pouvez spécifier les valeurs P1 et P2, respectivement, pour l'attribut ACROSSCOLUMN. 

TABLE FILE CENTORD
SUM LINEPRICE LINE_COGS AS 'Line Cost of,Goods Sold'
BY PLANT AS 'Plant'
ACROSS YEAR
WHERE YEAR EQ 2000 OR 2001
HEADING
"Cost Analysis"
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=REPORT, ACROSSCOLUMN=N1, STYLE=ITALIC,$
TYPE=REPORT, ACROSSCOLUMN=N2, STYLE=BOLD,$  
ENDSTYLE
END

La sortie est :
Haut de page
x
Syntaxe : Désigner une ligne de langage de modélisation financière (FML)
TYPE=REPORT, LABEL=label

où :

étiquette

Est une étiquette de ligne explicite.

Exemple : Désignation d'une ligne FML

L'exemple de requête de rapport suivant illustre comment désigner une ligne FML pour l'application d'un style. La ligne FML complète comprend l'étiquette et toutes les données de la ligne. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête. 

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND' LABEL COH OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD OVER
1030 AS 'TIME DEPOSITS' LABEL TD OVER
BAR OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, LABEL=COH, STYLE=ITALIC, $
TYPE=REPORT, LABEL=DD, STYLE=ITALIC, $
TYPE=REPORT, LABEL=TD, STYLE=ITALIC, $ 
ENDSTYLE
END

La sortie est :
Haut de page
x
Syntaxe : Désigner une ligne de total ou de sous-total entière
TYPE=type, [BY=sortcolumn]

où :

type

Désigne un total ou un sous-total. Vous pouvez choisir :

GRANDTOTAL qui s'agit d'un total global (généré par COLUMN-TOTAL, SUBTOTAL, SUB-TOTAL, RECOMPUTE ou SUMMARIZE).

SUBTOTAL qui s'agit d'un sous-total (généré par SUBTOTAL, SUB-TOTAL, RECOMPUTE ou SUMMARIZE).

RECAPqui s'agit d'un calcul de sous-total (généré par ON champdetri RECAP ou ON champdetri COMPUTE).

BY

Lorsqu'une requête de rapport contient plusieurs commandes de sous-total, dont chacune est associée à une différente colonne de tri vertical (BY), la commande BY permet d'identifier les commandes de sous-total spécifiques à formater.

sortcolumn

spécifie la colonne de tri vertical (BY) associé à l'un des sous-totaux des commandes du rapport. Vous devez utiliser le nom de champ pour désigner la colonne de tri.
Exemple : Désignation d'une ligne de total

L'exemple de requête de rapport suivant illustre comment désigner une ligne de total de colonne (COLUMN-TOTAL) pour l'application d'un style. La déclaration de feuille de style pertinente est mise en surbrillance dans la requête. 

TABLE FILE SALES
SUM RETURNS DAMAGED AND ROW-TOTAL AND COLUMN-TOTAL
BY PROD_CODE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $  
TYPE=GRANDTOTAL, STYLE=BOLD, SIZE=12, $ 
ENDSTYLE
END

La sortie est :
Exemple : Désignation d'un total de ligne

L'exemple de requête de rapport suivant illustre comment désigner un total de ligne pour l'application d'un style. La déclaration de feuille de style pertinente est mise en surbrillance dans la requête. Notez que si vous souhaitez formater une instance de total de ligne, vous pouvez ajouter une déclaration WHEN à votre feuille de style. Pour plus de détails, consultez Contrôle du formatage de rapports. 

TABLE FILE SALES
SUM RETURNS DAMAGED AND ROW-TOTAL
BY PROD_CODE AS 'PRODUCT,CODE'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, COLUMN=ROWTOTAL, STYLE=BOLD, $ 
ENDSTYLE
END

La sortie est :

WebFOCUS