Création d'un lien vers un URL

Comment :

Vous pouvez définir un lien à partir de n'importe quel composant de rapport vers n'importe quel URL, y compris des pages web, site web, des servlets, ou des ressources hors-World Wide Web, telles que des applications e-mail. Une fois un lien défini, vous pouvez sélectionner le composant de rapport pour accéder à l'adresse URL.

Les liens que vous définissez peuvent être dynamiques. Avec un lien dynamique, votre sélection envoie la valeur du composant de rapport sélectionné à l'URL. La ressource utilise la valeur envoyée afin de déterminer, de façon dynamique, les résultats qui lui sont renvoyés. Vous pouvez envoyer un ou plusieurs paramètres. Pour plus d'informations, consultez Création de paramètres.
Haut de page
x
Syntaxe : Créer un lien vers un URL
TYPE=type, [subtype], URL=url[(parameters ...)], [TARGET=frame,] [ALT =  'description',] $

où :

type
Identifiez le composant de rapport que vous sélectionnez dans le navigateur web pour exécuter le lien. L'attribut TYPE et sa valeur doivent apparaître au début de la déclaration.
subtype
sont des attributs supplémentaires, tels que COLUMN, LINE ou ITEM, nécessaires pour identifier le composant de rapport que vous formatez. Pour en savoir plus au sujet de l'identification des composants de rapport, consultez Désignation de composants de rapport dans la syntaxe de feuille de style WebFOCUS.
url
identifie toute adresse URL valable, y compris celle qui spécifie un programme servlet WebFOCUS, ou le nom d'une colonne de rapport entre parenthèses dont la valeur est une adresse URL valable pour le lien.

Remarque :

  • La longueur maximale de l'argument d'une adresse URL=url, y compris tous paramètres variable=objet associés, est limitée par le nombre maximal de caractères autorisés par le navigateur. Pour plus d'informations concernant cette limite de votre navigateur, effectuez des recherches sur le site de support du navigateur. L'argument URL peut s'étaler sur plus d'une ligne, comme le décrit la rubrique Création et gestion d’une feuille de style WebFOCUS

    Notez que la longueur de l'URL est limitée par le nombre maximal de caractères autorisés par le navigateur. Pour plus d'informations concernant cette limite pour votre navigateur, faites une recherche sur le site d'assistance technique de votre fournisseur.

  • Si l'URL pointe à un programme Servlet WebFOCUS qui prend en charge des paramètres, l'URL doit se terminer par un point d'interrogation (?).

GET
Valeurs qui sont envoyées à l'URL. Pour plus d'informations, consultez Création de paramètres.
cadre
Identifie le cadre cible dans la page web dans laquelle la sortie du lien de zoom en profondeur est affiché. Pour plus d'informations, consultez Spécification d'un cadre cible.
description
est une description textuelle du lien pris en charge dans le rapport HTML pour raisons de conformité avec l'accessibilité Section 508. Saisissez la description entre guillemets simples.

La description s'affiche aussi sous forme contextuelle lorsque vous survolez le lien avec la souris dans la sortie de rapport.
Exemple : Création d'un lien vers un URL

L'exemple ci-après illustre la façon de lier un URL d'un rapport. L'en-tête Click here to access the IB homepage [Cliquez ici pour accéder à la page d'accueil IB] est lié à l'URL http://www.ibi.com. Les déclarations de feuille de style pertinentes sont mises en surbrillance dans la requête.

Notez que webserver indique le nom du serveur web qui exécute WebFOCUS et Developer Studio.

TABLE FILE GGSALES
ON TABLE SET PAGE-NUM OFF
SUM UNITS AND DOLLARS
BY CATEGORY BY REGION
HEADING
"Regional Sales Report"
"Click here to access the IB homepage."
" "
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=HEADING, LINE=2, OBJECT=TEXT, ITEM=1,
   URL=http://www.ibi.com, $ 
ENDSTYLE
END

La sortie est :

Lorsque vous cliquez sur le lien, le site Web s'affiche dans votre navigateur.
Exemple : Créer un lien vers une adresse URL pour exécuter une procédure de zoom en profondeur du serveur WebFOCUS

La requête suivante est initiée à partir d'une session du navigateur et exécute un rapport de zoom en profondeur stocké sur le serveur de rapports WebFOCUS.

Cette procédure est exécutée à partir d'un navigateur, donc le zoom en profondeur dans l'exemple est spécifié comme une adresse URL relative (l'adresse URL n'a pas de protocole, d'hôte, ou de port), puisque la procédure est soumise en utilisant le protocole, l'hôte et le port de la session de navigation actuelle.

Remarque : cette technique est utile dans une procédure Managed Reporting pour la création d'un zoom en profondeur vers une procédure du serveur WebFOCUS. La technique FOCEXEC= pour l'exécution d'une procédure de zooms en profondeur ne fonctionne pas par ce que Managed Reporting s'attend toujours à trouver la procédure dans le référentiel Managed Reporting.

La procédure principale est : 

TABLE FILE GGSALES
ON TABLE SET PAGE-NUM OFF
SUM UNITS AND DOLLARS
BY CATEGORY BY REGION
HEADING
"Regional Sales Report"
" "
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=DATA, COLUMN=REGION,
URL=/ibi_apps/WFServlet?(IBIF_ex='ggdrill' AREA=REGION IBIC_server='EDASERVE' IBI_APPS='IBISAMP'),$
ENDSTYLE
END

Le rapport de zoom en profondeur, qui doit être dans l'application ibisamp, est : 

-DEFAULTS &REGION='$*';
TABLE FILE GGSALES
ON TABLE SET PAGE-NUM OFF
SUM UNITS AND DOLLARS
BY PRODUCT
WHERE REGION = '&AREA'
HEADING
"Sales Report for Region &AREA"
" "
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La sortie du rapport principal est :

Si vous cliquez sur la région Nord-Est, la sortie est :

WebFOCUS