BAR [AS 'character'] OVER

Hierbei gilt:

character

Ist entweder ein Bindestrich (-) oder ein Gleichheitszeichen (=). Setzen Sie das Zeichen in einfache Anführungszeichen. Das Default-Zeichen ist der Bindestrich (-).

In diesem Beispiel wird der Default-Unterstrich (_) verwendet:

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'       OVER
1020 AS 'DEMAND DEPOSITS'    OVER
1030 AS 'TIME DEPOSITS'      OVER 
BAR                          OVER 
RECAP TOTCASH = R1 + R2 + R3;
END

Die Ausgabe wird wie folgt angezeigt.

                 AMOUNT
                 ------
CASH ON HAND      8,784
DEMAND DEPOSITS   4,494
TIME DEPOSITS     7,961
                 ------
TOTCASH          21,239

Beachten Sie, dass die BAR ... OVER-Phrase nur die Spalte unterstreicht, die das Anzeigefeld enthält.

Nehmen Sie die folgende Syntax in die FML-Anfrage anstelle des Tag-Werts auf.

PAGE-BREAK OVER

In diesem Beispiel wird ein Seitenumbruch nach den ersten beiden RECAP-Befehlen eingefügt, um jede Berechnung hervorzuheben.

TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'                                    OVER
1020 AS 'DEMAND DEPOSITS'                                 OVER
1030 AS 'TIME DEPOSITS'                                   OVER
BAR                                                       OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH'             OVER 
PAGE-BREAK                                                OVER 
1100 AS 'ACCOUNTS RECEIVABLE' LABEL RECEIVE               OVER
1200 AS 'INVENTORY'  LABEL INVENT                         OVER
BAR                                                       OVER
RECAP TOTASSET = RECEIVE + INVENT; AS 'TOTAL ASSETS'      OVER 
PAGE-BREAK                                                OVER 
RECAP TOTAL = TOTCASH + TOTASSET;
END

Die Ausgabe wird wie folgt angezeigt.

TYPE=type, [COLUMN=column] [LABEL={Rn|label}], format_def, $

Hierbei gilt:

type

Indentifiziert die Komponente, die Sie formatieren möchten. Gültige Werte sind:

REPORT kennzeichnet eine Zeile mit dem angegebenen Label.

DATA kennzeichnet eine Zeile mit dem angegeben Label, das vom Benutzer angegebene Daten enthält.

FREETEXT kennzeichnet eine Freitext- oder eine Leerzeile mit dem angegebenen Label.

UNDERLINE kennzeichnet Unterstriche, die von BAR erzeugt wurden. Das Formatieren eines Unterstrichs wird für PDF- und PS-Reports unterstützt, aber nicht für HTML-Reports.

column

Identifiziert eine bestimmte Spalte. Sie können die Spalte über ihren Namen oder ihre Position in einer Zeile identifizieren.

LABEL

Ist der steuernde Faktor beim Identifizieren und Formatieren einer FML-Zeile.

Bitte beachten Sie, dass das Label verwendet wird, um eine Zeile zum Berechnen oder Formatieren zu identifizieren. Das Label für eine TAG- oder DATA-Zeile wird nie in der Reportausgabe angezeigt. Sie wird lediglich verwendet, um Zeilen innerhalb des FML-Codes zu identifizieren. Bei RECAP-Zeilen dient der Name des berechneten Werts als Label. Sie wird im Report angezeigt, falls kein anderer Titel angegeben wird.

Label ist ein explizites Zeilenlabel, das Sie zuweisen können, um eine Zeile deutlicher zu identifizieren.

format_def

Ist die Formatierungsdefinition, wie z. B. FONT, SIZE, STYLE und COLOR. Siehe Einen FML-Report formatieren.

Hinweis: Um eine Zelle zu formatieren, identifizieren Sie die Zelle als Schnittstelle einer Spalte und einer Zeile über COLUMN= ... plus LABEL= ... in derselben StyleSheet-Deklaration.

Im Folgenden wird beschrieben, wie Sie eine ganze FML-Zeile, die aus dem Zeilenlabel und den Zeilendaten besteht, identifizieren. Das LABEL-Attribut im StyleSheet identifiziert die drei TAG-Zeilen, die hier kursiv formatiert sind.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND' LABEL COH OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD OVER
1030 AS 'TIME DEPOSITS' LABEL TD OVER
BAR OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = COH, STYLE = ITALIC, $ 
TYPE = REPORT, LABEL = DD,  STYLE = ITALIC, $ 
TYPE = REPORT, LABEL = TD,  STYLE = ITALIC, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

Diese Anfrage wendet Fettdruck auf den angepassten Zeilentitel CASH und auf die zugehörigen Daten in der AMOUNT-Spalte an. Das StyleSheet verwendet das explizite Label CA, um die zu formatierende Komponente zu identifizieren.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
10$$ AS 'CASH'                LABEL CA   OVER
1100 AS 'ACCOUNTS RECEIVABLE' LABEL AR   OVER
1200 AS 'INVENTORY'           LABEL INV  OVER
RECAP CURASST/I5C = CA + AR + INV;
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = CA, STYLE = BOLD, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

Diese Anfrage erstellt einen Report, in dem der Datenwert für AMOUNT in der Zeile CASH fettgedruckt ist. Der Zeilentitel CASH ist jedoch nicht fettgedruckt. Dies wird dadurch erreicht, dass die Zellen in der StyleSheet-Deklaration genau angegeben werden. In diesem Fall ist es die Spalte (N) in der Zeile (CA).

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
10$$ AS 'CASH'                LABEL CA   OVER
1100 AS 'ACCOUNTS RECEIVABLE' LABEL AR   OVER
1200 AS 'INVENTORY'           LABEL INV  OVER
RECAP CURASST/I5C = CA + AR + INV;
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, COLUMN = N2, LABEL = CA, STYLE = BOLD, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

Diese Anfrage identifiziert die Spalte AMOUNT über ihren Namen und formatiert ihren Titel und ihre Daten mit Fettdruck. Dasselbe wird erreicht, wenn die Spalte als N2 identifiziert wird.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
"---CASH ACCOUNTS---"                   OVER
1010 AS 'CASH ON HAND'                  OVER
1020 AS 'DEMAND DEPOSITS'               OVER
1030 AS 'TIME DEPOSITS'                 OVER
" "                                     OVER
"---OTHER CURRENT ASSETS---"            OVER
1100 AS 'ACCOUNTS RECEIVABLE'           OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, COLUMN = AMOUNT, STYLE = BOLD, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

In dieser Anfrage wird Freitext mit Fettdruck formatiert. Da in diesem Beispiel dasselbe Styling für beide Freitextzeilen gilt, ist es nicht nötig, dass Labels zwischen ihnen unterscheiden.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
"---CASH ACCOUNTS---"  LABEL CA         OVER
1010 AS 'CASH ON HAND'                  OVER
1020 AS 'DEMAND DEPOSITS'               OVER
1030 AS 'TIME DEPOSITS'                 OVER
" "                                     OVER
"---OTHER CURRENT ASSETS---"  LABEL OCA OVER
1100 AS 'ACCOUNTS RECEIVABLE'           OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = FREETEXT, STYLE = BOLD, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

Diese Anfrage verwendet das SIZE-Attribut, um zwischen zwei Freitextzeilen zu unterscheiden: CASH ACCOUNTS und OTHER CURRENT ASSETS. Die Labels CA und OCA werden eingesetzt, um die Zeilen separat zu identifizieren und zu formatieren.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT 
" --- CASH ACCOUNTS ---" LABEL CA            OVER 
1010 AS 'CASH ON HAND'                       OVER
1020 AS 'DEMAND DEPOSITS'                    OVER
1030 AS 'TIME DEPOSITS'                      OVER
" "                                          OVER 
" --- OTHER CURRENT ASSETS ---" LABEL OCA    OVER 
1100 AS 'ACCOUNTS RECEIVABLE'                OVER
1200 AS 'INVENTORY'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = FREETEXT, LABEL = CA, STYLE = BOLD, SIZE = 12, $ 
TYPE = FREETEXT, LABEL = OCA, STYLE = BOLD, SIZE = 10, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

In diesem Beispiel werden die Text- und die Variablenkomponente der Freitextzeile separat formatiert. Der Text "Aktuelles Vermögen" ist kursiv und der Wert, der aus der RECAP-Berechnung abgeleitet wird, ist fettgedruckt.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT AS 'Amount' FOR ACCOUNT
10$$ AS 'Cash'                   LABEL CA    OVER
1100 AS 'Accounts Receivable'    LABEL AR    OVER
1200 AS 'Inventory'              LABEL INV   OVER
RECAP CURASST/I5C = CA + AR + INV; NOPRINT  OVER
"Current Assets: <CURASST"
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID=OFF, $ 
TYPE = FREETEXT, OBJECT = TEXT, ITEM = 1, SIZE = 12, STYLE = ITALIC, $ 
TYPE = FREETEXT, OBJECT = FIELD, ITEM = 1, STYLE = BOLD, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

Diese Anfrage wendet Fettdruck auf den Zeilentitel und auf den berechneten Wert in einer RECAP-Zeile an. Beachten Sie, dass das RECAP-Label im StyleSheet TOTCASH ist. In einem RECAP dient der Name, der dem berechneten Wert zugewiesen wird, auch als explizites Label.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH'
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = TOTCASH, STYLE = BOLD, $ 
TYPE = REPORT, LABEL = CASH, COLUMN = N1, STYLE = ITALIC, $
TYPE = REPORT, LABEL = DD, COLUMN = N1, STYLE = ITALIC, $
TYPE = REPORT, LABEL = TD, COLUMN = N1, STYLE = ITALIC, $
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

Um einen einheitlichen Rand um eine Zeile oder Zelle zu erhalten, verwenden Sie die folgende Syntax:

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER=option,
[BORDER-STYLE=line_style,] [BORDER-COLOR={color|RGB® g b)},] $

Um unterschiedliche Eigenschaften für obere, untere, linke und/oder rechte Ränder anzugeben, verwenden Sie die folgende Syntax

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER-position=option,
[BORDER-[position-]STYLE=line_style,]
[BORDER-[position-]COLOR={color|RGB(r g b)},] $

Um unterschiedliche Eigenschaften für obere, untere, linke und/oder rechte Ränder anzugeben, verwenden Sie die folgende Syntax

TYPE=REPORT, LABEL=row_label, [COLUMN=column,] BORDER-position=option,
[BORDER-[position-]STYLE=line_style,]
[BORDER-[position-]COLOR={color|RGB(r g b)},] $

Hierbei gilt:

row_label

Ist die Zeile, auf die die angegebenen Randcharakteristika angewendet werden sollen.

column

Wird zusammen mit dem Zeilenlabel verwendet. Bestimmt eine Zelle (am Schnittpunkt der Zeile und der Spalte), auf die die angegebenen Randcharakteristika angewendet werden.

option

Kann einer der folgenden Werte sein:

ON aktiviert Ränder für die gesamte Kopf- oder Fußzeile. ON erzeugt dieselbe Linie wie MEDIUM.

OFF deaktiviert Ränder für die gesamte Kopf- oder Fußzeile. OFF ist der Defaultwert.

LIGHT stellt eine dünne Linie ein. Sie können eine dünne Linie für die gesamte Kopf- oder Fußzeile angeben oder für eine oder mehrere Randpositionen.

MEDIUM gibt eine mitteldicke Linie an (ON stellt die Linie auf MEDIUM ein). Sie können eine dünne Linie für die gesamte Kopf- oder Fußzeile angeben oder für eine oder mehrere Randpositionen. Beachten Sie, dass die Einstellung mitteldicke Linie Einheitlichkeit mit Linien, die mit dem GRID-Attribut erstellt wurden, sicherstellt.

HEAVY stellt eine dicke Linie ein. Sie können eine dicke Linie für die gesamte Kopf- oder Fußzeile angeben oder für eine oder mehrere Randpositionen.

Breite gibt die Linienbreite in Punkten an (wobei 72 Punkte gleich 1 Zoll sind). Sie können eine Linienbreite in Punkten für die gesamte Kopf- oder Fußzeile angeben oder für eine oder mehrere Randpositionen. Linienbreite, die in Punkten angegeben wird, wird in der HTML-Ausgabe anders als in der PDF-Ausgabe angezeigt. Verwenden Sie LIGHT, MEDIUM oder HEAVY, wenn Sie sicherstellen möchten, dass die Linien in allen Anzeigeformaten gleich aussehen.

position

Gibt an, welcher Rand formatiert werden soll. TOP, BOTTOM, LEFT, RIGHT sind gültige Werte.

Sie können einen Positionskennzeichner für ein beliebiges BORDER-Schüsselwort angeben. Sie können so die Linienbreite, die Linienformatierung und die Linienfarbe für den oberen, unteren, rechten und linken Rand einzeln formatieren.

line_style

Stellt die Formatierung für den Rand ein. WebFOCUS-StyleSheets unterstützen alle standardmäßigen Cascading StyleSheet-Linienstylings. Einige dreidimensionale Stylings stehen Ihnen nur in HTML zur Verfügung. Sie sind mit einem Sternchen gekennzeichnet. Gültige Werte sind:

NONE
SOLID
DOTTED
DASHED
DOUBLE*
GROOVE*
RIDGE*
INSET*
OUTSET*

Farbe

Ist einer der voreingestellten Farbwerte. Der Defaultwert ist BLACK (schwarz).

Falls die Anzeige oder das Ausgabegerät keine Farben unterstützt, werden stattdessen Grautöne verwendet.

RGB

Gibt die Schriftfarbe als eine Mischung aus rot, grün und blau an.

(r g b)

Ist die gewünschte Farbstärke von rot, grün bzw. blau. Die Werte gehen auf einer Skala von 0 bis 255, wobei 0 am schwächsten und 255 am stärksten ist. Wenn die drei Farbkomponenten in gleicher Stärke verwendet werden, werden Grautöne angezeigt.

Hinweis: Bei HTML-Reports muss Cascading StyleSheets auf ON gestellt sein, damit Sie die BORDERS-Funktion verwenden können. Dieser Code ist bei PDF- und PS-Reports nicht erforderlich.

In diesem Beispiel wird eine mitteldicke gestrichelte Linie um die RECAP-Zeile platziert, die über das Label TOTCASH identifiziert wird. Bei HTML-Reports muss Cascading StyleSheets auf ON gestellt sein, damit Sie die BORDERS-Funktion verwenden können.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $ 
TYPE = REPORT, LABEL = TOTCASH, BORDER = MEDIUM, 
  BORDER-STYLE = DASHED, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

In diesem Beispiel wird eine dicke schwarze Randlinie über und unter der RECAP-Zeile, die über das Label TOTCASH identifiziert wird, platziert, und eine dünne gepunktete silberne Linie rechts und links von jeder Spalte in der Zeile.

Bei HTML-Reports muss Cascading StyleSheets auf ON gestellt sein, damit Sie die BORDERS-Funktion verwenden können.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF,$ 
TYPE = REPORT, LABEL = TOTCASH, 
     BORDER-TOP = HEAVY, 
     BORDER-BOTTOM = HEAVY, 
     BORDER-LEFT = LIGHT, 
     BORDER-RIGHT = LIGHT, 
     BORDER-TOP-STYLE = SOLID, 
     BORDER-BOTTOM-STYLE = SOLID, 
     BORDER-LEFT-STYLE = DOTTED, 
     BORDER-RIGHT-STYLE = DOTTED, 
     BORDER-LEFT-COLOR = 'SILVER', 
     BORDER-RIGHT-COLOR = 'SILVER', $
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

In diesem Beispiel wird ein mitteldicker Rand um die Zelle in der zweiten Spalte der Zeile, die über das Label TOTCASH identifiziert wird, platziert. Die kombinierten LABEL- und COLUMN-Spezifikationen sind in der Zelle identifiziert. Cascading StyleSheets muss auf ON gestellt sein, damit die BORDERS-Funktion verwendet werden kann.

SET PAGE-NUM=OFF
TABLE FILE LEDGER
SUM AMOUNT FOR ACCOUNT
1010 AS 'CASH ON HAND'    LABEL CASH    OVER
1020 AS 'DEMAND DEPOSITS' LABEL DD      OVER
1030 AS 'TIME DEPOSITS'   LABEL TD      OVER
RECAP TOTCASH = R1 + R2 + R3; AS 'TOTAL CASH' 
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON 
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF,$ 
TYPE = REPORT, LABEL = TOTCASH, COLUMN = N2, BORDER = MEDIUM, $ 
ENDSTYLE
END

Die Ausgabe wird im folgenden Bild illustriert.

FOR forfield [IN k]
tag [[GET CHILDREN|WITH CHILDREN] n] INDENT m [AS ['text'|CAPTION]] 
[OVER]

oder

RECAP fieldname[/format]=expression; INDENT m [AS 'text']

Hierbei gilt:

forfield

Ist ein Feld in der Datenquelle, dessen Werte im Report enthalten sind.

k

Ist die Anfangsspalte für den FOR-Wert in einem FML-Report.

tag

Ist ein Wert von forfield, der in einer Zeile im FML-Report angezeigt werden soll.

n

Ist die Anzahl der Ebenen einer FML-Hierarchie, die im FML-Report angezeigt werden sollen.

m

Ist eine positive ganze Zahl (Null wird nicht unterstützt), die die Anzahl der Leerstellen angibt, um die der Tag-Wert, das Label oder die Beschriftung einer FML-Zeile oder einer FML-Hierarchie eingerückt werden soll. Der Einzug beginnt in der ersten Spalte, falls keine IN-Phrase im FOR-Befehl angegeben wurde. Wenn eine IN-Phrase vorhanden ist, beginnt der Einzug in der Spalte, die in der IN-Phrase angeben ist. Der maximale Einzug ist die maximale Länge eines AS-Namens.

Wenn Sie eine FML-Hierarchie einrücken, wird die übergeordnete Zeile in der Hierarchie um die Anzahl der für das Einrücken angegebenen Leerstellen eingerückt. Die Hierarchieebenen werden um je zwei Leerstellen eingerückt. Falls die GET CHILDREN-Phrase verwendet wird, wird die erste Zeile der Hierarchie um zwei zusätzliche Leerstellen eingerückt, da die Hierarchieausgabe nicht mit dem übergeordneten Element sondern mit dem ersten untergeordneten Element beginnt. Weitere Informationen über die Verwendung von GET CHILDREN finden Sie unter Eine FML-Hierarchie anzeigen.

'Text'

Ist ein Label, das in einer Zeile des FML-Reports angezeigt werden soll.

CAPTION

Gibt an, dass ein Beschriftungsfeld in der Masterdatei definiert wurde.

OVER

Gibt an, dass dies nicht die letzte anzuzeigende Zeile ist.

fieldname

Ist ein Name, den Sie dem vom RECAP-Befehl berechneten Wert zuweisen.

Format

Ist das USAGE-Format für das RECAP-Feld. Es darf die Spaltenbreite nicht überschreiten. Der Default ist das Format der Spalte, in welcher der berechnete Wert angezeigt wird.

expression

Ist die Formel, die beschreibt, wie der Feldwert für RECAP berechnet wird.

In der folgenden Anfrage wird das Label der zweiten Zeile des Tag-Werts 3000 um fünf Leerstellen eingerückt. Da die GET CHILDREN-Phrase verwendet wurde, wird die erste Zeile der FML-Hierarchie in der dritten Zeile für den Tag-Wert 3000 um sieben Leerstellen (fünf + zwei) eingerückt.

SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                           AS 'Not Indented'        OVER
3000                 INDENT 5  AS 'Indented 5'          OVER
3000 GET  CHILDREN 2 INDENT 5  AS 'Hierarchy Indented 5'
END

Die Ausgabe wird wie folgt angezeigt.

                               Parent
                               ------
Not Indented                   3000
     Indented 5                3000
       Hierarchy Indented 5    3000
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3100
         Hierarchy Indented 5  3000
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200
         Hierarchy Indented 5  3200

Die folgende Anfrage summiert den Preis, die Kosten und die verbleibenden Stückzahlen für digitale und analoge Produkttypen. Der erste RECAP-Befehl berechnet die Summe für jede Spalte und rückt das Label um 5 Leerstellen ein. Der zweite RECAP-Befehl berechnet den Gewinn und rückt das Label um 10 Leerstellen ein.

SET FORMULTIPLE=ON
TABLE FILE CENTINV
SUM PRICE COST QTY_IN_STOCK
FOR PRODTYPE
Digital                                          OVER
Analog                                           OVER
BAR                                              OVER
RECAP TOTAL = R1 + R2; INDENT 5  AS 'Total:'     OVER
BAR                                              OVER
RECAP PROFIT(2) = TOTAL(1) - TOTAL(2); AS 'Profit:' INDENT 10
END

Die Ausgabe wird wie folgt angezeigt.

                                        Our    Quantity 
                         Price:         Cost:  In Stock:
                         ------         -----  ---------
Digital                4,080.00      3,052.00     119143
Analog                 1,883.00      1,371.00     139345
                   ------------  ------------    -------
     Total:            5,963.00      4,423.00     258488
                   ------------  ------------    -------
          Profit:                    1,540.00

Um die Verhältnisse innerhalb einer FML-Hierarchie zu klären, werden die Beschriftungen (Titel) der Werte auf jeder Ebene eingerückt. Verwenden Sie den BLANKINDENT-Parameter in HTML-, PDF- oder PostScript-Reports, um den Einzug zwischen den Ebenen der Hierarchie anzugeben. Sie können den Default-Einzug für jede Hierarchieebene verwenden oder selbst einen Einzugswert auswählen. Um eingerückte Beschreibungen in einem HTML-Report zu drucken, müssen Sie den BLANKINDENT-Parameter auf ON oder auf eine Nummer einstellen.

SET BLANKINDENT verbreitert die eingerückte Spalte nicht, wenn sie nicht breit genug ist, um die eingerückten Felder aufzunehmen. Dies ist möglich in HTML-Reports, kann aber in PDF- oder PostScript-Reports dazu führen, dass Daten in den Spalten, die der eingerückten Spalte folgen, nicht richtig ausgerichtet sind. Sie müssen ggf. StyleSheet-Syntax verwenden, um die Spalte für eingerückte Werte ausreichend zu verbreitern, oder um die Spalten, die ihr folgen, zu verschieben. Ändern Sie die Breite der Spalte mit dem StyleSheet-SQUEEZE-Attribut und geben Sie eine Anfangsposition für eine Spalte mit dem POSITION-Attribut an. Sie können eine Spalte in einem PostScript-Report auch mit der IN-Phrase verschieben.

Mit einer zugehörigen Funktion können Sie die Anzahl der Leerstellen vor der übergeordneten Zeile einer Hierarchie oder vor einem FML-Tag oder einer RECAP-Zeile in einer FML-Anfrage ändern. Weitere Informationen finden Sie unter Einen FML-Report formatieren.

SET BLANKINDENT={ON|OFF|n}
ON TABLE SET BLANKINDENT {ON|OFF|n}

SET PAGE-NUM=NOPAGE
SET BLANKINDENT=ON
SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                  AS CAPTION      OVER
3000 GET  CHILDREN 2  AS CAPTION  
ON TABLE SET ONLINE-FMT HTML 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE = REPORT, GRID = OFF, $
ENDSTYLE
END

SET PAGE-NUM=NOPAGE
SET BLANKINDENT=.25
SET FORMULTIPLE=ON
TABLE FILE CENTGL
PRINT GL_ACCOUNT_PARENT
FOR GL_ACCOUNT
3000                 AS CAPTION          OVER
3000 GET  CHILDREN 2 AS CAPTIONON TABLE SET STYLE *
TYPE = REPORT, GRID = OFF, $
ENDSTYLE
END