Cómo crear un archivo HOLD estructurado

Los archivos HOLD estructurados facilitan la migración de orígenes de datos e informes entre sistemas operativos.

Otros formatos HOLD capturan datos desde las fuentes originales y pueden mantener algunos elementos estructurales implícitos desde la propia solicitud. Sin embargo, no propagan la mayor parte de la información sobre las fuentes de datos originales a las que se accedió ni sus relaciones internas al archivo máster HOLD o sus orígenes de datos. Sin embargo, los archivos HOLD estructurados extraen los datos a una estructura paralela a las fuentes de datos originales. Posteriores solicitudes usando el archivo HOLD pueden usar esas relaciones de datos guardadas para recrear los mismos tipos de relaciones en otros entornos o en otros tipos de orígenes de datos.

En todos los casos el archivo HOLD contiene todos los segmentos originales necesarios para el informe completo basado en la propia solicitud TABLE. Sea cual sea el comando de visualización usada en la solicitud original (PRINT, LIST, SUM, COUNT), el archivo HOLD estructurado se crea como si la solicitud utilizara PRINT. Se pasa por alto el paso de agregación.

El archivo HOLD contiene o todos los campos en la estructura identificada por la solicitud que se usan para cumplir con la solicitud, o todos los campos de visualización y campos BY. El archivo no contiene campos DEFINE que no hayan sido específicamente referenciados en la solicitud. Sí contiene todos los campos necesarios para evaluar cualquier campo DEFINE al que se haya hecho referencia en la solicitud.

Los archivos HOLD estructurados sólo están admitidos para comandos TABLE y TABLEF. Se pueden crear en cualquier sitio donde esté admitido un archivo HOLD. Debe activar los archivos HOLD estructurados en una solicitud específica al emitir el comando ON TABLE SET EXTRACT en la solicitud antes de crear el archivo HOLD estructurado.

Sintaxis: Cómo Activar archivos HOLD estructurados para una solicitud

ON TABLE SET EXTRACT {ON|*|OFF}

donde:

ON: Activa los archivos HOLD estructurados para esta solicitud y extrae todos los campos mencionados en la solicitud.
*: Activa los archivos HOLD estructurados para la solicitud, e indica que le sigue un bloque de opciones de extracción. Por ejemplo, puede excluir campos específicos del archivo HOLD estructurado. Para más información, consulte Cómo Especificar las opciones para generar archivos HOLD estructurados.
OFF: Desactiva los archivos HOLD estructurados para esta solicitud. OFF es el valor predeterminado.

Sintaxis: Cómo Crear un archivo HOLD estructurado

Antes de emitir el comando HOLD, active los archivos HOLD estructurados para la solicitud mediante el comando ON TABLE SET EXTRACT descrita en Cómo Activar archivos HOLD estructurados para una solicitud. Después emita el comando HOLD para crear el archivo HOLD estructurado:

[ON TABLE] {HOLD|PCHOLD} [AS name] FORMAT {ALPHA|BINARY|FOCUS}

donde:

name: Es el nombre del archivo HOLD. Si se omite, el nombre será HOLD por defecto.
FORMAT: Es ALPHA, BINARY o FOCUS.

Nota: Puede emitir un comando SET para establecer el formato HOLD por defecto a ALPHA o a BINARY:

SET HOLDFORMAT=ALPHA
SET HOLDFORMAT=BINARY

Sintaxis: Cómo Especificar las opciones para generar archivos HOLD estructurados

Para especificar opciones para crear la extracción, y como resultado, excluir campos específicos, utilice la opción * del comando SET EXTRACT:

ON TABLE SET EXTRACT *
EXCLUDE = (fieldname1, fieldname2, fieldname3 , ..., fieldnamen),$
FIELDS={ALL|EXPLICIT},$
ENDEXTRACT
ON TABLE HOLD AS name FORMAT {ALPHA|BINARY|FOCUS}

donde:

EXCLUDE=(fieldname1, fieldname2, fieldname3,..., fieldnamen): Excluye los campos especificados del archivo HOLD.
,$: Es sintaxis necesaria para delimitar elementos en el bloque de extracción.
prefijo ALL: Incluye todos los campos reales y todos los campos DEFINE que se usan para ejecutar la solicitud.
EXPLICIT: Incluye sólo los campos reales y campos DEFINE que están en la lista de visualización o en la lista de campos de clasificación BY. Los campos DEFINE que no están referenciados explícitamente y los campos que se usan para evaluar DEFINEs, no están incluidos.
ENDEXTRACT: Termina el bloque de extracción.

Principio de página

Ejemplo: Cómo crear un archivo HOLD estructurado en formato ALPHA

TABLE FILE EMPLOYEE
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT ON
ON TABLE HOLD FORMAT ALPHA
END

Esta solicitud genera el siguiente archivo máster HOLD:

FILENAME=HOLD    , SUFFIX=FIX     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=RECTYPE, ALIAS=R, USAGE=A3, ACTUAL=A3, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, ACTUAL=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, ACTUAL=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10, ACTUAL=A10, $
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, ACTUAL=A06, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=RECTYPE, ALIAS=1, USAGE=A3, ACTUAL=A3, $
    FIELDNAME=SALARY, ALIAS='SAL', USAGE=D12.2M, ACTUAL=A12, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, ACTUAL=A03, $

Fíjese que el campo RECTYPE generado por los archivos HOLD estructurados ALPHA o BINARY. Cada registro en el archivo HOLD comienza por RECTYPE para indicar el segmento al que pertenecía en la estructura original. El segmento raíz tiene RECTYPE=R. Los RECTYPE para otros segmentos son números secuenciales asignados de arriba a abajo, de izquierda a derecha.

A continuación verá los primeros registros en el archivo HOLD:

R  STEVENS        ALFRED    PRODUCTION 25.00
1      11000.00A07
1      10000.00A07
R  SMITH          MARY      MIS        36.00
1      13200.00B14
R  JONES          DIANE     MIS        50.00
1      18480.00B03
1      17750.00B02
R  SMITH          RICHARD   PRODUCTION 10.00
1       9500.00A01
1       9050.00B01

Principio de página

Ejemplo: Cómo crear un archivo HOLD estructurado en formato FOCUS

TABLE FILE EMPLOYEE
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT ON
ON TABLE HOLD FORMAT FOCUS
END

Esta solicitud genera el siguiente archivo máster HOLD:

FILENAME=HOLD    , SUFFIX=FOC     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10, $
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=SALARY, ALIAS='SAL', USAGE=D12.2M, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, $

Principio de página

Ejemplo: Cómo reconstituir un archivo HOLD estructurado

La solicitud a continuación reconstituye la fuente de datos FOCUS original a partir del archivo HOLD estructurado creado en Cómo crear un archivo HOLD estructurado en formato ALPHA:

TABLE FILE HOLD
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT ON
ON TABLE HOLD AS RECONST FORMAT FOCUS
END

Esta solicitud genera el siguiente archivo máster:

FILENAME=RECONST    , SUFFIX=FOC     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10,
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=SALARY, ALIAS='SAL', USAGE=D12.2M, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, $

La siguiente solicitud imprime la salida del informe:

TABLE FILE RECONST
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
END

La salida es:

DEPARTMENT           SALARY  LAST_NAME        FIRST_NAME  JOBCODE  ED_HRS
----------           ------  ---------        ----------  -------  ------
MIS              $27,062.00  CROSS            BARBARA     A17       45.00
                 $25,775.00  CROSS            BARBARA     A16       45.00
                 $21,780.00  BLACKWOOD        ROSEMARIE   B04       75.00
                 $18,480.00  JONES            DIANE       B03       50.00
                             MCCOY            JOHN        B02         .00
                 $17,750.00  JONES            DIANE       B02       50.00
                 $13,200.00  SMITH            MARY        B14       36.00
                  $9,000.00  GREENSPAN        MARY        A07       25.00
                  $8,650.00  GREENSPAN        MARY        B01       25.00
PRODUCTION       $29,700.00  BANNING          JOHN        A17         .00
                 $26,862.00  IRVING           JOAN        A15       30.00
                 $24,420.00  IRVING           JOAN        A14       30.00
                 $21,120.00  ROMANS           ANTHONY     B04        5.00
                 $16,100.00  MCKNIGHT         ROGER       B02       50.00
                 $15,000.00  MCKNIGHT         ROGER       B02       50.00
                 $11,000.00  STEVENS          ALFRED      A07       25.00
                 $10,000.00  STEVENS          ALFRED      A07       25.00
                  $9,500.00  SMITH            RICHARD     A01       10.00
                  $9,050.00  SMITH            RICHARD     B01       10.00

Principio de página

Ejemplo: Cómo excluir campos de un archivo HOLD estructurado

Esta solicitud excluye el campo SALARY usado para secuenciación:

TABLE FILE EMPLOYEE
PRINT LAST_NAME FIRST_NAME JOBCODE ED_HRS
BY DEPARTMENT
BY HIGHEST SALARY
ON TABLE SET EXTRACT *
EXCLUDE=(SALARY),$
ENDEXTRACT
ON TABLE HOLD FORMAT FOCUS
END

Esta solicitud genera el siguiente archivo máster HOLD:

FILENAME=HOLD   , SUFFIX=FOC     , $
  SEGMENT=EMPINFO, SEGTYPE=S0, $
    FIELDNAME=LAST_NAME, ALIAS='LN', USAGE=A15, $
    FIELDNAME=FIRST_NAME, ALIAS='FN', USAGE=A10, $
    FIELDNAME=DEPARTMENT, ALIAS='DPT', USAGE=A10, $
    FIELDNAME=ED_HRS, ALIAS='OJT', USAGE=F6.2, $
  SEGMENT=PAYINFO, SEGTYPE=S0, PARENT=EMPINFO, $
    FIELDNAME=JOBCODE, ALIAS='JBC', USAGE=A3, $

Referencia: Elementos incluidos en un archivo HOLD estructurado

Los archivos HOLD estructurados contienen todos los casos de segmentos necesarios para completar la solicitud TABLE o TABLEF. Sea cual sea el comando de visualización usado en la solicitud original (PRINT, LIST, SUM o COUNT), el archivo HOLD estructurado se creará como si el comando fuera PRINT.

Para ser específicos, el archivo de extracción contiene los siguientes elementos:

Todos los campos reales nombrados en la solicitud, como objetos de visualización, campos de clasificación y campos usados en los criterios de selección (pruebas WHERE/IF).
Fíjese en que los campos referenciados múltiples veces en una solicitud están incluidos solamente una vez en el archivo HOLD.
Campos usados en la condición FILTER FILE.
Se ignoran los operadores de prefijo excepto ALL. (que solamente afecta la cantidad de datos recogidos y no implica un cálculo).
El reformateo basado en campos (FIELD1/FIELD2=) hace que el campo original y el campo de formato se incluyan.
Un campo GROUP, si se hace referencia a él explícitamente, o a todos sus miembros en la solicitud.
Nota: Si un miembro de grupo se excluye específicamente (EXCLUDE) o no se hace referencia a él, su GROUP no se añade al archivo máster extraído (se aplica también a los grupos anidados y solapados). Si un GROUP y sus elementos se llaman en una solicitud, el GROUP no se añade como un campo real en el archivo HOLD extraído.
Para FIELDS=ALL, todos los campos DEFINE usados en la solicitud se convierten en campos reales en el archivo HOLD estructurado y se incluyen junto con otros campos usados en la expresión DEFINE (incluyendo otros campos DEFINE). Utilice EXCLUDE para reducir el número de campos incluidos en la salida de EXTRACT.
Los objetos de visualización y campos de clasificación están incluidos en FIELDS=EXPLICIT. Los campos DEFINE se convierten en campos reales cuando aparecen referidos en la solicitud. No se incluyen los campos usados para crearlos, a menos que se les haga referencia explícitamente. Esto reduce el número de campos devueltos en la solicitud.

Referencia: Elementos no incluidos en un archivo HOLD estructurado

Los operadores de prefijo en campos WHERE son evaluados en la selección de datos, pero no quedan incluidos en la salida de extracción.
Se ignoran los operadores de prefijo en objetos de visualización (excepto ALL).
El uso de sintaxis de archivo HOLD estructurado en solicitudes MATCH, MORE y GRAPH, produce mensajes de error y el cierre del procedimiento.
No se admiten pruebas WHERE/IF TOTAL en solicitudes de archivo HOLD estructurado y resultan en la cancelación de la solicitud.
Se ignora el reformateo de campos reales (sólo cuando el campo real está incluido).
No están incluidos los campos computados, pero las expresiones COMPUTE si están incluidas en el archivo de extracción.

Referencia: Notas estructurales y de comportamiento

Las solicitudes de archivo HOLD estructurado están sujetas a las mismas limitaciones de número y tamaño de los campos, como en cualquier otra solicitud TABLE.

Notas estructurales

Los parámetros SET siguientes están desactivados o se les ignora en solicitudes de archivo HOLD estructurado:
- AUTOINDEX
- AUTOPATH
- AUTOSTRATEGY
- EXTHOLD
- EXTSORT
- HOLDATTR
- Al crear el archivo de extracción, se ignoran todos los comandos SET y ON TABLE SET usados para controlar el formato de salida.
Se respetan las vistas alternativas y aparecen reflejadas en la estructura del archivo de extracción.
Se respetan las vistas indexadas, especificadas en la solicitud, y aparecen reflejadas en la estructura del archivo de salida.
Si una solicitud genera un archivo que contiene dos segmentos huérfanos debido a que el segmento padre ha quedado específicamente excluido, se crea un segmento ficticio de sistema que actúe como padre de los dos segmentos no relacionados. Sólo hay una instancia de datos de ese segmento. Los dos segmentos huérfanos se refieren a ese segmento de sistema como el padre. Si el segmento principal no está disponible ya que no fue mencionado en la solicitud, queda activado en la solicitud e incluido como segmento principal.
En el caso de que dos segmentos únicos (U) queden incluidos sin el segmento padre, se convierten en segmentos con SEGTYPE S0, que tratan como padre al segmento de sistema.
Las estructuras JOIN y JOIN WHERE están admitidas.

Notas de optimización de SQL

La optimización de SQL para agregación debe estar desactivada en solicitudes EXTRACT.

Notas BY/ACROSS/FOR

Los campos de clasificación BY y ACROSS se convierten en objetos de visualización adicionales.
BY. . .ROWS and ACROSS . . .COLUMNS sólo funcionan como WHERE implícitos para limitar los valores de campo incluidos.
Los campos FOR están incluidos.
Los campos RECAP están excluidos (igual que los COMPUTE).
A la hora de crear archivos HOLD estructurados se ignoran los campos de resumen que hacen referencia a campos identificados anteriormente. Estos incluyen: SUMMARIZE, RECOMPUTE, SUBTOTAL, SUB-TOTAL ACROSS-TOTAL, ROW-TOTAL y COLUMN-TOTAL.

Notas de formateo

El procesamiento de archivos HOLD estructurados ignora todos los elementos de formateo, incuidos IN, OVER, NOPRINT, SUP-PRINT, FOLD-LINE, SKIP-LINE, UNDER-LINE, PAGE-BREAK,TABPAGENO, AS y justificación de títulos de columna. Sin embargo, los campos referidos en comandos de formateo, como HEADING, FOOTING, SUBHEAD y SUBFOOT, y cualquier expresión WHEN asociada a estos, están incluidos.
Al producir salida de extracción, se ignoran todos los comandos STYLE y STYLESHEET.
Se admiten los campos AnV y AnW. Los campos TX sólo se importan a archivos FOCUS.
En el caso de que FIELDNAME y ALIAS sean los mismos para un campo real y que el campo se redefina como sí mismo (posiblemente, con un formato distinto), se crean dos campos en el Archivo máster HOLD, con nombres de campo y alias idénticos. Ante esto, nunca se podrá acceder a la segunda versión del campo haciendo referencia al nombre. Puede usar FIELDS=EXPLICIT para incluir sólo la segunda versión del campo. El DEFINE siguiente muestra un ejemplo de cómo crear duplicados de nombre de campo y alias:
```
DEFINE FILE CAR
COUNTRY/A25=COUNTRY;
END
```

Notas DBA

Al ejecutar solicitudes de archivo HOLD estructurado, se respetan los controles DBA en archivos de origen, a excepción de RESTRICT=NOPRINT, donde no se muestran los campos nombrados en una solicitud (estos campos no pueden exportarse y deben ser EXCLUIDOS).
Las restricciones de DBA no se pasan al archivo máster HOLD.

Cómo reconstituir archivos de extracción

Para reconstituir un archivo plano o FOCUS desde un archivo HOLD estructurado, emplee la sintaxis utilizada para generar el archivo HOLD estructurado. Debe usar la sintaxis ON TABLE SET EXTRACT para preservar estructuras multiruta.
Todos los segmentos FOCUS reconstituidos son SEGTYPE=S0, ya que no se retiene la información de KEY e INDEX. Use la sintaxis REBUILD INDEX para reinsertar un INDEX.