Seitenzahlen einfügen

In diesem Abschnitt:

Vorgehensweise:

Referenz:

Per Default werden die ersten beiden Zeilen eines Reports reserviert. Die erste Zeile enthält die Seitenzahl in der oberen linken Ecke. Die zweite Zeile ist leer.

Sie können Folgendes tun:

Hinweis: Die Variablen TABPAGENO und TABLASTPAGE können nicht verwendet werden, um Styling mit bedingtem Styling (WHEN) zu definieren.

Wenn Sie Eingabehilfe nach Section 508 (Amerikanisches Arbeitsrecht) aktivieren, ist in der HTML-Tabelle keine Default-Seitenzahl enthalten.
Nach oben
x
Referenz: Seitenzahlbefehle

Befehl

Beschreibung

Anwendbar auf 

<BYLASTPAGE

Wird verwendet mit REPAGE. Fügt die Gesamtseitenanzahl innerhalb der Sortiergruppe ein, die die Option REPAGE hat.

HTML

PDF

PS

REPAGE

Stellt die Seitenzahl auf eins zurück.

HTML

PDF

PS

<TABPAGENO

Fügt die aktuelle Seitenzahl ein. TABPAGENO unterdrückt die Default-Seitenzahl und die ersten zwei Zeilen einer Seite sind leer.

HTML

PDF

PS

<TABLASTPAGE

Fügt die Gesamtseitenzahl in den Report ein.

HTML

PDF

PS

SET FOCFIRSTPAGE

Weist die festgelegte Seitenzahl der ersten Seite zu.

HTML

PDF

PS

SET PAGE-NUM

Steuert die Anzeige von Seitenzahlen.

HTML

PDF

PS
x
Syntax: Die aktuelle Seitenzahl einfügen

Um die aktuelle Seitenzahl hinzuzufügen, fügen Sie Ihrer Anfrage Folgendes hinzu. 

<TABPAGENO
Beispiel: Die aktuelle Seitenzahl in eine Sortierfußzeile einfügen

Diese Anfrage erzeugt immer dann eine neue Seite, wenn sich der Wert des Sortierfeldes REGION ändert. Es wird TABPAGENO verwendet, um eine Seitenzahl in eine Sortierfußzeile einzufügen. 

TABLE FILE GGSALES
SUM BUDDOLLARS
BY REGION BY ST BY CITY 
ON REGION PAGE-BREAK SUBFOOT
"Sales Quota for <REGION Cities"
"Page <TABPAGENO" 
ON TABLE SET ONLINE-FMT PDF
END

Die erste Seite der Ausgabe ist:
Nach oben
x
Die Gesamtseitenzahl einfügen

Vorgehensweise:

Referenz:

Sie können die Systemvariable <TABLASTPAGE verwenden, um die Gesamtseitenzahl in Ihren Report einzufügen. Wenn Sie z. B. eine Fußzeile "Seite 1 von 5" Ihrem Report hinzufügen möchten, können Sie die <TABLASTPAGE-Systemvariable zusammen mit der <TABPAGENO-Systemvariable verwenden, um dies durchzuführen.

x
Syntax: Die Gesamtseitenzahl einfügen

Fügen Sie, um die Gesamtseitenanzahl einzufügen, Ihrer Anfrage Folgendes hinzu: 

<TABLASTPAGE
x
Referenz: Verwendungshinweise für TABLASTPAGE
Beispiel: Die aktuelle Seitenzahl und die Gesamtseitenzahl einfügen

Im Folgenden wird beschrieben, wie Sie einem Report die aktuelle Seitenzahl und die Gesamtseitenzahl hinzufügen. Die relevante Syntax wird in der Anfrage markiert. 

TABLE FILE EMPLOYEE
PRINT EMP_ID AS 'Employee ID'
BY SALARY IN-GROUPS-OF 5000 AS 'Salary'
BY PCT_INC AS 'Percent,Increase'
BY DAT_INC AS 'Date of,Increase'
ON SALARY PAGE-BREAK
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
TYPE=TITLE, STYLE=BOLD, SIZE=11, $
ENDSTYLE
FOOTING 
"Page <TABPAGENO of <TABLASTPAGE" 
END

Die ersten zwei Seiten der Ausgabe sind:
Nach oben
x
Die Gesamtseitenzahl in einer Sortiergruppe anzeigen

Vorgehensweise:

Wenn die Variable <BYLASTPAGE in einer Kopf- oder Fußzeile verwendet wird, wird die Anzahl der Seiten in der Ausgabe innerhalb jeder Sortiergruppe angezeigt, wenn ein Report die Option REPAGE verwendet, um die Seitenzahlen für jede Sortiergruppe zurückzusetzen. Diese Variable kann nur mit Ausgabeformaten für Reports mit Styling verwendet werden.

Falls die REPAGE-Option in einem Report nicht verwendet wird, wird die Gesamtseitenanzahl im Report (<TABLASTPAGE-Variable) für <BYLASTPAGE verwendet.
x
Syntax: Die Gesamtseitenanzahl in jeder Sortiergruppe anzeigen

Die Anfrage muss die folgende Syntax haben und die Ausgabe in einem Ausgabeformat mit Styling speichern:

BY sortfield REPAGE

Die Kopf- oder Fußzeile kann die folgende Syntax verwenden, um “Seite x von y” anzuzeigen

{HEADING|FOOTING} 
"Page <TABPAGENO of <BYLASTPAGE"

Hierbei gilt:

sortfield

Ist das Sortierfeld mit der REPAGE-Option. Es ist in demselben Sortierfeld oder einem Sortierfeld einer unteren Ebene ein PAGE-BREAK erforderlich. PAGE-BREAK fängt für jeden Sortierumbruch eine neue Seite an. REPAGE stellt die Seitenzahl für jeden Sortierumbruch auf 1 ein.

<TABPAGENO

Ist die aktuelle Seitenzahl.

<BYLASTPAGE

Ist die letzte Seitenzahl vor Anfang der erneuten Nummerierung.

Beispiel: Seitenumbruch innerhalb einer Sortiergruppe

Die folgende Anfrage mit der GGSALES-Datenquelle sortiert nach Produkt, Region, Kategorie und Stadt. Sie setzt den Seitenumbruch jedes Mal zurück, wenn das Produkt geändert wird. Die Kopfzeile druckt die aktuelle Seitenzahl und die Summe innerhalb jeder Produktgruppe.

Beachten Sie, dass per Default die Variablen TABPAGENO und BYLASTPAGE das Format I5 haben, was vor den Seitenzahlen viel leeren Platz lässt. Sie können daher Platzmarkierungen verwenden oder COMPUTE-Befehle, um die Seitenzahlen nach links zu verschieben.

Im folgenden Beispiel erstellt ein COMPUTE-Befehl ein Feld namens X, das den Wert TABPAGENO hat, speichert es aber als ein I2-Feld, und die Platzmarkierung in der Kopfzeile verschiebt die Seitenzahl BYLASTPAGE um vier Stellen nach links. Der Kopfzeilenbefehl muss nach dem COMPUTE-Befehl kommen, da das Feld namens X sonst nicht erkannt wird:

TABLE FILE GGSALES                          
SUM UNITS                                   
COMPUTE X/I2 = TABPAGENO;
BY PRODUCT NOPRINT REPAGE        
BY REGION PAGE-BREAK                        
BY CATEGORY                                 
BY CITY                                     
HEADING CENTER  
"<PRODUCT : Page <X of <-4> <BYLASTPAGE "
ON TABLE PCHOLD FORMAT PDF           
END

Die folgende Teilausgabe zeigt, dass die Seitenzahl auf 1 zurückgesetzt wird, wenn sich das Produkt ändert, und dass die Variable BYLASTPAGE die Gesamtseitenanzahl für jedes Produkt anzeigt:
Nach oben
x
Der ersten Seite eine Seitenzahl zuweisen

Vorgehensweise:

Sie können der ersten Seite eines Reports eine Seitenzahl mit dem Parameter FOCFIRSTPAGE zuweisen. Dieses Feature ist hilfreich, wenn ein Report als Teil eines anderen Reports gedruckt und zusammengestellt wird.

Sie können auch die Seitennummerierung mehrerer Reports in derselben Prozedur mit dem Parameter FOCFIRSTPAGE mit der Variablen &FOCNEXTPAGE steuern.

Wenn TABPAGENO verwendet wird, wird FOCFIRSTPAGE ignoriert.
x
Syntax: Der ersten Seite eine Seitenzahl zuweisen

Für alle Reportanfragen in einer Prozedur 

SET FOCFIRSTPAGE = {n|1|&FOCNEXTPAGE}

Für eine Reportanfrage

ON TABLE SET FOCFIRSTPAGE {n|1|&FOCNEXTPAGE}

Hierbei gilt:

n

