Cómo mostrar superíndices en líneas de datos, encabezados y pies

Los caracteres de superíndice son compatibles con forma de estilo de texto en objetos de texto, mediante las etiquetas de formato HTML. La etiqueta de formato de superíndice es compatible actualmente con las columnas de datos, encabezados y pies, en formatos de salida HTML, PDF y PS. Puede definir valores de superíndice en los datos, añadirlos a campos virtuales o a cadenas de texto incluidas en encabezados y pies.

Para poder activar la traducción de las etiquetas de formato HTML, establezca MARKUP=ON en la hoja de estilos de cualquier componente que vaya a mostrar los superíndices. Sin este atributo, las etiquetas de formato son tratadas como texto en lugar de etiquetas.

Sintaxis: Cómo Mostrar superíndices en líneas de datos, encabezados y pies de informe

Si las etiquetas no se encuentran dentro de los datos, cree un campo que contenga el texto que va a ser utilizado como superíndice. Además, active las etiquetas de formato en los componentes que van a mostrar los superíndices:

En un comando DEFINE o COMPUTE, defina un campo que contenga el texto que va a mostrarse como superíndice.
La sintaxis del comando DEFINE FILE es:
```
DEFINE FILE ...
field/An = text;
END
```
La sintaxis de un comando COMPUTE o DEFINE, en un archivo máster, es:
```
{COMPUTE|DEFINE} field/An = text;
```
donde:
n
Es la longitud de la cadena que define el superíndice, incluido el texto que va a utilizarse como superíndice y las etiquetas de formato de apertura y cierre ( y ).
text
Es el texto que va a utilizarse como superíndice.
En la hoja de estilos, establezca MARKUP=ON para cualquier componente de informe que vaya a mostrar superíndices.
```
TYPE=component,MARKUP=ON ... ,$
```
donde:
component
Es uno de los siguientes componentes de informe: DATA, HEADING, FOOTING, SUBHEAD, SUBFOOT, TABHEADING, TABFOOTING.

Principio de página

Ejemplo: Cómo mostrar superíndices en líneas de datos y pies, en salida PDF

La siguiente solicitud, basada en el origen de datos GGSALES, define dos campos que aparecerán como superíndices. SUP1 y SUP2 están compuestos por los números 1 y 2, respectivamente. SUPCOPY está compuesto por un símbolo de copyright. Observe que la diferencia está en que la sintaxis se definido para un valor de texto, en lugar de un valor HEX.

El comando COMPUTE compara las ventas en dólares con los dólares presupuestados. Si el valor calculado es inferior a un mínimo definido, el superíndice SUP1 se concatena después del nombre de la categoría. Si el valor es superior, se concatena SUP2.

El superíndice SUPCOPY se emplea para mostrar el símbolo de copyright en el pie del informe.

El pie concatena los campos del superíndice delante de sus explicaciones.

En la hoja de estilos, cada componente que muestra el superíndice presenta el atributo MARKUP=ON.

DEFINE FILE GGSALES
SUP1/A12= '<SUP>1</SUP>';
SUP2/A15= '<SUP>2</SUP>';
SUPCOPY/A20= '<SUP>'||HEXBYT(169,'A2')||'</SUP>';
END
TABLE FILE GGSALES
SUM
COMPUTE PROFIT/D12CM=DOLLARS-BUDDOLLARS; NOPRINT
COMPUTE SHOWCAT/A100=IF PROFIT LE -50000 THEN CATEGORY || SUP1
       ELSE IF PROFIT GT 50000 THEN CATEGORY || SUP2
           ELSE CATEGORY; AS Category
BUDDOLLARS/D12CM
DOLLARS/D12CM
BY REGION 
BY CATEGORY NOPRINT
HEADING
"Analysis of Budgeted and Actual Sales"
FOOTING
""
"<SUP1 Dollar sales $50,000 less than budgeted amount."
"<SUP2 Dollar sales $50,000 greater than budgeted amount."
""
"Copyright<SUPCOPY 2012, by Information Builders, Inc " 
ON TABLE SET HTMLCSS ON
ON TABLE SET SQUEEZE ON
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
INCLUDE=ENDEFLT,$
TYPE=DATA,MARKUP=ON,$
TYPE=DATA,COLUMN=N5, COLOR=RED, WHEN=PROFIT LT -50000,$
TYPE=DATA,COLUMN=N6, COLOR=GREEN, WHEN=PROFIT GT 50000,$
TYPE=HEADING, JUSTIFY=LEFT,$
TYPE=FOOTING, MARKUP=ON, JUSTIFY=LEFT,$
TYPE=FOOTING, LINE=2,JUSTIFY=LEFT, COLOR=RED,$
TYPE=FOOTING, LINE=3,JUSTIFY=LEFT, COLOR=GREEN,$
END

La salida es: