En utilisant une commande SET, voici la syntaxe,

au début d'une requête :

SET COMPOUND = 'BYTOC [n]'

dans une requête, utilisez la syntaxe :

ON TABLE SET COMPOUND 'BYTOC [n]'

où :

n

Représente le nombre de champs de tri verticaux (BY) à inclure dans la table des matières, commençant par le premier champ de tri (niveau supérieur) dans la requête. L'hiérarchie des champs de tri est déterminée par l'ordre dans lequel ils sont spécifiés dans la requête.

La valeur par défaut est 1, signifiant qu'uniquement le champ de tri de niveau supérieur et ses valeurs s'affichent dans la table des matières.

A moins d'avoir spécifié autre chose, un saut de section est mis par défaut après le premier champ de tri (niveau supérieur).

Remarque : des guillemets simples (') devraient être utilisés quand BYTOC est spécifié avec un nombre dans une commande SET.

En utilisant une commande PCHOLD, la syntaxe est

ON TABLE PCHOLD FORMAT HTML BYTOC [n]

où :

n

Représente le nombre de champs de tri verticaux (BY) à inclure dans la table des matières, commençant par le premier champ de tri (niveau supérieur) dans la requête. L'hiérarchie des champs de tri est déterminée par l'ordre dans lequel ils sont spécifiés dans la requête.

La valeur par défaut est 1, signifiant qu'uniquement le champ de tri de niveau supérieur et ses valeurs s'affichent dans la table des matières.

A moins d'avoir spécifié autre chose, un saut de section est mis par défaut après le premier champ de tri (niveau supérieur).

Remarque : des guillemets simples (') ne devraient pas être utilisés quand BYTOC est spécifié avec un nombre dans une commande PCHOLD.

La syntaxe suivante active le contrôle d'arborescence TOC à une de feuille de style :

TYPE=REPORT, TOC='n',$

ou

TYPE=REPORT, TOC='sortfieldname',$

où :

n

Représente le nombre de champs de tri verticaux (BY) à inclure dans la table des matières, commençant par le premier champ de tri (niveau supérieur) dans la requête. La hiérarchie des critères de tri dans l'aborescence TDM (TOC) est déterminée par l'ordre dans lequel ces champs sont spécifiés dans la requête.

sortfieldname

Spécifie la colonne de tri vertical (BY) par son nom de champ.

Remarque : des guillemets simples (') devraient être utilisés quand TOC est spécifié dans la feuille de style.

Vous pouvez ajouter une table des matières HTML en tant qu'icône au coin supérieur gauche d'un rapport en faisant précéder la requête d'une commande SET, comme l'illustre la requête suivante. La table des matières liste les valeurs du premier critère de tri vertical (niveau supérieur), PLANT :

SET COMPOUND='BYTOC 2'

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Vous pouvez aussi ajouter une table des matières HTML en tant qu'icône au coin supérieur gauche d'un rapport en utilisant la commande SET dans la requête.

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 2'
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

L'exemple suivant illustre la façon dont vous pouvez utiliser une commande PCHOLD pour exécuter la requête :

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML BYTOC 2
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Dans la requête suivante, le contrôle d'arborescence TOC est activé dans la feuille de style de rapport.

TABLE FILE CENTORD 
HEADING
"SALES REPORT"
SUM LINEPRICE
BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, TOC='PRODCAT', $ 
ENDSTYLE
END

Remarque : des guillemets simples (') devraient être utilisés quand TOC est spécifié dans la feuille de style.

Exécutez le rapport. L'objet TOC s'affiche dans le coin supérieur gauche.

Double-cliquez sur l'icône TOC pour ouvrir le contrôle d'arborescence de la table des matières. Ceci affiche les valeurs des champs de tri dans le rapport dans l'ordre dans lequel ils ont été spécifiés.

Remarque : vous pouvez déplacer la table des matières en cliquant dans la zone bleue au-dessus de la mention « Table des matières » et en faisant glisser la table des matières vers une autre zone du rapport, ou en double cliquant sur l'emplacement souhaité dans le rapport.

Si vous souhaitez afficher tous les champs disponibles (le rapport complet), cliquez sur l'option Afficher le rapport complet (On/Off).

Conseil : vous pouvez aussi personnaliser l'aspect et la convivialité de l'objet de la TDM en éditant un fichier .css. Il est recommandé de faire une copie de sauvegarder avant l'édition.

• Si vous travaillez dans les projets locaux de Developer Studio, allez à

  \ibi\DevStudio##\ibi_apps\ibi_html\javaassist\intl\xx

  où :

  ##

  est la version de Developer Studio.

  xx

  est l'abbréviation de langue pour la version de Developer Studio.

• Si vous travaillez dans un environnement MR indépendant, dans Developer Studio ou à partir d'un navigateur, reportez-vous au répertoire \ibi\WebFOCUS##\ibi_apps\ibi_html\javaassist\intl\xx, où ## est la sortie de WebFOCUS et xx est le langage d'abréviation. Pour anglais (EN) le nom de fichier .css est toc.css. Pour toutes les autres langues, le nom de fichier .css est xxtoc.css, où xx est l'abréviation de la langue.

Remarque : si vous cliquez sur Supprimer la table des matières, puis souhaitez revoir la table des matières par la suite, il suffit de double-cliquer sur l'emplacement souhaité dans le rapport.

Les données dans un rapport TOC sont groupées en sections selon les champs de tri. Les rapports TOC affichent une section à la fois pour une meilleur visualisation. Chaque section comporte toutes les valeurs de son critère de tri associé. Vous pouvez personnaliser chaque section avec un saut de page. Par défaut, un saut de page est compris dans le premier champ de tri (niveau supérieur). Vous pouvez ajouter des sauts de page afin de créer des sections additionnels et de regrouper les données en fonction d'un critère de tri d'un niveau inférieur.

Lorsque vous ajoutez une table des matières à un en-tête, vous devez ajouter des sauts de page additionnels pour chaque critère de tri de niveau inférieur. Cela pour assurer le groupement et l'affichage corrects des données triées.

TABLE FILE SHORT
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
BY HOLDER
BY TYPE
ON HOLDER PAGE-BREAK
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 5'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
ENDSTYLE
END

Une section du rapport s'affiche à la fois.

Le rapport se divise en sections en fonction des valeurs de HOLDER. Vous verrez les détails de chaque valeur de HOLDER dans une section unique.

Si vous sélectionnez une valeur dans une table des matières, cette valeur clignote (elle est soulignée en gris) afin d'y attirer votre attention dans la fenêtre de navigation. L'emplacement où clignote cette valeur et tout changement à l'écran sont déterminés par les facteurs suivants :

• Lorsque vous changez le champ de tri de niveau supérieur de la table des matières (de l'hiérarchie au-dessus du rapport ou de la première liste déroulante dans un en-tête ou pied de page), la valeur sélectionnée clignote trois fois dans la fenêtre du navigateur.
• Lorsque vous changez une valeur de tri de niveau inférieur dans le champ de tri de niveau supérieur actuel, la valeur sélectionnée clignote trois fois dans la fenêtre. Ceci parce que vous êtes toujours dans le même champ de tri principal, et donc, dans le même saut de page. A partir de la valeur sélectionnée en haut de la fenêtre, vous pouvez faire défiler rapidement jusqu'au détails associés.

  Si la valeur de niveau inférieur est déjà visualable à l'écran, et que le rapport qui reste peut aller à l'écran, la valeur clignote, mais le rapport ne défile pas.

Cette requête ajoute une table des matières HTML dynamique en tant qu'icône dans le coin supérieur gauche du rapport en incluant une commande SET dans la requête. La table des matières affiche une hiérarchie composée de quatre niveaux de critères de tri, en commençant par le premier (niveau supérieur). Les champs de tri sont : CONTINENT, REGION, COUNTRY et TYPE.

TABLE FILE SHORT
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
BY HOLDER
BY TYPE
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 5'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
ENDSTYLE
END

La sortie s'affiche avec la table des matières dans le coin supérieur gauche :

Faîtes un double-clic sur l'objet afin d'élargir la table des matières.

Sélectionnez Afficher le rapport complet. Défilez vers le bas pour vous assurer que le rapport comprend des données pour tous les continents.

Redéfilez vers le haut de la fenêtre de rapport et rouvrez la table des matières. Ensuite, sélectionnez Americas. Votre sélection clignote à l'écran. Bien que l'affichage du rapport ne semble pas changer, si vous défilez vers le bas vous voyez que le rapport contient uniquement des valeurs correspondantes au champ Americas.

Redéfilez vers le haut et faîtes un double-clic n'importe où dans le rapport pour ouvrir la table des matières. Cette fois-ci, cliquez sur le symbole + à côté du champ Americas, puis cliquez sur le symbole + à côté du champ South America.

Les valeurs de champ (Argentina et Brazil) sont listées dans la table des matières. Ce sont des valeurs du champ COUNTRY. Si vous souhaitez voir le nom de champ d'une valeur dans la TDM, survolez-la avec votre curseur.

Sélectionnez Brazil. Votre sélection clignote et se déplace vers le haut de la fenêtre.

Défilez vers le bas pour visualiser les données pour Brazil.

Continuez à naviguer au détail que vous souhaitez visualiser en choisissant des valeurs à tout niveau de tri dans la table des matières.

• Cliquer sur un symbole + élargit le champ pour afficher ses valeurs dans la table des matières.
• Cliquer sur une valeur même (hyperlien) dans la table des matières souligne momentanément la valeur et, si besoin est, change de l'affichage de rapport pour mettre en vue la valeur.

  La table des matières se réduit à son icône lorsque vous cliquez sur Table des matières, mais vous pouvez continuer à la faire défiler, à la développer et à faire d'autres sélections.

TYPE=heading, [subtype,] TOC=sort_column, $

TABLE FILE SHORT
HEADING
"Projected Returns Report for Region:  <REGION in Continent:  <CONTINENT "
" "
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=1, TOC=CONTINENT, $
ENDSTYLE
END

TABLE FILE SHORT
"Projected Return"
" "
"For:<CONTINENT For:<REGION "
SUM PROJECTED_RETURN
BY CONTINENT BY REGION BY COUNTRY BY TYPE
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON CONTINENT PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
TYPE=HEADING, LINE=1, STYLE=BOLD, $
TYPE=HEADING, LINE=3, OBJECT=FIELD, ITEM=1, TOC=B1,$
TYPE=HEADING, LINE=3, OBJECT=FIELD, ITEM=2, TOC=REGION,$
ENDSTYLE
END