Ist eine ganze Zahl zwischen 1 und 999999, welche die Zahl ist, die der ersten Seite des Reports zugewiesen wurde.

1

Weist der ersten Seite die Zahl 1 zu. 1 ist der Defaultwert.

&FOCNEXTPAGE

Ist eine Variable, deren Wert eins höher ist als die letzte Seitenzahl des vorherigen Reports in einer Mehrfachanfrage. Der Wert wird bei der Ausführung berechnet.
Beispiel: Der ersten Seite eine Seitenzahl zuweisen

Diese Anfrage weist der ersten Seite des Reports die Zahl 3 zu. 

SET FOCFIRSTPAGE = 3 
TABLE FILE CENTORD
HEADING
"Sales By Store"
SUM LINEPRICE AS 'Sales'
BY SNAME
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Der Report ist:
Beispiel: Seitenzahlen in fortlaufenden Reports steuern

Diese Prozedur enthält zwei Reportanfragen. Die zweite Anfrage stellt FOCFIRSTPAGE auf den Wert von &FOCNEXTPAGE ein.

SET FOCFIRSTPAGE = 3
TABLE FILE CENTORD
HEADING
"Sales By Store"
SUM LINEPRICE AS 'Sales'
BY SNAME
WHERE SNAME EQ 'eMart'
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END
-RUN
SET FOCFIRSTPAGE = &FOCNEXTPAGE 
TABLE FILE CENTORD
HEADING
"Sales By Product"
SUM LINEPRICE AS 'Sales'
BY PRODCAT AS 'Product'
WHERE PRODCAT EQ 'VCRs'
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die erste Seite des zweiten Reports hat die Seitenzahl 4, was eins höher ist als die letzte Seite des vorherigen Reports:

Nach oben
x
Die Anzeige von Seitenzahlen steuern

Vorgehensweise:

Per Default werden die ersten beiden Zeilen eines Reports reserviert. Die erste Zeile zeigt die Seitenzahl in der oberen linken Ecke an. Die zweite Zeile ist leer. Verwenden Sie den Parameter PAGE-NUM, um die Defaultanzeige zu unterdrücken.

x
Syntax: Die Anzeige von Seitenzahlen steuern

Für alle Reportanfragen in einer Prozedur 

SET PAGE[-NUM] = num_display

Für eine Reportanfrage

ON TABLE SET PAGE[-NUM] num_display

Hierbei gilt:

-NUM

Ist optional. PAGE und PAGE-NUM sind synonym.

num_display

Ist eines des Folgenden:

ON zeigt Seitenzahlen in der oberen linken Ecke an, gefolgt von einer vorbehaltenen leeren Zeile. ON ist der Defaultwert.

OFF unterdrückt die Seitenzahlen.

Sie können die Systemvariable TABPAGENO verwenden.

Diese Einstellung gibt Seitenablehnungen aus.

NOPAGE unterdrückt Default-Seitenzahlen und stellt Ihnen die Benutzung der oberen zwei Zeilen auf der Reportseite zur Verfügung.

Sie können die Systemvariable TABPAGENO verwenden.

Diese Einstellung gibt keine Seitenablehnungen aus.

TOP entfernt die Zeile im oberen Bereich jeder Seite, die für die Seitenzahl reserviert ist, sowie die nachfolgende Leerzeile. Die erste Zeile eines Reports enthält die Report- oder Seitenkopfzeile falls angegeben, oder Spaltentitel, wenn es keine Kopfzeile gibt.

Sie können die Systemvariable TABPAGENO verwenden, um Seitenzahlen an einer anderen Stelle des Reports anzuzeigen.

Beispiel: Default-Seitenzahlen unterdrücken

Diese Anfrage verwendet SET PAGE-NUM = NOPAGE, um Default-Seitenzahlen zu unterdrücken. Sie verwendet die oberste Zeile des Reports für die Reportkopfzeile. 

SET PAGE-NUM = NOPAGE 
TABLE FILE GGPRODS
ON TABLE SUBHEAD
"PACKAGING INFORMATION"
" "
PRINT PACKAGE_TYPE AND SIZE AND UNIT_PRICE
BY PRODUCT_DESCRIPTION
ON PRODUCT_DESCRIPTION PAGE-BREAK SUBFOOT
"PRODUCT ID <PRODUCT_ID"
"Page <TABPAGENO "
ON TABLE SET ONLINE-FMT PDF
END

TABPAGENO fügt die Seitenzahl in die Sortierfußzeile ein. Dies ist die erste Seite des Reports:

WebFOCUS