Wenn sich die Tags nicht in den Daten selbst befinden, erstellen Sie ein Feld, das den Text enthält, der hochgestellt werden soll. Aktivieren Sie außerdem Markup-Tags für die Komponenten, für die hochgestellter Text angezeigt wird:
- Definieren Sie in einem DEFINE- oder COMPUTE-Befehl ein Feld, das den Text enthält, der hochgestellt werden soll.
Für einen DEFINE FILE-Befehl lautet die Syntax:
DEFINE FILE ... field/An = <sup>text</sup>; END
Für einen COMPUTE-Befehl oder einen DEFINE in einer Masterdatei lautet die Syntax:
{COMPUTE|DEFINE} field/An = <sup>text</sup>;Hierbei gilt:
- n
Ist die Länge der Zeichenfolge, die den hochgestellten Text definiert, einschließlich des Textes, der hochgestellt werden soll, und den Start- und End-Markup-Tags (<sup> und </sup>).
- Text
Ist der Text, der als hochgestellter Text verwendet werden soll.
- Stellen Sie im StyleSheet MARKUP=ON für alle Reportkomponenten ein, die hochgestellten Text anzeigen:
TYPE=component,MARKUP=ON ... ,$Hierbei gilt:
- Komponente
Ist eine der folgenden Reportkomponenten: DATA, HEADING, FOOTING, SUBHEAD, SUBFOOT, TABHEADING, TABFOOTING.
Die folgende Anfrage mit der Datenquelle GGSALES definiert zwei Felder, die als hochgestellter Text angezeigt werden. SUP1 und SUP2 sind die Zahlen 1 und 2. SUPCOPY ist ein Copyright-Symbol. Beachten Sie, dass der Unterschied in der Syntax besteht, die für einen Textwert definiert ist, gegenüber einem HEX-Wert.
Der COMPUTE-Befehl vergleicht Absatz in Dollar mit eingeplanten Dollar. Wenn der berechnete Wert geringer ist als ein definiertes Minimum, wird der hochgestellte Text SUP1 nach dem Kategorienamen angehängt. Wenn der Wert größer ist, wird SUP2 angehängt.
Der hochgestellte Text SUPCOPY wird verwendet, um das Copyright-Symbol in der Fußzeile des Reports anzuzeigen.
Die Fußzeile verkettet die hochgestellten Felder vor ihren Erklärungen.
Im StyleSheet hat jede Komponente, die hochgestellten Text anzeigt, das Attribut MARKUP=ON.
DEFINE FILE GGSALES
SUP1/A12= '<SUP>1</SUP>';
SUP2/A15= '<SUP>2</SUP>';
SUPCOPY/A20= '<SUP>'||HEXBYT(169,'A2')||'</SUP>';
END
TABLE FILE GGSALES
SUM
COMPUTE PROFIT/D12CM=DOLLARS-BUDDOLLARS; NOPRINT
COMPUTE SHOWCAT/A100=IF PROFIT LE -50000 THEN CATEGORY || SUP1
ELSE IF PROFIT GT 50000 THEN CATEGORY || SUP2
ELSE CATEGORY; AS Category
BUDDOLLARS/D12CM
DOLLARS/D12CM
BY REGION
BY CATEGORY NOPRINT
HEADING
"Analysis of Budgeted and Actual Sales"
FOOTING
""
"<SUP1 Dollar sales $50,000 less than budgeted amount."
"<SUP2 Dollar sales $50,000 greater than budgeted amount."
""
"Copyright<SUPCOPY 2012, by Information Builders, Inc "
ON TABLE SET HTMLCSS ON
ON TABLE SET SQUEEZE ON
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
INCLUDE=ENDEFLT,$
TYPE=DATA,MARKUP=ON,$
TYPE=DATA,COLUMN=N5, COLOR=RED, WHEN=PROFIT LT -50000,$
TYPE=DATA,COLUMN=N6, COLOR=GREEN, WHEN=PROFIT GT 50000,$
TYPE=HEADING, JUSTIFY=LEFT,$
TYPE=FOOTING, MARKUP=ON, JUSTIFY=LEFT,$
TYPE=FOOTING, LINE=2,JUSTIFY=LEFT, COLOR=RED,$
TYPE=FOOTING, LINE=3,JUSTIFY=LEFT, COLOR=GREEN,$
ENDDie Ausgabe ist:
