x

Para insertar el total de páginas, añada lo que sigue a su solicitud:

<TABLASTPAGE

x

• TABLASTPAGE no establece cambios en FOCFIRSTPAGE o en el comando REPAGE. Por ejemplo, si el informe tiene diez páginas y el usuario utiliza FOCFIRSTPAGE para establecer el número de la primera página en tres en vez de uno, el valor de TABLASTPAGE sigue siendo diez.
• TABLASTPAGE sólo es compatible con informes individuales, no con informes compuestos. Se genera un total de páginas individual para cada informe en un informe compuesto.
• TABLASTPAGE sólo se admite en informes con estilo, como HTML, PDF o PS. No se admite en EXL2K, WP, DOC o HTML con STYLE=OFF y STYLEMODE=FIXED
• TABLASTPAGE provoca una segunda pasada sobre el resultado del informe, primero para calcular la última página y luego para imprimirla con TABPAGENO (aun en el caso de SQUEEZE=OFF).
• TABLASTPAGE no admite la clasificación realizada por el sistema (externa).
• GRAPH FILE no admite TABLASTPAGE.
• TABLEF no admite TABLASTPAGE.

Principio de página

Ejemplo: Cómo insertar el número de la página actual y el total de páginas

A continuación se explica cómo añadir el número de la página actual y el total de páginas al informe. Se destaca la sintaxis relevante en la solicitud.

TABLE FILE EMPLOYEE
PRINT EMP_ID AS 'Employee ID'
BY SALARY IN-GROUPS-OF 5000 AS 'Salary'
BY PCT_INC AS 'Percent,Increase'
BY DAT_INC AS 'Date of,Increase'
ON SALARY PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TITLE, STYLE=BOLD, SIZE=11, $
ENDSTYLE
FOOTING 
"Page <TABPAGENO of <TABLASTPAGE" 
END

Las primeras dos páginas de salida son:

x

La solicitud debe tener la siguiente sintaxis y presentar la salida en un formato con estilo:

BY sortfield REPAGE

El encabezado, o el pie, puede usar la sintaxis siguiente para mostrar “Página x de y”

{HEADING|FOOTING} 
"Page <TABPAGENO of <BYLASTPAGE"

donde:

sortfield

Es el campo de clasificación que ofrece la opción REPAGE. Es necesario un PAGE-BREAK en el mismo campo de clasificación o en uno de nivel inferior. PAGE-BREAK inicia una página nueva por cada salto de clasificación. REPAGE restablece el número de la página en 1 por cada salto de clasificación.

<TABPAGENO

Es el número de la página actual.

<BYLASTPAGE

Es el número de la última página, antes del restablecimiento de página.

Principio de página

Ejemplo: Paginación dentro de un grupo de clasificación

La siguiente solicitud, emitida frente al origen de datos GGSALES, clasifica los datos por producto, región, categoría o ciudad. Restablece la paginación cada vez que el producto cambie. El encabezado imprime el número de página actual y el total de cada grupo de productos.

Tenga en cuenta que las variables TABPAGENO y BYLASTPAGE tienen un formato predeterminado I5, dejando mucho espacio en blanco antes del número de página. Por consiguiente, puede emplear marcadores de posición o comandos COMPUTE para desplazar los números de páginas hacia la izquierda.

En el ejemplo siguiente, un COMANDO compute crea un campo llamado X con un valor de TABPAGENO, pero lo almacena como campo I2, y el marcador de posición del encabezado desplaza el número de página BYLASTPAGE cuatro espacios a la izquierda. El comando de encabezado debe estar situado después del comando COMPUTE para que se reconozca el campo X:

TABLE FILE GGSALES                          
SUM UNITS                                   
COMPUTE X/I2 = TABPAGENO;
BY PRODUCT NOPRINT REPAGE        
BY REGION PAGE-BREAK                        
BY CATEGORY                                 
BY CITY                                     
HEADING CENTER  
"<PRODUCT : Page <X of <-4> <BYLASTPAGE "
ON TABLE PCHOLD FORMAT PDF           
END                                         

La salida parcial mostrada a continuación indica que el número de página se restablece en 1, cuando el producto ha cambiado, y que la variable muestra el número total de páginas para cada producto:

x

Para todas las solicitudes de informe en un procedimiento

SET FOCFIRSTPAGE = {n|1|&FOCNEXTPAGE}

Para una solicitud de informe

ON TABLE SET FOCFIRSTPAGE {n|1|&FOCNEXTPAGE}

donde:

n

Es un número entero entre 1 y 999999 que ha sido asignado a la primera página del informe.

1

Asigna el número uno a la primera página. 1 es el valor predeterminado.

&FOCNEXTPAGE

Es una variable cuyo valor es el último número de página del informe previo más uno en una solicitud múltiple. El valor se calcula en tiempo de ejecución.

Principio de página

Ejemplo: Cómo asignar un número de página a la primera página

Esta solicitud asigna el número tres a la primera página del informe.

SET FOCFIRSTPAGE = 3 
TABLE FILE CENTORD
HEADING
"Sales By Store"
SUM LINEPRICE AS 'Sales'
BY SNAME
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

El informe es:

Principio de página

Ejemplo: Cómo controlar los números de página en informes consecutivos

Este procedimiento contiene dos solicitudes de informe. La segunda solicitud establece FOCFIRSTPAGE al valor de &FOCNEXTPAGE.

SET FOCFIRSTPAGE = 3
TABLE FILE CENTORD
HEADING
"Sales By Store"
SUM LINEPRICE AS 'Sales'
BY SNAME
WHERE SNAME EQ 'eMart'
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END
-RUN

SET FOCFIRSTPAGE = &FOCNEXTPAGE 
TABLE FILE CENTORD
HEADING
"Sales By Product"
SUM LINEPRICE AS 'Sales'
BY PRODCAT AS 'Product'
WHERE PRODCAT EQ 'VCRs'
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

La primera página del segundo informe lleva el número cuatro, es decir uno mayor que la última página del informe anterior:

x

Para todas las solicitudes de informe en un procedimiento

SET PAGE[-NUM] = num_display

Para una solicitud de informe

ON TABLE SET PAGE[-NUM] num_display

donde:

-NUM

Es opcional. PAGE y PAGE-NUM son sinónimos.

num_display

Es uno de los siguientes:

ON muestra los números de página en la esquina superior izquierda, seguidos de una línea en blanco reservada. ON es el valor predeterminado.

OFF suprime los números de página predeterminados.

Puede utilizar la variable de sistema TABPAGENO.

Esto emite expulsiones de páginas.

NOPAGE suprime los números de página predeterminados y le permite el acceso a las dos líneas superiores de una página.

Puede utilizar la variable de sistema TABPAGENO.

Esto no emite expulsiones de páginas.

TOP elimina la línea superior de cada página reservada para el número de página además de la línea en blanco que le sigue. La primera línea del informe contiene el informe o el encabezado de página, si se especifica uno, o bien títulos de columna, si no hay encabezado.

Puede utilizar la variable de sistema TABPAGENO para mostrar números de página en cualquier otro punto del informe.

Principio de página

Ejemplo: Cómo suprimir los números de página predeterminados

Esta solicitud usa SET PAGE-NUM = NOPAGE para suprimir los números de página predeterminados. Usa la línea superior de la primera página del informe para el encabezado de informe.

SET PAGE-NUM = NOPAGE 
TABLE FILE GGPRODS
ON TABLE SUBHEAD
"PACKAGING INFORMATION"
" "
PRINT PACKAGE_TYPE AND SIZE AND UNIT_PRICE
BY PRODUCT_DESCRIPTION
ON PRODUCT_DESCRIPTION PAGE-BREAK SUBFOOT
"PRODUCT ID <PRODUCT_ID"
"Page <TABPAGENO "
ON TABLE SET ONLINE-FMT PDF
END

TABPAGENO inserta el número de página en el pie de clasificación. La primera página del informe es: