x

Característica	Descripción	Funciona en
SKIP-LINE*	Añade una línea en blanco.	HTML (requiere GRID=OFF) DHTML PDF PS 2K EXL XLSX
TYPE=SKIPLINE	Formatea una línea en blanco.	DHTML PDF PS
UNDER-LINE*	Subraya un grupo de clasificación.	HTML (requiere GRID=OFF) DHTML PDF PS
TYPE=UNDERLINE	Formatea un subrayado.	DHTML PDF PS
STYLE={+|-}UNDERLINE*	Añade subrayado a un componente de informe o elimina un subrayado de un componente de informe que no sea un título de columna.	HTML DHTML PDF PS 2K EXL XLSX
STYLE={+|-} EXTUNDERLINE*	Alarga o elimina el subrayado de la totalidad de la columna, en informes con estilo.	DHTML PDF PS PPT PPTX
BAR AS '{-|=}'*	Selecciona un subrayado suave o grueso en un informe FML.	HTML DHTML PDF PS EXL2K

* No admite bordes.

x

Utilice un solo SKIP-LINE por solicitud de informe.

display_command fieldname SKIP-LINE

o

{ON|BY} fieldname SKIP-LINE [WHEN expression;]

donde:

display_command

Es un comando de visualización.

fieldname

Es el campo de visualización o de clasificación después del cual se inserta una línea en blanco.

Si emplea SKIP-LINE con un campo de visualización, se añade una línea en blanco después de cada línea mostrada, doblando así el espacio entre las líneas de un informe. El doble espacio es útil cuando se revisa un informe, pues facilita la lectura de los comentarios cerca de las líneas individuales.

Cuando se utiliza SKIP-LINE con un campo de clasificación se añade una línea en blanco antes de cada cambio de valor de ese campo. Esta es una de las únicas condiciones ON que no tiene que referirse solamente a un campo de clasificación (BY).

ON|BY

Es una frase de clasificación vertical. Ambos son sinónimos.

WHEN expression

Especifica líneas condicionales en blanco en la visualización de un informe determinado por una expresión lógica. Consulte Cómo utilizar expresiones para más detalles sobre las expresiones.

Principio de página

Ejemplo: Cómo añadir una línea en blanco entre grupos de clasificación

Esta solicitud inserta una línea en blanco antes de cada cambio en el valor del campo de clasificación EMP_ID.

DEFINE FILE EMPLOYEE
INCREASE/D8.2M = .05*CURR_SAL;
CURR_SAL/D8.2M=CURR_SAL;
NEWSAL/D8.2M=CURR_SAL + INCREASE;
END
 
TABLE FILE EMPLOYEE
PRINT CURR_SAL OVER INCREASE OVER NEWSAL
BY LOWEST 4 EMP_ID BY LAST_NAME BY FIRST_NAME 
ON EMP_ID SKIP-LINE 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT PDF
END

Se destacan los datos de cada empleado, lo cual facilita la lectura:

x

TYPE=SKIPLINE, attribute=value, $

donde:

atributo

Es un atributo de hoja de estilo válido.

value

Es el valor del atributo

Nota: Esta opción es compatible con los informes PDF, PS y HTML (cuando se utiliza junto con hojas de estilos internas en cascada).

Principio de página

Ejemplo: Cómo añadir color a líneas en blanco

En esta solicitud, se formatean las líneas en blanco para que aparezcan en color plateado en la salida. La declaración de hoja de estilos correspondiente se destaca en la solicitud.

SET ONLINE-FMT=PDF
TABLE FILE CENTINV
HEADING
"Low Stock Report"
" "
SUM QTY_IN_STOCK 
WHERE QTY_IN_STOCK LT 5000
BY PRODNAME
ON PRODNAME SKIP-LINE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=SKIPLINE, BACKCOLOR=SILVER, $ 
ENDSTYLE
END

El informe es:

x

{ON|BY} fieldname UNDER-LINE [WHEN expression;]

donde:

ON|BY

Es una frase de clasificación vertical. Ambos son sinónimos.

fieldname

Es el campo de clasificación al que se aplica el subrayado. UNDER-LINE añade una línea cuando cambia el valor del campo de clasificación. Aparece un subrayado de manera automática después de opciones tales como RECAP o SUB-TOTAL pero antes de los saltos de página.

WHEN expression

Especifica subrayado condicional en la visualización de un informe determinado por una expresión lógica. Consulte Cómo utilizar expresiones para más detalles sobre las expresiones.

Principio de página

Ejemplo: Cómo subrayar un grupo de clasificación

Esta solicitud añade un subrayado cuando cambia el valor del campo de clasificación BANK_NAME. Establece el atributo GRID en OFF, valor requerido para un informe HTML..

TABLE FILE EMPLOYEE
PRINT EMP_ID AND BANK_ACCT AND LAST_NAME
BY BANK_NAME 
ON BANK_NAME UNDER-LINE 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Los datos de cada banco quedan resaltados para facilitar la lectura:

x

TYPE=UNDERLINE ... COLOR={color|RGB} (r g b), $

donde:

UNDERLINE

Indica subrayado generado por ON fieldname UNDER-LINE.

COLOR

Especifica el color del subrayado. Si la pantalla o el dispositivo de salida no admite colores, los sustituye por matices del gris. El valor predeterminado es negro.

color

Es uno de los valores de color predeterminados. Para obtener una lista de los valores admitidos, consulte Valores de color en un informe.

RGB

Especifica el color de texto mediante una mezcla de rojo, verde y azul.

(r g b)

Es la intensidad deseada de rojo, verde y azul, respectivamente. Los valores se encuentran en una escala de 0 a 255, en que cero es el menos intenso y 255 es el más intenso.

Tenga en cuenta que si se utilizan componentes de tres colores en intensidades iguales se producen tonos de gris.

Nota: Esta opción es compatible con los informes PDF, PS y HTML (cuando se utiliza junto con hojas de estilos internas en cascada).

Principio de página

Ejemplo: Cómo formatear el subrayado de un grupo de clasificación

Esta solicitud utiliza UNDERLINE para cambiar el color predeterminado de un subrayado de negro a rojo.

SET ONLINE-FMT = PDF
TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
HEADING
"Sales Report"
" "
ON CATEGORY UNDER-LINE
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=UNDERLINE, COLOR=RED, $ 
ENDSTYLE
END

El resultado es una llamativa separación entre los valores de grupo de clasificación. El informe en línea PDF es el siguiente:

x

TYPE=type, [subtype,] STYLE=[+|-]UNDERLINE, $

donde:

type

Es el componente de informe. Para obtener información sobre valores válidos, vaya a Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

subtype

Son atributos adicionales, como COLUMN, ACROSS o ITEM, necesarios para identificar el componente de informe. Para obtener información sobre valores válidos, vaya a Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

+

Añade subrayado a un estilo de texto heredado o especifica una combinación de estilos de texto (por ejemplo, STYLE=BOLD+UNDERLINE). Este es el valor predeterminado.

-

Elimina un subrayado de un texto heredado.

x

Esta sintaxis corresponde a los informes HTML con hojas de estilos internas en cascada.

TYPE=TITLE, [COLUMN=column,] STYLE=-UNDERLINE, $

donde:

COLUMN=column

Especifica una columna. Para obtener información sobre valores válidos, vaya a Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

Principio de página

Ejemplo: Cómo añadir subrayado de columna y eliminar subrayado de títulos de columna

Esta solicitud añade subrayado a los valores de la columna CATEGORY y elimina el subrayado por defecto de los títulos de columnas, en un informe HTML con hoja de estilos interna en cascada.

SET HTMLCSS = ON 
TABLE FILE MOVIES
PRINT TITLE DIRECTOR
BY CATEGORY
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=TITLE, STYLE=-UNDERLINE, $
TYPE=REPORT, COLUMN=CATEGORY, STYLE=UNDERLINE, $ 
ENDSTYLE
END

El informe parcial es:

x

Por defecto, el subrayado de los títulos de columna de un informe sólo abarca el texto de título de la columna. Puede extender el subrayado para que abarque toda la columna de informe, en una salida de informe, mediante la opción EXTUNDERLINE de su hoja de estilos WebFOCUS. EXTUNDERLINE es una opción del atributo STYLE para el componente de informe TITLE. Compatible con los formatos DHTML, PDF, PS, PPT y PPTX.

TYPE = TITLE, [COLUMN = colspec,] STYLE = [+|-]EXTUNDERLINE  ,$

donde:

colspec

Es cualquier especificación de columna válida.

+EXTUNDERLINE

Añade la opción EXTUNDERLINE al estilo de texto heredado o especifica una combinación de estilos de texto (por ejemplo, STYLE=BOLD+UNDERLINE).

-EXTUNDERLINE

Elimina la opción EXTUNDERLINE del estilo de texto heredado.

x

• No se admite el formato HTML, ya que el navegador calcula el ancho de columna y representa el informe.
• GRID=ON y EXTUNDERLINE son exclusivos mutuamente, debido a que la línea de GRID abarca el ancho de la columna. GRID anula cualquier estilo especificado para el subrayado de títulos de columnas.

Principio de página

Ejemplo: Cómo extender un subrayado a toda la columna de informe

La solicitud siguiente, emitida frente al origen de datos GGSALES, suma las ventas en dólares por ciudad y fecha:

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                  
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
END

La salida indica que sólo están subrayados los títulos de las columnas:

Para subrayar toda la columna, genere la salida en un formato al que se pueda dar UNDERLINEestilo y use la opción EXTUNDERLINE del atributo STYLE para el componente TITLE. Por ejemplo, la siguiente solicitud crea una salida DHTML, con los títulos de las columnas en negrita y justificados a la izquieda, y el subrayado extendido para abarcar toda la columna del informe:

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                 
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
ON TABLE SET STYLE *  
TYPE=TITLE, STYLE= BOLD +EXTUNDERLINE, JUSTIFY=LEFT, $ 
ENDSTYLE
END

La salida es:

La siguiente versión de la solicitud establece EXTUNDERLINE y JUSTIFY=LEFT como opciones predefinidas del componente TITLE, pone la columna Fecha en negrita y elimina el subrayado extendido de esa columna:

DEFINE FILE GGSALES               
YEAR/YY = DATE;                   
MONTH/M = DATE;
END                               
TABLE FILE GGSALES                
SUM DOLLARS AS 'Sales'                   
BY DATE                           
BY CITY
WHERE YEAR EQ 1997                
WHERE MONTH FROM 01 TO 05
WHERE CITY EQ 'Seattle' OR 'San Francisco' OR 'Los Angeles'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT DHTML
ON TABLE SET STYLE *  
TYPE=TITLE,STYLE= EXTUNDERLINE, JUSTIFY=LEFT ,$   
TYPE=TITLE,COLUMN= DATE, STYLE= -EXTUNDERLINE +BOLD ,$ 
ENDSTYLE                          
END

La salida es:

x

Esta sintaxis se aplica a un informe HTML.

BAR [AS '{-|=}'] OVER

donde:

-

Genera un subrayado suave. Ponga el guión entre comillas simples. Este es el valor predeterminado.

=

Genera un subrayado fuerte. Ponga el signo de igualdad entre comillas simples.

Principio de página

Ejemplo: Cómo cambiar el subrayado predeterminado en un informe HTML en Lenguaje de modelado financiero (FML)

Esta solicitud cambia el subrayado suave predeterminado por un subrayado fuerte en un informe FML.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR AS '='                   OVER 
RECAP TOTCASH = R1 + R2 + R3;
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Un subrayado fuerte separa total de efectivo de los datos detallados, con lo que se destacan.

Principio de página

Ejemplo: Cómo cambiar el subrayado predeterminado en informe PDF en Lenguaje de modelado financiero (FML)

Esta solicitud cambia el subrayado predeterminado de una sola línea por un subrayado de doble línea en un informe PDF.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR AS '='                   OVER 
RECAP TOTCASH = R1 + R2 + R3;
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es: