x

fieldname [AND] ROW-TOTAL[/justification][/format] [AS 'label'] 
fieldname [AND] COLUMN-TOTAL[/justification] [AS 'label']

o

fieldname [AND] COLUMN-TOTAL[/justification] [AS 'label']

donde:

fieldname

Es un campo identificado en un comando de visualización.

justification

Es la alineación de la etiqueta. Los valores válidos son:

L que justifica la etiqueta a la izquierda.

R que justifica la etiqueta a la derecha.

C que centra la etiqueta.

Para obtener información relacionada, consulte Cómo justificar una etiqueta para un total de fila o de columna.

format

Es el formato del total de fila o de columna. Cuando se suman campos con el mismo formato, el formato del total es el mismo que el formato de los campos. Cuando se suman campos con diferente formato, se usa el predeterminado D12.2 para el total de la fila o el de la columna.

label

Es la etiqueta personalizada del total de fila o de columna. La etiqueta predeterminada es TOTAL.

También puede especificar un total de fila o de columna con la frase ON TABLE. Con esta sintaxis no es posible incluir nombres de campo con ROW-TOTAL. Los nombres de campo son opcionales con ROW-TOTAL.

ON TABLE ROW-TOTAL[/justification][/format] [AS 'label']
ON TABLE COLUMN-TOTAL[/justification] [AS 'label']
 [fieldname fieldname fieldname]

Si una solicitud consulta un campo creado con COMPUTE, se incluye el valor de ese campo en un total de fila o de columna. Tenga esto en mente cuando personalice una etiqueta que identifique el total.

Principio de página

Ejemplo: Cómo crear una etiqueta para un total de fila o de columna

Esta solicitud crea la etiqueta Total Population by State para el total de fila y la etiqueta Total Population by Gender para el total de columna. El formato D12 para ROW-TOTAL muestra esos datos con comas.

TABLE FILE GGDEMOG
PRINT MALEPOP98 FEMPOP98 
ROW-TOTAL/D12 AS 'Total Population by State' 
BY ST
WHERE (ST EQ 'WY' OR 'MT') 
ON TABLE COLUMN-TOTAL AS 'Total Population by Gender' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo crear una etiqueta para un total de fila con ACROSS

Esta solicitud suma las poblaciones de dos estados, clasifica la información con la frase ACROSS y marca los totales de columna como Total by Gender (total por género). Existen dos totales de fila en la columna Total by Gender, Male Population y Female Population (población masculina y población femenina, respectivamente).

TABLE FILE GGDEMOG
SUM MALEPOP98/D12 FEMPOP98/D12 
ROW-TOTAL AS 'Total by Gender'  
ACROSS ST
WHERE ST EQ 'WY' OR 'MT';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:

x

{BY|ON} fieldname {SUB-TOTAL|SUBTOTAL|COLUMN-TOTAL} [MULTILINES]
        [field1 [AND] field2...] [AS 'label'] [WHEN expression;]

donde:

fieldname

Es un campo de clasificación identificado en una frase BY u ON.

MULTILINES

Suprime un subtotal cuando hay un solo valor en un salto de clasificación. Después que se especifica, MULTILINES suprime el subtotal de cada salto de clasificación con apenas una línea de detalle. MULTI-LINES es sinónimo de MULTILINES.

field1 field2

Son campos específicos a los que se asignará un subtotal. Un campo específico anula el predeterminado, que incluye todos los campos de visualización numéricos.

AS 'label'

Es la etiqueta personalizada para el subtotal. No puede cambiar la etiqueta predeterminada por un campo de clasificación superior si utiliza SUB-TOTAL.

WHEN expression

Especifica un subtotal condicional determinado por una expresión lógica. Para obtener información detallada, consulte Cómo utilizar expresiones.

Principio de página

Ejemplo: Cómo crear una etiqueta para un subtotal y un total general

Esta solicitud crea una etiqueta personalizada para el subtotal, que es el monto total en metálico deducido del pago de los empleados para pagar los impuestos municipales, por departamento, así como para el total general, que es el monto total en metálico correspondiente a ambos departamentos.

TABLE FILE EMPLOYEE
SUM DED_AMT BY DED_CODE BY DEPARTMENT
BY BANK_ACCT
WHERE DED_CODE EQ 'CITY'
WHERE BANK_ACCT NE 0 
ON DEPARTMENT SUBTOTAL AS 'Total City Deduction for'
ON TABLE COLUMN-TOTAL AS '**GRAND TOTAL**' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

En la salida se incluyen de forma predeterminada los valores del departamento MIS y PRODUCTION en la etiqueta subtotal personalizada.

Principio de página

Ejemplo: Cómo crear una etiqueta para el subtotal de un campo específico

Esta solicitud crea una etiqueta personalizada, llamada Order Total, para el subtotal de LINEPRICE. Utiliza la etiqueta predeterminada TOTAL para el total general.

TABLE FILE CENTORD
PRINT PNUM QUANTITY LINEPRICE 
BY ORDER_NUM SUBTOTAL LINEPRICE AS 'Order Total' 
WHERE ORDER_NUM EQ '28003' OR '28004';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:

x

{BY|ON} fieldname {SUMMARIZE|RECOMPUTE} [MULTILINES]
        [field1 [AND] field2...] [AS 'label'] [WHEN expression;]
ON TABLE {SUMMARIZE|RECOMPUTE}

donde:

fieldname

Es un campo de clasificación identificado en una frase BY u ON.

MULTILINES

Suprime un subtotal cuando hay un solo valor en un salto de clasificación. Después que se especifica, MULTILINES suprime el subtotal de cada salto de clasificación con apenas una línea de detalle. MULTI-LINES es sinónimo de MULTILINES.

field1 field2

Son campos específicos a los que se asignará un subtotal. Los campos especificados anulan los predeterminados, que incluye todos los campos de visualización numéricos.

AS 'label'

Es la etiqueta personalizada para el subtotal. No puede cambiar la etiqueta predeterminada por un campo de clasificación de nivel superior si utiliza SUMMARIZE.

WHEN expression

Especifica un subtotal condicional determinado por una expresión lógica. Para obtener información detallada, consulte Cómo utilizar expresiones.

También puede generar un subtotal con la frase ON TABLE:

ON TABLE {SUMMARIZE|RECOMPUTE}

Principio de página

Ejemplo: Cómo crear una etiqueta para el subtotal de un valor calculado

Esta solicitud crea una etiqueta personalizada para el subtotal, incluyendo el cálculo para el campo DG_RATIO, creado con COMPUTE.

TABLE FILE EMPLOYEE
SUM GROSS DED_AMT AND COMPUTE
DG_RATIO/F4.2 = DED_AMT / GROSS;
BY DEPARTMENT BY BANK_ACCT
WHERE BANK_ACCT NE 0 
ON DEPARTMENT SUMMARIZE AS 'SUBTOTAL FOR ' 
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

En la salida se incluyen de forma predeterminada los valores del departamento MIS y PRODUCTION en la etiqueta subtotal personalizada. La etiqueta predeterminada para el total general es TOTAL.