Toute déclaration de feuille de style spécifie une série d'attributs à la forme

attribute = value, [attribute = value, ...] $

où :

attribut

Est l'attribut que vous spécifiez, tel que TYPE, COLUMN, COLOR ou FONT.

value

Est la valeur que vous attribuez à l'attribut.

La requête ci-après comprend une feuille de style incorporée. La feuille de style commence par ON TABLE SET STYLE * et termine par ENDSTYLE.

TABLE FILE CENTORD
HEADING
" "
"C e n t u r y  C o r p o r a t i o n"
" "
"Order Revenue - 2000 Q3"
" "
"page <TABPAGENO"
" "
SUM ORDER_DATE/MtDY ORDER_NUM LINEPRICE AS 'Order,Total:'
BY LOWEST 9 ORDER_DATE NOPRINT
WHERE (ORDER_DATE GE '2000/10/01') AND (ORDER_DATE LE '2000/12/31');
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
 
ON TABLE SET STYLESHEET *
TYPE=Report, GRID=Off, UNITS=Inches, $
TYPE=Data, FONT='Times', $
TYPE=Data, BACKCOLOR=Aqua, COLOR=Navy,
     WHEN=LinePrice GT 500000, $
TYPE=Data, COLUMN=LinePrice, BACKCOLOR=Aqua, COLOR=Navy, STYLE=Bold,
     WHEN=LinePrice GT 500000, $
TYPE=Title, FONT='Helvetica', $
TYPE=Heading, FONT='Helvetica', STYLE=Bold, SIZE=14, JUSTIFY=Center,
     COLOR=White, BACKCOLOR=Dark Turquoise, $
TYPE=Heading, LINE=6, BACKCOLOR=White, COLOR=Dark Turquoise, $
TYPE=Heading, LINE=7, BACKCOLOR=White, $
ENDSTYLE
 
END

Il y a de nombreuses façons de structurer vos déclarations de feuille de style afin de les rendre plus faciles à lire. Vous pouvez effectuer une ou une combinaison des procédures suivantes :

• Commencez une déclaration dans toute colonne comportant des espaces ou des onglets.
• Insérez des lignes blanches entre les déclarations.
• Saisissez les déclarations entièrement en majuscules, en minuscules ou avec une combinaison des deux cases.
• Employez plus d'une déclaration pour formater un composant de rapport unique.
• Insérez des espaces ou des onglets entre l'attribut, le signe égal (=), la valeur, la virgule et le symbole du dollar ($).
• Divisez une déclaration unique sur plusieurs lignes. Cela a pour effet le traitement de la déclaration jusqu'au symbole du dollar. Par exemple, vous pouvez partager une déclaration de la façon suivante :

  TYPE=HEADING, FONT=ARIAL,
  SIZE=14, STYLE=BOLD, $

• Partagez une paire attribut =valeur sur une ligne. Utilisez la barre oblique inverse (\) en tant que syntaxe de continuation à la fin de la première ligne si vous partagez un attribut ou une valeur dans une déclaration sur une ligne. Par exemple :

  TYPE=TITLE, COLUMN=N2, STY\
  LE=BOLD+ITALIC, COLOR=BLUE, $

L'ajout de commentaires aux feuilles de style donne du contexte aux déclarations. Les commentaires n'ont pas d'incidence sur le comportement de la feuille de style.

Vous pouvez ajouter un commenaire :

• Sur une ligne de déclaration. Ajoutez le texte voulu après le symbole du dollar ($). Par exemple,

  TYPE=HEADING, STYLE=BOLD, COLOR=BLUE, SIZE=14, $ Sample comment

• Sur une ligne tout seul. Commencez la ligne avec soit un symbol du dollar ($) soit un trait d'union et une astérisque (-*), suivi du texte voulu. Par exemple,

  -* This is a sample comment
  $ This is another sample comment

Remarque : vous pouvez ajouter des commentaires n'importe où dans la requête, pas seulement dans les feuilles de styles.

La commande CHECK STYLE permet de vérifier s'il y a des erreurs de syntaxe dans un fichier de feuille de style. CHECK STYLE ne vérifie pas l'orthographe des noms de police, ni la disponibilité des polices spécifiées sur votre système.

Vous pouvez lancer cette commande dans la console de commandes de Developer Studio.

CHECK STYLE file