x

Atributo	Descripción	Funciona en
POSITION	Establece la posición inicial absoluta o relativa de una columna. Una posición absoluta es la distancia a partir del margen izquierdo de la página impresa. Una posición relativa es la distancia a partir de la posición predeterminada. Después de la primera columna, la posición predeterminada es el final de la columna anterior.	PDF PS
TOPGAP BOTTOMGAP	Añade un espacio en blanco al principio o final de una línea de informe.	PDF PS
LEFTGAP RIGHTGAP	Añade un espacio en blanco a la izquierda o a la derecha de una columna de informe.	PDF PS

x

Esta sintaxis se aplica a un informe PDF o PS.

TYPE=REPORT, COLUMN=identifier, POSITION={+|-}position, $

donde:

identifier

Selecciona una columna y coloca conjuntamente el título de columna, datos y totales, si los hubiera. Para obtener información sobre valores válidos, vaya a Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

+

Inicia la columna a la distancia especificada hacia la derecha de la posición inicial predeterminada.

De forma predeterminada, el texto y los campos alfanuméricos se justifican a la izquierda en una columna, mientras que los campos numéricos se justifican a la derecha.

-

Inicia la columna a la distancia especificada hacia la izquierda de la posición inicia predeterminada.

Es posible crear un informe con columnas que se solapan. En tal caso, sólo tiene que ajustar los valores.

position

Es la distancia deseada, expresada en la unidad de medida especificada con el atributo UNITS.

Principio de página

Ejemplo: Cómo especificar una posición inicial absoluta para una columna

A continuación se muestra cómo posicionar una columna en un informe impreso. Se especifica en la solicitud que el campo PRODUCT_DESCRIPTION aparezca tres pulgadas a partir del margen izquierdo del informe PDF.

SET ONLINE-FMT = PDF 
TABLE FILE GGORDER
"PRODUCTS ORDERED ON 08/01/96"
SUM QUANTITY BY PRODUCT_DESCRIPTION
WHERE ORDER_DATE EQ '080196'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, COLUMN=PRODUCT_DESCRIPTION, POSITION=3, $ 
ENDSTYLE
END

La salida es:

Principio de página

Ejemplo: Cómo especificar una posición inicial relativa para una columna

Esta solicitud posiciona el título y los datos de la columna para el campo QUANTITY dos pulgadas a partir de la posición predeterminada; en este caso, dos pulgadas a partir del final de la columna anterior.

SET ONLINE-FMT = PDF 
TABLE FILE GGORDER
"PRODUCTS ORDERED ON 08/01/96"
SUM QUANTITY BY PRODUCT_DESCRIPTION
WHERE ORDER_DATE EQ '080196'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=PRODUCT_DESCRIPTION, POSITION=3, $ 
TYPE=REPORT, COLUMN=QUANTITY, POSITION=+2, $ 
ENDSTYLE
END

QUANTITY, titulada Unidades pedidas en el informe, está posicionada relativamente en cuanto a Producto:

x

Esta sintaxis se aplica a un informe PDF o PS.

TYPE=REPORT, {TOPGAP|BOTTOMGAP}=gap, $
TYPE=type, [COLUMN=identifier,|ACROSSCOLUMN=acrosscolumn,]
 {LEFTGAP|RIGHTGAP}=gap, $

TYPE=type, [COLUMN=identifier,|ACROSSCOLUMN=acrosscolumn,]
 {LEFTGAP|RIGHTGAP}=gap, $

donde:

TOPGAP

Indica cuánto espacio añadir encima de la línea de informe.

BOTTOMGAP

Indica cuánto espacio añadir debajo de la línea de informe.

gap

Es la cantidad de espacio en blanco, expresada en la unidad de medida especificada con el atributo UNITS.

Cuando no hay cuadrículas o color de fondo, el valor predeterminado es 0. El valor predeterminado para RIGHTGAP es proporcional al tamaño de la tipografía del texto.

Cuando hay cuadrículas o colores de fondo, el valor predeterminado se incrementa para proveer espacio entre la cuadrícula y el texto o para ampliar el color más allá del texto.

Los espacios deben ser iguales en una misma columna o fila. Es decir, no puede especificar espacios diferentes para el lado izquierdo o el derecho que correspondan a celdas individuales en la misma columna, como tampoco espacios diferentes encima o debajo de celdas individuales en la misma fila.

type

Identifica el componente de informe. Para obtener información sobre valores válidos, vaya a Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

identifier

Selecciona una o más columnas mediante el atributo COLUMN descrito en Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

acrosscolumn

Selecciona la misma columna en cada ocurrencia de un campo de clasificación ACROSS usando el atributo ACROSSCOLUMN descrito en Cómo identificar un componente de informe en una hoja de estilo de WebFOCUS.

LEFTGAP

Indica cuánto espacio añadir a la izquierda de una columna de informe.

RIGHTGAP

Indica cuánto espacio añadir a la derecha de una columna de informe.

Nota: Para TOPGAP, BOTTOMGAP, LEFTGAP, y RIGHT GAP, debe especificar un valor de al menos 0.013889 (que expresa el tamaño decimal de un punto en pulgadas). Si especifica un valor inferior a éste, WebFOCUS lo, redondea a la baja hasta el punto más cercano, el cero.

Principio de página

Ejemplo: Añadir un espacio en blanco encima de valores de datos

Esta solicitud produce una décima de pulgada de espacio en blanco encima de cada valor de datos en un informe PDF.

SET ONLINE-FMT = PDF 
SET PAGE-NUM = OFF
TABLE FILE GGORDER
"PRODUCTS ORDERED ON 08/01/96"
" "
SUM QUANTITY BY PRODUCT_DESCRIPTION
WHERE ORDER_DATE EQ '080196'
ON TABLE SET STYLE * 
TYPE=DATA, TOPGAP = 0.1, $ 
ENDSTYLE
END

Los datos aparecen espaciados, para mejor legibilidad.

Principio de página

Ejemplo: Añadir un espacio en blanco a la izquierda de una columna

A continuación se muestra cómo añadir un espacio en blanco a la izquierda de valores de datos. En este ejemplo se insertan 1.5 pulgadas de espacio en blanco a la izquierda de la columna Product Category.

SET ONLINE-FMT=PDF
TABLE FILE CENTORD
HEADING CENTER
"Summary Report for Digital Products"
" "
SUM    LINE_COGS/D12       AS 'Cost of Goods Sold'
BY     PRODTYPE            AS 'Product Type'
BY     PRODCAT             AS 'Product Category'
WHERE PRODTYPE EQ 'Digital';
ON TABLE COLUMN-TOTAL/D12
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE * 
TYPE=REPORT, COLUMN=PRODCAT, LEFTGAP=1.5, $ 
ENDSTYLE
END

La salida es: