Jede StyleSheet-Deklaration gibt eine Gruppe von Attributen folgendermaßen an

attribute = value, [attribute = value, ...] $

Hierbei gilt:

attribute

Ist das Attribut, dass Sie angeben, wie z. B. TYPE, COLUMN, COLOR oder FONT.

Wert

Ist der Wert, den Sie dem Attribut zuweisen.

Die folgende Anfrage enthält ein Inline-StyleSheet. Dieses StyleSheet fängt mit ON TABLE SET STYLE * an und endet mit ENDSTYLE.

TABLE FILE CENTORD
HEADING
" "
"C e n t u r y  C o r p o r a t i o n"
" "
"Order Revenue - 2000 Q3"
" "
"page <TABPAGENO"
" "
SUM ORDER_DATE/MtDY ORDER_NUM LINEPRICE AS 'Order,Total:'
BY LOWEST 9 ORDER_DATE NOPRINT
WHERE (ORDER_DATE GE '2000/10/01') AND (ORDER_DATE LE '2000/12/31');
ON TABLE SET ONLINE-FMT HTML
ON TABLE SET HTMLCSS ON
 
ON TABLE SET STYLESHEET *
TYPE=Report, GRID=Off, UNITS=Inches, $
TYPE=Data, FONT='Times', $
TYPE=Data, BACKCOLOR=Aqua, COLOR=Navy,
     WHEN=LinePrice GT 500000, $
TYPE=Data, COLUMN=LinePrice, BACKCOLOR=Aqua, COLOR=Navy, STYLE=Bold,
     WHEN=LinePrice GT 500000, $
TYPE=Title, FONT='Helvetica', $
TYPE=Heading, FONT='Helvetica', STYLE=Bold, SIZE=14, JUSTIFY=Center,
     COLOR=White, BACKCOLOR=Dark Turquoise, $
TYPE=Heading, LINE=6, BACKCOLOR=White, COLOR=Dark Turquoise, $
TYPE=Heading, LINE=7, BACKCOLOR=White, $
ENDSTYLE
 
END

Es gibt viele Möglichkeiten Ihr StyleSheet so zu strukturieren, dass es einfacher zu lesen ist. Sie können eine oder mehrere der folgenden Möglichkeiten verwenden:

• Beginnen Sie eine Deklaration in einer beliebigen Spalte mit Leerzeichen oder Tabulatoren.
• Fügen Sie zwischen Deklarationen Leerzeilen ein.
• Erstellen Sie Deklarationen mit Großbuchstaben, Kleinbuchstaben oder gemischt.
• Verwenden Sie mehr als eine Deklaration, um eine einzelne Reportkomponente zu formatieren.
• Fügen Sie Leerzeichen oder Tabulatoren zwischen dem Attribut, dem Gleichheitszeichen (=), dem Komma und dem Dollarzeichen ($) ein.
• Unterteilen Sie eine einzelne Deklaration, so dass sie über eine Zeile hinausgeht. Die Deklaration wird bis zum abschließenden Dollarzeichen weiter verarbeitet. Sie können eine Deklaration beispielsweise wie folgt unterteilen:

  TYPE=HEADING, FONT=ARIAL,
  SIZE=14, STYLE=BOLD, $

• Unterteilen Sie ein Attribut=Wert-Paar auf einer Zeile. Verwenden Sie den umgekehrten Schrägstrich (\) als weiterführende Syntax am Ende der ersten Zeile, falls Sie ein Attribut oder einen Wert in einer Deklaration auf einer Zeile trennen. Beispiel:

  TYPE=TITLE, COLUMN=N2, STY\
  LE=BOLD+ITALIC, COLOR=BLUE, $

Sie können einem StyleSheet Anmerkungen hinzufügen, um einer Deklaration Kontext zu geben. Anmerkungen wirken sich auf das Verhalten von StyleSheets nicht aus.

Sie können eine Anmerkung hinzufügen:

• In einer Deklarationszeile. Fügen Sie den gewünschten Text nach dem Dollarzeichen ($) hinzu. Beispiel,

  TYPE=HEADING, STYLE=BOLD, COLOR=BLUE, SIZE=14, $ Sample comment

• In einer separaten Zeile. Beginnen Sie die Zeile entweder mit einem Dollarzeichen ($) oder einem Bindestrich und einem Sternchen (-*), gefolgt vom gewünschten Text. Beispiel,

  -* This is a sample comment
  $ This is another sample comment

Hinweis: Sie können Anmerkungen nicht nur in StyleSheets, sondern überall in Ihrer Anfrage hinzufügen.

Sie können eine StyleSheet-Datei prüfen, um zu sehen, ob es Syntaxfehler gibt, indem Sie den CHECK STYLE-Befehl verwenden. CHECK STYLE überprüft die Rechtschreibung von Schriftartnamen nicht und verifiziert auch nicht die Verfügbarkeit spezifischer Schriftarten auf Ihrem System.

Sie können den CHECK STYLE-Befehl in der Befehlskonsole im Developer Studio ausgeben.

CHECK STYLE file