Cómo crear parámetros

Si su informe de drill down se basa en un valor de datos específicos en el informe base, debe crear un parámetro (o parámetros) que pueda pasar uno o más valores al informe al que hace el drill down.

Los parámetros son útiles cuando quiere crear un vínculo dinámico. Por ejemplo, su primer informe es un resumen que lista el número total de productos ordenados por una compañía en una fecha específica. Puede jerarquizar desde un producto específico en ese informe a un informe más detallado que muestre el nombre del proveedor del producto y la cantidad de unidades ordenadas, organizadas por número de orden. Con un vínculo dinámico crea sólo un informe detallado (o drill down) que usa el valor que le ha pasado el primer informe para determinar qué información mostrar, en vez de varios informes estáticos.

Puede crear parámetros múltiples. Toda la cadena de parámetros debe ir entre paréntesis separados por espacios en blanco, y no puede ser mayor de 2400 caracteres.

Puede utilizar cualquier combinación de los siguientes métodos para crear parámetros en su declaración de hoja de estilos. Puede especificar:

Sintaxis: Cómo Crear parámetros

parameter=value

donde:

parameter

Es el nombre de la variable en el procedimiento enlazado.

Nota: Para evitar cualquier conflicto, no asigne nombres a las variables que empiecen por Date, IBI o WF. El uso de nombres de variables que empiezan por estos valores está reservado a Information Builders.

value

identifica el valor que hay que pasar. Dichos valores pueden ser cualquiera de los siguientes:

'constant_value' identifica un valor real que hay que pasar. El valor debe estar encerrado entre comillas simples.

field identifica el campo en el informe cuyo valor hay que pasar al procedimiento. Puede identificar el campo por su nombre o su posición. Para obtener información detallada acerca de la posición del campo, vaya a Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

'&variable' identifica una variable ampersand cuyo valor hay que pasar al procedimiento. El nombre de la variable ampersand debe ir entre comillas simples. Puede utilizar variables ampersand sólo en hojas de estilos en línea.

Nota: El uso más común de una variable ampersand consiste en pasar un valor constante. Si la variable ampersand (&) corresponde a un campo alfanumérico, dicha variable tendría que estar encerrada entre comillas simples, por ejemplo:

'&ABC'.

Toda la cadena de nombres y valores de parámetros debe ir entre paréntesis. Cada parameter=value debe separarse con un espacio en blanco. Puede incluir parámetros múltiples en su solicitud, pero la cadena completa no puede pasar de 2400 caracteres.

Nota: Si el informe de drill down contiene una declaración -DEFAULTS que establece un valor predeterminado a la misma variable ampersand (&) del informe principal, el valor de la variable ampersand que se haya pasado anula la declaración -DEFAULTS en el procedimiento de destino.

Principio de página

Ejemplo: Cómo crear parámetros especificando un valor constante

El siguiente ejemplo muestra cómo crear parámetros especificando un valor constante. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

Informe principal:

SET LOOKGRAPH BAR
SET 3D=OFF
GRAPH FILE SHORT
HEADING
"Sum of Balance Across Short Date"
"Click Any Bar For a Report on Projected Returns Since June 29, 1998 "
SUM BALANCE
ACROSS SHORT_DATE
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=N1,FOCEXEC=PROJRET(Short_Date='06291998'),$ 
ENDSTYLE
END

Informe detallado o drill down (PROJRET):

TABLE FILE SHORT
HEADING
"Projected Returns Since June 29, 1998 "
SUM PROJECTED_RETURN
BY SHORT_DATE
BY REGION
WHERE SHORT_DATE GE '&Short_Date';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida del informe principal es:

Cuando pulsa en una barra el resultado es:

Projected Returns Since June 29, 1998

Date of		Projected
Statement	Region	Annualized
		Return
06/29/1998	CENTRAL AMERICA	1.360
	EASTERN EUROPE	2.300
	FAR EAST	1.300
	MIDDLE EAST	1.140
	NORTH AMERICA	1.780
	SOUTH AMERICA	1.200
	WESTERN EUROPE	1.140
06/30/1998	CENTRAL AMERICA	1.360
	EASTERN EUROPE	2.350
	FAR EAST	1.300
	MIDDLE EAST	1.140
	NORTH AMERICA	1.780
	SOUTH AMERICA	1.200
	WESTERN EUROPE	1.140
07/01/1998	CENTRAL AMERICA	1.360
	EASTERN EUROPE	2.300
	FAR EAST	1.300
	MIDDLE EAST	1.140
	NORTH AMERICA	1.780
	SOUTH AMERICA	1.200
	WESTERN EUROPE	1.140

Principio de página

Ejemplo: Cómo crear parámetros especificando un campo

El siguiente ejemplo muestra cómo crear parámetros especificando un campo, CATEGORY en este caso. El informe detallado (o drill down) SALES (es decir, el informe que enlaza con el informe principal) iguala el campo CATEGORY con &TYPE. En el informe base, TYPE es igual al campo CATEGORY.

Cuando se ejecuta el informe, los valores para el campo CATEGORY (Coffee, Food, Gifts) están enlazados a un informe que contiene los análisis regionales y del producto para los valores respectivos.

Informe principal:

TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY
HEADING 
"* Click category to see product and regional breakdowns."
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=DATA, COLUMN=CATEGORY, FOCEXEC=SALES (TYPE=CATEGORY), $ 
ENDSTYLE
FOOTING
"This report was created on &DATE ."
END

Informe detallado o drill down (SALES):

TABLE FILE GGSALES
ON TABLE SET PAGE-NUM OFF
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
ACROSS REGION
WHERE CATEGORY = '&TYPE';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida del informe principal es:

Pulse Coffee y aparecerán los análisis regionales y del producto correspondientes a Coffee:

Principio de página

Ejemplo: Cómo crear parámetros especificando una variable ampersand

La siguiente solicitud muestra cómo crear un parámetro especificando una variable ampersand. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

Informe principal:

SET3D=OFF
GRAPH FILE EMPLOYEE
HEADING
"Salary Report Per Employee ID"
"Click A Bar For The List of Employees in the '&DEPARTMENT' Department"
SUM SALARY
ACROSS EMP_ID AS 'EMPLOYEE ID'
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=SALARY,
FOCEXEC=EMPBYDEP(DEPARTMENT='&DEPARTMENT'), $ 
ENDSTYLE
END

Informe enlazado (EMPBYDEP):

TABLE FILE EMPLOYEE
HEADING
"List Of Employees in the '&DEPARTMENT' Department "
PRINT FIRST_NAME LAST_NAME
BY DEPARTMENT
WHERE DEPARTMENT EQ '&DEPARTMENT';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Cuando se ejecuta la solicitud del informe principal, aparece el siguiente aviso:

Introduzca MIS y pulse Enviar. La salida es:

Cuando pulsa en una barra del gráfico, el resultado es:

List Of Employees in the 'MIS' Department
DEPARTMENT	FIRST NAME	LAST NAME
MIS	MARY	SMITH
	DIANE	JONES
	JOHN	MCCOY
	ROSEMARIE	BLACKWOOD
	MARY	GREENSPAN
	BARBARA	CROSS

Principio de página

Ejemplo: Cómo usar parámetros múltiples

Cuando se utilizan parámetros múltiples, toda la cadena debe estar entre paréntesis y cada parámetro debe estar separado por un espacio en blanco. Las declaraciones de hoja de estilos relevantes están resaltadas en la solicitud.

Informe principal:

SET 3D=OFF
GRAPH FILE EMPLOYEE
SUM CURR_SAL
ACROSS DEPARTMENT
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=CURR_SAL,
FOCEXEC=REPORT2 (DEPARTMENT='&DEPARTMENT' LAST_NAME='SMITH'), $ 
ENDSTYLE
END

Informe drill down (REPORT2):

TABLE FILE EMPLOYEE
PRINT SALARY
BY DEPARTMENT
BY FIRST_NAME
BY LAST_NAME
WHERE DEPARTMENT EQ '&DEPARTMENT'
WHERE LAST_NAME EQ '&LAST_NAME'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Cuando se ejecuta la solicitud del informe principal, aparece el siguiente aviso:

Introduzca MIS y pulse Enviar. La salida es:

Cuando pulsa en la barra MIS, el resultado es:

DEPARTMENT	FIRST NAME	LAST NAME	SALARY
MIS	MARY	SMITH	$13,200.00