Cómo identificar un informe completo, una columna o una fila

A continuación se muestra el lugar del informe en el que aparecen el componente REPORT y los atributos COLUMN y ACROSSCOLUMN, además de los valores TYPE que se usan para identificarlos.. Aunque en este ejemplo el valor para COLUMN es B1 y el valor para ACROSSCOLUMN es N2, estos no son los únicos valores que puede utilizar para identificar estos componentes.

Nota: Dado que esta solicitud sólo muestra dónde aparecen los componentes en un informe, omite una hoja de estilo.

Sintaxis: Cómo Identificar un informe completo

Para identificar un informe completo en una hoja de estilo, utilice este atributo y este valor:

TYPE=REPORT

Principio de página

Ejemplo: Cómo identificar un informe completo

A continuación se muestra cómo identificar y aplicar formato a un informe completo. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

TABLE FILE CENTINV
HEADING
"Excess Stock Report"
SUM QTY_IN_STOCK  
BY PRODNAME
WHERE QTY_IN_STOCK GT 10000
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, GRID=OFF,$
TYPE=REPORT, STYLE=BOLD,$ 
ENDSTYLE
END

La salida es:

Sintaxis: Cómo Identificar una columna completa

TYPE=REPORT, coltype=column

donde:

coltype

Especifica el tipo de columna. Puede ser:

COLUMN, que especifica una columna de clasificación (generada por BY), una columna de salida (generada por PRINT, LIST, SUM o COUNT), una columna calculada (generada por COMPUTE) o una columna de totales de fila (generada por ROW-TOTAL).
ACROSSCOLUMN, que especifica cada instancia de una columna que se repite en una fila de clasificación horizontal (ACROSS). Este procedimiento aplica también el formato a los valores de clasificación horizontal (ACROSS) que aparecen encima de los títulos de columna.

column

Especifica una o más columnas. Si está identificando un ACROSSCOLUMN, los únicos identificadores válidos son Nn y Pn, que sólo sirven para contar campos ACROSS, no los campos de visualización.

Las opciones para identificar columnas en una hoja de estilo son:

Identifier	Descripción
Nn	Identifica una columna por su posición en el informe. Para determinar este valor, cuente los campos de clasificación vertical (BY), los campos de visualización y los campos ROW-TOTAL de izquierda a derecha, incluyendo los campos NOPRINT. Para ver un ejemplo, vaya a Cómo identificar una columna de datos. Para ACROSSCOLUMN sólo se cuentan los campos ACROSS.
Pn	Identifica una columna por su posición en el informe. Para determinar el valor de n, cuente los campos de clasificación vertical (BY), los campos de salida y los campos ROW-TOTAL de izquierda a derecha. No cuente los campos NOPRINT. Para ACROSSCOLUMN sólo se cuentan los campos ACROSS.
Cn	Identifica una columna de visualización por su posición en el informe. Para determinar el valor de n, cuente solamente los campos de salida de izquierda a derecha, incluyendo los campos NOPRINT. No cuente los campos de clasificación vertical (BY) ni los campos ROW-TOTAL. Para seleccionar todos los campos de visualización, utilice C*.
Bn	Identifica una columna de clasificación vertical (BY) por su posición en el informe. Para determinar el valor de n, cuente solamente los campos de clasificación vertical (BY), incluyendo los campos NOPRINT, de izquierda a derecha. Para seleccionar todos los campos BY, utilice B*.
field	Identifica una columna por su nombre de campo. Cuando aparezca más de una vez un campo, utilice el campo n para seleccionar una ocurrencia particular del campo y (*) para seleccionar todas las ocurrencias del campo.
ROWTOTAL	Identifica una fila de totales de columna generados con ROW-TOTAL. Cuando se utiliza con ACROSS y múltiples comandos de visualización, ROWTOTAL genera múltiples totales de columna. Utilice ROWTOTAL(n) para seleccionar un total de columna particular. Utilice ROWTOTAL(field) para seleccionar el total de columna de un campo particular. Utilice ROWTOTAL(*) para seleccionar todos los totales de columna en el informe.

Nota: Dentro de una hoja de estilo, es necesario especificar todas las columnas del mismo modo, ya sea usando el nombre de campo o una referencia a su posición.

Principio de página

Ejemplo: Cómo identificar una columna completa

A continuación se muestra cómo identificar una columna completa, compuesta por los datos y títulos de columnas de un informe. La declaración de hoja de estilos correspondiente se destaca en la solicitud.

Nota: Para lograr los mismos resultados puede, alternativamente, utilizar los valores P1, B1 o el nombre de campo (PRODNAME) para el atributo COLUMN en la declaración de hoja de estilo.

TABLE FILE CENTINV
HEADING
"Excess Stock Report"
SUM QTY_IN_STOCK  
BY PRODNAME
WHERE QTY_IN_STOCK GT 10000
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=REPORT, COLUMN=N1, STYLE=ITALIC,$ 
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo identificar una columna horizontal (ACROSS) completa

A continuación se muestra cómo identificar una columna horizontal (ACROSS). Cuando identifica y formatea una ACROSSCOLUMN, todos los valores de datos, el título de columna y cualquier valor de clasificación horizontal (ACROSS) asociado con el campo se formatean para cada ocurrencia de la columna en la salida de informe. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

Nota: Para lograr los mismos resultados puede, de manera alternativa, utilizar los valores P1 y P2, respectivamente, para el atributo ACROSSCOLUMN.

TABLE FILE CENTORD
SUM LINEPRICE LINE_COGS AS 'Line Cost of,Goods Sold'
BY PLANT AS 'Plant'
ACROSS YEAR
WHERE YEAR EQ 2000 OR 2001
HEADING
"Cost Analysis"
FOOTING CENTER
"**End of Report**"
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF,$ 
TYPE=REPORT, ACROSSCOLUMN=N1, STYLE=ITALIC,$
TYPE=REPORT, ACROSSCOLUMN=N2, STYLE=BOLD,$  
ENDSTYLE
END

La salida es:

Sintaxis: Cómo Identificar una fila completa en Lenguaje de modelado financiero (FML)

TYPE=REPORT, LABEL=label

donde:

label: Es una etiqueta de fila implícita.

Principio de página

Ejemplo: Cómo identificar una fila FML completa

A continuación se muestra cómo identificar una fila FML completa, compuesta por la etiqueta y los datos de la fila. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND' LABEL COH OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD OVER
1030 AS 'TIME DEPOSITS' LABEL TD OVER
BAR OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, LABEL=COH, STYLE=ITALIC, $
TYPE=REPORT, LABEL=DD, STYLE=ITALIC, $
TYPE=REPORT, LABEL=TD, STYLE=ITALIC, $ 
ENDSTYLE
END

La salida es:

Sintaxis: Cómo Identificar una fila completa de total y subtotal

TYPE=type, [BY=sortcolumn]

donde:

type

Identifica un subtotal o total. Seleccione entre:

GRANDTOTAL que es el total (generado mediante COLUMN-TOTAL, SUBTOTAL, SUB-TOTAL, RECOMPUTE o SUMMARIZE).

SUBTOTAL que es un subtotal (generado mediante SUBTOTAL, SUB-TOTAL, RECOMPUTE o SUMMARIZE).

RECAP que es un cálculo de subtotal (generado mediante ON sortfield RECAP u ON sortfield COMPUTE).

BY

Cuando existen varios comandos de subtotal, con cada uno asociado a una columna de clasificación vertical (BY) diferente, puede identificar los comandos de subtotal que desea formatear.

sortcolumn

Especifica la columna de clasificación vertical (BY) asociada a uno de los distintos subtotales en los comandos de informe. Utilice el nombre del campo para identificar la columna de clasificación.

Principio de página

Ejemplo: Cómo identificar una fila de total completa

A continuación se muestra cómo identificar toda una fila COLUMN-TOTAL en una hoja de estilo. La declaración de hoja de estilos correspondiente se destaca en la solicitud.

TABLE FILE SALES
SUM RETURNS DAMAGED AND ROW-TOTAL AND COLUMN-TOTAL
BY PROD_CODE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $  
TYPE=GRANDTOTAL, STYLE=BOLD, SIZE=12, $ 
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo identificar un total de fila

A continuación se muestra cómo identificar un total de fila. La declaración de hoja de estilos correspondiente se destaca en la solicitud. Tenga en cuenta que si desea formatear una ocurrencia de row-total (total de fila), puede añadir una frase WHEN a su hoja de estilo. Para obtener información detallada, consulte Cómo controlar el formato del informe.

TABLE FILE SALES
SUM RETURNS DAMAGED AND ROW-TOTAL
BY PROD_CODE AS 'PRODUCT,CODE'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, COLUMN=ROWTOTAL, STYLE=BOLD, $ 
ENDSTYLE
END

La salida es: