parameter=value

Hierbei gilt:

Parameter

Ist der Name der Variable in der verknüpften Prozedur.

Hinweis: Sie sollten, um Konflikten vorzubeugen, Variable vermeiden, die mit Date, IBI oder WF anfangen. Variablennamen, die mit diesen Werten anfangen, sind für die Verwendung durch Information Builders reserviert.

Wert

Identifiziert den Wert, der weitergereicht werden soll. Folgende Werte sind möglich:

'constant_value' bezeichnet einen tatsächlichen Wert, der weitergeleitet werden soll. Der Wert muss in einfachen Anführungszeichen eingeschlossen sein.

field bezeichnet das Feld im Report, dessen Wert an die Prozedur weitergeleitet werden soll. Sie können das Feld identifizieren, indem Sie entweder den Feldnamen oder die Feldposition verwenden. Genaueres über Feldpositionierung finden Sie unter Eine Reportkomponente in einem WebFOCUS StyleSheet identifizieren.

'&variable' bezeichnet eine Ampersandvariable, deren Wert an die Prozedur weitergeleitet werden muss. Der Name der Ampervariable muss in einfache Anführungszeichen gesetzt werden. Sie können Ampervariable nur in Inline-StyleSheets verwenden.

Hinweis: Normalerweise werden Ampersandvariablen verwendet, um Konstantwerte weiterzuleiten. Wenn die Ampervariable einem alphanumerischen Feld entspricht, muss die Ampervariable in einfache Anführungszeichen gesetzt werden, z. B.:

'&ABC'.

Es muss die gesamte Zeichenfolge mit den Parameternamen und Werten in Klammern gesetzt werden. Jedes parameter=value-Paar muss durch ein Leerzeichen getrennt werden. Ihre Anfrage kann mehrere Parameter enthalten, jedoch darf die gesamte Zeichenfolge höchstens 2400 Zeichen enthalten.

Hinweis: Wenn der Drilldown-Report eine -DEFAULTS-Anweisung enthält, die einen Defaultwert auf dieselbe Amper-Variable einstellt, die vom Hauptreport überreicht wurde, überschreibt der überreichte Variablenwert die -DEFAULTS-Anweisung in der Zielprozedur.

Im folgenden Beispiel ist zu sehen, wie Sie Parameter erstellen, indem Sie einen konstanten Wert angeben. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert.

Hauptreport

SET LOOKGRAPH BAR
SET 3D=OFF
GRAPH FILE SHORT
HEADING
"Sum of Balance Across Short Date"
"Click Any Bar For a Report on Projected Returns Since June 29, 1998 "
SUM BALANCE
ACROSS SHORT_DATE
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=N1,FOCEXEC=PROJRET(Short_Date='06291998'),$ 
ENDSTYLE
END

Drilldown-Report (PROJRET):

TABLE FILE SHORT
HEADING
"Projected Returns Since June 29, 1998 "
SUM PROJECTED_RETURN
BY SHORT_DATE
BY REGION
WHERE SHORT_DATE GE '&Short_Date';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Ausgabe für den Hauptreport ist:

Wenn Sie auf einen Balken klicken, ist die Ausgabe:

Projected Returns Since June 29, 1998

Date of

 Projected

Statement

Region

Annualized

Return

06/29/1998

CENTRAL AMERICA

     1.360

EASTERN EUROPE

     2.300

FAR EAST

     1.300

MIDDLE EAST

     1.140

NORTH AMERICA

     1.780

SOUTH AMERICA

     1.200

WESTERN EUROPE

     1.140

06/30/1998

CENTRAL AMERICA

     1.360

EASTERN EUROPE

     2.350

FAR EAST

     1.300

MIDDLE EAST

     1.140

NORTH AMERICA

     1.780

SOUTH AMERICA

     1.200

WESTERN EUROPE

     1.140

07/01/1998

CENTRAL AMERICA

     1.360

EASTERN EUROPE

     2.300

FAR EAST

     1.300

MIDDLE 
EAST

     1.140

NORTH AMERICA

     1.780

SOUTH AMERICA

     1.200

WESTERN EUROPE

     1.140

Im folgenden Beispiel ist zu sehen, wie Sie einen Parameter erstellen, indem Sie ein Feld angeben, in diesem Fall CATEGORY. Der SALES-Drilldown-Report (der Report, der mit dem Hauptreport verknüpft ist) stellt das CATEGORY-Feld gleich &TYPE ein. Im Grundreport ist TYPE gleich dem Feld CATEGORY eingestellt.

Wenn Sie den Report ausführen, werden die Werte für das Feld CATEGORY (Kaffee, Essen, Geschenke) mit einem Report verknüpft, die die Aufgliederungen nach Produkt und Region für den jeweiligen Wert enthalten.

Hauptreport

TABLE FILE GGSALES
SUM UNITS DOLLARS
BY CATEGORY
HEADING 
"* Click category to see product and regional breakdowns."
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $ 
TYPE=DATA, COLUMN=CATEGORY, FOCEXEC=SALES (TYPE=CATEGORY), $ 
ENDSTYLE
FOOTING
"This report was created on &DATE ."
END

Drilldown-Report (SALES):

TABLE FILE GGSALES
ON TABLE SET PAGE-NUM OFF
SUM UNITS DOLLARS
BY CATEGORY BY PRODUCT
ACROSS REGION
WHERE CATEGORY = '&TYPE';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Die Ausgabe für den Hauptreport ist:

Klicken Sie auf Kaffee und die Produkt- und Regionenaufteilung für Kaffee wird angezeigt:

Die folgende Anfrage verdeutlicht, wie Sie einen Parameter erstellen, indem Sie eine Ampervariable angeben. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert.

Hauptreport

SET3D=OFF
GRAPH FILE EMPLOYEE
HEADING
"Salary Report Per Employee ID"
"Click A Bar For The List of Employees in the '&DEPARTMENT' Department"
SUM SALARY
ACROSS EMP_ID AS 'EMPLOYEE ID'
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=SALARY,
FOCEXEC=EMPBYDEP(DEPARTMENT='&DEPARTMENT'), $ 
ENDSTYLE
END

Verknüpfter Report (EMPBYDEP):

TABLE FILE EMPLOYEE
HEADING
"List Of Employees in the '&DEPARTMENT' Department "
PRINT FIRST_NAME LAST_NAME
BY DEPARTMENT
WHERE DEPARTMENT EQ '&DEPARTMENT';
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Wenn die Hauptreport-Anfrage ausgeführt wird, wird die folgende Eingabeaufforderung geöffnet:

Geben Sie MIS ein, und klicken Sie auf Senden. Die Ausgabe ist:

Wenn Sie auf einen Balken im Diagramm klicken, ist die Ausgabe:

List Of Employees in the 'MIS' Department

DEPARTMENT

FIRST NAME

LAST NAME

MIS

MARY

  SMITH

DIANE

  JONES

JOHN

  MCCOY

ROSEMARIE

  BLACKWOOD

MARY

  GREENSPAN

BARBARA

  CROSS

Wenn mehrere Parameter verwendet werden, muss die gesamte Zeichenfolge in Klammern gesetzt werden und voneinander mit Leerzeichen getrennt werden. Die relevanten StyleSheet-Deklarationen sind in der Anfrage markiert.

Hauptreport

SET 3D=OFF
GRAPH FILE EMPLOYEE
SUM CURR_SAL
ACROSS DEPARTMENT
ON GRAPH SET STYLE * 
TYPE=DATA, ACROSSCOLUMN=CURR_SAL,
FOCEXEC=REPORT2 (DEPARTMENT='&DEPARTMENT' LAST_NAME='SMITH'), $ 
ENDSTYLE
END

Drilldown-Report (REPORT2):

TABLE FILE EMPLOYEE
PRINT SALARY
BY DEPARTMENT
BY FIRST_NAME
BY LAST_NAME
WHERE DEPARTMENT EQ '&DEPARTMENT'
WHERE LAST_NAME EQ '&LAST_NAME'
ON TABLE SET PAGE-NUM OFF
ON TABLE SET STYLE *
TYPE=REPORT, GRID=OFF, $
ENDSTYLE
END

Wenn die Hauptreport-Anfrage ausgeführt wird, wird die folgende Eingabeaufforderung geöffnet:

Geben Sie MIS ein, und klicken Sie auf Senden. Die Ausgabe ist:

Wenn Sie auf den MIS-Balken klicken, ist die Ausgabe:

DEPARTMENT

FIRST NAME

LAST NAME

SALARY

MIS

MARY

SMITH

$13,200.00