Cómo ajustar un título de columna

El título de una columna identifica los datos que aparecen en un informe. Use la frase AS si quiere cambiar el título predeterminado de la columna para una identificación más precisa de los datos o para dar un formato más a su gusto. Puede cambiar los títulos de columnas:

El título de la columna se predetermina al nombre del campo en el archivo máster. En el caso de un valor calculado (uno creado con COMPUTE, por ejemplo), el título se predetermina al nombre del campo en la solicitud.

Referencia: Límites de títulos de columna

La anchura asignada a los títulos de columna no tiene otro límite que el de la memoria disponible.
En formatos de salida con estilo, los títulos de las columnas pueden incluir hasta cinco líneas de texto.
Puede reemplazar un título de columna con un campo identificado en una frase ACROSS con sólo una línea de texto.

Sintaxis: Cómo Ajustar un título de columna en una solicitud

fieldname AS 'title_line_1 [,title_line_2,...]'

donde:

fieldname: Es un campo que ha sido identificado en un comando de visualización (como PRINT o SUM), en una frase ACROSS o en una frase BY.
title_line_1,title_line_2: Es el título de columna ajustado a sus necesidades y puesto entre comillas simples.
Para especificar un título de columna de múltiples líneas, separe cada línea con una coma.

Para ajustar a sus necesidades un título de columna para un valor calculado, use la sintaxis:

COMPUTE fieldname[/format] = expression AS 'title'

Para obtener información relacionada, consulte Cómo crear campos temporales.

Sugerencia:

Para evitar que aparezca un título de columna, introduzca dos comillas simples, consecutivas sin espacio entre ambas. Por ejemplo:
```
PRINT LAST_NAME AS ''
```
Para mostrar guiones bajos, los espacios en blanco deben ir entre comillas simples.
Si usa una frase AS para un valor calculado, repita el comando COMPUTE antes de referirse el próximo campo computado.
Los títulos de columnas multilínea creados con la frase AS, no son compatibles con los campos ACROSS.

Principio de página

Ejemplo: Cómo ajustar los títulos de columna en una solicitud

Esta solicitud establece los títulos de columna para un campo identificado en el comando SUM (SALARY) y en los campos identificados en las frases BY (DIV y DEPT).

TABLE FILE EMPDATA
SUM SALARY AS 'Total,Salary'
BY DIV AS 'Division'
BY DEPT AS 'Department'
WHERE DIV EQ 'NE' OR 'SE' OR 'CORP'
HEADING
"Current Salary Report"
ON TABLE SET STYLE *
TYPE=REPORT,GRID=OFF,$
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo suprimir un título de columna

Esta solicitud suprime el título de la columna para LAST_NAME. Muestra además un título de columna de líneas múltiples (EMPLOYEE NUMBER) para los datos de EMP_ID.

TABLE FILE EMPLOYEE
PRINT FIRST_NAME AS 'NAME' AND LAST_NAME AS '' 
BY DEPARTMENT
BY EMP_ID AS 'EMPLOYEE,NUMBER'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo ajustar un título de columna a un valor calculado

Esta solicitud establece el título de columna para el valor calculado REV.

TABLE FILE SALES
SUM UNIT_SOLD RETAIL_PRICE 
COMPUTE REV/D12.2M = UNIT_SOLD * RETAIL_PRICE;AS 'GENERATED REVENUE' 
BY PROD_CODE
WHERE CITY EQ 'NEW YORK'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET STYLESHEET *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La salida es:

Cómo ajustar un título de columna en un archivo máster

Puede cambiar el título de columna predeterminado mediante el atributo opcional TITLE para un campo. Cualquier formato que aplique al campo se aplicará a su título ajustado. Para una salida de lo anterior, vaya a Cómo justificar un encabezado de informe.

Consulte el manual Cómo describir datos con el lenguaje WebFOCUS. para más detalles sobre el atributo TITLE.

Cómo distinguir entre nombres de campos duplicados

Cómo:

Distinguir entre nombres de campos duplicados

El comando SET QUALITIES determina si aparecerán nombres de campo duplicados como títulos de columna cualificados en la salida de informe. Los títulos de columna cualificados son capaces de distinguir entre dos nombres de campo idénticos mediante la inclusión del segmento.

Los títulos de columnas especificados en una frase AS se usan cuando los nombres de campo duplicados aparecen en un comando MATCH, o cuando los nombres de campo duplicados existen en un archivo HOLD.

Principio de página

Sintaxis: Cómo Distinguir entre nombres de campos duplicados

SET QUALTITLES = {ON|OFF}

donde:

ON: Habilita los nombres de columna cualificados cuando existen nombres de campo duplicados y SET FIELDNAME está en NEW (la posición predeterminada). Para más información sobre comandos SET, consulte el manual Cómo desarrollar aplicaciones de informes.
OFF: Deshabilita los títulos de columna cualificados. OFF es el valor predeterminado.