x

Fonctionnalité	Description	S'applique à
SKIP-LINE*	Ajoute une ligne vierge	HMTL (exige GRID=OFF) DHTML PDF PS EXL2K EXL07 XLSX
TYPE=SKIPLINE	Formate une ligne vierge	DHTML PDF PS
UNDER-LINE*	Souligne un groupe de tri	HMTL (exige GRID=OFF) DHTML PDF PS
TYPE=UNDERLINE	Formate un soulignement	DHTML PDF PS
STYLE={+|-}UNDERLINE*	Ajoute un soulignement à un composant de rapport, ou enlève un soulignement d'un composant de rapport autre qu'un titre de colonne.	HTML DHTML PDF PS EXL2K EXL07 XLSX
STYLE={+|-}EXTUNDERLINE*	Etend le trait de soulignement à, ou supprime le trait de soulignement de la colonne entière du rapport dans un rapport stylisé.	DHTML PDF PS PPT
BAR AS '{-|=}'*	Sélectionne un soulignement léger ou épais dans un rapport FML.	HTML DHTML PDF PS EXL2K

* Pas pris en charge avec la bordure.

x

Vous ne pouvez utiliser qu'un champ SKIP-LINE par requête de rapport.

display_command fieldname SKIP-LINE

ou

{ON|BY} fieldname SKIP-LINE [WHEN expression;]

où :

display_command

Est une commande d'affichage.

fieldname

Est le champ d'affichage ou de tri après lequel une ligne vierge est insérée.

SKIP-LINE utilisé conjointement avec un champ d'affichage ajoute une ligne vierge après chaque ligne affichée, ce qui applique en effet l'espacement double au rapport. L'espacement double est utile pour réviser un rapport, de sorte qu'il permet au lecteur de faire des annotations à côté des lignes individuelles.

SKIP-LINE utilisé avec les champs de tri ajoute une ligne vierge avant tout changement dans la valeur du champ. Cette condition ON est parmi les seules qui n'ont pas à faire référence à un champ de tri (BY) uniquement.

ON|BY

Est une phrase de tri vertical. Les deux termes sont synonymes.

WHEN expression

spécifie des lignes vierges conditionnelles dans l'affichage d'un rapport, comme cela est déterminé par une expression logique. Consultez Utilisation d'expressions pour plus de détails à propos des expressions.

Haut de page

Exemple : Ajout d'une ligne vierge entre des groupes de tri

Cette requête insère une ligne vierge avant tout changement de valeur du champ de tri EMP_ID.

DEFINE FILE EMPLOYEE
INCREASE/D8.2M = .05*CURR_SAL;
CURR_SAL/D8.2M=CURR_SAL;
NEWSAL/D8.2M=CURR_SAL + INCREASE;
END
 
TABLE FILE EMPLOYEE
PRINT CURR_SAL OVER INCREASE OVER NEWSAL
BY LOWEST 4 EMP_ID BY LAST_NAME BY FIRST_NAME 
ON EMP_ID SKIP-LINE 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT PDF
END

Les données relatives à chaque employé attirent l'attention et sont faciles à lire :

x

TYPE=SKIPLINE, attribute=value, $

où :

attribut

Est un attribut de feuille de style valable.

value

Est la valeur de l’attribut.

Remarque : cette option est prise en charge pour les rapports PDF, PS et HTML (lorsqu'elle est utilisée conjointement avec des feuilles de style en cascade internes).

Haut de page

Exemple : Ajout de couleur aux lignes vierges

Dans cette requête, des lignes vierges sont formatés pour s'afficher en argent dans la sortie. La déclaration de feuille de style pertinente est mise en surbrillance dans la requête.

SET ONLINE-FMT=PDF
TABLE FILE CENTINV
HEADING
"Low Stock Report"
" "
SUM QTY_IN_STOCK 
WHERE QTY_IN_STOCK LT 5000
BY PRODNAME
ON PRODNAME SKIP-LINE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=SKIPLINE, BACKCOLOR=SILVER, $ 
ENDSTYLE
END

Voici le rapport :

x

{ON|BY} fieldname UNDER-LINE [WHEN expression;]

où :

ON|BY

Est une phrase de tri vertical. Les deux termes sont synonymes.

fieldname

Est le champ de tri auquel le soulignement s'applique. UNDER-LINE ajoute un soulignement lorsque la valeur du champ de tri change. Un soulignement s'affiche automatiquement après les options telles que RECAP et SUB-TOTAL mais avant les sauts de page.

WHEN expression

spécifie des soulignements conditionnelles dans l'affichage d'un rapport, comme cela est déterminé par une expression logique. Consultez Utilisation d'expressions pour plus de détails à propos des expressions.

Haut de page

Exemple : Soulignement d'un groupe de tri

Cette requête ajoute un soulignement lorsque la valeur du champ de tri BANK_NAME change. Elle met l'attribut GRID à OFF, comme l'exige le rapport HTML.

TABLE FILE EMPLOYEE
PRINT EMP_ID AND BANK_ACCT AND LAST_NAME
BY BANK_NAME 
ON BANK_NAME UNDER-LINE 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Les données relatives à chaque banque attirent l'attention et sont faciles à lire :

x

TYPE=UNDERLINE ... COLOR={color|RGB} (r g b), $

où :

UNDERLINE

signifie des soulignements générés par ON fieldname UNDER-LINE.

COLOR

Spécifie la couleur du soulignement. Si le périphérique de sortie ou d'affichage ne supporte pas les couleurs, il substitue des tons gris. Noir est la valeur par défaut.

color

Est une des valeurs de couleur supportées. Pour consulter une liste des valeurs prises en charge, consultez Valeurs de couleur dans un rapport.

RGB

Spécifie la couleur de texte en utilisant un mélange de rouge, de vert et de bleu.

(r g b)

est l'intensité de rouge, de vert et de bleu souhaitée, respectivement. Les valeurs sont sur une échelle de 0 à 255, où 0 est la valeur la moins intense et 255 est la valeur la plus intense.

Notez que l'utilisation des trois composants de couleur au même niveau d'intensité a pour résultat des tons gris.

Remarque : cette option est prise en charge pour les rapports PDF, PS et HTML (lorsqu'elle est utilisée conjointement avec des feuilles de style en cascade internes).

Haut de page

Exemple : Formatage d'un soulignement de groupe de tri

Cette requête utilise UNDERLINE pour changer la couleur par défaut d'un soulignement de noir à rouge.

SET ONLINE-FMT = PDF
TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
HEADING
"Sales Report"
" "
ON CATEGORY UNDER-LINE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=UNDERLINE, COLOR=RED, $ 
ENDSTYLE
END

Cela a pour résultat une séparation attrayante entre les valeurs du groupe de tri. Voici le rapport PDF en ligne :

x

TYPE=type, [subtype,] STYLE=[+|-]UNDERLINE, $

où :

type

Est le composant de rapport. Pour voir la liste des valeurs valables, consultez Désignation de composants de rapport dans la syntaxe de feuille de style WebFOCUS.

subtype

Sont des attributs supplémentaires, tels que COLUMN, ACROSS et ITEM, nécessaires pour identifier le composant de rapport. Pour voir la liste des valeurs valables, consultez Désignation de composants de rapport dans la syntaxe de feuille de style WebFOCUS.

+

Ajoute un soulignement au style de texte hérité ou spécifie une combinaison de styles de texte (par exemple, STYLE=BOLD+UNDERLINE). C'est la valeur par défaut.

-

Enlève un soulignement d'un style de texte hérité.

x

Cette syntaxe s'applique à un rapport HTML avec une feuille de style en cascade interne.

TYPE=TITLE, [COLUMN=column,] STYLE=-UNDERLINE, $

où :

COLUMN=column

Spécifie une colonne. Pour voir la liste des valeurs valables, consultez Désignation de composants de rapport dans la syntaxe de feuille de style WebFOCUS.

Haut de page

Exemple : Ajout de soulignements de colonne et enlèvement de soulignements de titre de colonne

Cette requête ajoute des soulignements aux valeurs de la colonne CATEGORY et enlève les soulignements par défaut des titres de colonne dans un rapport HTML avec une feuille de style en cascade interne.

SET HTMLCSS = ON 
TABLE FILE MOVIES
PRINT TITLE DIRECTOR
BY CATEGORY
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=TITLE, STYLE=-UNDERLINE, $
TYPE=REPORT, COLUMN=CATEGORY, STYLE=UNDERLINE, $ 
ENDSTYLE
END

Voici le rapport partiel :

x

Par défaut,les soulignements de titres de colonnes dans un rapport se développent seulement du début à la fin du texte du titre de colonne. Vous pouvez développer le soulignement sur la colonne entière d'un rapport dans une sortie de rapport stylée à l'aide de l'option EXTUNDERLINE dans votre feuille de style WebFOCUS. EXTUNDERLINE est une option de l'attribut STYLE pour le composant de rapport TITLE. Est pris en charge pour les formats DHTML, PDF, PS, et PPT.

TYPE = TITLE, [COLUMN = colspec,] STYLE = [+|-]EXTUNDERLINE  ,$

où :

colspec

est toute spécification de colonne valide.

+EXTUNDERLINE

ajoute l'option EXTUNDERLINE au texte hérité ou spécifie une combinaison de styles de texte (par exemple, STYLE=BOLD+UNDERLINE).

-EXTUNDERLINE

supprime l'option EXTUNDERLINE du style de texte hérité.

x

• Le format HTML n'est pas pris en charge parce que le navigateur calcule la largeur de colonne et rend le rapport.
• GRID=ON et EXTUNDERLINE s'annulent mutuellement car la ligne GRID développe la largeur de la colonne. GRID annule tout style spécifié pour le soulignement du titre de colonne.

Haut de page

Exemple : Développer un soulignement sur toute la colonne de rapport

La requête suivante contre la source de données GGSALES calcule les ventes en dollars par ville et par date :

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                  
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
END

La sortie montre seulement les titres de colonnes soulignés :

Pour souligner les colonnes entières, générez la sortie dans un format qui peut être stylé et utilisez l'option EXTUNDERLINE dans l'attribut STYLE pour le composant TITLE. Par exemple, la requête suivante crée la sortie DHTML dans laquelle les titres de colonne sont en caractère gras et justifiés à gauche, et le soulignement est développé sur toute la colonne de rapport :

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                 
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
ON TABLE SET STYLE *  
TYPE=TITLE, STYLE= BOLD +EXTUNDERLINE, JUSTIFY=LEFT, $ 
ENDSTYLE
END

La sortie est :

La version suivante de la requête fait des options EXTUNDERLINE et JUSTIFY=LEFT, des options par défaut pour le composant TITLE, ensuite rend le titre de colonne Date en caractère gras et supprime le soulignement développé de cette colonne :

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                   
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
ON TABLE SET STYLE *  
TYPE=TITLE,STYLE= EXTUNDERLINE, JUSTIFY=LEFT ,$   
TYPE=TITLE,COLUMN= DATE, STYLE= -EXTUNDERLINE +BOLD ,$ 
ENDSTYLE                          
END

La sortie est :

x

Cette syntaxe s'applique aux rapports HTML.

BAR [AS '{-|=}'] OVER

où :

-

Génère un soulignement léger. Entourez le hyperlien de guillemets simples. C'est la valeur par défaut.

=

Génère un soulignement épais. Entourez le signe égale de guillemets simples.

Haut de page

Exemple : Changement du soulignement par défaut dans un rapport FML (HTML)

Cette requête chanqe le soulignement léger par défaut à un soulignement épais dans le rapport FML.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR AS '='                   OVER 
RECAP TOTCASH = R1 + R2 + R3;
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Un soulignement épais sépare la somme d'argent totale des données détaillées, et attire l'attention à cette première.

Haut de page

Exemple : Changement du soulignement par défaut dans un rapport FML (PDF)

Cette requête change le soulignement unique par défaut dans un rapport PDF à un soulignement double.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR AS '='                   OVER 
RECAP TOTCASH = R1 + R2 + R3;
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La sortie est :