La bifurcación condicional realiza una prueba de los valores de las variables y, en función de ella, transfiere el control a una etiqueta del procedimiento, con el comando -IF ... GOTO. Esto ayuda a controlar la ejecución de solicitudes y a construir un procedimiento dinámico, ejecutando o no ejecutando partes de un procedimiento.
Por ejemplo, puede comprobar si se ha creado un archivo de extracción a partir de un origen de datos de producción. Si el archivo de extracción existe, el programa ejecuta un conjunto de informes basados en la extracción. Si no existe, el programa se bifurca en torno a los informes y envía un mensaje a un archivo de registro.
x
Sintaxis: Cómo Realizar la bifurcación condicional
-IF expression [THEN] {GOTO label1|CONTINUE} [ELSE IF...;] [ELSE {GOTO label2|CONTINUE}];donde:
- expression
Es una expresión válida. Los valores literales no necesitan estar entre comillas simples a menos que contengan espacios en blanco o comas insertados.
- THEN
Es un comando opcional que mejora la legibilidad del comando.
- label1
Es un nombre de hasta 64 caracteres, definido por el usuario, que recibe el control cuando la prueba -IF es verdadera. No use espacios en blanco insertados ni el nombre de otro comando de Dialogue Manager, excepto -QUIT o -EXIT. No utilice operaciones aritméticas, lógicas, palabras que puedan confundirse con operaciones ni palabras reservadas como CONTINUE.
El texto de label puede estar situado antes o después de los criterios -IF, en el procedimiento.
- CONTINUE
Continúa el comando posterior al punto y coma del comando -IF.
Nota: No se puede utilizar CONTINUE como etiqueta en una declaración -IF.
- ELSE IF
Especifica una prueba -IF compuesta. El comando -IF debe termina con un punto y coma para indicar que la lógica se ha especificado. Para más información, consulte Cómo efectuar una prueba -IF compuesta.
- ELSE GOTO
Pasa el control a label2 cuando falla la prueba -IF.
Si un comando ocupa más de una línea, las líneas de continuación deben empezar por un guión y uno o varios espacios.
Ejemplo: Cómo establecer bifurcaciones condicionales
En el siguiente ejemplo el control pasa a la etiqueta -PRODSALES si &OPTION es igual a S. De lo contrario, el control pasa a la etiqueta -PRODRETURNS, que es la próxima línea del procedimiento.
-IF &OPTION EQ 'S' GOTO PRODSALES;
-PRODRETURNS
TABLE FILE SALES
PRINT PROD_CODE UNIT_SOLD
BY STORE_CODE
END
-EXIT
-PRODSALES
TABLE FILE SALES
SUM UNIT_SOLD
BY PROD_CODE
END
-EXIT
El siguiente comando especifica ambas transferencias de forma explícita:
-IF &OPTION EQ 'S' GOTO PRODSALES ELSE
- GOTO PRODRETURNS;Observe que la línea de continuación comienza con un guión seguido de un espacio.
Ejemplo: Cómo probar las variables estadísticas y del sistema
En el siguiente ejemplo, si los datos (&LINES) se recuperan con la solicitud, el procedimiento se bifurca en la etiqueta -PRODSALES. De lo contrario, finaliza.
TABLE FILE SALES
SUM UNIT_SOLD
BY PROD_CODE BY CITY
WHERE TOTAL UNIT_SOLD GE 50
ON TABLE HOLD
END
-IF &LINES NE 0 GOTO PRODSALES;
-EXIT
-PRODSALES
TABLE FILE SALES
SUM UNIT_SOLD
BY PROD_CODE ACROSS CITY
END
Ejemplo: Cómo ejecutar comandos apilados y salir del procedimiento
En el siguiente ejemplo, se ejecuta la primera o la segunda solicitud de informe, pero no ambas. Suponga que el informe ha sido abierto por un formulario HTML que emplea una variable de entrada de texto llamada &PROC, para indicar al usuario que proporcione el procedimiento que quiere ejecutar. El usuario puede introducir SALES o EMPLOYEE.
1. -IF &PROC EQ 'EMPLOYEE' GOTO EMPLOYEE;
2. -SALES
TABLE FILE SALES
SUM UNIT_SOLD
BY PROD_CODE
END
3. -EXIT
-EMPLOYEE
TABLE FILE EMPLOYEE
PRINT LAST_NAME
BY DEPARTMENT
ENDEl procedimiento se procesa del siguiente modo:
- Dialogue Manager pasa SALES a &PROC. Se realiza una prueba de -IF, que falla, ya que el valor de &PROC no es EMPLOYEE, y el control pasa a la próxima línea, -SALES.
Si el valor de &PROC fuese EMPLOYEE, el control pasaría a -EMPLOYEE.
- Se procesa el código FOCUS, que se apila para ser procesado más adelante.
- -EXIT ejecuta los comandos apilados. La salida se envía a la aplicación Cliente WebFOCUS y el procedimiento finaliza.
No se ejecuta la solicitud bajo la etiqueta -EMPLOYEE.
Este ejemplo también presenta una salida o cierre explícito. Si el valor de &PROC fuese EMPLOYEE, el control pasaría a la etiqueta -EMPLOYEE, después de la prueba -IF, y el procedimiento nunca recibiría un -EXIT. Se ejecutaría la solicitud TABLE FILE EMPLOYEE y el procedimiento terminaría automáticamente.
Ejemplo: Cómo cancelar la ejecución de un procedimiento con la bifurcación condicional
El siguiente ejemplo explica el uso de -QUIT para cancelar la ejecución, en base a los resultados de una prueba -IF. Suponga que el informe ha sido abierto por un formulario HTML que emplea una variable de entrada de texto llamada &SELECT, para indicar al usuario que proporcione el procedimiento que quiere ejecutar.
-IF &SELECT EQ 'DONE' GOTO QUIT;
-REPORT
TABLE FILE SALES
SUM UNIT_SOLD
BY PROD_CODE
WHERE AREA EQ '&SELECT';
END
-RUN
-QUIT
El usuario ejecuta los informes secuenciales pulsando el botón Anterior del navegador, introduciendo un nuevo valor para SELECT y reenviando el formulario. Si se ha seleccionado un código de producto, el procedimiento continúa por la próxima línea y la solicitud se ejecuta antes de que aparezca -QUIT. Cuando el usuario introduce DONE, el control pasa a -QUIT. Se cierra el procedimiento.
x
Cómo efectuar una prueba -IF compuesta
La prueba -IF compuesta consta de una serie de pruebas -IF anidadas unas dentro de otras. Puede usar una prueba -IF compuesta cuando cada prueba especifica una etiqueta de destino.
Ejemplo: Cómo usar una prueba -IF compuesta
En el siguiente ejemplo, si el valor de &OPTION no es R ni tampoco S, el procedimiento finaliza (-GOTO QUIT). -QUIT sirve como etiqueta de destino para GOTO y como comando ejecutable. Suponga que el informe ha sido abierto por un formulario HTML que emplea una variable de entrada de texto llamada &OPTION, para indicar al usuario que proporcione el procedimiento que quiere ejecutar.
-IF &OPTION EQ 'R' THEN GOTO PRODRETURNS ELSE IF
- &OPTION EQ 'S' THEN GOTO PRODSALES ELSE
- GOTO QUIT;
-PRODRETURNS
TABLE FILE SALES
PRINT PROD_CODE UNIT_CODE
BY STORE_CODE
END
-EXIT
-PRODSALES
TABLE FILE SALES
SUM UNIT_SOLD
BY PROD_CODE
END
-QUIT
