Cómo enlazar páginas de informe

Cómo:

Con una hoja de estilo, puede insertar uno o más hipervínculos de navegación en un informe HTML de múltiples páginas. Esta función facilita el vínculo de páginas consecutivas de un informe sin crear vínculos de hipertexto individuales para cada página.

Puede definir cualquier componente de informe como hipervínculo.

Principio de página
x
Sintaxis: Cómo Vincular páginas de informes

Utilice la siguiente sintaxis en un informe HTML 

URL=#_destination, $

donde:

destination
Es uno de los siguientes:

#_next va a la parte superior de la siguiente página del informe.

#_previous va a la parte superior de la anterior página del informe.

#_top va a la parte superior de la actual página del informe.

#_start va a la parte superior de la primera página del informe.

#_end va a la parte superior de la última página del informe.

Nota: Para usar estos destinos en aplicaciones de autoservicio debe emitir el siguiente comando al principio del FOCEXEC:

SET BASEURL=''
Ejemplo: Cómo enlazar páginas de informe a través de imágenes en un encabezado

Esta solicitud muestra dos imágenes en el encabezado de página de un informe largo. Crea un vínculo entre BULLET.GIF y la próxima página del informe y entre GOBACK.GIF y la página anterior del informe. 

TABLE FILE GGORDER
ON TABLE SUBHEAD
"COFFEE GRINDER SALES BY STORE"
" "
HEADING
"Next page or previous page."
PRINT QUANTITY AS 'Ordered Units' BY STORE_CODE BY PRODUCT NOPRINT
BY ORDER_NUMBER
WHERE PRODUCT EQ 'Coffee Grinder'
ON STORE_CODE PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TABHEADING, STYLE=BOLD,$ 
TYPE=HEADING, IMAGE=/IBI_APPS/IBI_HTML/GGDEMO/BULLET, URL=#_next, 
IMAGEALIGN=LEFT,$
TYPE=HEADING, IMAGE=/IBI_APPs/IBI_HTML/GGDEMO/GOBACK, URL=#_previous, 
IMAGEALIGN=RIGHT,$ 
ENDSTYLE
END

Las imágenes aparecen en cada encabezado de página.

Pulse la imagen a la izquierda de la página 1 para mostrar la página 2.

Pulse la imagen "regresar" en la página 2 para volver a mostrar la página 1.

Para obtener información detallada acerca de cómo incluir y colocar imágenes en un informe, vaya a Cómo diseñar la página de informe.

Tenga en cuenta que si el procedimiento forma parte de una aplicación de autoservicio, debe emitirse el comando siguiente al principio del procedimiento:

SET BASEURL = ''
Ejemplo: Cómo enlazar páginas de informe mediante números y elementos de un encabezado

Esta solicitud crea hipervínculos desde el número de página a la próxima página en el informe y desde el texto del encabezado, que aparece en la parte superior de cada página de informe, a la página anterior o a la primera página. 

TABLE FILE GGORDER
ON TABLE SUBHEAD
"COFFEE GRINDER SALES BY STORE"
" "
HEADING
"return to previous page"
"return to beginning"
PRINT QUANTITY AS 'Ordered Units' BY STORE_CODE BY PRODUCT NOPRINT
BY ORDER_NUMBER
WHERE PRODUCT EQ 'Coffee Grinder'
ON STORE_CODE PAGE-BREAK
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TABHEADING, STYLE=BOLD,$
TYPE=PAGENUM, URL=#_next, $ 
TYPE=HEADING, LINE=1, URL=#_previous, $
TYPE=HEADING, LINE=2, URL=#_start, $
ENDSTYLE
END

La primera página tiene este aspecto:

Pulse tres veces en el número de página para ir a PAGE 4.

Pulse página anterior para regresar a PAGE 3. Pulse volver al principio para ir directamente a PAGE 1.

Tenga en cuenta que si el procedimiento forma parte de una aplicación de autoservicio, debe emitirse el comando siguiente al principio del procedimiento:

SET BASEURL = ''

WebFOCUS