BAR [AS 'character'] OVER

donde:

character

Es el carácter de guión (-) o el carácter de igual (=). Ponga el carácter entre comillas simples. El carácter predeterminado es el guión (-).

Este ejemplo utiliza el carácter de subrayado predeterminado (_) .

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR                          OVER 
RECAP TOTCASH = R1 + R2 + R3;
END

La salida aparece en la imagen siguiente.

                 AMOUNT
                 ------
CASH ON HAND      8,784
DEMAND DEPOSITS   4,494
TIME DEPOSITS     7,961
                 ------
TOTCASH          21,239

Observe como la frase BAR ... OVER subraya únicamente la columna que contiene el campo de visualización.

Incluya la sintaxis siguiente en la solicitud FML en lugar de un valor de etiqueta.

PAGE-BREAK OVER

En este ejemplo, se inserta un salto de página después de los dos primeros comandos RECAP para destacar cada cálculo.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'                                    OVER
1020 AS 'DEMAND DEPOSITS'                                 OVER
1030 AS 'TIME DEPOSITS'                                   OVER
BAR                                                       OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH'             OVER 
PAGE-BREAK                                                OVER 
1100 AS 'ACCOUNTS RECEIVABLE' LABEL RECEIVE               OVER
1200 AS 'INVENTORY'  LABEL INVENT                         OVER
BAR                                                       OVER
RECAP TOTASSET = RECEIVE + INVENT; AS 'TOTAL ASSETS'      OVER 
PAGE-BREAK                                                OVER 
RECAP TOTAL = TOTCASH + TOTASSET;
END

La salida aparece en la imagen siguiente.

TYPE=type, [COLUMN=column] [LABEL={Rn|label}], format_def, $

donde:

type

Identifica el componente que desea formatear. Los valores aceptables son:

REPORT indica una fila con la etiqueta especificada.

DATA indica una fila con la etiqueta especificada, que contiene valores de datos proporcionados por el usuario.

FREETEXT indica un texto libre o una fila en blanco con la etiqueta especificada.

UNDERLINE indica subrayado generado con BAR. PDF y PS admiten formateado de un subrayado; HTML, no lo admite.

column

Identifica una columna específica. Puede identificar la columna por su nombre y posición en una fila.

LABEL

Es el factor de control al identificar y formatear una fila FML.

Tenga en cuenta que la etiqueta se utiliza para identificar una fila para cálculos y formateado. La etiqueta de una fila TAG o DATA nunca aparece en la salida de informe. Solo se utiliza para identificar filas en el código FML. En filas RECAP, el nombre del valor calculado sirve como etiqueta y aparece en el informe a menos que se especifique un título alternativo.

label es una etiqueta de fila explícita que asigna para identificar una fila de manera más clara.

format_def

Es la definición de formato, como FONT, SIZE, STYLE y COLOR. Consulte Cómo dar formato a un informe FML.

Nota: Para formatear una celda, identifique la celda como la intersección de una columna y una fila con COLUMN=... más LABEL= ... en la misma declaración de hoja de estilos.

A continuación se ilustra cómo identificar y formatear una fila FML completa, que consista de una etiqueta de fila y los datos de la fila. El atributo LABEL en la hoja de estilos identifica las tres filas TAG, que aquí aparecen con estilo en cursiva.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND' LABEL COH OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD OVER
1030 AS 'TIME DEPOSITS' LABEL TD OVER
BAR OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = COH, STYLE = ITALIC, $ 
TYPE = REPORT, LABEL = DD,  STYLE = ITALIC, $ 
TYPE = REPORT, LABEL = TD,  STYLE = ITALIC, $ 
ENDSTYLE
END

La salida se muestra en la siguiente imagen.

La solicitud aplica negrita a CASH, que es el título de fila personalizado, así como a los datos relacionados en la columna AMOUNT. La hoja de estilos utiliza la etiqueta explícita CA para identificar el componente que hay que formatear.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
10$$ AS 'CASH'                LABEL CA   OVER
1100 AS 'ACCOUNTS RECEIVABLE' LABEL AR   OVER
1200 AS 'INVENTORY'           LABEL INV  OVER
RECAP CURASST/I5C = CA + AR + INV;
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = CA, STYLE = BOLD, $ 
ENDSTYLE
END

La salida se muestra en la siguiente imagen.

La solicitud genera un informe en que el valor de datos de AMOUNT aparece en negrita en la fila titulada CASH. Sin embargo, el título de la fila CASH no está en negrita. Esto se logra señalando la celda en la declaración de hoja de estilos. En este caso, la columna (N2) en la fila (CA).

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
10$$ AS 'CASH'                LABEL CA   OVER
1100 AS 'ACCOUNTS RECEIVABLE' LABEL AR   OVER
1200 AS 'INVENTORY'           LABEL INV  OVER
RECAP CURASST/I5C = CA + AR + INV;
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, COLUMN = N2, LABEL = CA, STYLE = BOLD, $ 
ENDSTYLE
END

La salida se muestra en la siguiente imagen.

Esta solicitud identifica por nombre a la columna AMOUNT y aplica un formato de negrita al título y a los datos. Se obtiene el mismo resultado si se identifica la columna como N2.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
"---CASH ACCOUNTS---"                   OVER
1010 AS 'CASH ON HAND'                  OVER
1020 AS 'DEMAND DEPOSITS'               OVER
1030 AS 'TIME DEPOSITS'                 OVER
" "                                     OVER
"---OTHER CURRENT ASSETS---"            OVER
1100 AS 'ACCOUNTS RECEIVABLE'           OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, COLUMN = AMOUNT, STYLE = BOLD, $ 
ENDSTYLE
END

La salida aparece en la siguiente imagen.

Esta solicitud pone el texto libre en negrita. Puesto que en este ejemplo se aplica el mismo estilo en ambas filas de texto libre, no se necesitan etiquetas para distinguirlas.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
"---CASH ACCOUNTS---"  LABEL CA         OVER
1010 AS 'CASH ON HAND'                  OVER
1020 AS 'DEMAND DEPOSITS'               OVER
1030 AS 'TIME DEPOSITS'                 OVER
" "                                     OVER
"---OTHER CURRENT ASSETS---"  LABEL OCA OVER
1100 AS 'ACCOUNTS RECEIVABLE'           OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = FREETEXT, STYLE = BOLD, $ 
ENDSTYLE
END

La salida aparece en la siguiente imagen.

Esta solicitud usa el atributo SIZE para distinguir dos líneas de texto libre: CASH ACCOUNTS y OTHER CURRENT ASSETS. Se usan las etiquetas CA y OCA para identificar y formatear cada fila de forma separada.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT 
" --- CASH ACCOUNTS ---" LABEL CA            OVER 
1010 AS 'CASH ON HAND'                       OVER
1020 AS 'DEMAND DEPOSITS'                    OVER
1030 AS 'TIME DEPOSITS'                      OVER
" "                                          OVER 
" --- OTHER CURRENT ASSETS ---" LABEL OCA    OVER 
1100 AS 'ACCOUNTS RECEIVABLE'                OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = FREETEXT, LABEL = CA, STYLE = BOLD, SIZE = 12, $ 
TYPE = FREETEXT, LABEL = OCA, STYLE = BOLD, SIZE = 10, $ 
ENDSTYLE
END

La salida aparece en la siguiente imagen.

En este ejemplo los componentes de texto y variables de la fila de texto libre reciben estilo por separado. El texto, Current Assets, aparece en cursiva y el valor derivado del cálculo RECAP, en negrita.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT AS 'Amount' FOR ACCOUNT
10$$ AS 'Cash'                   LABEL CA    OVER
1100 AS 'Accounts Receivable'    LABEL AR    OVER
1200 AS 'Inventory'              LABEL INV   OVER
RECAP CURASST/I5C = CA + AR + INV; NOPRINT  OVER
"Current Assets: <CURASST"
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID=OFF, $ 
TYPE = FREETEXT, OBJECT = TEXT, ITEM = 1, SIZE = 12, STYLE = ITALIC, $ 
TYPE = FREETEXT, OBJECT = FIELD, ITEM = 1, STYLE = BOLD, $ 
ENDSTYLE
END

La salida aparece en la siguiente imagen.

Esta solicitud aplica negrita al título de la fila y al valor calculado en una fila RECAP. Note que la etiqueta RECAP en la hoja de estilos es TOTCASH. En una RECAP, el nobre asignado al valor calculado sirve como etiqueta explícita.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = TOTCASH, STYLE = BOLD, $ 
TYPE = REPORT, LABEL = CASH, COLUMN = N1, STYLE = ITALIC, $
TYPE = REPORT, LABEL = DD, COLUMN = N1, STYLE = ITALIC, $
TYPE = REPORT, LABEL = TD, COLUMN = N1, STYLE = ITALIC, $
ENDSTYLE
END

La salida aparece en la siguiente imagen.

Para solicitar un borde uniforme alrededor de una fila o celda, utilice esta sintaxis:

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER=option,
[BORDER-STYLE=line_style,] [BORDER-COLOR={color|RGB® g b)},] $

Para especificar características diferentes para el borde superior, inferior, izquierdo o derecho, emplee esta sintaxis:

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER-position=option,
[BORDER-[position-]STYLE=line_style,]
[BORDER-[position-]COLOR={color|RGB(r g b)},] $

Para especificar características diferentes para el borde superior, inferior, izquierdo o derecho, emplee esta sintaxis:

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER-position=option,
[BORDER-[position-]STYLE=line_style,]
[BORDER-[position-]COLOR={color|RGB(r g b)},] $

donde:

row_label

Es la fila a la que se aplican las características de borde especificadas.

column

Utilizada junto con la etiqueta de fila. Designa un celda (en el punto de intersección de la fila y la columna) en la que aplican las características de borde especificadas.

option

Puede ser uno de los valores siguientes:

ON activa los bordes de todo el encabezado o pie. ON genera la misma línea que MEDIUM.

OFF desactiva los bordes de todo el encabezado o pie. OFF es el valor predeterminado.

LIGHT especifica una línea fina. Puede especificar una línea fina para todo el encabezado o pie o para una o más posiciones de borde.

MEDIUM identifica una línea de grosor medio (ON establece la línea al grosor medio). Puede especificar una línea fina para todo el encabezado o pie o para una o más posiciones de borde. Tenga en cuenta que la configuración de una línea de grosor medio garantiza la consistencia entre líneas creada mediante el atributo GRID.

HEAVY identifica una línea gruesa. Puede especificar una línea gruesa para todo el encabezado o pie o para una o más posiciones de borde.

width especifica el grosor de línea en puntos (72 puntos=1 pulgada). Puede especificar el grosor de la una línea en puntos para todo el encabezado o pie, o para una o más posiciones de los bordes. El grosor de línea especificado en puntos se muestra de forma distinta en salidas HTML y PDF. Para lograr un aspecto uniforme, independientemente del formato de visualización, utilice LIGHT, MEDIUM o HEAVY.

position

Especifica la línea del borde que se va a formatear. Los valores válidos son TOP, BOTTOM, LEFT, RIGHT.

Puede especificar un cualificador de posición para cualquiera de las palabras clave BORDER. Esto le permite formatear el ancho, estilo y color de la línea individualmente, para cualquier lado del borde.

line_style

Ajusta el estilo del margen de la línea. Las hojas de estilos de WebFOCUS admiten todos los estilos de línea estándar de las hojas de estilos en cascada. Algunos de los estilos tridimensionales (señalados con asteriscos) no están disponibles en HTML. Los valores válidos son:

NONE
SOLID
DOTTED
DASHED
DOUBLE*
GROOVE*
RIDGE*
INSET*
OUTSET*

color

Es uno de los valores de colores preestablecidos. El valor predeterminado es BLACK.

Si la pantalla o el dispositivo de salida no admite colores, los sustituye por matices del gris.

RGB

Especifica el color de fuente con una mezcla de rojo, verde y azul.

(r g b)

Es la intensidad deseada de rojo, verde y azul, respectivamente. Los valores se encuentran en una escala de 0 a 255, en que cero es el menos intenso y 255 es el más intenso. Fíjese que si usa los tres componentes de color en intensidades iguales obtiene matices del gris.

Nota: Para informes HTML, la característica BORDER requiere que se activen las hojas de estilo en cascada. No se requiere este código para informes PDF o PS.

Este ejemplo coloca un borde de rayas de grosor medio alrededor de una fila RECAP identificada con la etiqueta TOTCASH. En informes HTML, la característica BORDERS requiere que se activen las hojas de estilos en cascada.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = TOTCASH, BORDER = MEDIUM, 
  BORDER-STYLE = DASHED, $ 
ENDSTYLE
END

La salida aparece en la siguiente imagen.

Este ejemplo coloca una gruesa línea negra sobre y debajo de la fila RECAP identificada mediante la etiqueta TOTCASH, y una fina línea punteada color plata a la izquierda y a la derecha de cada columna de una fila.

En informes HTML, la característica BORDERS requiere que se activen las hojas de estilos en cascada.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF,$ 
TYPE = REPORT, LABEL = TOTCASH, 
     BORDER-TOP = HEAVY, 
     BORDER-BOTTOM = HEAVY, 
     BORDER-LEFT = LIGHT, 
     BORDER-RIGHT = LIGHT, 
     BORDER-TOP-STYLE = SOLID, 
     BORDER-BOTTOM-STYLE = SOLID, 
     BORDER-LEFT-STYLE = DOTTED, 
     BORDER-RIGHT-STYLE = DOTTED, 
     BORDER-LEFT-COLOR = 'SILVER', 
     BORDER-RIGHT-COLOR = 'SILVER', $
ENDSTYLE
END

La salida aparece en la siguiente imagen.

Este ejemplo coloca un borde de grosor medio alrededor de una celda en la segunda columna de la fila identificada con la etiqueta TOTCASH. Las especificaciones combinadas LABEL y COLUMN se identifican en la celda. La característica BORDERS requiere que se activen las hojas de estilos en cascada.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF,$ 
TYPE = REPORT, LABEL = TOTCASH, COLUMN = N2, BORDER = MEDIUM, $ 
ENDSTYLE
END

La salida aparece en la siguiente imagen.

FOR forfield [IN k]
tag [[GET CHILDREN|WITH CHILDREN] n] INDENT m [AS ['text'|CAPTION]] 
[OVER]

o

RECAP fieldname[/format]=expression; INDENT m [AS 'text']

donde:

forfield

Es un campo en el origen de datos cuyos valores se incluyen en el informe.

k

Es la columna inicial para el valor FOR en un informe FML.

tag

Es un valor de forfield que hay que mostrar en una fila del informe FML.

n

Es el número de niveles de una jerarquía FML que hay que mostrar en el informe FML.

m

Es un número entero positivo (no se admite el cero) que especifica el número de espacios que hay que sangrar el valor de etiqueta, la etiqueta o el título de una fila o una jerarquía FML. La sangría empieza desde la columna uno si no se ha especificado una frase IN en el comando FOR. Si existe una frase IN, la sangría empieza desde la columna especificada en la frase IN. La sangría máxima es la misma que la longitud máxima de un nombre AS.

Si sangra una jerarquía FML, la línea principal de la jerarquía se sangra en la cantidad de espacios especificados como sangría. Los niveles de jerarquía se sangran dos espacios a partir de cada uno. Si se utiliza la frase GET CHILDREN, la sangría de la primera línea de la jerarquía aumenta en dos espacios adicionales porque la salida de jerarquía empieza con la primera secundaria y no con la principal. Para más información sobre el uso de GET CHILDREN, vaya a Cómo mostrar una jerarquía FML .

'text'

Es una etiqueta que hay que mostrar en una fila de un informe FML.

CAPTION

Indica que se ha definido un campo de título en el archivo máster.

OVER

Indica que esta fila no es la última fila que hay que mostrar.

fieldname

Es un nombre que asigna al valor calculado por el comando RECAP.

format

Es el formato USAGE del campo RECAP. No puede exceder el ancho de la columna. El formato predeterminado es el formato de la columna en que se muestra el valor calculado.

expression

Es la expresión que describe cómo calcular el valor de campo de RECAP.

En la siguiente solicitud, la etiqueta de la segunda fila correspondiente al valor de etiqueta 3000 ha sido sangrada en cinco espacios. Como se utiliza la frase GET CHILDREN, la primera línea de la jerarquía FML, en la tercera fila del valor de etiqueta 3000, ha sido sangrada en siete espacios (cinco + dos).

SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                           AS 'Not Indented'        OVER
3000                 INDENT 5  AS 'Indented 5'          OVER
3000 GET  CHILDREN 2 INDENT 5  AS 'Hierarchy Indented 5'
END

La salida aparece en la imagen siguiente.

                               Parent
                               ------
Not Indented                   3000
     Indented 5                3000
       Hierarchy Indented 5    3000
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3000
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200

La siguiente solicitud suma precio, costo y cantidad en existencia de productos digitales y análogos. El primer comando RECAP calcula el total de cada columna y sangra la etiqueta en cinco espacios. El segundo comando RECAP calcula el beneficio y sangra la etiqueta en 10 espacios.

SET FORMULTIPLE=ON
TABLE FILE CENTINV
SUM PRICE COST QTY_IN_STOCK
FOR PRODTYPE
Digital                                          OVER
Analog                                           OVER
BAR                                              OVER
RECAP TOTAL = R1 + R2; INDENT 5  AS 'Total:'     OVER
BAR                                              OVER
RECAP PROFIT(2) = TOTAL(1) - TOTAL(2); AS 'Profit:' INDENT 10
END

La salida aparece en la imagen siguiente.

                                        Our    Quantity 
                         Price:         Cost:  In Stock:
                         ------         -----  ---------
Digital                4,080.00      3,052.00     119143
Analog                 1,883.00      1,371.00     139345
                   ------------  ------------    -------
     Total:            5,963.00      4,423.00     258488
                   ------------  ------------    -------
          Profit:                    1,540.00

Para aclarar las relaciones en una jerarquía FML, se sangran los títulos de valores en cada nivel. Utilice el parámetro BLANKINDENT en un informe HTML, PDF o PostScript para especificar la sangría entre cada nivel de la jerarquía. Puede utilizar la sangría predeterminada para cada nivel de jerarquía, o bien elegir su propio valor de sangrado. Para imprimir títulos sangrados en un informe HTML, debe ajustar el parámetro BLANKINDENT en ON o en un número.

SET BLANKINDENT no aumenta el ancho de la columna sangrada si no es lo suficientemente ancho como para acomodar los campos sangrados. Aunque es posible en informes HTML, en PDF o PostScript puede causar que los datos se desplacen y queden desalineados en las columnas posteriores a la columna sangrada. Podría tener que utilizar sintaxis de hoja de estilos para aumentar el ancho de la columna de manera que quepan los valores sangrados o mover las columnas para que se ajusten. Cambie el ancho de la columna con el atributo SQUEEZE de hoja de estilos y especifique una posición inicial para una columna mediante el atributo POSITION. Puede también mover una columna en un informe PostScript con la frase IN.

Una característica relacionada le permite cambiar el número de espacios en blanco antes de la línea principal de una jerarquía antes de cualquier etiqueta FML o fila RECAP en una solicitud FML. Para más información, consulte Cómo dar formato a un informe FML.

SET BLANKINDENT={ON|OFF|n}
ON TABLE SET BLANKINDENT {ON|OFF|n}

SET PAGE-NUM=NOPAGE
SET BLANKINDENT=ON
SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                  AS CAPTION      OVER
3000 GET  CHILDREN 2  AS CAPTION  
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE = REPORT, GRID = OFF, $
ENDSTYLE
END

SET PAGE-NUM=NOPAGE
SET BLANKINDENT=.25
SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                 AS CAPTION          OVER
3000 GET  CHILDREN 2 AS CAPTIONON TABLE SET STYLE *
TYPE = REPORT, GRID = OFF, $
ENDSTYLE
END