Sintaxis general de la hoja de estilo de WebFOCUS

Una hoja de estilos consiste de declaraciones que le permiten identificar el tipo de formato que desea utilizar y los componentes en que lo va a aplicar. Una declaración suele empezar con el atributo TYPE y va seguida de los pares attribute=value que asigne al componente de informe. Puede incluir también comentarios que ofrezcan información contextual de la hoja de estilo. Los comentarios no afectan al comportamiento de la hoja de estilo. Para obtener información detallada, consulte Cómo añadir un comentario a una hoja de estilo de WebFOCUS.

Sintaxis: Cómo Especificar una declaración de hoja de estilo de WebFOCUS

Cada declaración de hoja de estilo especifica una serie de atributos de la siguiente forma

attribute = value, [attribute = value, ...] $

donde:

atributo: Es el atributo que especifica, como TYPE, COLUMN, COLOR o FONT.
value: Es el valor que asigna al atributo.

Principio de página

Ejemplo: Ejemplo de hoja de estilo de WebFOCUS

A continuación aparece una solicitud que incluye una hoja de estilo en línea. La hoja de estilo empieza con ON TABLE SET STYLE * y termina con ENDSTYLE.

TABLE FILE CENTORD
HEADING
" "
"C e n t u r y  C o r p o r a t i o n"
" "
"Order Revenue - 2000 Q3"
" "
"page <TABPAGENO"
" "
SUM ORDER_DATE/MtDY ORDER_NUM LINEPRICE AS 'Order,Total:'
BY LOWEST 9 ORDER_DATE NOPRINT
WHERE (ORDER_DATE GE '2000/10/01') AND (ORDER_DATE LE '2000/12/31');
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
 
ON TABLE SET STYLESHEET *
TYPE=Report, GRID=Off, UNITS=Inches, $
TYPE=Data, FONT='Times', $
TYPE=Data, BACKCOLOR=Aqua, COLOR=Navy,
     WHEN=LinePrice GT 500000, $
TYPE=Data, COLUMN=LinePrice, BACKCOLOR=Aqua, COLOR=Navy, STYLE=Bold,
     WHEN=LinePrice GT 500000, $
TYPE=Title, FONT='Helvetica', $
TYPE=Heading, FONT='Helvetica', STYLE=Bold, SIZE=14, JUSTIFY=Center,
     COLOR=White, BACKCOLOR=Dark Turquoise, $
TYPE=Heading, LINE=6, BACKCOLOR=White, COLOR=Dark Turquoise, $
TYPE=Heading, LINE=7, BACKCOLOR=White, $
ENDSTYLE
 
END

Cómo mejorar la legibilidad de la hoja de estilo de WebFOCUS

Hay muchas formas de estructurar sus declaraciones de hoja de estilo para facilitar la lectura de las hojas de estilo. Puede utilizar uno o una combinación de los pasos que aparecen a continuación:

Empiece una declaración en cualquier columna con espacios en blanco o espacios de tabulación.
Incluya líneas en blanco entre las declaraciones.
Cree declaraciones en que todas las letras sean mayúsculas o todas sean minúsculas, o bien mezcle mayúsculas y minúsculas.
Utilice más de una declaración para dar formato a un solo componente de informe.
Incluya espacios en blanco o espacios de tabulación entre el atributo, el signo de igualdad (=), la coma y el signo de dólar ($).
Divida una sola declaración a través de la línea. La declaración continuará procesándose hasta el signo de dólar del final. Por ejemplo, puede dividir una declaración de la manera siguiente:
```
TYPE=HEADING, FONT=ARIAL,
SIZE=14, STYLE=BOLD, $
```
Divida un par attribute=value a lo largo de una línea. Si está dividiendo un atributo o valor en una declaración, a lo largo de una línea, utilice el carácter de barra invertida (\) como sintaxis de continuación al final de la primera línea. Por ejemplo:
```
TYPE=TITLE, COLUMN=N2, STY\
LE=BOLD+ITALIC, COLOR=BLUE, $
```

Cómo añadir un comentario a una hoja de estilo de WebFOCUS

Puede añadir comentarios a una hoja de estilo para dar contexto a la declaración. Los comentarios no afectan al comportamiento de la hoja de estilo.

Puede añadir un comentario:

En una línea de declaración. Añada el texto deseado después del signo de dólar($). Por ejemplo,
```
TYPE=HEADING, STYLE=BOLD, COLOR=BLUE, SIZE=14, $ Sample comment
```
En su propia línea. Empiece la línea con un signo de dólar ($) o un guión y un asterisco (-*) seguidos del texto deseado. Por ejemplo,
```
-* This is a sample comment
$ This is another sample comment
```

Nota: Puede añadir comentarios en cualquier lugar de su solicitud, no solamente en las hojas de estilo.

Cómo validar la sintaxis de una hoja de estilo de WebFOCUS

Cómo:

Validar la sintaxis de una hoja de estilo de WebFOCUS

Puede revisar un archivo de hoja de estilo para verificar si contiene errores de sintaxis mediante el comando CHECK STYLE. Tenga presente que CHECK STYLE no revisa la escritura de los nombres de fuentes, como tampoco verifica la disponibilidad de fuentes especificadas en su sistema.

Puede emitir el comando CHECK STYLE en la consola de comandos de Developer Studio.

Principio de página

Sintaxis: Cómo Validar la sintaxis de una hoja de estilo de WebFOCUS

Para validar la sintaxis de un archivo de hoja de estilo, emita este comando desde la consola de comandos de Developer Studio.

CHECK STYLE file

donde:

file: Es el nombre del archivo de hoja de estilo. No incluya la extensión del archivo.