x

-<description>text</description>

donde:

text

Es la descripción del procedimiento. Si la descripción requiere varias líneas, repita las etiquetas <description> y </description>

Principio de página

Ejemplo: Cómo añadir una descripción del procedimiento

Ésta es una descripción del procedimiento. Observe que la etiqueta sólo es visible en el código XML devuelto.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>

TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE'
WHERE STORENAME EQ '&STORENAME'
WHERE PRODNAME EQ '&PRODNAME'
END

x

-<heading> text </heading>

donde:

text

Es el encabezado que aparecerá en el formulario.

Principio de página

Ejemplo: Cómo añadir un encabezado

El código siguiente proporciona un aviso con texto para el formulario.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>

-<heading> Please specify a state, storename and product name: </heading>

TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE'
WHERE STORENAME EQ '&STORENAME'
WHERE PRODNAME EQ '&PRODNAME'
END

x

'&variable.description.'

donde:

&variable

Es el nombre de la variable, incluido el ampersand (&), cuyo valor se está solicitando.

description

Es una descripción de la variable que sustituye al nombre de la variable, en el aviso.

Nota: Éstas son las limitaciones de uso para los valores de la descripción:

• El carácter de ampersand (&) es compatible en la descripción de una variable, si especifica el carácter de barra vertical (|) inmediatamente después del carácter &, en la descripción.
• El punto (.) no puede usarse en una descripción, ya que es el delimitador que especifica el principio y final del valor de descripción.
• El carácter de paréntesis de apertura, debe estar precedido de un espacio.

Principio de página

Ejemplo: Cómo añadir la descripción de una variable

El ejemplo siguiente presenta un nombre más descriptivo para los campos STATE, STORENAME y PRODNAME, en el formulario. Las descripciones de los campos preceden a los controles de campos, en el formulario de aviso automático.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>
-<heading> Please specify a state, storename and product name: </heading>
TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE.2 letters for US State.'
WHERE STORENAME EQ '&STORENAME.Store Name.'
WHERE PRODNAME EQ '&PRODNAME.Product Name.'
END

x

-DEFAULT variable=value

donde:

variable

Es la variable, incluido el ampersand, para el que está estableciendo un valor por defecto.

value

Es el valor predeterminado de la variable.

Principio de página

Ejemplo: Cómo establecer el valor predeterminado de una variable

En el ejemplo siguiente se ha establecido el valor predeterminado NY para el campo STATE. Observe que debe haber un ampersand delante del nombre del campo en el comando -DEFAULT para que la variable ampersand contenga un atributo predeterminado en el formulario.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>
-<heading> Please specify a state, storename and product name: </heading>

-DEFAULT &STATE=NY

TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE.2 letters for US State.'
WHERE STORENAME EQ '&STORENAME.Store Name.'
WHERE PRODNAME EQ '&PRODNAME.Product Name.'
END

x

-DEFAULTH variable=value

donde:

variable

Es el nombre de la variable oculta.

value

Es el valor inicial de la variable.

x

'&variable.(value,value2[,value3][,value4]...).[description.]'

donde:

&variable

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores.

value, value2, value3, value4...

Son los valores que forman parte de la lista de valores que se pueden seleccionar para las variables.

description

Es una descripción opcional de la variable. Para más detalles sobre las restricciones, consulte Cómo añadir la descripción de una variable al formulario.

Nota: Los valores estáticos no pueden contener el carácter de coma (,) si se encuentran especificados en la sintaxis de la declaración WHERE, ya que la coma se emplea como carácter delimitador a la hora de especificar valores de visualización. Si uno o varios valores estáticos presentan una coma, colóquelos en un archivo y utilice la funcionalidad de lista dinámica (FIND).

Principio de página

Ejemplo: Cómo añadir una lista estática de selección individual de valores

A continuación aparece una lista con valores válidos para el campo STORENAME. El usuario sólo puede seleccionar un valor de la lista.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>
-<heading> Please specify a state, storename and product name: </heading>
-DEFAULT &STATE=NY
TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE.2 letters for US State.'
WHERE STORENAME EQ '&STORENAME.(eMart,TV City,Web Sales).Store Name.'
WHERE PRODNAME EQ '&PRODNAME.Product Name.'
END

x

'&variable.(FIND return_fieldname [,display_fieldname] IN datasource).[description.]'

donde:

&variable

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores.

return_fieldname

Es el nombre del campo que contiene los valores posibles de las variables devueltas al FOCEXEC.

display_fieldname

Es el nombre del campo que contiene los valores posibles de las variables mostradas en el formulario de aviso automático.

Nota: return_fieldname y display_fieldname pueden ser un campo DEFINE en una MFD (descripción de archivo máster), pero no un campo DEFINE en un procedimiento.

datasource

Es el origen de datos que contiene los campos especificados en return_fieldname y display_fieldname. Si los campos residen en un archivo de referencia cruzada perteneciente a un origen de datos usado en un join, utilice el nombre del origen de datos que contiene los campos.

Nota: En las listas dinámicas, el Cliente WF construye la solicitud para obtener los valores, mediante el origen de datos especificado. Todos los comandos de entornos, como los comandos SET, necesarios para obtener los valores del origen de datos especificado, deben emitirse en el perfil del Servidor de WebFOCUS, en el perfil del usuario o en el perfil del Cliente WebFOCUS.

description

Es una descripción opcional de la variable. Para más detalles sobre las restricciones, consulte Cómo añadir la descripción de una variable al formulario.

Principio de página

Ejemplo: Cómo añadir una lista dinámica de selección individual de valores

La lista siguiente incluye valores válidos para el campo de nombre de producto. La lista se rellena con valores del origen de datos CENTORD. El usuario sólo puede seleccionar un valor de la lista.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product number. </description>
-<heading> Please specify a state, storename and product name: </heading>
-DEFAULT &STATE=NY
TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PROD_NUM
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE.2 letters for US State.'
WHERE STORENAME EQ '&STORENAME.(eMart,TV City,Web Sales).Store Name.'
WHERE PROD_NUM EQ '&PROD_NUM.(FIND PROD_NUM,PRODNAME IN CENTORD).Product Name.'
END

x

&variable.({AND|OR}(<displayvalue1,value1>, <displayvalue2,value2>,...<displayvalueN,valueN>)).[description.]

donde:

&variable

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores.

displayvalue, displayvalue2, displayvalue3, displayvalue4...

Son los valores que forman parte de la lista de valores que se pueden seleccionar para las variables.

value, value2, value3, value4...

Son los valores que forman parte de la lista de valores seleccionables de variables, pasados al servidor de informes.

description

Es una descripción opcional de la variable. Para más detalles sobre las restricciones, consulte Cómo añadir la descripción de una variable al formulario.

Nota: Los valores estáticos no pueden contener el carácter de coma (,) si se encuentran especificados en la sintaxis de la declaración WHERE, ya que la coma se emplea como carácter delimitador a la hora de especificar valores de visualización. Si uno o varios valores estáticos presentan una coma, colóquelos en un archivo y utilice la funcionalidad de lista dinámica (FIND).

Principio de página

Ejemplo: Cómo añadir una lista estática de selección múltiple de valores

A continuación aparece una lista con valores válidos para el campo STORENAME. El usuario puede seleccionar más de un valor de la lista.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>
-<heading> Please specify a state, storename and product name: </heading>
-DEFAULT &STATE=NY
TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STATE EQ '&STATE.2 letters for US State.'
WHERE STORENAME EQ &STORENAME.(OR(eMart,TV City,Web Sales)).Store Name.
WHERE PRODNAME EQ '&PRODNAME.Product Name.'
END

x

&variable.({AND|OR}(FIND return_fieldname [,display_fieldname] IN datasource)).[description.]

donde:

&variable

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores.

return_fieldname

Es el nombre del campo que contiene los valores posibles de las variables devueltas al FOCEXEC.

display_fieldname

Es el nombre del campo que contiene los valores posibles de las variables mostradas en el formulario de aviso automático.

Nota: return_fieldname y display_fieldname pueden ser un campo DEFINE en una MFD (descripción de archivo máster), pero no un campo DEFINE en un procedimiento.

datasource

Es el origen de datos que contiene los campos especificados en return_fieldname y display_fieldname. Si los campos residen en un archivo de referencia cruzada perteneciente a un origen de datos usado en un join, utilice el nombre del origen de datos que contiene los campos.

Nota: En las listas dinámicas, el Cliente WF construye la solicitud para obtener los valores, mediante el origen de datos especificado. Todos los comandos de entornos, como los comandos SET, necesarios para obtener los valores del origen de datos especificado, deben emitirse en el perfil del Servidor de WebFOCUS, en el perfil del usuario o en el perfil del Cliente WebFOCUS.

description

Es una descripción opcional de la variable. Para más detalles sobre las restricciones, consulte Cómo añadir la descripción de una variable al formulario.

Principio de página

Ejemplo: Cómo añadir una lista dinámica de selección múltiple de valores

A continuación aparece una lista con valores válidos para el campo de estado. La lista se rellena con valores del origen de datos CENTORD. El usuario puede seleccionar más de un valor de la lista.

-<description>This procedure reports on Inventory </description>
-<description>by store code, state and product name. </description>
-<heading> Please specify a storename, state and product name: </heading>
TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STORE_CODE BY STATE BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE STORE_CODE EQ &STORE_CODE.(OR(FIND STORE_CODE,STORENAME 
IN CENTORD)).Store Name.
WHERE STATE EQ &STATE.(OR(CA,IL,MA,NY,NJ,FL,TX)).2 letters for US State.
WHERE PRODNAME EQ '&PRODNAME.(FIND PRODNAME IN CENTORD).Product Name.'
END

x

&variable.(FROM Range1 TO Range2).

donde:

&variable

Es la variable numérica, incluido el ampersand (&), para la que está proporcionando una lista de valores.

Range1

Es el valor numérico inicial del intervalo de la lista de valores.

Range2

Es el valor numérico final del intervalo de la lista de valores.

Principio de página

Ejemplo: Cómo añadir una lista de intervalo de valores

A continuación aparece una lista de los valores numéricos aceptables para el campo QTY_IN_STOCK. Esta lista se rellena con valores del origen de datos CENTORD, que caen dentro del intervalo.

-<description>This procedure reports on Inventory </description>
-<description>by state, storename and product name. </description>
-<heading> Please specify a state, storename and product name: </heading>
TABLE FILE CENTORD
SUM QTY_IN_STOCK BY STATE BY STORENAME BY PRODNAME
ON TABLE SUBHEAD
"Inventory Report"
WHERE QTY_IN_STOCK GT &STOCK.(FROM 5000 TO 10000).
END

x

• No ponga los valores individuales entre comillas simples al crear una lista de selección múltiple de valores. WebFOCUS coloca cada valor entre comillas simples, automáticamente, en las listas de selección múltiple. Si añade sus propias comillas simples, se producirá un error. Por ejemplo, WHERE COUNTRY EQ '&COUNTRY' genera un error. Emplee &COUNTRY sin comillas.
• Al utilizar el resultado de una lista de selección múltiple de valores como parámetro en un drill-down, emplee QUOTEDSTRING para manipular los espacios en blanco insertados, añadidos como separadores entre los parámetros.

  El ejemplo siguiente es correcto:

  FOCEXEC=DRILLDOWN(COUNTRY=&COUNTRY.QUOTEDSTRING OTHER=xxx)

  En cambio, el ejemplo siguiente no lo es; los espacios en blanco insertados en el parámetro &COUNTRY darán por terminado el drill-down.

  FOCEXEC=DRILLDOWN(COUNTRY=&COUNTRY OTHER=xxx)

  Para más información, consulte Cómo crear una cadena estándar, delimitada por comillas

x

• Si su informe contiene una lista estática de selección múltiple de valores, puede utilizar la opción Seleccionar todo para escoger todos los valores de la lista de parámetros. Internamente, el valor FOC_ALL se pasa para la opción Seleccionar todo de la lista estática de selección múltiple, lo que provoca que el parámetro quede establecido en todos los valores de la lista de selección múltiple, separados por el calificador AND u OR, en la declaración WHERE. Para más información, consulte Procesamiento interno de Seleccionar todo.
• Si su informe contiene una lista dinámica de selección múltiple de valores, puede utilizar la opción Ninguna selección para que no se seleccione ningún valor de la lista de parámetros. Internamente, se pasa el valor _FOC_NULL o FOC_NONE para la opción Ninguna selección de la lista dinámica de selección múltiple. El valor pasado por defecto es _FOC_NULL. Sin embargo, puede determinar los valores que se pasarán para la opción Ninguna selección, mediante la variable IBIF_describe_null, que configura el valor enviado por el Cliente WebFOCUS. Para más información sobre las propiedades de Aviso de parámetros, consulte el manual Seguridad y administración de WebFOCUS.
• Las frases y expresiones individuales que contengan el valor _FOC_NULL, quedan eliminadas del procedimiento antes de que éste sea ejecutado por el servidor de informes. Para más información sobre _FOC_NULL, consulte Procesamiento interno de _FOC_NULL.
• Las líneas de Dialogue Manager (no empiezan por por un guión '-') que contengan el valor FOC_NONE, quedan eliminadas del procedimiento antes de que éste sea ejecutado por el servidor de informes. Para más información sobre FOC_NONE, consulte Procesamiento interno de _FOC_NONE.

x

Cuando la opción Ninguna selección se ha seleccionado o codificado de forma manual, dentro de una lista de selección múltiple, el valor del parámetro enviado al Servidor de WebFOCUS es _FOC_NULL, por defecto. A continuación, la capa de descripción del Servidor de WebFOCUS realiza un procesamiento interno de búsqueda en el procedimiento, para eliminar las frases de WebFOCUS (como BY o WHERE) o las expresiones que contienen _FOC_NULL. Después, el procedimiento es pasado al motor central de WebFOCUS para que ejecute la solicitud.

El siguiente ejemplo de WHERE explica cómo seleccionar o codificar manualmente la opción Ninguna selección, que genera el valor _FOC_NULL para las listas dinámicas de selección múltiple:

WHERE CATEGORY EQ &CATEGORY.(OR(FIND CATEGORY IN MOVIES)).CATEGORY. AND DIRECTOR EQ &DIRECTOR.(OR(FIND DIRECTOR IN MOVIES)).DIRECTOR.;

Aunque la opción devuelta para CATEGORY sea Ninguna selección, la prueba de DIRECTOR se procesará de cualquier modo.

El siguiente ejemplo de WHERE explica cómo seleccionar o codificar manualmente la opción Ninguna selección, que genera el valor _FOC_NULL para una lista estática de selección múltiple y otra dinámica:

WHERE COPIES EQ 
&COPIES.(<No Selection,_FOC_NULL>,<1,1>,<2,2>,<3,3>).COPIES. 
AND DIRECTOR EQ &DIRECTOR.(OR(FIND DIRECTOR IN MOVIES)).DIRECTOR.;

Cada lista debe estar completamente codificada en una sola línea del procedimiento.

Si está codificando un HEADING, FOOTING, SUBHEAD o SUBFOOT, debe haber, como mínimo, una línea que no incluya parámetro que se puede asignar al valor de _FOC_NULL.

x

Cuando la opción Ninguna selección se ha seleccionado o codificado de forma manual, dentro de una lista de selección múltiple, el valor del parámetro que puede enviarse al Servidor de WebFOCUS es FOC_NONE. A continuación, la capa de descripción del Servidor de WebFOCUS realiza un procesamiento interno de búsqueda en el procedimiento, para eliminar todas las líneas que no sean de Dialogue Manager (no empiezan por un guión ‘-’) y contengan FOC_NONE. Después, el procedimiento es pasado al motor central de WebFOCUS para que ejecute la solicitud.

Los siguientes ejemplos de WHERE indican cómo seleccionar o codificar manualmente la opción Ninguna selección, que genera el valor de FOC_NONE:

• Multiselección dinámica

  WHERE CATEGORY EQ &CATEGORY.(OR(FIND CATEGORY IN MOVIES)).CATEGORY.;

• Multiselección estática con FOC_NONE

  WHERE COPIES EQ &COPIES.(<No Selection,FOC_NONE>,<1,1>,<2,2>,<3,3>).
  COPIES.;

Consideraciones de codificación de FOC_NONE:

• Si está codificando un HEADING, FOOTING, SUBHEAD o SUBFOOT, debe haber, como mínimo, una línea que no incluya parámetro que se puede asignar al valor de FOC_NONE.
• Si emplea la opción Ninguna selección en el interior de una lista dinámica de selección múltiple, o una declaración WHERE codificada manualmente pasa el valor de parámetro FOC_NONE:
  • Codifique una declaración de WHERE que pase el valor FOC_NONE en una línea individual del procedimiento (FOCEXEC). Esto previene la eliminación parcial de la declaración de WHERE, en la solicitud, y evita que se produzca el error FOC002.
  • No codifique una declaración de WHERE compleja, en una línea individual, cuando se haya pasado FOC_NONE para un campo. Esto evita que se elimine la totalidad de la declaración WHERE compleja de la solicitud. Observe que la declaración WHERE compleja incluye pruebas de selección de más de un campo, a través de los operadores AND u OR.

x

Cuando ejecuta una solicitud con una lista estática de selección múltiple, el recurso de Aviso automático de ampersands añade la opción Seleccionar todo, dinámicamente, a la lista de valores que, al estar seleccionada, asigna al parámetro todos los valores de la lista estática de selección múltiple. Si ha seleccionado valores individuales y de Seleccionar todo, se ignora el valor de Seleccionar todo.

Cuando Seleccionar todo se encuentra seleccionado, se asigna el valor de FOC_ALL al parámetro. Después, el Recurso de aviso automático de ampersands de WebFOCUS lleva a cabo un procesamiento interno para asignar los valores de la lista de selección al parámetro, separados por el calificador (AND u OR) especificado en la declaración WHERE que está haciendo referencia al parámetro.

El siguiente ejemplo presenta una declaración WHERE que está usando el calificador OR, con una lista estática de selección múltiple para el parámetro &RATING. El parámetro &RATING aparece citado en la declaración WHERE y en HEADING. HEADING muestra el modo en que el valor del parámetro se establece en todos los valores de la lista de selección múltiple, separados por el calificador OR.

TABLE FILE MOVIES
HEADING
" Ratings selected: "
" &RATING "
PRINT
     'MOVIES.MOVINFO.TITLE'
     'MOVIES.MOVINFO.COPIES'
BY 'MOVIES.MOVINFO.RATING'
BY 'MOVIES.MOVINFO.CATEGORY'
HEADING
""
FOOTING
""

WHERE MOVIES.MOVINFO.RATING EQ &RATING.(OR(<General Audience,G>,
  <Not Rated,NR>,<Parental Guidance,PG>,<PG Over 13,PG13>,
  <R Over 18,R>)).Rating.;

ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=TITLE,
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=12,
     STYLE=BOLD,
$
ENDSTYLE
END

La siguiente imagen muestra el formulario de Aviso automático de ampersands y el informe, con Seleccionar todo seleccionado.

El Cliente WebFOCUS asigna &RATING a la lista de valores, creando y añadiendo la siguiente sintaxis a la solicitud enviada al servidor de informes:

 -SET &RATING='''G'' OR ''NR'' OR ''PG'' OR ''PG13'' OR ''R'''; 

x

cmd &var.(<dsply1[,val1>],<dsply2[,val2>],...<dsplyN[,valN>]).[desc.]

donde:

cmd

Es el comando al que se aplicará la lista de campos. Los valores válidos son PRINT, COUNT, SUM, WRITE, ADD, BY y ACROSS.

&var

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores de campos.

dsply1, dsply2, ...

Son las entradas que aparecen en una página de inicio. Al seleccionar una entrada, el campo correspondiente queda seleccionado automáticamente.

val1, val2, ...

Son los nombres de campos pasados al servidor de informes. Puede tratarse de nombres de campos cualificados que pueden ser omitidos, si el valor de visualización es idéntico al nombre del campo.

desc

Es una descripción opcional de la variable.

Nota: La totalidad del comando, incluida la descripción, si la hay, debe aparecer en una línea de la solicitud de informe.

Principio de página

Ejemplo: Cómo añadir listas de selección simple de campos de suma y clasificación

La siguiente solicitud, basada en el origen de datos GGSALES, permite que el usuario seleccione una de estas opciones de cada lista al ejecutar el procedimiento:

• Suma: DOLLARS, BUDDOLLARS, UNITS.
• Campos BY: CATEGORY, PRODUCT.
• Campos ACROSS: REGION, ST, Ninguno.

  Nota: Para información sobre la opción Ninguna selección, consulte Procesamiento interno de _FOC_NONE.

TABLE FILE GGSALES
HEADING
"Sales Report Summary for: "
"Fields: &SumFlds"
"Sort: &SortBy"
"Across: &Acrs"
" "
SUM &SumFlds.(<Sales,DOLLARS>,<Budget,BUDDOLLARS>,<Units,UNITS>).Sum.
BY &SortBy.(<Category,GGSALES.SALES01.CATEGORY>,<PRODUCT>).By.
ACROSS &Acrs.(<Area,REGION>,<State,ST>,<None,FOC_NONE>).Across.
WHERE REGION NE 'West'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, FONT=ARIAL,SIZE=10,SQUEEZE=ON,$
TYPE=HEADING, FONT=ARIAL, STYLE=BOLD, JUSTIFY=LEFT,$
TYPE=HEADING, LINE=1, FONT=ARIAL, STYLE=BOLD, JUSTIFY=LEFT,$
TYPE=TITLE, BACKCOLOR=BLACK, COLOR=WHITE,$
TYPE=ACROSSTITLE, BACKCOLOR=LIGHT BLUE, COLOR=BLUE,$
TYPE=ACROSSVALUE, BACKCOLOR=LIGHT GRAY, COLOR=GREEN,$
END

Al ejecutar la solicitud se abre la siguiente página de inicio, donde la selección del campo de clasificación REGION aparece como Área, la selección del campo DOLLARS, como Ventas, la del campo de clasificación CATEGORY y los campos de visualización BUDDOLLARS y UNITS, con un uso mixto de mayúsculas y minúsculas, y el valor de visualización de PRODUCT es idéntico al nombre del campo de clasificación. Sólo se permite una selección de cada lista.

Si selecciona Ventas, Categoría y Ninguno, se genera el informe siguiente:

x

cmd &var.(cmd(<dsply1[,val1>],<dsply2[,val2>],...<dsplyN[,srtN>])).[desc.]

donde:

cmd

Es el comando al que se aplicará la lista de campos. Los valores válidos son BY y ACROSS. Si añade el comando alrededor de la lista de selección, se genera una lista de selección múltiple.

&var

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores de campos.

dsply1, dsply2, ...

Son las entradas que aparecen en una página de inicio. Al seleccionar una entrada, el campo de clasificación correspondiente queda seleccionado automáticamente.

val1, val2, ...

Son los nombres de campos pasados al servidor de informes. Puede tratarse de nombres de campos cualificados que pueden ser omitidos, si el valor de visualización es idéntico al nombre del campo.

desc

Es una descripción opcional de la variable.

Nota: La totalidad del comando, incluida la descripción, si la hay, debe aparecer en una línea de la solicitud de informe.

x

cmd &var.(AND(<dsply1[,val1>],<dsply2[,val2>],...<dsplyN[,srtN>])).[desc.]

donde:

cmd

Es el comando al que se aplicará la lista de campos. Los valores válidos son PRINT, COUNT, SUM, WRITE y ADD.

&var

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores de campos.

AND

Es el conector que genera una lista de selección múltiple.

dsply1, dsply2, ...

Son las entradas que aparecen en una página de inicio. Al seleccionar una entrada, el campo de clasificación correspondiente queda seleccionado automáticamente.

val1, val2, ...

Son los nombres de campos pasados al servidor de informes. Puede tratarse de nombres de campos cualificados que pueden ser omitidos, si el valor de visualización es idéntico al nombre del campo.

desc

Es una descripción opcional de la variable.

Nota: La totalidad del comando, incluida la descripción, si la hay, debe aparecer en una línea de la solicitud de informe.

Principio de página

Ejemplo: Cómo añadir listas de selección múltiple de campos de suma y clasificación

La siguiente solicitud, basada en el origen de datos GGSALES, permite que el usuario seleccione una o varias de estas opciones al ejecutar el procedimiento:

• Suma: DOLLARS, BUDDOLLARS, UNITS.
• Campos BY: CATEGORY, PRODUCT.
• Campos ACROSS: REGION, ST, Ninguno.

TABLE FILE GGSALES
HEADING
"Sales Report Summary for: "
"Fields: &SumFlds"
"Sort: &SortBy"
"Across: &Acrs"
" "
SUM &SumFlds.(AND(<Sales,DOLLARS>,<Budget,BUDDOLLARS>,<Units,UNITS>)).Sum.
BY &SortBy.(BY(<Category,GGSALES.SALES01.CATEGORY>,<PRODUCT>)).By.
ACROSS &Acrs.(ACROSS(<Area,REGION>,<State,ST>,<None,FOC_NONE>)).Across.
WHERE REGION NE 'West'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, FONT=ARIAL,SIZE=10,SQUEEZE=ON,$
TYPE=HEADING, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=HEADING, LINE=1, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=TITLE, BACKCOLOR=BLACK, COLOR=WHITE,$
TYPE=ACROSSTITLE, BACKCOLOR=LIGHT BLUE, COLOR=BLUE,$
TYPE=ACROSSVALUE, BACKCOLOR=LIGHT GRAY, COLOR = GREEN,$
END

Al ejecutar la solicitud se abre la siguiente página de inicio, donde la selección del campo de clasificación REGION aparece como Área, la selección del campo DOLLARS, como Ventas, la del campo de clasificación CATEGORY y los campos de visualización BUDDOLLARS y UNITS, con un uso mixto de mayúsculas y minúsculas, y el valor de visualización de PRODUCT es idéntico al nombre del campo de clasificación:

Si selecciona Ventas, Unidades, Categoría y Área, se genera el informe siguiente:

x

Los ejemplos siguientes presentan tres orígenes de datos utilizados en los ejemplos en que se crearon las listas dinámicas de campos:

• GGDETFLD, que contiene nombres de campos del origen de datos GGSALES que se usarán como campos de visualización en listas de selección.
• GGBYFLD, que contiene nombres de campos del origen de datos GGSALES que se usarán como campos BY en listas de selección.
• GGACRFLD, que contiene nombres de campos del origen de datos GGSALES que se usarán como campos ACROSS en listas de selección.

Principio de página

Ejemplo: Cómo crear el origen de datos GGDETFLD

El procedimiento siguiente crea el origen de datos FOCUS, llamado GGDETFLD:

APP HOLD IBISAMP
DEFINE FILE SYSCOLUM
FLDDESC/A20=IF NAME EQ 'DOLLARS' THEN 'Dollars' 
  ELSE IF NAME EQ 'BUDDOLLARS' THEN 'Budget' 
  ELSE IF NAME EQ 'UNITS' THEN 'Units' ELSE 'N/A';
END
TABLE FILE SYSCOLUM
PRINT FLDDESC
BY NAME
WHERE TBNAME EQ 'GGSALES'
WHERE NAME EQ 'DOLLARS' OR 'BUDDOLLARS' OR 'UNITS'
ON TABLE HOLD AS GGDETFLD FORMAT FOCUS
END

Principio de página

Ejemplo: Cómo crear el origen de datos GGBYFLD

El procedimiento siguiente crea el origen de datos FOCUS, llamado GGBYFLD:

APP HOLD IBISAMP
DEFINE FILE SYSCOLUM
FLDDESC/A20=IF NAME EQ 'CATEGORY' THEN 'Category' 
  ELSE IF NAME EQ 'PRODUCT' THEN 'Product' ELSE 'N/A';
END
TABLE FILE SYSCOLUM
PRINT FLDDESC
BY NAME
WHERE TBNAME EQ 'GGSALES'
WHERE NAME EQ 'CATEGORY' OR 'PRODUCT'
ON TABLE HOLD AS GGBYFLD FORMAT FOCUS
END

Principio de página

Ejemplo: Cómo crear el origen de datos GGACRFLD

El procedimiento siguiente crea el origen de datos FOCUS, llamado GGACRFLD:

APP HOLD IBISAMP
DEFINE FILE SYSCOLUM
FLDDESC/A20=IF NAME EQ 'REGION' THEN 'Region' 
  ELSE IF NAME EQ 'ST' THEN 'State' ELSE 'N/A';
END
TABLE FILE SYSCOLUM
PRINT FLDDESC
BY NAME
WHERE TBNAME EQ 'GGSALES'
WHERE NAME EQ 'REGION' OR 'ST'
ON TABLE HOLD AS GGACRFLD FORMAT FOCUS
END

x

cmd &var.(FIND return_fieldname [,display_fieldname] IN datasource).[description.]

donde:

cmd

Es el comando al que se aplicará la lista de campos. Los valores válidos son PRINT, COUNT, SUM, WRITE, ADD, BY y ACROSS.

&var

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores de campos.

return_fieldname

Es el nombre del campo que contiene los valores posibles de las variables devueltas al FOCEXEC.

display_fieldname

Es el nombre del campo que contiene los valores posibles de las variables mostradas en el formulario de aviso automático.

Nota: return_fieldname y display_fieldname pueden ser un campo DEFINE en un archivo máster, pero no un campo DEFINE en un procedimiento.

datasource

Es el origen de datos que contiene los campos especificados en return_fieldname y display_fieldname. Si los campos residen en un archivo de referencia cruzada perteneciente a un origen de datos usado en un join, utilice el nombre del origen de datos que contiene los campos.

Nota: En las listas dinámicas, el Cliente WebFOCUS construye la solicitud para obtener los valores, mediante el origen de datos especificado. Todos los comandos de entornos, como los comandos SET, necesarios para obtener los valores del origen de datos especificado, deben emitirse en el perfil del Servidor de WebFOCUS, en el perfil del usuario o en el perfil del Cliente WebFOCUS.

description

Es una descripción opcional de la variable.

Principio de página

Ejemplo: Cómo crear listas dinámicas de selección simple de campos de visualización y clasificación

La siguiente solicitud, basada en el origen de datos GGSALES, genera tres listas dinámicas de selección simple mediante la recuperación de nombres de campos de los orígenes de datos FOCUS GGDETFLD, GGBYFLD y GGACRFLD:

TABLE FILE GGSALES
HEADING
"Sales Report Summary for: "
"Fields: &SumFlds"
"Sort: &SortBy"
"Across: &Acrs"
" "
SUM &SumFlds.(FIND NAME, FLDDESC IN GGDETFLD).Sum Fields.
BY &SortBy.(FIND NAME, FLDDESC IN GGBYFLD).By.
ACROSS &Acrs.(FIND NAME, FLDDESC IN GGACRFLD).Across.
WHERE REGION NE 'West'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, FONT=ARIAL,SIZE=10,SQUEEZE=ON,$
TYPE=HEADING, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=HEADING, LINE=1, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=TITLE, BACKCOLOR=BLACK, COLOR=WHITE,$
TYPE=ACROSSTITLE, BACKCOLOR=LIGHT BLUE, COLOR=BLUE,$
TYPE=ACROSSVALUE, BACKCOLOR=LIGHT GRAY, COLOR = GREEN,$
END

Si ejecuta la solicitud, se abre la siguiente página de inicio con listas de selección simple para los comandos SUM, BY y ACROSS:

Si selecciona Dólares en la lista desplegable Campos de suma, Categoría, en la lista By, y Región, en la lista Across, se genera el informe siguiente:

x

cmd &var.(cmd(FIND return_fieldname [,display_fieldname] IN datasource)).[description.]

donde:

cmd

Es el comando al que se aplicará la lista de campos. Los valores válidos son BY y ACROSS. Si añade el comando alrededor de la lista de selección, se genera una lista de valores de selección múltiple.

&var

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores de campos.

return_fieldname

Es el nombre del campo que contiene los valores posibles de las variables devueltas al FOCEXEC.

display_fieldname

Es el nombre del campo que contiene los valores posibles de las variables mostradas en el formulario de aviso automático.

Nota: return_fieldname y display_fieldname pueden ser un campo DEFINE en un archivo máster, pero no un campo DEFINE en un procedimiento.

datasource

Es el origen de datos que contiene los campos especificados en return_fieldname y display_fieldname. Si los campos residen en un archivo de referencia cruzada perteneciente a un origen de datos usado en un join, utilice el nombre del origen de datos que contiene los campos.

Nota: En las listas dinámicas, el Cliente WebFOCUS construye la solicitud para obtener los valores, mediante el origen de datos especificado. Todos los comandos de entornos, como los comandos SET, necesarios para obtener los valores del origen de datos especificado, deben emitirse en el perfil del Servidor de WebFOCUS, en el perfil del usuario o en el perfil del Cliente WebFOCUS.

description

Es una descripción opcional de la variable.

x

cmd &var.(AND(FIND return_fieldname [,display_fieldname] IN datasource)).[description.]

donde:

cmd

Es el comando al que se aplicará la lista de campos. Los valores válidos son PRINT, COUNT, SUM, WRITE y ADD.

&var

Es la variable, incluido el ampersand (&), para la que está proporcionando una lista de valores de campos.

AND

Es el conector que genera una lista de selección múltiple.

return_fieldname

Es el nombre del campo que contiene los valores posibles de las variables devueltas al FOCEXEC.

display_fieldname

Es el nombre del campo que contiene los valores posibles de las variables mostradas en el formulario de aviso automático.

Nota: return_fieldname y display_fieldname pueden ser un campo DEFINE en un archivo máster, pero no un campo DEFINE en un procedimiento.

datasource

Es el origen de datos que contiene los campos especificados en return_fieldname y display_fieldname. Si los campos residen en un archivo de referencia cruzada perteneciente a un origen de datos usado en un join, utilice el nombre del origen de datos que contiene los campos.

Nota: En las listas dinámicas, el Cliente WebFOCUS construye la solicitud para obtener los valores, mediante el origen de datos especificado. Todos los comandos de entornos, como los comandos SET, necesarios para obtener los valores del origen de datos especificado, deben emitirse en el perfil del Servidor de WebFOCUS, en el perfil del usuario o en el perfil del Cliente WebFOCUS.

description

Es una descripción opcional de la variable.

Principio de página

Ejemplo: Cómo crear listas dinámicas de selección múltiple de campos de visualización y clasificación

La siguiente solicitud, basada en el origen de datos GGSALES, genera tres listas dinámicas de selección múltiple mediante la recuperación de nombres de campos de los orígenes de datos FOCUS GGDETFLD, GGBYFLD y GGACRFLD:

TABLE FILE GGSALES
HEADING
"Sales Report Summary for: "
"Fields: &SumFlds"
"Sort: &SortBy"
"Across: &Acrs"
" "
SUM &SumFlds.(AND(FIND NAME, FLDDESC IN GGDETFLD)).Sum Fields.
BY &SortBy.(BY(FIND NAME, FLDDESC IN GGBYFLD)).By.
ACROSS &Acrs.(ACROSS(FIND NAME, FLDDESC IN GGACRFLD)).Across.
WHERE REGION NE 'West'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, FONT=ARIAL,SIZE=10,SQUEEZE=ON,$
TYPE=HEADING, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=HEADING, LINE=1, FONT=ARIAL, STYLE=BOLD, JUSTIFY=CENTER,$
TYPE=TITLE, BACKCOLOR=BLACK, COLOR=WHITE,$
TYPE=ACROSSTITLE, BACKCOLOR=LIGHT BLUE, COLOR=BLUE,$
TYPE=ACROSSVALUE, BACKCOLOR=LIGHT GRAY, COLOR = GREEN,$
END

Si ejecuta la solicitud, se abre la siguiente página de inicio con listas de selección múltiple para los comandos SUM, BY y ACROSS. Tenga en cuenta que la opción Ninguna selección queda automáticamente añadida a cada lista:

Si selecciona Dólares, Unidades, Categoría y Región, se genera el informe siguiente: