Cómo añadir el control de árbol de tabla de contenidos a los informes

Sintaxis: Cómo Añadir un control de árbol TOC a un informe utilizando un comando SET

Con el comando SET, la sintaxis es

Al principio de una solicitud:

SET COMPOUND = 'BYTOC [n]'

En una solicitud, utilice la sintaxis:

ON TABLE SET COMPOUND 'BYTOC [n]'

donde:

n

Representa el número de campos de clasificación vertical (BY) que hay que incluir en la tabla de contenido, empezando por el primer campo de clasificación (el más alto nivel) en la solicitud. La jerarquía de campos de clasificación se determina por el orden en que se los especifica en el informe.

El valor predeterminado es 1, lo que significa que solamente el campo de clasificación de más alto nivel y sus valores se muestran en la tabla de contenido.

De forma predeterminada, se coloca una pausa de sección después del primer campo de clasificación (el más alto nivel), a menos que se especifique otra cosa en la solicitud.

Nota: Debe emplear comillas simples (') cuando BYTOC aparezca especificado con un número en un comando SET.

Sintaxis: Cómo Añadir un control de árbol TOC a un informe utilizando el comando PCHOLD

Con el comando PCHOLD, la sintaxis es

ON TABLE PCHOLD FORMAT HTML BYTOC [n]

donde:

n

Representa el número de campos de clasificación vertical (BY) que hay que incluir en la tabla de contenido, empezando por el primer campo de clasificación (el más alto nivel) en la solicitud. La jerarquía de campos de clasificación se determina por el orden en que se los especifica en el informe.

El valor predeterminado es 1, lo que significa que solamente el campo de clasificación de más alto nivel y sus valores se muestran en la tabla de contenido.

De forma predeterminada, se coloca una pausa de sección después del primer campo de clasificación (el más alto nivel), a menos que se especifique otra cosa en la solicitud.

Nota: No debe emplear comillas simples (') cuando BYTOC aparezca especificado con un número en un comando PCHOLD.

Sintaxis: Cómo Añadir un control de árbol TOC a un informe utilizando una declaración de hoja de estilos

La sintaxis siguiente activa el control de árbol TOC en la hoja de estilos:

TYPE=REPORT, TOC='n',$

o

TYPE=REPORT, TOC='sortfieldname',$

donde:

n: Representa el número de campos de clasificación vertical (BY) que hay que incluir en la tabla de contenido, empezando por el primer campo de clasificación (el más alto nivel) en la solicitud. La jerarquía de campos de clasificación del árbol TOC está determinada por el orden en que aparecen listados en la solicitud.
sortfieldname: Especifica la columna de clasificación vertical (BY) por el nombre de su campo.

Nota: Debe emplear comillas simples (') cuando TOC aparezca especificado en la hoja de estilos.

Principio de página

Ejemplo: Cómo añadir una tabla de contenido HTML como un objeto en el informe (opción informe)

Puede añadir una tabla de contenido HTML como icono en la esquina superior izquierda de un informe, si inserta un comando SET antes de la solicitud, como se explica en la siguiente solicitud. La tabla de contenido listará valores del primer campo de clasificación vertical, PLANT (es decir, del nivel más alto):

SET COMPOUND='BYTOC 2'

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

También puede añadir un una tabla de contenido HTML como icono, en la esquina superior izquierda de un informe, mediante un comando SET dentro en la solicitud.

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 2'
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

El siguiente ejemplo muestra cómo puede usar un comando PCHOLD para ejecutar la solicitud:

TABLE FILE CENTORD
HEADING
"SALES REPORT"
SUM LINEPRICE BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL 
ON TABLE PCHOLD FORMAT HTML BYTOC 2
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

En la siguiente solicitud, el control de árbol TOC está activado en la hoja de estilos del informe:

TABLE FILE CENTORD 
HEADING
"SALES REPORT"
SUM LINEPRICE
BY PLANT BY PRODCAT
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=REPORT, TOC='PRODCAT', $ 
ENDSTYLE
END

Nota: Debe emplear comillas simples (') cuando TOC aparezca especificado en la hoja de estilos.

Ejecute el informe. El objeto TOC está situado en la esquina superior izquierda.

Pulse el icono TOC dos veces para abrir el control Árbol de tabla de contenidos. Los valores de los campos de clasificación del informe aparecen en el orden en que se han especificado.

Nota: Puede mover la TOC pulsando el área azul situada sobre ella y luego arrastrarla a otra área del informe, o pulsar dos veces sobre un lugar deseado del informe.

Si desea que aparezcan todos los campos disponibles (es decir, todo el informe), pulse la opción Ver informe completo (activar/desactivar).

Sugerencia: También puede personalizar el aspecto y comportamiento del objeto TOC editando un archivo .css. Le recomendamos que haga una copia de seguridad antes de realizar cualquier modificación.

Si está trabajando en los proyectos locales de Developer Studio, vaya a
```
\ibi\DevStudio##\ibi_apps\ibi_html\javaassist\intl\xx
```
donde:
##
Es la edición de Developer Studio.
xx
Es la abreviatura del idioma de la versión Developer Studio.
Si está trabajando en un entorno autoservicio o en Managed Reporting, abra Developer Studio o, desde un navegador, vaya al directorio, \ibi\WebFOCUS##\ibi_apps\ibi_html\javaassist\intl\xx, donde ## es la edición de WebFOCUS y xx, la abreviatura del idioma. En inglés (EN), el nombre de archivo .css es toc.css. Para el resto de los idiomas, el nombre del archivo .css es xxtoc.css, donde xx es la abreviación de idioma.

Nota: Si pulsa Eliminar tabla de contenido y luego quiere ver nuevamente la tabla de contenido, simplemente pulse dos veces la parte que desee de su informe.

Referencia: Cómo agrupar campos de clasificación para muestra

Los datos de un informe de tabla de contenido se agrupan en secciones basadas en los campos de clasificación. Los informes de tabla de contenido sólo muestran una sección a la vez, para mejor apreciación. Cada sección contiene todos los valores de su campo de clasificación. Puede personalizar cada sección con un salto de página. Por defecto, se incluye un salto de página en el primer campo de clasificación (nivel superior). Puede añadir saltos de página para crear secciones adicionales y agrupar los datos de acuerdo a un campo de clasificación de nivel más bajo.

A la hora de añadir una tabla de contenido a un encabezado, añada saltos de página adicionales para cada campo de clasificación de nivel más bajo. De ese modo se asegura de que los datos clasificados se agrupen y muestren correctamente.

Principio de página

Ejemplo: Cómo personalizar secciones del informe con un salto de página

TABLE FILE SHORT
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
BY HOLDER
BY TYPE
ON HOLDER PAGE-BREAK
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 5'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
COLOR='BLACK',
BACKCOLOR='NONE',
STYLE=NORMAL,
$
ENDSTYLE
END

Se muestra una sección del informe a la vez.

El informe se divide en secciones sobre la base de los valores para HOLDER. Verá el detalle de cada valor de HOLDER en una sección única.

Comportamiento de navegación en una tabla de contenido de niveles múltiples

Cómo:

Añadir controles de lista desplegable TOC a un encabezado

Referencia:

Si selecciona un valor en el TOC, ese valor se destaca (aparece en gris) para llamar su atención en la ventana del navegador. Los factores siguientes controlan el lugar en que aparece el destello y cuándo y cómo cambia la visualización de la pantalla:

Cuando cambia el grupo de clasificación de más alto nivel desde la tabla de contenido (ya sea desde la jerarquía que se halla encima del informe o desde la primera lista desplegable en un encabezado o pie de página), el valor seleccionado parpadea tres veces en la ventana del navegador.
Cuando cambia un valor de clasificación de nivel inferior en el grupo actual de clasificación de nivel superior, el valor seleccionado parpadea tres veces en la ventana. Esto es así porque aún se encuentra dentro del mismo gran grupo de clasificación y, por lo tanto, dentro del mismo salto de página. Desde el valor seleccionado en la parte superior de la ventana, puede desplazarse rápidamente a los detalles relacionados.
Si el valor de nivel inferior seleccionado ya es visible en la pantalla y el informe restante cabe en la pantalla, el valor destella, pero el informe no se desplaza.

Principio de página

Ejemplo: Cómo navegar entre datos clasificados desde una tabla de contenido de niveles múltiples

Esta solicitud añade una TOC dinámica HTML como un icono, en la esquina superior izquierda del informe, mediante la inclusión un comando SET en la solicitud. La tabla de contenido muestra una jerarquía que consta de cuatro niveles de campos de clasificación, empezando por el primero (el de nivel más alto). Los campos de clasificación son: CONTINENT, REGION, COUNTRY y TYPE.

TABLE FILE SHORT
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
BY HOLDER
BY TYPE
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET COMPOUND 'BYTOC 5'
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
ENDSTYLE
END

La salida aparece con el objeto TOC en la esquina superior izquierda.

Pulse dos veces el objeto para ampliar el índice.

Seleccione Ver informe completo. Desplácese hacia abajo para verificar que el informe contiene datos para todos los continentes.

Desplácese de vuelta hacia arriba de la ventana de informe y reabra la tabla de contenido. Ahora seleccione Americas. El elemento seleccionado destella para destacarse en la pantalla. Aunque la visualización de informe no parece haber cambiado, si se desplaza hacia abajo verá que el informe sólo contiene valores para Americas.

Desplácese nuevamente hacia arriba y pulse dos veces cualquier parte del informe para abrir la tabla de contenido. Esta vez pulse el signo de suma (+) al lado de Americas, luego pulse el signo de suma (+) al lado de South America.

Los valores de campo (Argentina y Brasil) se listan en la tabla de contenido. Estos son los valores del campo COUNTRY. Si desea ver el nombre del campo de un valor en la TOC, pase el cursor por encima del valor.

Seleccione Brazil. El elemento seleccionado destella y se desplaza hacia la parte superior de la ventana, tal como se muestra en la parte que sigue.

Desplácese hacia abajo para ver los datos correspondientes a Brasil.

Continúe navegando hasta alcanzar el detalle deseado mediante la selección de valores en cualquier nivel de clasificación en la tabla de contenido.

Si pulsa en el signo de suma (+) se expande el campo para mostrar sus valores en la tabla de contenido.
Si pulsa en un campo real (hipervínculo) en la tabla de contenido, destaca momentáneamente ese valor, y de ser necesario, establece la visualización de informe para que traiga el valor a la vista.
La tabla de contenido se cierra y vuelve a su icono cuando pulsa en Índice, pero puede continuar desplazándose hacia atrás, ampliándolo y puede también hacer selecciones adicionales.

Principio de página

Sintaxis: Cómo Añadir controles de lista desplegable TOC a un encabezado

Incluya el siguiente atributo en su declaración de hoja de estilo

TYPE=heading, [subtype,] TOC=sort_column, $

donde:

heading

Es el tipo de encabezado o pie de página que contiene la tabla de contenido.

Los valores válidos son:

TABHEADING	encabezado de informe.
TABFOOTING	Pie de informe.
HEADING	encabezado de página.
FOOTING	pie de página.

subtype

Son atributos que identifican la ubicación en el encabezado o el pie de página en que se mostrará cada lista desplegable solicitada. Se pueden usar estas opciones por separado o combinarlas, dependiendo del grado de especificidad requerido para identificar el componente. Los valores válidos son:

LINE_# identifica una línea en base a su posición en un encabezado o pie.

Si el encabezado o el pie constan de múltiples líneas y aplica una declaración de hoja de estilo que no especifique LINE_#, la declaración se aplica a todas las líneas. Los líneas en blanco se cuentan al interpretar el valor de LINE.

LINE=n se requiere para un encabezado o pie con múltiples líneas. De lo contrario, lo puede omitir.

OBJECT identifica el objeto de la tabla de contenido en un encabezado o pie como una cadena de texto o un valor de campo. Los valores válidos son TEXT o FIELD.

Puede utilizar un campo o un texto como marcador de posición de una lista desplegable de tabla de contenido. Ahora bien, es preferible utilizar un campo. (Si la característica Tabla de contenido no está en vigor, el nombre del campo aparece en el informe).

TEXT puede representar texto libre o una variable ampersand "&" de Dialogue Manager.

No es necesario especificar OBJECT=TEXT a menos que esté dando estilo tanto a las cadenas de texto como a los campos insertados en el mismo encabezado o pie.

Para obtener información relacionada, consulte ITEM_#.

ITEM_# que identifica un elemento por su posición en una línea.

Para determinar un ITEM_# para un OBJECT, siga estas instrucciones:

Si lo utiliza con OBJECT=TEXT, cuente sólo las cadenas de texto desde la izquierda hasta la derecha.
Si lo utiliza con OBJECT=FIELD, cuente sólo los campos desde la izquierda a la derecha.

Si aplica una declaración de hoja de estilo que especifique ITEM_#, se cuenta el número desde el principio de cada línea en el encabezado o pie, no sólo desde el principio de la primera línea.

sort_column

Identifica las columnas de clasificación vertical (campos BY) para incluirlas como tabla de contenido. Puede identificar una columna mediante las siguientes notaciones:

TOC=fieldname especifica la columna de clasificación por su nombre de campo.

TOC=Bn especifica la columna de clasificación por su orden en la solicitud. Por ejemplo, B2 denota el segundo campo BY (los campos NO PRINT BY están incluidos en el recuento).

TOC=n es lo mismo que TOC=Bn.

Nota: Debe mantener la jerarquía de los campos BY, ya que los objetos TOC de los encabezados (listas desplegables) son interdependientes y concuerdan con la jerarquía del informe.

Principio de página

Ejemplo: Añadir listas desplegables TOC HTML en un encabezado de página

Esta solicitud utiliza los atributos de hoja de estilo necesarios para añadir una tabla de contenido a un informe HTML. La listas desplegables de tabla de contenido presentan los valores del campo CONTINENT identificados en el código de hoja de estilos como OBJECT=FIELD, ITEM=1, TOC=CONTINENT.

TABLE FILE SHORT
HEADING
"Projected Returns Report for Region:  <REGION in Continent:  <CONTINENT "
" "
PRINT PROJECTED_RETURN
BY CONTINENT
BY REGION
BY COUNTRY
ON TABLE SET PAGE-NUM OFF 
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=1, TOC=CONTINENT, $
ENDSTYLE
END

Al ejecutar el informe. La tabla de contenido aparece como un menú desplegable en el encabezado, en lugar del campo CONTINENT:

Pulse la tabla de contenido para ver la lista de valores de clasificación: AMERICAS, ASIA, EUROPE.

Pulse cada continente para ver la información relacionada. El valor seleccionado destella en gris para destacarse en la ventana.

Puede mostrar todos los campos disponibles (todo el informe) pulsando la opción Ver informe completo. Para eliminar la tabla de contenido, pulse la opción Eliminar tabla de contenido. Para restaurar la tabla de contenido, pulse dos veces cualquier parte del informe o pulse el botón Actualizar de su navegador.

Principio de página

Ejemplo: Cómo navegar una tabla de contenido de niveles múltiples en un encabezado de página

Esta solicitud utiliza una hoja de estilos para añadir una TOC HTML, con listas desplegables en la tercera línea del encabezado de página para dos campos de clasificación (BY) especificados en la solicitud: CONTINENT y REGION. Cada campo se convierte en un marcador de posición para su tabla de contenido. (Si las características de tabla de contenido no estuviera activas, el campo se mostraría en el informe).

TABLE FILE SHORT
"Projected Return"
" "
"For:<CONTINENT For:<REGION "
SUM PROJECTED_RETURN
BY CONTINENT BY REGION BY COUNTRY BY TYPE
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON CONTINENT PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
STYLE=NORMAL,
$
TYPE=HEADING, LINE=1, STYLE=BOLD, $
TYPE=HEADING, LINE=3, OBJECT=FIELD, ITEM=1, TOC=B1,$
TYPE=HEADING, LINE=3, OBJECT=FIELD, ITEM=2, TOC=REGION,$
ENDSTYLE
END

La salida es:

Pulse la flecha en la segunda tabla de contenido desplegable y seleccione North America. Recuerde que los valores de esta lista desplegable están relacionados a los de las listas del nivel superior. Todos ellos forman parte del mismo grupo de clasificación de nivel superior y, por tanto, se encuentran en el mismo salto de sección. El valor seleccionado, North America, parpadea y se desplaza a la parte superior de la ventana del navegador. Desde ahí puede desplazarse para ver los datos relacionados, como se aprecia en la siguiente imagen.

Tenga en cuenta que, si selecciona información que ya aparece en su campo de visión, el valor se resaltará en gris y comenzará a parpadear para llamar su atención.

Luego, desplácese hacia arriba y elija ASIA de la primera lista de tablas de contenido. Esta selección cambia su grupo de clasificación de nivel más alto y afecta todas las listas por debajo de este. ASIA parpadea y se mueve a la parte superior de la ventana, donde aparece la información del primer país (Hong Kong) de la región Far East. El número de página ahora es 2, ya que se trata del segundo grupo de clasificación de alto nivel en la tabla de contenido.

Continúe el experimento con otras selecciones.

Principio de página

Referencia: Navegar entre informes

Además de técnicas y herramientas para navegar dentro de un informe, WebFOCUS proporciona varios mecanismos para navegar entre informes. Con estas características, un usuario navega desde una muestra de informe. Puede:

Hacer "drill-down" (búsqueda detallada de lo general a lo específico) hasta otros informes, URLs y funciones de JavaScript. Consulte Cómo vincular un informe a otros recursos.
Defina marcaos y aliméntelos con informes. Consulte Cómo especificar un marco de destino.

Principio de página

Referencia: Límites del índice HTML

La característica Tabla de contenido:

Se aplica a la salida HTML.
Compatible con Internet Explorer. Esta característica puede dar lugar a un comportamiento inesperado con otros navegadores. Consulta la Declaración de compatibilidad con navegadores de WebFOCUS (https://techsupport.informationbuilders.com/tech/wbf/wbf_tmo_027.html) para obtener información sobre los navegadores compatibles con ésta y otras características WebFOCUS.
No admite el comando de Dialogue Manager -HTMLFORM.
No se admite con los informes de acordeón.
No se puede designar una tabla de contenido a un campo BY sin también especificar una para sus campos principales (BY). La razón es que los controles TOC son interdependientes y requieren la presencia física de cada control principal para operar correctamente. Por ejemplo, si la solicitud contiene BY COUNTRY BY CAR BY MODEL, un informe no incluye un control TOC para CAR si no incluye también uno para COUNTRY.
El tamaño de un informe con capacidad para TOC está limitado por la memoria disponible en el Cliente WebFOCUS.
Si su solicitud tiene ambas tablas de contenido BYTOC y una tabla de contenido de encabezado en la hoja de estilos, la salida incluirá la tabla de contenido de encabezado.

Si ha instalado ReportCaster, puede distribuir un informe con una TOC HTML incluyendo los comandos siguientes en la solicitud del informe:

El comando SET BASEURL, establecido en el URL usado para conectarse al servidor de aplicaciones en que encuentra instalado el Cliente WebFOCUS. Para más información, consulte Cómo especificar un URL base .