x

Utilice las siguientes opciones de sintaxis para añadir líneas encima, debajo o dentro de un encabezado o pie de página, donde:

</n

Es un marcador de posición que especifica el número de líneas que hay que saltar. Lo mejor es colocar el marcador de posición en la misma línea que el texto en la solicitud. Si coloca el marcador de posición </n solo en una línea, añadirá esa línea además del número designado de saltos de línea.

" "

Indica una línea individual en blanco en el encabezado o pie de página.

Puede utilizar estas técnicas por separado o combinarlas.

Principio de página

Ejemplo: Cómo añadir líneas en blanco encima o debajo de un encabezado de informe

Esta solicitud crea un infome HTML con una línea en blanco entre cada línea del encabezado de la página y dos líneas en blanco entre el encabezado de la página y el contenido del informe. La primera línea en blanco queda añadida como una línea de texto vacía. Las líneas en blanco posteriores se añaden con el marcador de lugar de salto de línea.

TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"SALES REPORT" 
" "
"**(CONFIDENTIAL)**</1"
"December 2002 </2" 
ON TABLE SET PAGE-NUM OFF 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, TOPMARGIN=0, $
TYPE = TABHEADING, JUSTIFY = CENTER, $
ENDSTYLE
END

La salida es:

x

En un informe PDF, puede utilizar los atributos TOPGAP y BOTTOMGAP para controlar el espacio situado encima o debajo de la línea de encabezado o pie, o la distancia entre el texto de encabezado o pie y las líneas de cuadrícula que se encuentren encima o debajo de estos.

Nota: Puede utilizar TOPGAP y BOTTOMGAP con encabezados de líneas múltiples. Recuerde que se insertará el espacio superior y el inferior entre las líneas del encabezado, lo que aumentará el espacio entre las líneas y lo hará mayor que el espacio encima y debajo de la propia encabezado.

TYPE=headfoot, {TOPGAP|BOTTOMGAP}=gap, $

donde:

headfoot

Es el tipo de encabezado o pie. Los valores válidos son TABHEADING, TABFOOTING, HEADING, FOOTING, SUBHEAD y SUBFOOT.

TOPGAP

Indica la cantidad de espacio que se va a añadir encima de un componente del informe.

BOTTOMGAP

Indica la cantidad de espacio que se va añadir debajo de un componente del informe.

gap

Es la cantidad de espacio en blanco, en la unidad de medida especificada por el parámetro UNITS (pulgadas, por defecto).

Si no hay cuadrículas, el valor predeterminado es 0.

Si hay cuadrículas, el valor predeterminado aumenta para proporcionar espacio entre la cuadrícula y el texto.

Principio de página

Ejemplo: Cómo añadir un espacio en blanco para separar el texto de las líneas de cuadrícula en un informe PDF

Esta solicitud genera un informe PDF con espacio en blanco encima y debajo de un encabezado de informe para separar el texto de las líneas de cuadrícula superior e inferior. El espacio de encima se añade mediante el atributo TOPGAP. El espacio de debajo se añade mediante el atributo BOTTOMGAP.

TABLE FILE GGSALES
SUM BUDUNITS UNITS BUDDOLLARS DOLLARS
BY CATEGORY
ON TABLE SUBHEAD
"SALES REPORT <+0>December 2001"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET *
TYPE = TABHEADING, GRID=ON, JUSTIFY=CENTER, TOPGAP=.25, BOTTOMGAP=.25, $
TYPE = TABHEADING,  FONT='TIMES', SIZE=12, STYLE=BOLD, $
TYPE = TABHEADING, ITEM=2, SIZE=10, STYLE=ITALIC, $
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo ajustar el espaciado vertical debajo de un pie de página de clasificación

Esta solicitud genera un informe PDF en que los pies de clasificación aparecen en negrita para destacarlos y se añade espacio debajo de cada pie de página para enlazar visualmente el texto del pie de página a los datos que lo preceden.

TABLE FILE GGPRODS
PRINT PACKAGE_TYPE AND UNIT_PRICE
WHERE UNIT_PRICE GT 50
BY PRODUCT_DESCRIPTION NOPRINT BY PRODUCT_ID
ON PRODUCT_DESCRIPTION SUBFOOT
"Summary for <PRODUCT_DESCRIPTION"
ON TABLE SET PAGE-NUM OFF 
ON TABLE SET ONLINE-FMT PDF 
ON TABLE SET SQUEEZE ON
ON TABLE SET STYLESHEET * 
TYPE=SUBFOOT, STYLE=BOLD, BOTTOMGAP=.25, $ 
ENDSTYLE
END

La salida es:

x

Puede colocar un pie de página en la parte inferior de la página. Como acción predeterminada, siempre aparece un pie de página dos líneas por debajo de los datos del informe.

FOOTING [BOTTOM]
  "content ... "
["content ... "]
.
.
.
["content ... "]

donde:

FOOTING

Es el comando necesario para identificar el contenido como un pie de página.

BOTTOM

Es un comando opcional que coloca el pie de página al final de la página. Si omite BOTTOM, el pie de página aparece dos líneas por debajo de los datos del informe.

Nota: Los informes HTML y el Visualizado WebFOCUS no admiten FOOTING BOTTOM.

contenido

El contenido del pie de página puede incluir los siguientes elementos, entre comillas dobles. (si se omiten las comillas finales, todas las líneas posteriores de la solicitud se tratan como parte del pie.)

text

Es el texto del pie. Puede incluir múltiples líneas de texto.

El texto debe empezar en una línea independiente, luego del comando FOOTING.

El texto se puede combinar con variables y marcadores de posición.

Para obtener información relacionada, consulte Limitaciones de los encabezados y pies.

variable

Puede ser cualquiera de los siguientes o una combinación de estos:

Campos (campos reales de orígenes de datos, campos virtuales creados con el comando DEFINE en un archivo máster o una solicitud de informe, valores calculados creados con el comando COMPUTE en una solicitud o campos de sistema, como TABPAGENO). Puede calificar campos de origen de datos con ciertos operadores de prefijo.

Dialogue Manager variables.

Imágenes. Puede incluir imágenes en un encabezado o pie de página.

Para obtener información detallada, consulte Cómo incluir un elemento en un encabezado o en un pie de página.

spot marker

Le permite colocar elementos, identificar elementos para dar formato y ampliar el código más allá del límite de 80 caracteres por línea del editor de texto.

<+0> divide un encabezado o pie en elementos a los que dar formato. Para obtener información detallada, consulte Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

</n especifica saltos de línea. Para obtener información detallada, consulte Cómo controlar la ubicación vertical de un encabezado o pie de página.

<-n para colocar el próximo carácter en la línea. Para obtener información detallada, consulte Cómo utilizar marcadores de posición para afinar el posicionamiento.

<0X continúa la especificación de un encabezado o pie de página en la línea siguiente del informe. Para obtener información detallada, consulte Cómo ampliar código de encabezados y pies a múltiples líneas en una solicitud de informe.

Nota: Cuando un marcador de posición de cierre está seguido inmediatamente de uno de apertura (><), se colocará entre ambos marcadores un elemento de texto de un solo espacio (> <). Debe tomarse esto en consideración cuando se aplica formato.

Blank lines

Si omite todo el texto, las variables y los marcadores de posición, el resultado es un encabezado o pie de página en blanco (por ejemplo, " "), que puede utilizar para saltar una línea en un encabezado o pie de página. (También puede saltar una línea mediante un marcador de posición vertical, como </1.)

Nota: El número máximo de encabezados de clasificación o pies de clasificación en una solicitud es de 33.

Principio de página

Ejemplo: Cómo colocar un pie de página al final de una página

Esta solicitud produce un informe PDF en que el pie de página aparece al final de la página, en vez de en la posición predeterminada, dos líneas por debajo de los datos del informe.

TABLE FILE GGSALES
PRINT UNITS DOLLARS
BY CATEGORY BY STCD
WHERE TOTAL DOLLARS GE 25000
FOOTING BOTTOM
"PRELIMINARY SALES FIGURES"
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE-NUM OFF
END

La siguiente salida muestra el final del informe, con el pie de página.